New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcstp.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/trcstp.F90 @ 10419

Last change on this file since 10419 was 10372, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: action 8: remove communications in TOP, see #2133

  • Property svn:keywords set to Id
File size: 11.1 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!----------------------------------------------------------------------
8#if defined key_top
9   !!----------------------------------------------------------------------
10   !!   trc_stp       : passive tracer system time-stepping
11   !!----------------------------------------------------------------------
12   USE oce_trc        ! ocean dynamics and active tracers variables
13   USE sbc_oce
14   USE trc
15   USE trctrp         ! passive tracers transport
16   USE trcsms         ! passive tracers sources and sinks
17   USE trcwri
18   USE trcrst
19   USE trcsub         !
20   USE trdtrc_oce
21   USE trdmxl_trc
22   USE sms_pisces,  ONLY : ln_check_mass
23   !
24   USE prtctl_trc     ! Print control for debbuging
25   USE iom            !
26   USE in_out_manager !
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   trc_stp    ! called by step
32
33   LOGICAL  ::   llnew                   ! ???
34   REAL(wp) ::   rdt_sampl               ! ???
35   INTEGER  ::   nb_rec_per_day, ktdcy   ! ???
36   REAL(wp) ::   rsecfst, rseclast       ! ???
37   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr   ! save qsr during TOP time-step
38
39   !!----------------------------------------------------------------------
40   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE trc_stp( kt )
47      !!-------------------------------------------------------------------
48      !!                     ***  ROUTINE trc_stp  ***
49      !!                     
50      !! ** Purpose :   Time loop of opa for passive tracer
51      !!
52      !! ** Method  :   Compute the passive tracers trends
53      !!                Update the passive tracers
54      !!-------------------------------------------------------------------
55      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
56      !
57      INTEGER ::   jk, jn   ! dummy loop indices
58      REAL(wp)::   ztrai    ! local scalar
59      CHARACTER (len=25) ::   charout   !
60      !!-------------------------------------------------------------------
61      !
62      IF( ln_timing )   CALL timing_start('trc_stp')
63      !
64      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
65         r2dttrc =  rdttrc           ! = rdttrc (use or restarting with Euler time stepping)
66      ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
67         r2dttrc = 2. * rdttrc       ! = 2 rdttrc (leapfrog)
68      ENDIF
69      !
70      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
71      !
72      IF( .NOT.ln_linssh ) THEN                                           ! update ocean volume due to ssh temporal evolution
73         DO jk = 1, jpk
74            cvol(:,:,jk) = e1e2t(:,:) * e3t_n(:,:,jk) * tmask(:,:,jk)
75         END DO
76         IF ( ln_ctl .OR. kt == nitrst .OR. ( ln_check_mass .AND. kt == nitend )              &
77            & .OR. iom_use( "pno3tot" ) .OR. iom_use( "ppo4tot" ) .OR. iom_use( "psiltot" )   &
78            & .OR. iom_use( "palktot" ) .OR. iom_use( "pfertot" ) )                           &
79            &     areatot = glob_sum( 'trcstp', cvol(:,:,:) )
80      ENDIF
81      !
82      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
83      !   
84      IF( nn_dttrc /= 1 )   CALL trc_sub_stp( kt )  ! averaging physical variables for sub-stepping
85      !   
86      IF( MOD( kt , nn_dttrc ) == 0 ) THEN      ! only every nn_dttrc time step
87         !
88         IF(ln_ctl) THEN
89            WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
90            CALL prt_ctl_trc_info(charout)
91         ENDIF
92         !
93         tra(:,:,:,:) = 0.e0
94         !
95                                   CALL trc_rst_opn  ( kt )       ! Open tracer restart file
96         IF( lrst_trc )            CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
97                                   CALL trc_wri      ( kt )       ! output of passive tracers with iom I/O manager
98                                   CALL trc_sms      ( kt )       ! tracers: sinks and sources
99                                   CALL trc_trp      ( kt )       ! transport of passive tracers
100         IF( kt == nittrc000 ) THEN
101            CALL iom_close( numrtr )       ! close input tracer restart file
102            IF(lwm) CALL FLUSH( numont )   ! flush namelist output
103         ENDIF
104         IF( lrst_trc )            CALL trc_rst_wri  ( kt )       ! write tracer restart file
105         IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt )       ! trends: Mixed-layer
106         !
107         IF( nn_dttrc /= 1   )     CALL trc_sub_reset( kt )       ! resetting physical variables when sub-stepping
108         !
109      ENDIF
110      !
111      IF (ln_ctl ) THEN
112         ztrai = 0._wp                                                   !  content of all tracers
113         DO jn = 1, jptra
114            ztrai = ztrai + glob_sum( 'trcstp', trn(:,:,:,jn) * cvol(:,:,:)   )
115         END DO
116         IF( lwm ) WRITE(numstr,9300) kt,  ztrai / areatot
117      ENDIF
1189300  FORMAT(i10,D23.16)
119      !
120      IF( ln_timing )   CALL timing_stop('trc_stp')
121      !
122   END SUBROUTINE trc_stp
123
124
125   SUBROUTINE trc_mean_qsr( kt )
126      !!----------------------------------------------------------------------
127      !!             ***  ROUTINE trc_mean_qsr  ***
128      !!
129      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
130      !!               of diurnal cycle
131      !!
132      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
133      !!              is greater than 1 hour ) and then, compute the  mean with
134      !!              a moving average over 24 hours.
135      !!              In coupled mode, the sampling is done at every coupling frequency
136      !!----------------------------------------------------------------------
137      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
138      !
139      INTEGER  ::   jn   ! dummy loop indices
140      REAL(wp) ::   zkt, zrec     ! local scalars
141      CHARACTER(len=1) ::   cl1   ! 1 character
142      CHARACTER(len=2) ::   cl2   ! 2 characters
143      !!----------------------------------------------------------------------
144      !
145      IF( ln_timing )   CALL timing_start('trc_mean_qsr')
146      !
147      IF( kt == nittrc000 ) THEN
148         IF( ln_cpl )  THEN 
149            rdt_sampl = rday / ncpl_qsr_freq
150            nb_rec_per_day = ncpl_qsr_freq
151         ELSE 
152            rdt_sampl = MAX( 3600., rdttrc )
153            nb_rec_per_day = INT( rday / rdt_sampl )
154         ENDIF
155         !
156         IF(lwp) THEN
157            WRITE(numout,*) 
158            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
159            WRITE(numout,*) 
160         ENDIF
161         !
162         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
163         !
164         !                                            !* Restart: read in restart file
165         IF( ln_rsttr .AND. nn_rsttr /= 0 .AND. iom_varid( numrtr, 'qsr_mean' , ldstop = .FALSE. ) > 0  &
166           &                              .AND. iom_varid( numrtr, 'qsr_arr_1', ldstop = .FALSE. ) > 0  &
167           &                              .AND. iom_varid( numrtr, 'ktdcy'    , ldstop = .FALSE. ) > 0  &
168           &                              .AND. iom_varid( numrtr, 'nrdcy'    , ldstop = .FALSE. ) > 0  ) THEN
169
170            CALL iom_get( numrtr, 'ktdcy', zkt ) 
171            rsecfst = INT( zkt ) * rdttrc
172            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file at time-step rsecfst =', rsecfst, ' s '
173            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
174            CALL iom_get( numrtr, 'nrdcy', zrec )   !  Number of record per days
175            IF( INT( zrec ) == nb_rec_per_day ) THEN
176               DO jn = 1, nb_rec_per_day 
177                  IF( jn <= 9 )  THEN
178                    WRITE(cl1,'(i1)') jn
179                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )   !  A mean of qsr
180                  ELSE
181                    WRITE(cl2,'(i2.2)') jn
182                    CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )   !  A mean of qsr
183                  ENDIF
184              END DO
185            ELSE
186               DO jn = 1, nb_rec_per_day
187                  qsr_arr(:,:,jn) = qsr_mean(:,:)
188               ENDDO
189            ENDIF
190         ELSE                                         !* no restart: set from nit000 values
191            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
192            rsecfst  = kt * rdttrc
193            !
194            qsr_mean(:,:) = qsr(:,:)
195            DO jn = 1, nb_rec_per_day
196               qsr_arr(:,:,jn) = qsr_mean(:,:)
197            END DO
198         ENDIF
199         !
200      ENDIF
201      !
202      rseclast = kt * rdttrc
203      !
204      llnew   = ( rseclast - rsecfst ) .ge.  rdt_sampl    !   new shortwave to store
205      IF( llnew ) THEN
206          ktdcy = kt
207          IF( lwp .AND. kt < nittrc000 + 100 ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', ktdcy, &
208             &                      ' time = ', rseclast/3600.,'hours '
209          rsecfst = rseclast
210          DO jn = 1, nb_rec_per_day - 1
211             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
212          ENDDO
213          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
214          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
215      ENDIF
216      !
217      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
218         IF(lwp) WRITE(numout,*)
219         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
220         IF(lwp) WRITE(numout,*) '~~~~~~~'
221         zkt  = REAL( ktdcy, wp )
222         zrec = REAL( nb_rec_per_day, wp )
223         CALL iom_rstput( kt, nitrst, numrtw, 'ktdcy', zkt  )
224         CALL iom_rstput( kt, nitrst, numrtw, 'nrdcy', zrec )
225          DO jn = 1, nb_rec_per_day 
226             IF( jn <= 9 )  THEN
227               WRITE(cl1,'(i1)') jn
228               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )
229             ELSE
230               WRITE(cl2,'(i2.2)') jn
231               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )
232             ENDIF
233         END DO
234         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
235      ENDIF
236      !
237      IF( ln_timing )   CALL timing_stop('trc_mean_qsr')
238      !
239   END SUBROUTINE trc_mean_qsr
240
241#else
242   !!----------------------------------------------------------------------
243   !!   Default key                                     NO passive tracers
244   !!----------------------------------------------------------------------
245CONTAINS
246   SUBROUTINE trc_stp( kt )        ! Empty routine
247      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
248   END SUBROUTINE trc_stp
249#endif
250
251   !!======================================================================
252END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.