New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpctl.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/tests/CANAL/MY_SRC – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/tests/CANAL/MY_SRC/stpctl.F90 @ 10358

Last change on this file since 10358 was 10358, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: action 5b: by default, suppress global communication in stpctl, see #2133
  • Property svn:keywords set to Id
File size: 9.8 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (G. Madec) Original code
7   !!            6.0  ! 1992-06  (M. Imbard)
8   !!            8.0  ! 1997-06  (A.M. Treguier)
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
11   !!            3.7  ! 2016-09  (G. Madec)  Remove solver
12   !!            4.0  ! 2017-04  (G. Madec)  regroup global communications
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   stp_ctl      : Control the run
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE c1d             ! 1D vertical configuration
21   USE diawri          ! Standard run outputs       (dia_wri_state routine)
22   !
23   USE in_out_manager  ! I/O manager
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE lib_mpp         ! distributed memory computing
26   USE wet_dry,   ONLY : ll_wd, ssh_ref    ! reference depth for negative bathy
27
28   USE netcdf          ! NetCDF library
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC stp_ctl           ! routine called by step.F90
33
34   INTEGER  ::   idrun, idtime, idssh, idu, ids1, ids2, istatus
35   LOGICAL  ::   lsomeoce
36   !!----------------------------------------------------------------------
37   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
38   !! $Id$
39   !! Software governed by the CeCILL license (see ./LICENSE)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE stp_ctl( kt, kindic )
44      !!----------------------------------------------------------------------
45      !!                    ***  ROUTINE stp_ctl  ***
46      !!                     
47      !! ** Purpose :   Control the run
48      !!
49      !! ** Method  : - Save the time step in numstp
50      !!              - Print it each 50 time steps
51      !!              - Stop the run IF problem encountered by setting indic=-3
52      !!                Problems checked: |ssh| maximum larger than 10 m
53      !!                                  |U|   maximum larger than 10 m/s
54      !!                                  negative sea surface salinity
55      !!
56      !! ** Actions :   "time.step" file = last ocean time-step
57      !!                "run.stat"  file = run statistics
58      !!                nstop indicator sheared among all local domain (lk_mpp=T)
59      !!----------------------------------------------------------------------
60      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
61      INTEGER, INTENT(inout) ::   kindic   ! error indicator
62      !!
63      INTEGER                ::   ji, jj, jk          ! dummy loop indices
64      INTEGER, DIMENSION(2)  ::   ih                  ! min/max loc indices
65      INTEGER, DIMENSION(3)  ::   iu, is1, is2        ! min/max loc indices
66      REAL(wp)               ::   zzz                 ! local real
67      REAL(wp), DIMENSION(5) ::   zmax
68      CHARACTER(len=20) :: clname
69      !!----------------------------------------------------------------------
70      !
71      IF( kt == nit000 .AND. lwp ) THEN
72         WRITE(numout,*)
73         WRITE(numout,*) 'stp_ctl : time-stepping control'
74         WRITE(numout,*) '~~~~~~~'
75         !                                ! open time.step file
76         IF( lwm ) CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
77         !                                ! open run.stat file
78         IF( ln_ctl .AND. lwm ) THEN
79            CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
80            clname = 'run.stat.nc'
81            IF( .NOT. Agrif_Root() )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(clname)
82            istatus = NF90_CREATE( TRIM(clname), NF90_CLOBBER, idrun )
83            istatus = NF90_DEF_DIM( idrun, 'time', NF90_UNLIMITED, idtime )
84            istatus = NF90_DEF_VAR( idrun, 'abs_ssh_max', NF90_DOUBLE, (/ idtime /), idssh )
85            istatus = NF90_DEF_VAR( idrun,   'abs_u_max', NF90_DOUBLE, (/ idtime /), idu   )
86            istatus = NF90_DEF_VAR( idrun,       's_min', NF90_DOUBLE, (/ idtime /), ids1  )
87            istatus = NF90_DEF_VAR( idrun,       's_max', NF90_DOUBLE, (/ idtime /), ids2  )
88            istatus = NF90_ENDDEF(idrun)
89         ENDIF
90      ENDIF
91      IF( kt == nit000 )   lsomeoce = COUNT( ssmask(:,:) == 1._wp ) > 0
92      !
93      IF(lwm) THEN                        !==  current time step  ==!   ("time.step" file)
94         WRITE ( numstp, '(1x, i8)' )   kt
95         REWIND( numstp )
96      ENDIF
97      !
98      !                                   !==  test of extrema  ==!
99      IF( ll_wd ) THEN
100         zmax(1) = MAXVAL(  ABS( sshn(:,:) + ssh_ref*tmask(:,:,1) )  )        ! ssh max
101      ELSE
102         zmax(1) = MAXVAL(  ABS( sshn(:,:) )  )                               ! ssh max
103      ENDIF
104      zmax(2) = MAXVAL(  ABS( un(:,:,:) )  )                                  ! velocity max (zonal only)
105      zmax(3) = MAXVAL( -tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )   ! minus salinity max
106      zmax(4) = MAXVAL(  tsn(:,:,:,jp_sal) , mask = tmask(:,:,:) == 1._wp )   !       salinity max
107      zmax(5) = REAL( nstop , wp )                                            ! stop indicator
108      !
109      IF( lk_mpp .AND. ln_ctl ) THEN
110         CALL mpp_max( "stpctl", zmax )          ! max over the global domain
111         nstop = NINT( zmax(5) )                 ! nstop indicator sheared among all local domains
112      ENDIF
113      !                                   !==  run statistics  ==!   ("run.stat" files)
114      IF( ln_ctl .AND. lwm ) THEN
115         WRITE(numrun,9500) kt, zmax(1), zmax(2), -zmax(3), zmax(4)
116         istatus = NF90_PUT_VAR( idrun, idssh, (/ zmax(1)/), (/kt/), (/1/) )
117         istatus = NF90_PUT_VAR( idrun,   idu, (/ zmax(2)/), (/kt/), (/1/) )
118         istatus = NF90_PUT_VAR( idrun,  ids1, (/-zmax(3)/), (/kt/), (/1/) )
119         istatus = NF90_PUT_VAR( idrun,  ids2, (/ zmax(4)/), (/kt/), (/1/) )
120         IF( MOD( kt , 100 ) == 0 ) istatus = NF90_SYNC(idrun)
121         IF( kt == nitend         ) istatus = NF90_CLOSE(idrun)
122      END IF
123      !                                   !==  error handling  ==!
124      IF( ( ln_ctl .OR. lsomeoce ) .AND. (   &             ! have use mpp_max (because ln_ctl=.T.) or contains some ocean points
125         &  zmax(1) >   50._wp .OR.   &                    ! too large sea surface height ( > 50 m )
126         &  zmax(2) >   20._wp .OR.   &                    ! too large velocity ( > 20 m/s)
127         &  zmax(3) >= 100._wp .OR.   &                    ! too small sea surface salinity ( < -100 )
128         &  zmax(4) >= 100._wp .OR.   &                    ! too large sea surface salinity ( > 100 )
129         &  zmax(4) < -100._wp .OR.   &                    ! too large sea surface salinity (keep this line for sea-ice)
130         &  ISNAN( zmax(1) + zmax(2) + zmax(3) )  ) THEN   ! NaN encounter in the tests
131         IF( lk_mpp .AND. ln_ctl ) THEN
132            CALL mpp_maxloc( 'stpctl', ABS(sshn)        , ssmask(:,:)  , zzz, ih  )
133            CALL mpp_maxloc( 'stpctl', ABS(un)          , umask (:,:,:), zzz, iu  )
134            CALL mpp_minloc( 'stpctl', tsn(:,:,:,jp_sal), tmask (:,:,:), zzz, is1 )
135            CALL mpp_maxloc( 'stpctl', tsn(:,:,:,jp_sal), tmask (:,:,:), zzz, is2 )
136         ELSE
137            ih(:)  = MAXLOC( ABS( sshn(:,:)   )                              ) + (/ nimpp - 1, njmpp - 1    /)
138            iu(:)  = MAXLOC( ABS( un  (:,:,:) )                              ) + (/ nimpp - 1, njmpp - 1, 0 /)
139            is1(:) = MINLOC( tsn(:,:,:,jp_sal), mask = tmask(:,:,:) == 1._wp ) + (/ nimpp - 1, njmpp - 1, 0 /)
140            is2(:) = MAXLOC( tsn(:,:,:,jp_sal), mask = tmask(:,:,:) == 1._wp ) + (/ nimpp - 1, njmpp - 1, 0 /)
141         ENDIF
142         IF( numout == 6 )   &   ! force to open ocean.output file
143            CALL ctl_opn( numout, 'ocean.output', 'APPEND', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
144
145         WRITE(numout,cform_err)
146         WRITE(numout,*) ' stp_ctl: |ssh| > 50 m  or  |U| > 20 m/s  or  S <= -100  or  S >= 100  or  NaN encounter in the tests'
147         WRITE(numout,*) ' ======= '
148         IF( lk_mpp .AND. .NOT. ln_ctl ) WRITE(numout,*) 'E R R O R message from sub-domain: ', narea
149         WRITE(numout,9100) kt,   zmax(1), ih(1) , ih(2)
150         WRITE(numout,9200) kt,   zmax(2), iu(1) , iu(2) , iu(3)
151         WRITE(numout,9300) kt, - zmax(3), is1(1), is1(2), is1(3)
152         WRITE(numout,9400) kt,   zmax(4), is2(1), is2(2), is2(3)
153         WRITE(numout,*)
154         WRITE(numout,*) '          output of last computed fields in output.abort.nc file'
155         
156         CALL dia_wri_state( 'output.abort' )     ! create an output.abort file
157         
158         IF( ln_ctl ) THEN
159            kindic = -3
160            nstop = nstop + 1                            ! increase nstop by 1 (on all local domains)
161         ELSE
162            CALL ctl_stop()
163            CALL mppstop(ld_force_abort = .true.)
164         ENDIF
165         !
166      ENDIF
167      !
1689100  FORMAT (' kt=',i8,'   |ssh| max: ',1pg11.4,', at  i j  : ',2i5)
1699200  FORMAT (' kt=',i8,'   |U|   max: ',1pg11.4,', at  i j k: ',3i5)
1709300  FORMAT (' kt=',i8,'   S     min: ',1pg11.4,', at  i j k: ',3i5)
1719400  FORMAT (' kt=',i8,'   S     max: ',1pg11.4,', at  i j k: ',3i5)
1729500  FORMAT(' it :', i8, '    |ssh|_max: ', D23.16, ' |U|_max: ', D23.16,' S_min: ', D23.16,' S_max: ', D23.16)
173      !
174   END SUBROUTINE stp_ctl
175
176   !!======================================================================
177END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.