New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in NEMO/branches/2018/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: NEMO/branches/2018/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 10115

Last change on this file since 10115 was 10115, checked in by cbricaud, 6 years ago
phase 3.6 coarsening branch with nemo_3.6_rev9192
Property svn:keywords set to `Id`
File size: 40.6 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!!----------------------------------------------------------------------
33
34	!!----------------------------------------------------------------------
35	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36	!! nemo_init : initialization of the NEMO system
37	!! nemo_ctl : initialisation of the contol print
38	!! nemo_closefile : close remaining open files
39	!! nemo_alloc : dynamical allocation
40	!! nemo_partition : calculate MPP domain decomposition
41	!! factorise : calculate the factors of the no. of MPI processes
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE bdyini ! open boundary cond. setting (bdy_init routine)
53	USE bdydta ! open boundary cond. setting (bdy_dta_init routine)
54	USE bdytides ! open boundary cond. setting (bdytide_init routine)
55	USE istate ! initial state setting (istate_init routine)
56	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
57	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
58	USE ldftra_crs ! lateral diffusivity setting (ldftra_init routine)
59	USE zdfini ! vertical physics setting (zdf_init routine)
60	USE phycst ! physical constant (par_cst routine)
61	USE trdini ! dyn/tra trends initialization (trd_init routine)
62	USE asminc ! assimilation increments
63	USE asmbkg ! writing out state trajectory
64	USE diaptr ! poleward transports (dia_ptr_init routine)
65	USE diadct ! sections transports (dia_dct_init routine)
66	USE diaobs ! Observation diagnostics (dia_obs_init routine)
67	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68	USE step ! NEMO time-stepping (stp routine)
69	USE icbini ! handle bergs, initialisation
70	USE icbstp ! handle bergs, calving, themodynamics and transport
71	USE cpl_oasis3 ! OASIS3 coupling
72	USE c1d ! 1D configuration
73	USE step_c1d ! Time stepping loop for the 1D configuration
74	USE dyndmp ! Momentum damping
75	#if defined key_top
76	USE trcini ! passive tracer initialisation
77	#endif
78	USE lib_mpp ! distributed memory computing
79	#if defined key_iomput
80	USE xios
81	#endif
82	USE sbctide, ONLY: lk_tide
83	USE crsini ! initialise grid coarsening utility
84	USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
85	!cbr USE trabbl_crs
86	USE sbc_oce, ONLY: lk_oasis
87	USE stopar
88	USE stopts
89
90	IMPLICIT NONE
91	PRIVATE
92
93	PUBLIC nemo_gcm ! called by model.F90
94	PUBLIC nemo_init ! needed by AGRIF
95	PUBLIC nemo_alloc ! needed by TAM
96
97	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
98
99	!!----------------------------------------------------------------------
100	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
101	!! $Id$
102	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
103	!!----------------------------------------------------------------------
104	CONTAINS
105
106	SUBROUTINE nemo_gcm
107	!!----------------------------------------------------------------------
108	!! * ROUTINE nemo_gcm *
109	!!
110	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
111	!! curvilinear mesh on the sphere.
112	!!
113	!! ** Method : - model general initialization
114	!! - launch the time-stepping (stp routine)
115	!! - finalize the run by closing files and communications
116	!!
117	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
118	!! Madec, 2008, internal report, IPSL.
119	!!----------------------------------------------------------------------
120	INTEGER :: istp ! time step index
121	CHARACTER(len=30) :: cmd
122	!!----------------------------------------------------------------------
123	!
124	#if defined key_agrif
125	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
126	#endif
127
128	! !-----------------------!
129	CALL nemo_init !== Initialisations ==!
130	! !-----------------------!
131	#if defined key_agrif
132	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
133	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
134	# if defined key_top
135	CALL Agrif_Declare_Var_top ! " " " " " TOP
136	# endif
137	# if defined key_lim2
138	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM
139	# endif
140	#endif
141	! check that all process are still there... If some process have an error,
142	! they will never enter in step and other processes will wait until the end of the cpu time!
143	IF( lk_mpp ) CALL mpp_max( nstop )
144
145	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
146
147	! !-----------------------!
148	! !== time stepping ==!
149	! !-----------------------!
150	istp = nit000
151	#if defined key_c1d
152	DO WHILE ( istp <= nitend .AND. nstop == 0 )
153	CALL stp_c1d( istp )
154	istp = istp + 1
155	END DO
156	#else
157	IF( lk_asminc ) THEN
158	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
159	IF( ln_asmdin ) THEN ! Direct initialization
160	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
161	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
162	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
163	ENDIF
164	ENDIF
165
166	#if defined key_agrif
167	CALL Agrif_Regrid()
168	#endif
169
170	DO WHILE ( istp <= nitend .AND. nstop == 0 )
171	#if defined key_agrif
172	CALL stp ! AGRIF: time stepping
173	#else
174	CALL stp( istp ) ! standard time stepping
175	#endif
176	istp = istp + 1
177	IF( lk_mpp ) CALL mpp_max( nstop )
178	END DO
179	#endif
180
181	IF( lk_diaobs ) CALL dia_obs_wri
182	!
183	IF( ln_icebergs ) CALL icb_end( nitend )
184
185	! !------------------------!
186	! !== finalize the run ==!
187	! !------------------------!
188	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
189	!
190	IF( nstop /= 0 ) THEN ! error print
191	cmd='touch nemo_NOK'
192	CALL system(cmd)
193	WRITE(numout,cform_err)
194	WRITE(numout,*) nstop, ' error have been found'
195	ELSE
196	cmd='touch nemo_OK'
197	CALL system(cmd)
198	ENDIF
199	!
200	#if defined key_agrif
201	CALL Agrif_ParentGrid_To_ChildGrid()
202	IF( lk_diaobs ) CALL dia_obs_wri
203	IF( nn_timing == 1 ) CALL timing_finalize
204	CALL Agrif_ChildGrid_To_ParentGrid()
205	#endif
206	IF( nn_timing == 1 ) CALL timing_finalize
207	!
208	CALL nemo_closefile
209	!
210	#if defined key_iomput
211	CALL xios_finalize ! end mpp communications with xios
212	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
213	#else
214	IF( lk_oasis ) THEN
215	CALL cpl_finalize ! end coupling and mpp communications with OASIS
216	ELSE
217	IF( lk_mpp ) CALL mppstop ! end mpp communications
218	ENDIF
219	#endif
220	!
221	END SUBROUTINE nemo_gcm
222
223
224	SUBROUTINE nemo_init
225	!!----------------------------------------------------------------------
226	!! * ROUTINE nemo_init *
227	!!
228	!! ** Purpose : initialization of the NEMO GCM
229	!!----------------------------------------------------------------------
230	INTEGER :: ji ! dummy loop indices
231	INTEGER :: ilocal_comm ! local integer
232	INTEGER :: ios
233	CHARACTER(len=80), DIMENSION(16) :: cltxt
234	!
235	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
236	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
237	& nn_bench, nn_timing
238	NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
239	& jpizoom, jpjzoom, jperio, ln_use_jattr
240	!!----------------------------------------------------------------------
241	!
242	cltxt = ''
243	cxios_context = 'nemo'
244	!
245	! ! Open reference namelist and configuration namelist files
246	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
247	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
248	!
249	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark
250	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
251	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
252
253	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark
254	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
255	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
256
257	!
258	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints & Benchmark
259	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
260	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
261
262	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
263	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
264	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
265
266	! Force values for AGRIF zoom (cf. agrif_user.F90)
267	#if defined key_agrif
268	IF( .NOT. Agrif_Root() ) THEN
269	jpiglo = nbcellsx + 2 + 2*nbghostcells
270	jpjglo = nbcellsy + 2 + 2*nbghostcells
271	jpi = ( jpiglo-2jpreci + (jpni-1+0) ) / jpni + 2jpreci
272	jpj = ( jpjglo-2jprecj + (jpnj-1+0) ) / jpnj + 2jprecj
273	jpidta = jpiglo
274	jpjdta = jpjglo
275	jpizoom = 1
276	jpjzoom = 1
277	nperio = 0
278	jperio = 0
279	ln_use_jattr = .false.
280	ENDIF
281	#endif
282	!
283	! !--------------------------------------------!
284	! ! set communicator & select the local node !
285	! ! NB: mynode also opens output.namelist.dyn !
286	! ! on unit number numond on first proc !
287	! !--------------------------------------------!
288	#if defined key_iomput
289	IF( Agrif_Root() ) THEN
290	IF( lk_oasis ) THEN
291	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
292	CALL xios_initialize( "not used",local_comm=ilocal_comm ) ! send nemo communicator to xios
293	ELSE
294	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios
295	ENDIF
296	ENDIF
297	! Nodes selection (control print return in cltxt)
298	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
299	#else
300	IF( lk_oasis ) THEN
301	IF( Agrif_Root() ) THEN
302	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
303	ENDIF
304	! Nodes selection (control print return in cltxt)
305	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
306	ELSE
307	ilocal_comm = 0
308	! Nodes selection (control print return in cltxt)
309	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
310	ENDIF
311	#endif
312	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
313
314	lwm = (narea == 1) ! control of output namelists
315	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
316
317	IF(lwm) THEN
318	! write merged namelists from earlier to output namelist now that the
319	! file has been opened in call to mynode. nammpp has already been
320	! written in mynode (if lk_mpp_mpi)
321	WRITE( numond, namctl )
322	WRITE( numond, namcfg )
323	ENDIF
324
325	! If dimensions of processor grid weren't specified in the namelist file
326	! then we calculate them here now that we have our communicator size
327	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
328	#if defined key_mpp_mpi
329	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
330	#else
331	jpni = 1
332	jpnj = 1
333	jpnij = jpni*jpnj
334	#endif
335	END IF
336
337	! Calculate domain dimensions given calculated jpni and jpnj
338	! This used to be done in par_oce.F90 when they were parameters rather
339	! than variables
340	IF( Agrif_Root() ) THEN
341	#if defined key_nemocice_decomp
342	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
343	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
344	#else
345	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
346	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
347	#endif
348	ENDIF
349	jpk = jpkdta ! third dim
350	#if defined key_agrif
351	! simple trick to use same vertical grid as parent
352	! but different number of levels:
353	! Save maximum number of levels in jpkdta, then define all vertical grids
354	! with this number.
355	! Suppress once vertical online interpolation is ok
356	IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
357	#endif
358	jpim1 = jpi-1 ! inner domain indices
359	jpjm1 = jpj-1 ! " "
360	jpkm1 = jpk-1 ! " "
361	jpij = jpi*jpj ! jpi x j
362
363	IF(lwp) THEN ! open listing units
364	!
365	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
366	!
367	WRITE(numout,*)
368	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
369	WRITE(numout,*) ' NEMO team'
370	WRITE(numout,*) ' Ocean General Circulation Model'
371	WRITE(numout,*) ' version 3.6 (2015) '
372	WRITE(numout,*)
373	WRITE(numout,*)
374	DO ji = 1, SIZE(cltxt)
375	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
376	END DO
377	WRITE(numout,cform_aaa) ! Flag AAAAAAA
378	!
379	ENDIF
380
381	! Now we know the dimensions of the grid and numout has been set we can
382	! allocate arrays
383	CALL nemo_alloc()
384
385	! !-------------------------------!
386	! ! NEMO general initialization !
387	! !-------------------------------!
388
389	CALL nemo_ctl ! Control prints & Benchmark
390
391	! ! Domain decomposition
392	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
393	ELSE ; CALL mpp_init2 ! eliminate land processors
394	ENDIF
395	!
396	IF( nn_timing == 1 ) CALL timing_init
397	!
398	! ! General initialization
399	CALL phy_cst ! Physical constants
400	CALL eos_init ! Equation of state
401	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
402	CALL dom_cfg ! Domain configuration
403	CALL dom_init ! Domain
404
405	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
406
407	IF( ln_ctl ) CALL prt_ctl_init ! Print control
408
409	IF( lk_crs ) CALL crs_init ! Domain initialization of coarsened grid
410
411	CALL istate_init ! ocean initial state (Dynamics and tracers)
412
413	IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
414
415	CALL sbc_init ! Forcings : surface module (clem: moved here for bdy purpose)
416
417	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
418	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
419	IF( lk_bdy .AND. lk_tide ) &
420	& CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
421
422	CALL dyn_nept_init ! simplified form of Neptune effect
423	!
424	IF( lk_crs ) CALL eos_init_crs ! Equation of state
425	!
426	! Ocean physics
427	! ! Vertical physics
428	CALL zdf_init ! namelist read
429	CALL zdf_bfr_init ! bottom friction
430	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
431	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
432	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
433	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
434	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
435	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
436	& CALL zdf_ddm_init ! double diffusive mixing
437	! ! Lateral physics
438	CALL ldf_tra_init ! Lateral ocean tracer physics
439	CALL ldf_dyn_init ! Lateral ocean momentum physics
440	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
441	!
442	IF( ln_crs_top .AND. lk_ldfslp ) THEN
443	CALL dom_grid_crs
444	CALL ldf_slp_init_crs
445	CALL dom_grid_glo
446	ENDIF
447	! ! Active tracers
448	CALL tra_qsr_init ! penetrative solar radiation qsr
449	CALL tra_bbc_init ! bottom heat flux
450	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
451	!
452	!cbr IF( ln_crs_top .AND. lk_trabbl ) THEN
453	! CALL dom_grid_crs
454	! CALL tra_bbl_init_crs ! advective (and/or diffusive) bottom boundary layer scheme
455	! CALL dom_grid_glo
456	!ENDIF
457	!
458	CALL tra_dmp_init ! internal damping trends- tracers
459	CALL tra_adv_init ! horizontal & vertical advection
460	CALL tra_ldf_init ! lateral mixing
461	CALL tra_zdf_init ! vertical mixing and after tracer fields
462
463	! ! Dynamics
464	IF( lk_c1d ) CALL dyn_dmp_init ! internal damping trends- momentum
465	CALL dyn_adv_init ! advection (vector or flux form)
466	CALL dyn_vor_init ! vorticity term including Coriolis
467	CALL dyn_ldf_init ! lateral mixing
468	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
469	CALL dyn_zdf_init ! vertical diffusion
470	CALL dyn_spg_init ! surface pressure gradient
471
472	! ! Misc. options
473	IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 ) CALL cla_init ! Cross Land Advection
474	CALL icb_init( rdt, nit000) ! initialise icebergs instance
475	CALL sto_par_init ! Stochastic parametrization
476	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
477
478	#if defined key_top
479	! ! Passive tracers
480	IF( ln_crs_top ) CALL dom_grid_crs
481	CALL trc_init
482	IF( ln_crs_top ) CALL ldf_tra_crs_init
483	IF( ln_crs_top ) CALL dom_grid_glo
484	#endif
485	! ! Diagnostics
486	IF( lk_floats ) CALL flo_init ! drifting Floats
487	CALL dia_ptr_init ! Poleward TRansports initialization
488	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
489	CALL dia_hsb_init ! heat content, salt content and volume budgets
490	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
491	IF( lk_diaobs ) THEN ! Observation & model comparison
492	CALL dia_obs_init ! Initialize observational data
493	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
494	ENDIF
495
496	! ! Assimilation increments
497	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
498	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
499	!
500	END SUBROUTINE nemo_init
501
502
503	SUBROUTINE nemo_ctl
504	!!----------------------------------------------------------------------
505	!! * ROUTINE nemo_ctl *
506	!!
507	!! ** Purpose : control print setting
508	!!
509	!! ** Method : - print namctl information and check some consistencies
510	!!----------------------------------------------------------------------
511	!
512	IF(lwp) THEN ! control print
513	WRITE(numout,*)
514	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
515	WRITE(numout,*) '~~~~~~~ '
516	WRITE(numout,*) ' Namelist namctl'
517	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
518	WRITE(numout,*) ' level of print nn_print = ', nn_print
519	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
520	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
521	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
522	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
523	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
524	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
525	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
526	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
527	ENDIF
528	!
529	nprint = nn_print ! convert DOCTOR namelist names into OLD names
530	nictls = nn_ictls
531	nictle = nn_ictle
532	njctls = nn_jctls
533	njctle = nn_jctle
534	isplt = nn_isplt
535	jsplt = nn_jsplt
536	nbench = nn_bench
537
538	IF(lwp) THEN ! control print
539	WRITE(numout,*)
540	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
541	WRITE(numout,*) '~~~~~~~ '
542	WRITE(numout,*) ' Namelist namcfg'
543	WRITE(numout,*) ' configuration name cp_cfg = ', TRIM(cp_cfg)
544	WRITE(numout,*) ' configuration zoom name cp_cfz = ', TRIM(cp_cfz)
545	WRITE(numout,*) ' configuration resolution jp_cfg = ', jp_cfg
546	WRITE(numout,*) ' 1st lateral dimension ( >= jpi ) jpidta = ', jpidta
547	WRITE(numout,*) ' 2nd " " ( >= jpj ) jpjdta = ', jpjdta
548	WRITE(numout,*) ' 3nd " " jpkdta = ', jpkdta
549	WRITE(numout,*) ' 1st dimension of global domain in i jpiglo = ', jpiglo
550	WRITE(numout,*) ' 2nd - - in j jpjglo = ', jpjglo
551	WRITE(numout,*) ' left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
552	WRITE(numout,*) ' left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
553	WRITE(numout,*) ' lateral cond. type (between 0 and 6) jperio = ', jperio
554	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
555	ENDIF
556	! ! Parameter control
557	!
558	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
559	IF( lk_mpp .AND. jpnij > 1 ) THEN
560	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
561	ELSE
562	IF( isplt == 1 .AND. jsplt == 1 ) THEN
563	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
564	& ' - the print control will be done over the whole domain' )
565	ENDIF
566	ijsplt = isplt * jsplt ! total number of processors ijsplt
567	ENDIF
568	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
569	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
570	!
571	! ! indices used for the SUM control
572	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
573	lsp_area = .FALSE.
574	ELSE ! print control done over a specific area
575	lsp_area = .TRUE.
576	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
577	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
578	nictls = 1
579	ENDIF
580	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
581	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
582	nictle = jpiglo
583	ENDIF
584	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
585	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
586	njctls = 1
587	ENDIF
588	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
589	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
590	njctle = jpjglo
591	ENDIF
592	ENDIF
593	ENDIF
594	!
595	IF( nbench == 1 ) THEN ! Benchmark
596	SELECT CASE ( cp_cfg )
597	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
598	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
599	& ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
600	END SELECT
601	ENDIF
602	!
603	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
604	& 'f2003 standard. ' , &
605	& 'Compile with key_nosignedzero enabled' )
606	!
607	END SUBROUTINE nemo_ctl
608
609
610	SUBROUTINE nemo_closefile
611	!!----------------------------------------------------------------------
612	!! * ROUTINE nemo_closefile *
613	!!
614	!! ** Purpose : Close the files
615	!!----------------------------------------------------------------------
616	!
617	IF( lk_mpp ) CALL mppsync
618	!
619	CALL iom_close ! close all input/output files managed by iom_*
620	!
621	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
622	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
623	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
624	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
625	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
626	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
627	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
628	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
629	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
630	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
631	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
632	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
633	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
634
635	!
636	numout = 6 ! redefine numout in case it is used after this point...
637	!
638	END SUBROUTINE nemo_closefile
639
640
641	SUBROUTINE nemo_alloc
642	!!----------------------------------------------------------------------
643	!! * ROUTINE nemo_alloc *
644	!!
645	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
646	!!
647	!! ** Method :
648	!!----------------------------------------------------------------------
649	USE diawri , ONLY: dia_wri_alloc
650	USE dom_oce , ONLY: dom_oce_alloc
651	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
652	USE ldftra_oce, ONLY: ldftra_oce_alloc
653	USE trc_oce , ONLY: trc_oce_alloc
654	USE zdfmxl , ONLY: zdf_mxl_alloc
655	#if defined key_diadct
656	USE diadct , ONLY: diadct_alloc
657	#endif
658	#if defined key_bdy
659	USE bdy_oce , ONLY: bdy_oce_alloc
660	#endif
661	!
662	INTEGER :: ierr
663	!!----------------------------------------------------------------------
664	!
665	ierr = oce_alloc () ! ocean
666	ierr = ierr + dia_wri_alloc ()
667	ierr = ierr + dom_oce_alloc () ! ocean domain
668	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
669	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
670	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
671	ierr = ierr + zdf_mxl_alloc () ! mixed layer
672	!
673	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
674	!
675	#if defined key_diadct
676	ierr = ierr + diadct_alloc () !
677	#endif
678	#if defined key_bdy
679	ierr = ierr + bdy_oce_alloc () ! bdy masks (incl. initialization)
680	#endif
681	!
682	IF( lk_mpp ) CALL mpp_sum( ierr )
683	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
684	!
685	END SUBROUTINE nemo_alloc
686
687
688	SUBROUTINE nemo_partition( num_pes )
689	!!----------------------------------------------------------------------
690	!! * ROUTINE nemo_partition *
691	!!
692	!! ** Purpose :
693	!!
694	!! ** Method :
695	!!----------------------------------------------------------------------
696	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
697	!
698	INTEGER, PARAMETER :: nfactmax = 20
699	INTEGER :: nfact ! The no. of factors returned
700	INTEGER :: ierr ! Error flag
701	INTEGER :: ji
702	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
703	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
704	!!----------------------------------------------------------------------
705	!
706	ierr = 0
707	!
708	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
709	!
710	IF( nfact <= 1 ) THEN
711	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
712	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
713	jpnj = 1
714	jpni = num_pes
715	ELSE
716	! Search through factors for the pair that are closest in value
717	mindiff = 1000000
718	imin = 1
719	DO ji = 1, nfact-1, 2
720	idiff = ABS( ifact(ji) - ifact(ji+1) )
721	IF( idiff < mindiff ) THEN
722	mindiff = idiff
723	imin = ji
724	ENDIF
725	END DO
726	jpnj = ifact(imin)
727	jpni = ifact(imin + 1)
728	ENDIF
729	!
730	jpnij = jpni*jpnj
731	!
732	END SUBROUTINE nemo_partition
733
734
735	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
736	!!----------------------------------------------------------------------
737	!! * ROUTINE factorise *
738	!!
739	!! ** Purpose : return the prime factors of n.
740	!! knfax factors are returned in array kfax which is of
741	!! maximum dimension kmaxfax.
742	!! ** Method :
743	!!----------------------------------------------------------------------
744	INTEGER , INTENT(in ) :: kn, kmaxfax
745	INTEGER , INTENT( out) :: kerr, knfax
746	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
747	!
748	INTEGER :: ifac, jl, inu
749	INTEGER, PARAMETER :: ntest = 14
750	INTEGER, DIMENSION(ntest) :: ilfax
751	!
752	! ilfax contains the set of allowed factors.
753	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
754
755	! Clear the error flag and initialise output vars
756	kerr = 0
757	kfax = 1
758	knfax = 0
759
760	! Find the factors of n.
761	IF( kn == 1 ) GOTO 20
762
763	! nu holds the unfactorised part of the number.
764	! knfax holds the number of factors found.
765	! l points to the allowed factor list.
766	! ifac holds the current factor.
767
768	inu = kn
769	knfax = 0
770
771	DO jl = ntest, 1, -1
772	!
773	ifac = ilfax(jl)
774	IF( ifac > inu ) CYCLE
775
776	! Test whether the factor will divide.
777
778	IF( MOD(inu,ifac) == 0 ) THEN
779	!
780	knfax = knfax + 1 ! Add the factor to the list
781	IF( knfax > kmaxfax ) THEN
782	kerr = 6
783	write (,) 'FACTOR: insufficient space in factor array ', knfax
784	return
785	ENDIF
786	kfax(knfax) = ifac
787	! Store the other factor that goes with this one
788	knfax = knfax + 1
789	kfax(knfax) = inu / ifac
790	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
791	ENDIF
792	!
793	END DO
794
795	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
796	!
797	END SUBROUTINE factorise
798
799	#if defined key_mpp_mpi
800
801	SUBROUTINE nemo_northcomms
802	!!======================================================================
803	!! * ROUTINE nemo_northcomms *
804	!! nemo_northcomms : Setup for north fold exchanges with explicit
805	!! point-to-point messaging
806	!!=====================================================================
807	!!----------------------------------------------------------------------
808	!!
809	!! ** Purpose : Initialization of the northern neighbours lists.
810	!!----------------------------------------------------------------------
811	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
812	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
813	!!----------------------------------------------------------------------
814
815	INTEGER :: sxM, dxM, sxT, dxT, jn
816	INTEGER :: njmppmax
817
818	njmppmax = MAXVAL( njmppt )
819
820	!initializes the north-fold communication variables
821	isendto(:) = 0
822	nsndto = 0
823
824	!if I am a process in the north
825	IF ( njmpp == njmppmax ) THEN
826	!sxM is the first point (in the global domain) needed to compute the
827	!north-fold for the current process
828	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
829	!dxM is the last point (in the global domain) needed to compute the
830	!north-fold for the current process
831	dxM = jpiglo - nimppt(narea) + 2
832
833	!loop over the other north-fold processes to find the processes
834	!managing the points belonging to the sxT-dxT range
835
836	DO jn = 1, jpni
837	!sxT is the first point (in the global domain) of the jn
838	!process
839	sxT = nfiimpp(jn, jpnj)
840	!dxT is the last point (in the global domain) of the jn
841	!process
842	dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
843	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
844	nsndto = nsndto + 1
845	isendto(nsndto) = jn
846	ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
847	nsndto = nsndto + 1
848	isendto(nsndto) = jn
849	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
850	nsndto = nsndto + 1
851	isendto(nsndto) = jn
852	END IF
853	END DO
854	nfsloop = 1
855	nfeloop = nlci
856	DO jn = 2,jpni-1
857	IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
858	IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
859	nfsloop = nldi
860	ENDIF
861	IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
862	nfeloop = nlei
863	ENDIF
864	ENDIF
865	END DO
866
867	ENDIF
868	l_north_nogather = .TRUE.
869	END SUBROUTINE nemo_northcomms
870	#else
871	SUBROUTINE nemo_northcomms ! Dummy routine
872	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
873	END SUBROUTINE nemo_northcomms
874	#endif
875
876	!!======================================================================
877	END MODULE nemogcm
878
879

Note: See TracBrowser for help on using the repository browser.

Download in other formats: