New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2018/dev_r9759_HPC09_ESIWACE/src/OCE – NEMO

source: NEMO/branches/2018/dev_r9759_HPC09_ESIWACE/src/OCE/nemogcm.F90 @ 9814

Last change on this file since 9814 was 9814, checked in by smasson, 6 years ago

dev_r9759_HPC09_ESIWACE: get more informations

  • Property svn:keywords set to Id
File size: 31.3 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE step           ! NEMO time-stepping                 (stp     routine)
62   USE icbini         ! handle bergs, initialisation
63   USE icbstp         ! handle bergs, calving, themodynamics and transport
64   USE cpl_oasis3     ! OASIS3 coupling
65   USE c1d            ! 1D configuration
66   USE step_c1d       ! Time stepping loop for the 1D configuration
67   USE dyndmp         ! Momentum damping
68   USE stopar         ! Stochastic param.: ???
69   USE stopts         ! Stochastic param.: ???
70   USE diurnal_bulk   ! diurnal bulk SST
71   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
72   USE crsini         ! initialise grid coarsening utility
73   USE diatmb         ! Top,middle,bottom output
74   USE dia25h         ! 25h mean output
75   USE sbc_oce , ONLY : lk_oasis
76   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
77#if defined key_top
78   USE trcini         ! passive tracer initialisation
79#endif
80#if defined key_nemocice_decomp
81   USE ice_domain_size, only: nx_global, ny_global
82#endif
83   !
84   USE lib_mpp        ! distributed memory computing
85   USE mppini         ! shared/distributed memory setting (mpp_init routine)
86   USE lbclnk 
87   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
88   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
89#if defined key_iomput
90   USE xios           ! xIOserver
91#endif
92
93   IMPLICIT NONE
94   PRIVATE
95
96   PUBLIC   nemo_gcm    ! called by model.F90
97   PUBLIC   nemo_init   ! needed by AGRIF
98   PUBLIC   nemo_alloc  ! needed by TAM
99
100   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
101
102#if defined key_mpp_mpi
103   INCLUDE 'mpif.h'
104#endif
105
106   !!----------------------------------------------------------------------
107   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
108   !! $Id$
109   !! Software governed by the CeCILL licence     (./LICENSE)
110   !!----------------------------------------------------------------------
111CONTAINS
112
113   SUBROUTINE nemo_gcm
114      !!----------------------------------------------------------------------
115      !!                     ***  ROUTINE nemo_gcm  ***
116      !!
117      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
118      !!              curvilinear mesh on the sphere.
119      !!
120      !! ** Method  : - model general initialization
121      !!              - launch the time-stepping (stp routine)
122      !!              - finalize the run by closing files and communications
123      !!
124      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
125      !!              Madec, 2008, internal report, IPSL.
126      !!----------------------------------------------------------------------
127      INTEGER ::   istp   ! time step index
128      INTEGER ::   i, ik, id, iend, iseq   ! time step index
129      REAL(wp) ::   tic 
130
131      !!----------------------------------------------------------------------
132      !
133#if defined key_agrif
134      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
135#endif
136      !                            !-----------------------!
137      CALL nemo_init               !==  Initialisations  ==!
138      !                            !-----------------------!
139#if defined key_agrif
140      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
141      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
142# if defined key_top
143      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
144# endif
145# if defined key_si3
146      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
147# endif
148#endif
149      ! check that all process are still there... If some process have an error,
150      ! they will never enter in step and other processes will wait until the end of the cpu time!
151      IF( lk_mpp )   CALL mpp_max( nstop )
152
153      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
154
155      !                            !-----------------------!
156      !                            !==   time stepping   ==!
157      !                            !-----------------------!
158      istp = nit000
159      !
160#if defined key_c1d
161      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
162         CALL stp_c1d( istp )
163         istp = istp + 1
164      END DO
165#else
166      !
167# if defined key_agrif
168      !                                               !==  AGRIF time-stepping  ==!
169      CALL Agrif_Regrid()
170      !
171      DO WHILE( istp <= nitend .AND. nstop == 0 )
172         CALL stp
173         istp = istp + 1
174      END DO
175      !
176      IF( .NOT. Agrif_Root() ) THEN
177         CALL Agrif_ParentGrid_To_ChildGrid()
178         IF( ln_diaobs )   CALL dia_obs_wri
179         IF( ln_timing )   CALL timing_finalize
180         CALL Agrif_ChildGrid_To_ParentGrid()
181      ENDIF
182      !
183# else
184      !
185      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
186         !
187         DO WHILE( istp <= nitend .AND. nstop == 0 )
188#if   defined key_mpp_mpi
189            ncom_stp = istp
190#endif
191            IF ( istp == ( nit000 + 1 ) ) tic = MPI_Wtime()
192            IF ( ln_comm_only .AND. istp >= ( nit000  + 1 )) THEN
193              CALL simulated_lbc_lnk
194            ELSE
195              CALL stp        ( istp ) 
196            ENDIF
197            istp = istp + 1
198            IF ( istp == ( nitend - 1) ) tic = MPI_Wtime() - tic
199         END DO
200         WRITE(6,'(A20,F11.6,A15,I8)') 'timeloop duration : ',tic,' on MPI rank : ', narea
201         !
202      ELSE                                            !==  diurnal SST time-steeping only  ==!
203         !
204         DO WHILE( istp <= nitend .AND. nstop == 0 )
205            CALL stp_diurnal( istp )   ! time step only the diurnal SST
206            istp = istp + 1
207         END DO
208         !
209      ENDIF
210      !
211# endif
212      !
213#endif
214      !
215      IF( ln_diaobs   )   CALL dia_obs_wri
216      !
217      IF( ln_icebergs )   CALL icb_end( nitend )
218
219      !                            !------------------------!
220      !                            !==  finalize the run  ==!
221      !                            !------------------------!
222      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
223      !
224      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
225         WRITE(numout,cform_err)
226         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
227         WRITE(numout,*)
228      ENDIF
229      !
230      IF( ln_timing )   CALL timing_finalize
231      !
232      CALL nemo_closefile
233      !
234#if defined key_iomput
235                                    CALL xios_finalize  ! end mpp communications with xios
236      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
237#else
238      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
239      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
240      ENDIF
241#endif
242      !
243   END SUBROUTINE nemo_gcm
244
245
246   SUBROUTINE nemo_init
247      !!----------------------------------------------------------------------
248      !!                     ***  ROUTINE nemo_init  ***
249      !!
250      !! ** Purpose :   initialization of the NEMO GCM
251      !!----------------------------------------------------------------------
252      INTEGER  ::   ji                 ! dummy loop indices
253      INTEGER  ::   ios, ilocal_comm   ! local integers
254      CHARACTER(len=120), DIMENSION(60) ::   cltxt, cltxt2, clnam
255      !!
256      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
257         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
258         &             ln_timing, ln_diacfl
259      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
260      !!----------------------------------------------------------------------
261      !
262      cltxt  = ''
263      cltxt2 = ''
264      clnam  = '' 
265      cxios_context = 'nemo'
266      !
267      !                             ! Open reference namelist and configuration namelist files
268      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
269      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
270      !
271      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
272      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
273901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
274      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
275      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
276902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
277      !
278      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
279      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
280903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
281      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
282      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
283904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
284
285      !                             !--------------------------!
286      !                             !  Set global domain size  !   (control print return in cltxt2)
287      !                             !--------------------------!
288      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
289         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
290         !
291      ELSE                                ! user-defined namelist
292         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
293      ENDIF
294      !
295      !
296      !                             !--------------------------------------------!
297      !                             !  set communicator & select the local node  !
298      !                             !  NB: mynode also opens output.namelist.dyn !
299      !                             !      on unit number numond on first proc   !
300      !                             !--------------------------------------------!
301#if defined key_iomput
302      IF( Agrif_Root() ) THEN
303         IF( lk_oasis ) THEN
304            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
305            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
306         ELSE
307            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
308         ENDIF
309      ENDIF
310      ! Nodes selection (control print return in cltxt)
311      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
312#else
313      IF( lk_oasis ) THEN
314         IF( Agrif_Root() ) THEN
315            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
316         ENDIF
317         ! Nodes selection (control print return in cltxt)
318         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
319      ELSE
320         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
321         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
322      ENDIF
323#endif
324
325      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
326
327      lwm = (narea == 1)                                    ! control of output namelists
328      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
329
330      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
331         !                       ! now that the file has been opened in call to mynode.
332         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
333         WRITE( numond, namctl )
334         WRITE( numond, namcfg )
335         IF( .NOT.ln_read_cfg ) THEN
336            DO ji = 1, SIZE(clnam)
337               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
338            END DO
339         ENDIF
340      ENDIF
341
342      IF(lwp) THEN                            ! open listing units
343         !
344         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
345         !
346         WRITE(numout,*)
347         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
348         WRITE(numout,*) '                       NEMO team'
349         WRITE(numout,*) '            Ocean General Circulation Model'
350         WRITE(numout,*) '                NEMO version 4.0  (2017) '
351         WRITE(numout,*)
352         WRITE(numout,*)
353         DO ji = 1, SIZE(cltxt)
354            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
355         END DO
356         WRITE(numout,*)
357         WRITE(numout,*)
358         DO ji = 1, SIZE(cltxt2)
359            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
360         END DO
361         !
362         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
363         !
364      ENDIF
365      !                                      ! Domain decomposition
366      CALL mpp_init                          ! MPP
367
368      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
369      CALL nemo_alloc()
370
371      !                             !-------------------------------!
372      !                             !  NEMO general initialization  !
373      !                             !-------------------------------!
374
375      CALL nemo_ctl                          ! Control prints
376      !
377      !                                      ! General initialization
378      IF( ln_timing    )   CALL timing_init     ! timing
379      IF( ln_timing    )   CALL timing_start( 'nemo_init')
380      !
381                           CALL     phy_cst         ! Physical constants
382                           CALL     eos_init        ! Equation of state
383      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
384                           CALL     wad_init        ! Wetting and drying options
385                           CALL     dom_init("OPA") ! Domain
386      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
387      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
388     
389      CALL diurnal_sst_bulk_init                ! diurnal sst
390      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
391      !                           
392      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
393         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
394         CALL     sbc_init                            ! Forcings : surface module
395         CALL tra_qsr_init                            ! penetrative solar radiation qsr
396         IF( ln_diaobs ) THEN                         ! Observation & model comparison
397            CALL dia_obs_init                            ! Initialize observational data
398            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
399         ENDIF     
400         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
401         !
402         RETURN                                       ! end of initialization
403      ENDIF
404     
405                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
406
407      !                                      ! external forcing
408                           CALL    tide_init    ! tidal harmonics
409                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
410                           CALL     bdy_init    ! Open boundaries initialisation
411
412      !                                      ! Ocean physics
413                           CALL zdf_phy_init    ! Vertical physics
414                                     
415      !                                         ! Lateral physics
416                           CALL ldf_tra_init      ! Lateral ocean tracer physics
417                           CALL ldf_eiv_init      ! eddy induced velocity param.
418                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
419
420      !                                      ! Active tracers
421      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
422                           CALL tra_bbc_init      ! bottom heat flux
423      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
424                           CALL tra_dmp_init      ! internal tracer damping
425                           CALL tra_adv_init      ! horizontal & vertical advection
426                           CALL tra_ldf_init      ! lateral mixing
427
428      !                                      ! Dynamics
429      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
430                           CALL dyn_adv_init      ! advection (vector or flux form)
431                           CALL dyn_vor_init      ! vorticity term including Coriolis
432                           CALL dyn_ldf_init      ! lateral mixing
433                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
434                           CALL dyn_spg_init      ! surface pressure gradient
435
436#if defined key_top
437      !                                      ! Passive tracers
438                           CALL     trc_init
439#endif
440      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
441
442      !                                      ! Icebergs
443                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
444
445      !                                      ! Misc. options
446                           CALL sto_par_init    ! Stochastic parametrization
447      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
448     
449      !                                      ! Diagnostics
450      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
451      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
452                           CALL dia_ptr_init    ! Poleward TRansports initialization
453      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
454                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
455                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
456                           CALL dia_obs_init    ! Initialize observational data
457                           CALL dia_tmb_init    ! TMB outputs
458                           CALL dia_25h_init    ! 25h mean  outputs
459      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
460
461      !                                      ! Assimilation increments
462      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
463      !
464      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
465      !
466      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
467      !
468   END SUBROUTINE nemo_init
469
470
471   SUBROUTINE nemo_ctl
472      !!----------------------------------------------------------------------
473      !!                     ***  ROUTINE nemo_ctl  ***
474      !!
475      !! ** Purpose :   control print setting
476      !!
477      !! ** Method  : - print namctl information and check some consistencies
478      !!----------------------------------------------------------------------
479      !
480      IF(lwp) THEN                  ! control print
481         WRITE(numout,*)
482         WRITE(numout,*) 'nemo_ctl: Control prints'
483         WRITE(numout,*) '~~~~~~~~'
484         WRITE(numout,*) '   Namelist namctl'
485         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
486         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
487         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
488         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
489         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
490         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
491         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
492         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
493         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
494         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
495      ENDIF
496      !
497      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
498      nictls    = nn_ictls
499      nictle    = nn_ictle
500      njctls    = nn_jctls
501      njctle    = nn_jctle
502      isplt     = nn_isplt
503      jsplt     = nn_jsplt
504
505      IF(lwp) THEN                  ! control print
506         WRITE(numout,*)
507         WRITE(numout,*) '   Namelist namcfg'
508         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
509         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
510         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
511         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
512         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
513         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
514      ENDIF
515      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
516      !
517      !                             ! Parameter control
518      !
519      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
520         IF( lk_mpp .AND. jpnij > 1 ) THEN
521            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
522         ELSE
523            IF( isplt == 1 .AND. jsplt == 1  ) THEN
524               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
525                  &           ' - the print control will be done over the whole domain' )
526            ENDIF
527            ijsplt = isplt * jsplt            ! total number of processors ijsplt
528         ENDIF
529         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
530         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
531         !
532         !                              ! indices used for the SUM control
533         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
534            lsp_area = .FALSE.
535         ELSE                                             ! print control done over a specific  area
536            lsp_area = .TRUE.
537            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
538               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
539               nictls = 1
540            ENDIF
541            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
542               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
543               nictle = jpiglo
544            ENDIF
545            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
546               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
547               njctls = 1
548            ENDIF
549            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
550               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
551               njctle = jpjglo
552            ENDIF
553         ENDIF
554      ENDIF
555      !
556      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
557         &                                                'Compile with key_nosignedzero enabled' )
558      !
559#if defined key_agrif
560      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
561#endif
562      !
563   END SUBROUTINE nemo_ctl
564
565
566   SUBROUTINE nemo_closefile
567      !!----------------------------------------------------------------------
568      !!                     ***  ROUTINE nemo_closefile  ***
569      !!
570      !! ** Purpose :   Close the files
571      !!----------------------------------------------------------------------
572      !
573      IF( lk_mpp )   CALL mppsync
574      !
575      CALL iom_close                                 ! close all input/output files managed by iom_*
576      !
577      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
578      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
579      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
580      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
581      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
582      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
583      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
584      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
585      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
586      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
587      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
588      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
589      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
590      !
591      numout = 6                                     ! redefine numout in case it is used after this point...
592      !
593   END SUBROUTINE nemo_closefile
594
595
596   SUBROUTINE nemo_alloc
597      !!----------------------------------------------------------------------
598      !!                     ***  ROUTINE nemo_alloc  ***
599      !!
600      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
601      !!
602      !! ** Method  :
603      !!----------------------------------------------------------------------
604      USE diawri    , ONLY : dia_wri_alloc
605      USE dom_oce   , ONLY : dom_oce_alloc
606      USE trc_oce   , ONLY : trc_oce_alloc
607      USE bdy_oce   , ONLY : bdy_oce_alloc
608#if defined key_diadct 
609      USE diadct    , ONLY : diadct_alloc 
610#endif 
611      !
612      INTEGER :: ierr
613      !!----------------------------------------------------------------------
614      !
615      ierr =        oce_alloc    ()    ! ocean
616      !EM useless alloc for BENCH
617      !EM ierr = ierr + dia_wri_alloc()
618      ierr = ierr + dom_oce_alloc()    ! ocean domain
619      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
620      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
621      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
622      !
623#if defined key_diadct 
624      ierr = ierr + diadct_alloc ()    !
625#endif 
626      !
627      IF( lk_mpp    )   CALL mpp_sum( ierr )
628      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
629      !
630   END SUBROUTINE nemo_alloc
631
632   !!======================================================================
633END MODULE nemogcm
634
Note: See TracBrowser for help on using the repository browser.