Context Navigation

restart.F90 @ 10136

Last change on this file since 10136 was 10136, checked in by dguibert, 6 years ago

bull: async/datatype

Experimental changes to enable/study/bench various mpi "optimisations":

BULL_ASYNC
BULL_DATATYPE_VECTOR/SUBARRAY

this has been applied to the nonosc subroutine (only for now).

File size: 16.0 KB

Line
1	MODULE restart
2	!!======================================================================
3	!! * MODULE restart *
4	!! Ocean restart : write the ocean restart file
5	!!======================================================================
6	!! History : OPA ! 1999-11 (M. Imbard) Original code
7	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form
8	!! 2.0 ! 2006-07 (S. Masson) use IOM for restart
9	!! 3.3 ! 2010-04 (M. Leclair, G. Madec) modified LF-RA
10	!! - - ! 2010-10 (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11	!! 3.7 ! 2014-01 (G. Madec) suppression of curl and hdiv from the restart
12	!! - ! 2014-12 (G. Madec) remove KPP scheme
13	!!----------------------------------------------------------------------
14
15	!!----------------------------------------------------------------------
16	!! rst_opn : open the ocean restart file
17	!! rst_write : write the ocean restart file
18	!! rst_read : read the ocean restart file
19	!!----------------------------------------------------------------------
20	USE oce ! ocean dynamics and tracers
21	USE dom_oce ! ocean space and time domain
22	USE sbc_ice ! only lk_si3
23	USE phycst ! physical constants
24	USE eosbn2 ! equation of state (eos bn2 routine)
25	USE trdmxl_oce ! ocean active mixed layer tracers trends variables
26	!
27	USE in_out_manager ! I/O manager
28	USE iom ! I/O module
29	USE diurnal_bulk
30
31	IMPLICIT NONE
32	PRIVATE
33
34	PUBLIC rst_opn ! routine called by step module
35	PUBLIC rst_write ! routine called by step module
36	PUBLIC rst_read ! routine called by istate module
37	PUBLIC rst_read_open ! routine called in rst_read and (possibly) in dom_vvl_init
38
39	!! * Substitutions
40	# include "vectopt_loop_substitute.h90"
41	!!----------------------------------------------------------------------
42	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
43	!! $Id: restart.F90 9654 2018-05-28 09:08:53Z clem $
44	!! Software governed by the CeCILL licence (./LICENSE)
45	!!----------------------------------------------------------------------
46	CONTAINS
47
48	SUBROUTINE rst_opn( kt )
49	!!---------------------------------------------------------------------
50	!! * ROUTINE rst_opn *
51	!!
52	!! ** Purpose : + initialization (should be read in the namelist) of nitrst
53	!! + open the restart when we are one time step before nitrst
54	!! - restart header is defined when kt = nitrst-1
55	!! - restart data are written when kt = nitrst
56	!! + define lrst_oce to .TRUE. when we need to define or write the restart
57	!!----------------------------------------------------------------------
58	INTEGER, INTENT(in) :: kt ! ocean time-step
59	!!
60	CHARACTER(LEN=20) :: clkt ! ocean time-step deine as a character
61	CHARACTER(LEN=50) :: clname ! ocean output restart file name
62	CHARACTER(lc) :: clpath ! full path to ocean output restart file
63	CHARACTER(LEN=52) :: clpname ! ocean output restart file name including prefix for AGRIF
64	CHARACTER(LEN=256) :: clinfo ! info character
65	!!----------------------------------------------------------------------
66	!
67	IF( kt == nit000 ) THEN ! default definitions
68	lrst_oce = .FALSE.
69	IF( ln_rst_list ) THEN
70	nrst_lst = 1
71	nitrst = nstocklist( nrst_lst )
72	ELSE
73	nitrst = nitend
74	ENDIF
75	ENDIF
76
77	! frequency-based restart dumping (nn_stock)
78	IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN
79	! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
80	nitrst = kt + nstock - 1 ! define the next value of nitrst for restart writing
81	IF( nitrst > nitend ) nitrst = nitend ! make sure we write a restart at the end of the run
82	ENDIF
83	! to get better performances with NetCDF format:
84	! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
85	! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
86	IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
87	IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
88	! beware of the format used to write kt (default is i8.8, that should be large enough...)
89	IF( nitrst > 999999999 ) THEN ; WRITE(clkt, * ) nitrst
90	ELSE ; WRITE(clkt, '(i8.8)') nitrst
91	ENDIF
92	! create the file
93	clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
94	clpath = TRIM(cn_ocerst_outdir)
95	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
96	IF(lwp) THEN
97	WRITE(numout,*)
98	IF(.NOT.lwxios) THEN
99	SELECT CASE ( jprstlib )
100	CASE DEFAULT ; WRITE(numout,*) &
101	' open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
102	END SELECT
103	IF ( snc4set%luse ) WRITE(numout,*) ' opened for NetCDF4 chunking and compression'
104	IF( kt == nitrst - 1 ) THEN ; WRITE(numout,*) ' kt = nitrst - 1 = ', kt
105	ELSE ; WRITE(numout,*) ' kt = ' , kt
106	ENDIF
107	ENDIF
108	ENDIF
109	!
110	IF(.NOT.lwxios) THEN
111	!EM no call to restart opening
112	!EM CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
113	ELSE
114	#if defined key_iomput
115	cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
116	IF( TRIM(Agrif_CFixed()) == '0' ) THEN
117	clpname = clname
118	ELSE
119	clpname = TRIM(Agrif_CFixed())//"_"//clname
120	ENDIF
121	CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname))
122	CALL xios_update_calendar(nitrst)
123	CALL iom_swap( cxios_context )
124	#else
125	clinfo = 'Can not use XIOS in rst_opn'
126	CALL ctl_stop(TRIM(clinfo))
127	#endif
128	ENDIF
129	!EM restart writing
130	!EM lrst_oce = .TRUE.
131	ENDIF
132	ENDIF
133	!
134	END SUBROUTINE rst_opn
135
136
137	SUBROUTINE rst_write( kt )
138	!!---------------------------------------------------------------------
139	!! * ROUTINE rstwrite *
140	!!
141	!! ** Purpose : Write restart fields in the format corresponding to jprstlib
142	!!
143	!! ** Method : Write in numrow when kt == nitrst in NetCDF
144	!! file, save fields which are necessary for restart
145	!!----------------------------------------------------------------------
146	INTEGER, INTENT(in) :: kt ! ocean time-step
147	!!----------------------------------------------------------------------
148	IF(lwxios) CALL iom_swap( cwxios_context )
149	CALL iom_rstput( kt, nitrst, numrow, 'rdt' , rdt , ldxios = lwxios) ! dynamics time step
150
151	IF ( .NOT. ln_diurnal_only ) THEN
152	CALL iom_rstput( kt, nitrst, numrow, 'ub' , ub, ldxios = lwxios ) ! before fields
153	CALL iom_rstput( kt, nitrst, numrow, 'vb' , vb, ldxios = lwxios )
154	CALL iom_rstput( kt, nitrst, numrow, 'tb' , tsb(:,:,:,jp_tem), ldxios = lwxios )
155	CALL iom_rstput( kt, nitrst, numrow, 'sb' , tsb(:,:,:,jp_sal), ldxios = lwxios )
156	CALL iom_rstput( kt, nitrst, numrow, 'sshb' , sshb, ldxios = lwxios )
157	!
158	CALL iom_rstput( kt, nitrst, numrow, 'un' , un, ldxios = lwxios ) ! now fields
159	CALL iom_rstput( kt, nitrst, numrow, 'vn' , vn, ldxios = lwxios )
160	CALL iom_rstput( kt, nitrst, numrow, 'tn' , tsn(:,:,:,jp_tem), ldxios = lwxios )
161	CALL iom_rstput( kt, nitrst, numrow, 'sn' , tsn(:,:,:,jp_sal), ldxios = lwxios )
162	CALL iom_rstput( kt, nitrst, numrow, 'sshn' , sshn, ldxios = lwxios )
163	CALL iom_rstput( kt, nitrst, numrow, 'rhop' , rhop, ldxios = lwxios )
164	! extra variable needed for the ice sheet coupling
165	IF ( ln_iscpl ) THEN
166	CALL iom_rstput( kt, nitrst, numrow, 'tmask' , tmask, ldxios = lwxios ) ! need to extrapolate T/S
167	CALL iom_rstput( kt, nitrst, numrow, 'umask' , umask, ldxios = lwxios ) ! need to correct barotropic velocity
168	CALL iom_rstput( kt, nitrst, numrow, 'vmask' , vmask, ldxios = lwxios ) ! need to correct barotropic velocity
169	CALL iom_rstput( kt, nitrst, numrow, 'smask' , ssmask, ldxios = lwxios) ! need to correct barotropic velocity
170	CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:), ldxios = lwxios ) ! need to compute temperature correction
171	CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:), ldxios = lwxios ) ! need to compute bt conservation
172	CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:), ldxios = lwxios ) ! need to compute bt conservation
173	CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:), ldxios = lwxios ) ! need to compute extrapolation if vvl
174	END IF
175	ENDIF
176
177	IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios )
178	IF(lwxios) CALL iom_swap( cxios_context )
179	IF( kt == nitrst ) THEN
180	IF(.NOT.lwxios) THEN
181	CALL iom_close( numrow ) ! close the restart file (only at last time step)
182	ELSE
183	CALL iom_context_finalize( cwxios_context )
184	ENDIF
185	!!gm IF( .NOT. lk_trdmld ) lrst_oce = .FALSE.
186	!!gm not sure what to do here ===>>> ask to Sebastian
187	lrst_oce = .FALSE.
188	IF( ln_rst_list ) THEN
189	nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
190	nitrst = nstocklist( nrst_lst )
191	ENDIF
192	ENDIF
193	!
194	END SUBROUTINE rst_write
195
196
197	SUBROUTINE rst_read_open
198	!!----------------------------------------------------------------------
199	!! * ROUTINE rst_read_open *
200	!!
201	!! ** Purpose : Open read files for restart (format fixed by jprstlib )
202	!!
203	!! ** Method : Use a non-zero, positive value of numror to assess whether or not
204	!! the file has already been opened
205	!!----------------------------------------------------------------------
206	INTEGER :: jlibalt = jprstlib
207	LOGICAL :: llok
208	CHARACTER(lc) :: clpath ! full path to ocean output restart file
209	!!----------------------------------------------------------------------
210	!
211	IF( numror <= 0 ) THEN
212	IF(lwp) THEN ! Contol prints
213	WRITE(numout,*)
214	SELECT CASE ( jprstlib )
215	CASE ( jpnf90 ) ; WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
216	END SELECT
217	IF ( snc4set%luse ) WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
218	WRITE(numout,*) '~~~~~~~~'
219	ENDIF
220	lxios_sini = .FALSE.
221	clpath = TRIM(cn_ocerst_indir)
222	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
223	CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
224	! are we using XIOS to read the data? Part above will have to modified once XIOS
225	! can handle checking if variable is in the restart file (there will be no need to open
226	! restart)
227	IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
228	IF( lrxios) THEN
229	crxios_context = 'nemo_rst'
230	IF( .NOT.lxios_set ) THEN
231	IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
232	CALL iom_init( crxios_context )
233	lxios_set = .TRUE.
234	ENDIF
235	ENDIF
236	IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
237	CALL iom_init( crxios_context )
238	IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
239	lxios_set = .TRUE.
240	ENDIF
241	ENDIF
242
243	END SUBROUTINE rst_read_open
244
245
246	SUBROUTINE rst_read
247	!!----------------------------------------------------------------------
248	!! * ROUTINE rst_read *
249	!!
250	!! ** Purpose : Read files for restart (format fixed by jprstlib )
251	!!
252	!! ** Method : Read in restart.nc file fields which are necessary for restart
253	!!----------------------------------------------------------------------
254	REAL(wp) :: zrdt
255	INTEGER :: jk
256	REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
257	!!----------------------------------------------------------------------
258
259	CALL rst_read_open ! open restart for reading (if not already opened)
260
261	! Check dynamics and tracer time-step consistency and force Euler restart if changed
262	IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 ) THEN
263	CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
264	IF( zrdt /= rdt ) neuler = 0
265	ENDIF
266
267	! Diurnal DSST
268	IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios )
269	IF ( ln_diurnal_only ) THEN
270	IF(lwp) WRITE( numout, * ) &
271	& "rst_read:- ln_diurnal_only set, setting rhop=rau0"
272	rhop = rau0
273	CALL iom_get( numror, jpdom_autoglo, 'tn' , w3d, ldxios = lrxios )
274	tsn(:,:,1,jp_tem) = w3d(:,:,1)
275	RETURN
276	ENDIF
277
278	IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
279	CALL iom_get( numror, jpdom_autoglo, 'ub' , ub, ldxios = lrxios ) ! before fields
280	CALL iom_get( numror, jpdom_autoglo, 'vb' , vb, ldxios = lrxios )
281	CALL iom_get( numror, jpdom_autoglo, 'tb' , tsb(:,:,:,jp_tem), ldxios = lrxios )
282	CALL iom_get( numror, jpdom_autoglo, 'sb' , tsb(:,:,:,jp_sal), ldxios = lrxios )
283	CALL iom_get( numror, jpdom_autoglo, 'sshb' , sshb, ldxios = lrxios )
284	ELSE
285	neuler = 0
286	ENDIF
287	!
288	CALL iom_get( numror, jpdom_autoglo, 'un' , un, ldxios = lrxios ) ! now fields
289	CALL iom_get( numror, jpdom_autoglo, 'vn' , vn, ldxios = lrxios )
290	CALL iom_get( numror, jpdom_autoglo, 'tn' , tsn(:,:,:,jp_tem), ldxios = lrxios )
291	CALL iom_get( numror, jpdom_autoglo, 'sn' , tsn(:,:,:,jp_sal), ldxios = lrxios )
292	CALL iom_get( numror, jpdom_autoglo, 'sshn' , sshn, ldxios = lrxios )
293	IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
294	CALL iom_get( numror, jpdom_autoglo, 'rhop' , rhop, ldxios = lrxios ) ! now potential density
295	ELSE
296	CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )
297	ENDIF
298	!
299	IF( neuler == 0 ) THEN ! Euler restart (neuler=0)
300	tsb (:,:,:,:) = tsn (:,:,:,:) ! all before fields set to now values
301	ub (:,:,:) = un (:,:,:)
302	vb (:,:,:) = vn (:,:,:)
303	sshb (:,:) = sshn (:,:)
304	!
305	IF( .NOT.ln_linssh ) THEN
306	DO jk = 1, jpk
307	e3t_b(:,:,jk) = e3t_n(:,:,jk)
308	END DO
309	ENDIF
310	!
311	ENDIF
312	!
313	END SUBROUTINE rst_read
314
315	!!=====================================================================
316	END MODULE restart

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/branches/2018/dev_r9759_HPC09_ESIWACE/tests/BENCH_025/MY_SRC/restart.F90 @ 10136

Download in other formats: