New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/branches/2018/dev_r9838_ENHANCE04_MLF/src/OCE/DOM – NEMO

source: NEMO/branches/2018/dev_r9838_ENHANCE04_MLF/src/OCE/DOM/restart.F90 @ 9863

Last change on this file since 9863 was 9863, checked in by gm, 6 years ago

#1911 (ENHANCE-04): simplified implementation of the Euler stepping at nit000

  • Property svn:keywords set to Id
File size: 16.0 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec)  TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec)  suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec)  remove KPP scheme
13   !!            4.0  !  2018-06  (G. Madec)  introduce l_1st_euler
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   rst_opn       : open the ocean restart file in write mode
18   !!   rst_write     : write the ocean restart file
19   !!   rst_read_open : open the ocean restart file in read mode
20   !!   rst_read      : read the ocean restart file
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and tracers
23   USE dom_oce        ! ocean space and time domain
24   USE sbc_ice        ! only lk_si3
25   USE phycst         ! physical constants
26   USE eosbn2         ! equation of state            (eos bn2 routine)
27   USE trdmxl_oce     ! ocean active mixed layer tracers trends variables
28   USE diurnal_bulk   !
29   !
30   USE in_out_manager ! I/O manager
31   USE iom            ! I/O module
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   rst_opn         ! routine called by step module
37   PUBLIC   rst_write       ! routine called by step module
38   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
39   PUBLIC   rst_read        ! routine called by istate module
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE rst_opn( kt )
51      !!---------------------------------------------------------------------
52      !!                   ***  ROUTINE rst_opn  ***
53      !!                     
54      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
55      !!              + open the restart when we are one time step before nitrst
56      !!                   - restart header is defined when kt = nitrst-1
57      !!                   - restart data  are written when kt = nitrst
58      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
59      !!----------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt     ! ocean time-step
61      !!
62      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
63      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
64      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
65      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
66      CHARACTER(LEN=256)  ::   clinfo    ! info character
67      !!----------------------------------------------------------------------
68      !
69      IF( kt == nit000 ) THEN   ! default definitions
70         lrst_oce = .FALSE.   
71         IF( ln_rst_list ) THEN
72            nrst_lst = 1
73            nitrst = nstocklist( nrst_lst )
74         ELSE
75            nitrst = nitend
76         ENDIF
77      ENDIF
78
79      ! frequency-based restart dumping (nn_stock)
80      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
81         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
82         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
83         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
84      ENDIF
85      ! to get better performances with NetCDF format:
86      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
87      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
88      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
89         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
90            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
91            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
92            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
93            ENDIF
94            ! create the file
95            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
96            clpath = TRIM(cn_ocerst_outdir)
97            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
98            IF(lwp) THEN
99               WRITE(numout,*)
100               IF(.NOT.lwxios) THEN
101                  SELECT CASE ( jprstlib )
102                  CASE DEFAULT         ;   WRITE(numout,*)                            &
103                      '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
104                  END SELECT
105                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
106                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
107                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
108                  ENDIF
109               ENDIF
110            ENDIF
111            !
112            IF(.NOT.lwxios) THEN
113               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
114            ELSE
115#if defined key_iomput
116               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
117               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
118                  clpname = clname
119               ELSE
120                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
121               ENDIF
122               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname))
123               CALL xios_update_calendar(nitrst)
124               CALL iom_swap(      cxios_context          )
125#else
126               clinfo = 'Can not use XIOS in rst_opn'
127               CALL ctl_stop(TRIM(clinfo))
128#endif
129            ENDIF
130            lrst_oce = .TRUE.
131         ENDIF
132      ENDIF
133      !
134   END SUBROUTINE rst_opn
135
136
137   SUBROUTINE rst_write( kt )
138      !!---------------------------------------------------------------------
139      !!                   ***  ROUTINE rstwrite  ***
140      !!                     
141      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
142      !!
143      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
144      !!              file, save fields which are necessary for restart
145      !!----------------------------------------------------------------------
146      INTEGER, INTENT(in) ::   kt   ! ocean time-step
147      !!----------------------------------------------------------------------
148      IF( lwxios )   CALL iom_swap( cwxios_context )
149         
150      CALL    iom_rstput( kt, nitrst, numrow, 'rdt'    , rn_rdt           , ldxios = lwxios )   ! dynamics time step
151      !
152      IF( .NOT. ln_diurnal_only ) THEN
153         CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub               , ldxios = lwxios )   ! before fields
154         CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb               , ldxios = lwxios )
155         CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lwxios )
156         CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lwxios )
157         CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb             , ldxios = lwxios )
158         !
159         CALL iom_rstput( kt, nitrst, numrow, 'un'     , un               , ldxios = lwxios )     ! now fields
160         CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn               , ldxios = lwxios )
161         CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lwxios )
162         CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lwxios )
163         CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn             , ldxios = lwxios )
164         CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop             , ldxios = lwxios )
165         !
166         IF( ln_iscpl ) THEN          ! extra variable needed for the ice sheet coupling
167            CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask  , ldxios = lwxios )    ! need to extrapolate T/S
168            CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask  , ldxios = lwxios )    ! need to correct barotropic velocity
169            CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask  , ldxios = lwxios )    ! need to correct barotropic velocity
170            CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask , ldxios = lwxios )    ! need to correct barotropic velocity
171            CALL iom_rstput( kt, nitrst, numrow, 'e3t_n'  , e3t_n  , ldxios = lwxios )    ! need to compute temperature correction
172            CALL iom_rstput( kt, nitrst, numrow, 'e3u_n'  , e3u_n  , ldxios = lwxios )    ! need to compute bt conservation
173            CALL iom_rstput( kt, nitrst, numrow, 'e3v_n'  , e3v_n  , ldxios = lwxios )    ! need to compute bt conservation
174            CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n, ldxios = lwxios )    ! need to compute extrapolation if vvl
175         ENDIF
176      ENDIF
177      !
178      IF( ln_diurnal )   CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios ) 
179      IF( lwxios     )   CALL iom_swap( cxios_context )
180      IF( kt == nitrst ) THEN
181         IF( lwxios ) THEN   ;   CALL iom_context_finalize( cwxios_context )
182         ELSE                ;   CALL iom_close( numrow )     ! close the restart file (only at last time step)
183         ENDIF
184!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
185!!gm  not sure what to do here   ===>>>  ask to Sebastian
186         lrst_oce = .FALSE.
187         IF( ln_rst_list ) THEN
188            nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
189            nitrst = nstocklist( nrst_lst )
190         ENDIF
191      ENDIF
192      !
193   END SUBROUTINE rst_write
194
195
196   SUBROUTINE rst_read_open
197      !!----------------------------------------------------------------------
198      !!                   ***  ROUTINE rst_read_open  ***
199      !!
200      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
201      !!
202      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
203      !!                the file has already been opened
204      !!----------------------------------------------------------------------
205      INTEGER       ::   jlibalt = jprstlib
206      LOGICAL       ::   llok
207      CHARACTER(lc) ::   clpath   ! full path to ocean output restart file
208      !!----------------------------------------------------------------------
209      !
210      IF( numror <= 0 ) THEN
211         IF(lwp) THEN                                             ! Contol prints
212            WRITE(numout,*)
213            SELECT CASE ( jprstlib )
214            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
215            END SELECT
216            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
217            WRITE(numout,*) '~~~~~~~~'
218         ENDIF
219         lxios_sini = .FALSE.
220         clpath = TRIM(cn_ocerst_indir)
221         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
222         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
223! are we using XIOS to read the data? Part above will have to modified once XIOS
224! can handle checking if variable is in the restart file (there will be no need to open
225! restart)
226         IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
227         IF( lrxios) THEN
228             crxios_context = 'nemo_rst'
229             IF( .NOT.lxios_set ) THEN
230                 IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
231                 CALL iom_init( crxios_context )
232                 lxios_set = .TRUE.
233             ENDIF
234         ENDIF
235         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
236             CALL iom_init( crxios_context )
237             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
238             lxios_set = .TRUE.
239         ENDIF
240      ENDIF
241      !
242   END SUBROUTINE rst_read_open
243
244
245   SUBROUTINE rst_read
246      !!----------------------------------------------------------------------
247      !!                   ***  ROUTINE rst_read  ***
248      !!
249      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
250      !!
251      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
252      !!----------------------------------------------------------------------
253      REAL(wp) ::   zrdt
254      INTEGER  ::   jk
255      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
256      !!----------------------------------------------------------------------
257      !
258      CALL rst_read_open           ! open restart for reading (if not already opened)
259
260      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
261      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
262         CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
263         IF( zrdt /= rn_rdt ) THEN
264            IF(lwp) WRITE( numout,*)
265            IF(lwp) WRITE( numout,*) 'rst_read:  rdt not equal to the read one'
266            IF(lwp) WRITE( numout,*)
267            IF(lwp) WRITE( numout,*) '      ==>>>   forced euler first time-step'
268            l_1st_euler =  .TRUE.
269         ENDIF
270      ENDIF
271
272      ! Diurnal DSST
273      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios ) 
274      IF ( ln_diurnal_only ) THEN
275         IF(lwp) WRITE( numout,*) 'rst_read: ln_diurnal_only set, setting rhop=rau0'
276         rhop = rau0
277         CALL iom_get( numror, jpdom_autoglo, 'tn'     , w3d, ldxios = lrxios ) 
278         tsn(:,:,1,jp_tem) = w3d(:,:,1)
279         RETURN
280      ENDIF 
281     
282      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0  .AND. .NOT.l_1st_euler ) THEN
283         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub, ldxios = lrxios                )   ! before fields
284         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb, ldxios = lrxios                )
285         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lrxios )
286         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lrxios )
287         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb, ldxios = lrxios              )
288      ELSE
289         l_1st_euler =  .TRUE.      ! before field not found, forced euler 1st time-step
290      ENDIF
291      !
292      CALL iom_get( numror, jpdom_autoglo, 'un'     , un, ldxios = lrxios )   ! now    fields
293      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn, ldxios = lrxios )
294      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lrxios )
295      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lrxios )
296      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn, ldxios = lrxios )
297      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
298         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop, ldxios = lrxios )   ! now    potential density
299      ELSE
300         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
301      ENDIF
302      !
303      IF( l_1st_euler ) THEN              ! Euler restart
304         tsb (:,:,:,:) = tsn (:,:,:,:)          ! all before fields set to now values
305         ub  (:,:,:)   = un  (:,:,:)
306         vb  (:,:,:)   = vn  (:,:,:)
307         sshb(:,:)     = sshn(:,:)
308         IF( .NOT.ln_linssh )   e3t_b(:,:,:) = e3t_n(:,:,:)
309      ENDIF
310      !
311   END SUBROUTINE rst_read
312
313   !!=====================================================================
314END MODULE restart
Note: See TracBrowser for help on using the repository browser.