New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in NEMO/branches/2018/dev_r9838_ENHANCE04_MLF/src/OCE/TRA – NEMO

source: NEMO/branches/2018/dev_r9838_ENHANCE04_MLF/src/OCE/TRA/traadv_fct.F90 @ 9923

Last change on this file since 9923 was 9923, checked in by gm, 6 years ago

#1911 (ENHANCE-04): step I.2: dev_r9838_ENHANCE04_MLF
  • Property svn:keywords set to Id
File size: 33.5 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            !
25   USE lib_mpp        ! MPP library
26   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
27   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_adv_fct        ! called by traadv.F90
33   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
34
35   LOGICAL  ::   l_trd   ! flag to compute trends
36   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
37   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
38   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
39
40   !                                        ! tridiag solver associated indices:
41   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
42   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
43
44   !! * Substitutions
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pun, pvn, pwn,       &
54      &                                              ptb, ptn, pta, kjpt, kn_fct_h, kn_fct_v )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_adv_fct  ***
57      !!
58      !! **  Purpose :   Compute the now trend due to total advection of tracers
59      !!               and add it to the general trend of tracer equations
60      !!
61      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
62      !!               (choice through the value of kn_fct)
63      !!               - on the vertical the 4th order is a compact scheme
64      !!               - corrected flux (monotonic correction)
65      !!
66      !! ** Action : - update pta  with the now advective tracer trends
67      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
68      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
69      !!----------------------------------------------------------------------
70      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
71      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
74      INTEGER                              , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
75      INTEGER                              , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
76      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
80      !
81      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
82      REAL(wp) ::   ztra                                     ! local scalar
83      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
84      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
85      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
86      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
87      !!----------------------------------------------------------------------
88      !
89      IF( kt == kit000 )  THEN
90         IF(lwp) WRITE(numout,*)
91         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
92         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
93      ENDIF
94      !
95      l_trd = .FALSE.            ! set local switches
96      l_hst = .FALSE.
97      l_ptr = .FALSE.
98      IF( ( cdtype =='TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )       l_trd = .TRUE.
99      IF(   cdtype =='TRA' .AND. ln_diaptr )                                                l_ptr = .TRUE. 
100      IF(   cdtype =='TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
101         &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
102      !
103      IF( l_trd .OR. l_hst )  THEN
104         ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
105         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
106      ENDIF
107      !
108      IF( l_ptr ) THEN 
109         ALLOCATE( zptry(jpi,jpj,jpk) )
110         zptry(:,:,:) = 0._wp
111      ENDIF
112      !                          ! surface & bottom value : flux set to zero one for all
113      zwz(:,:, 1 ) = 0._wp           
114      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
115      !
116      zwi(:,:,:) = 0._wp       
117      !
118      DO jn = 1, kjpt            !==  loop over the tracers  ==!
119         !
120         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
121         !                    !* upstream tracer flux in the i and j direction
122         DO jk = 1, jpkm1
123            DO jj = 1, jpjm1
124               DO ji = 1, fs_jpim1   ! vector opt.
125                  ! upstream scheme
126                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
127                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
128                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
129                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
130                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
131                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
132!!gm faster coding ?   ===>>> to be tested :
133!                  zwx(ji,jj,jk) = MAX( pun(ji,jj,jk) , 0._wp ) * ptb(ji  ,jj,jk,jn)   &
134!                     &          + MIN( pun(ji,jj,jk) , 0._wp ) * ptb(ji+1,jj,jk,jn)
135!                  zwy(ji,jj,jk) = MAX( pvn(ji,jj,jk) , 0._wp ) * ptb(ji,jj  ,jk,jn)   &
136!                     &          + MIN( pvn(ji,jj,jk) , 0._wp ) * ptb(ji,jj+1,jk,jn)
137!!gm
138                 
139               END DO
140            END DO
141         END DO
142         !                    !* upstream tracer flux in the k direction *!
143         DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
144            DO jj = 1, jpj
145               DO ji = 1, jpi
146                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
147                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
148                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
149!!gm faster coding ?   ===>>> to be tested :
150!                  zwx(ji,jj,jk) = MAX( pwn(ji,jj,jk) , 0._wp ) * pwn(ji,jj,jk  ,jn)   &
151!                     &          + MIN( pwn(ji,jj,jk) , 0._wp ) * pwn(ji,jj,jk-1,jn)
152!!gm
153               END DO
154            END DO
155         END DO
156         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
157            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
158               DO jj = 1, jpj
159                  DO ji = 1, jpi
160                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
161                  END DO
162               END DO   
163            ELSE                             ! no cavities: only at the ocean surface
164               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
165            ENDIF
166         ENDIF
167         !               
168         DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
169            DO jj = 2, jpjm1
170               DO ji = fs_2, fs_jpim1   ! vector opt.
171                  !                             ! total intermediate advective trends
172                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
173                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
174                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
175                  !                             ! update and guess with monotonic sheme
176                  pta(ji,jj,jk,jn) =                     pta(ji,jj,jk,jn) +        ztra   / e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
177                  zwi(ji,jj,jk)    = ( e3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + p2dt * ztra ) / e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
178               END DO
179            END DO
180         END DO
181         CALL lbc_lnk( zwi, 'T', 1. )  ! Lateral boundary conditions on zwi  (unchanged sign)
182         !               
183         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
184            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
185         END IF
186         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
187         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
188         !
189         !        !==  anti-diffusive flux : high order minus low order  ==!
190         !
191         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
192         !
193         CASE(  2  )                   !- 2nd order centered
194            DO jk = 1, jpkm1
195               DO jj = 1, jpjm1
196                  DO ji = 1, fs_jpim1   ! vector opt.
197                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
198                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
199                  END DO
200               END DO
201            END DO
202            !
203         CASE(  4  )                   !- 4th order centered
204            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
205            zltv(:,:,jpk) = 0._wp
206            DO jk = 1, jpkm1                 ! Laplacian
207               DO jj = 1, jpjm1                    ! 1st derivative (gradient)
208                  DO ji = 1, fs_jpim1   ! vector opt.
209                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
210                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
211                  END DO
212               END DO
213               DO jj = 2, jpjm1                    ! 2nd derivative * 1/ 6
214                  DO ji = fs_2, fs_jpim1   ! vector opt.
215                     zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
216                     zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
217                  END DO
218               END DO
219            END DO
220            CALL lbc_lnk_multi( zltu, 'T', 1. , zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
221            !
222            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
223               DO jj = 1, jpjm1
224                  DO ji = 1, fs_jpim1   ! vector opt.
225                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points
226                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
227                     !                                                  ! C4 minus upstream advective fluxes
228                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
229                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
230                  END DO
231               END DO
232            END DO         
233            !
234         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
235            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
236            ztv(:,:,jpk) = 0._wp
237            DO jk = 1, jpkm1                 ! 1st derivative (gradient)
238               DO jj = 1, jpjm1
239                  DO ji = 1, fs_jpim1   ! vector opt.
240                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
241                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
242                  END DO
243               END DO
244            END DO
245            CALL lbc_lnk_multi( ztu, 'U', -1. , ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
246            !
247            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
248               DO jj = 2, jpjm1
249                  DO ji = 2, fs_jpim1   ! vector opt.
250                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points (x2)
251                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
252                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
253                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
254                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
255                     !                                                  ! C4 minus upstream advective fluxes
256                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
257                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
258                  END DO
259               END DO
260            END DO
261            !
262         END SELECT
263         !                     
264         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
265         !
266         CASE(  2  )                   !- 2nd order centered
267            DO jk = 2, jpkm1   
268               DO jj = 2, jpjm1
269                  DO ji = fs_2, fs_jpim1
270                     zwz(ji,jj,jk) =  (  pwn(ji,jj,jk) * 0.5_wp * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) )   &
271                        &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
272                  END DO
273               END DO
274            END DO
275            !
276         CASE(  4  )                   !- 4th order COMPACT
277            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )   ! zwt = COMPACT interpolation of T at w-point
278            DO jk = 2, jpkm1
279               DO jj = 2, jpjm1
280                  DO ji = fs_2, fs_jpim1
281                     zwz(ji,jj,jk) = ( pwn(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
282                  END DO
283               END DO
284            END DO
285            !
286         END SELECT
287         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
288            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
289         ENDIF
290         !
291         CALL lbc_lnk_multi( zwx, 'U', -1. , zwy, 'V', -1.,  zwz, 'W',  1. )
292         !
293         !        !==  monotonicity algorithm  ==!
294         !
295         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
296         !
297         !        !==  final trend with corrected fluxes  ==!
298         !
299         DO jk = 1, jpkm1
300            DO jj = 2, jpjm1
301               DO ji = fs_2, fs_jpim1   ! vector opt. 
302                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
303                     &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
304                     &                                   + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) &
305                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
306               END DO
307            END DO
308         END DO
309         !
310         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
311            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
312            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
313            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
314            !
315            IF( l_trd ) THEN              ! trend diagnostics
316               CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
317               CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
318               CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
319            ENDIF
320            !                             ! heat/salt transport
321            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
322            !
323            DEALLOCATE( ztrdx, ztrdy, ztrdz )
324         ENDIF
325         IF( l_ptr ) THEN              ! "Poleward" transports
326            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
327            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
328            DEALLOCATE( zptry )
329         ENDIF
330         !
331      END DO                     ! end of tracer loop
332      !
333   END SUBROUTINE tra_adv_fct
334
335
336   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
337      !!---------------------------------------------------------------------
338      !!                    ***  ROUTINE nonosc  ***
339      !!     
340      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
341      !!       scheme and the before field by a nonoscillatory algorithm
342      !!
343      !! **  Method  :   ... ???
344      !!       warning : pbef and paft must be masked, but the boundaries
345      !!       conditions on the fluxes are not necessary zalezak (1979)
346      !!       drange (1995) multi-dimensional forward-in-time and upstream-
347      !!       in-space based differencing for fluid
348      !!----------------------------------------------------------------------
349      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
350      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
351      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
352      !
353      INTEGER  ::   ji, jj, jk   ! dummy loop indices
354      INTEGER  ::   ikm1         ! local integer
355      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
356      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
357      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zbetup, zbetdo, zbup, zbdo
358      !!----------------------------------------------------------------------
359      !
360      zbig  = 1.e+40_wp
361      zrtrn = 1.e-15_wp
362      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
363
364      ! Search local extrema
365      ! --------------------
366      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
367      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
368         &        paft * tmask - zbig * ( 1._wp - tmask )  )
369      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
370         &        paft * tmask + zbig * ( 1._wp - tmask )  )
371
372      DO jk = 1, jpkm1
373         ikm1 = MAX(jk-1,1)
374         DO jj = 2, jpjm1
375            DO ji = fs_2, fs_jpim1   ! vector opt.
376
377               ! search maximum in neighbourhood
378               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
379                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
380                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
381                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
382
383               ! search minimum in neighbourhood
384               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
385                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
386                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
387                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
388
389               ! positive part of the flux
390               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
391                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
392                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
393
394               ! negative part of the flux
395               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
396                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
397                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
398
399               ! up & down beta terms
400               zbt = e1e2t(ji,jj) * e3t_n(ji,jj,jk) / p2dt
401               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
402               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
403            END DO
404         END DO
405      END DO
406      CALL lbc_lnk_multi( zbetup, 'T', 1. , zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
407
408      ! 3. monotonic flux in the i & j direction (paa & pbb)
409      ! ----------------------------------------
410      DO jk = 1, jpkm1
411         DO jj = 2, jpjm1
412            DO ji = fs_2, fs_jpim1   ! vector opt.
413               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
414               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
415               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
416               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
417
418               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
419               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
420               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
421               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
422
423      ! monotonic flux in the k direction, i.e. pcc
424      ! -------------------------------------------
425               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
426               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
427               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
428               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
429            END DO
430         END DO
431      END DO
432      CALL lbc_lnk_multi( paa, 'U', -1. , pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
433      !
434   END SUBROUTINE nonosc
435
436
437   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
438      !!----------------------------------------------------------------------
439      !!                  ***  ROUTINE interp_4th_cpt_org  ***
440      !!
441      !! **  Purpose :   Compute the interpolation of tracer at w-point
442      !!
443      !! **  Method  :   4th order compact interpolation
444      !!----------------------------------------------------------------------
445      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
446      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
447      !
448      INTEGER :: ji, jj, jk   ! dummy loop integers
449      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
450      !!----------------------------------------------------------------------
451     
452      DO jk = 3, jpkm1        !==  build the three diagonal matrix  ==!
453         DO jj = 1, jpj
454            DO ji = 1, jpi
455               zwd (ji,jj,jk) = 4._wp
456               zwi (ji,jj,jk) = 1._wp
457               zws (ji,jj,jk) = 1._wp
458               zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
459               !
460               IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
461                  zwd (ji,jj,jk) = 1._wp
462                  zwi (ji,jj,jk) = 0._wp
463                  zws (ji,jj,jk) = 0._wp
464                  zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
465               ENDIF
466            END DO
467         END DO
468      END DO
469      !
470      jk = 2                                          ! Switch to second order centered at top
471      DO jj = 1, jpj
472         DO ji = 1, jpi
473            zwd (ji,jj,jk) = 1._wp
474            zwi (ji,jj,jk) = 0._wp
475            zws (ji,jj,jk) = 0._wp
476            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
477         END DO
478      END DO   
479      !
480      !                       !==  tridiagonal solve  ==!
481      DO jj = 1, jpj                ! first recurrence
482         DO ji = 1, jpi
483            zwt(ji,jj,2) = zwd(ji,jj,2)
484         END DO
485      END DO
486      DO jk = 3, jpkm1
487         DO jj = 1, jpj
488            DO ji = 1, jpi
489               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
490            END DO
491         END DO
492      END DO
493      !
494      DO jj = 1, jpj                ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
495         DO ji = 1, jpi
496            pt_out(ji,jj,2) = zwrm(ji,jj,2)
497         END DO
498      END DO
499      DO jk = 3, jpkm1
500         DO jj = 1, jpj
501            DO ji = 1, jpi
502               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
503            END DO
504         END DO
505      END DO
506
507      DO jj = 1, jpj                ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
508         DO ji = 1, jpi
509            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
510         END DO
511      END DO
512      DO jk = jpk-2, 2, -1
513         DO jj = 1, jpj
514            DO ji = 1, jpi
515               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
516            END DO
517         END DO
518      END DO
519      !   
520   END SUBROUTINE interp_4th_cpt_org
521   
522
523   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
524      !!----------------------------------------------------------------------
525      !!                  ***  ROUTINE interp_4th_cpt  ***
526      !!
527      !! **  Purpose :   Compute the interpolation of tracer at w-point
528      !!
529      !! **  Method  :   4th order compact interpolation
530      !!----------------------------------------------------------------------
531      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
532      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
533      !
534      INTEGER ::   ji, jj, jk   ! dummy loop integers
535      INTEGER ::   ikt, ikb     ! local integers
536      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
537      !!----------------------------------------------------------------------
538      !
539      !                      !==  build the three diagonal matrix & the RHS  ==!
540      !
541      DO jk = 3, jpkm1                 ! interior (from jk=3 to jpk-1)
542         DO jj = 2, jpjm1
543            DO ji = fs_2, fs_jpim1
544               zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
545               zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
546               zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
547               zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
548                  &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
549            END DO
550         END DO
551      END DO
552      !
553!!gm
554!      SELECT CASE( kbc )               !* boundary condition
555!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
556!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
557!      END SELECT
558!!gm 
559      !
560      DO jj = 2, jpjm1                 ! 2nd order centered at top & bottom
561         DO ji = fs_2, fs_jpim1
562            ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
563            ikb = mbkt(ji,jj)                !     -   above the last wet point
564            !
565            zwd (ji,jj,ikt) = 1._wp          ! top
566            zwi (ji,jj,ikt) = 0._wp
567            zws (ji,jj,ikt) = 0._wp
568            zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
569            !
570            zwd (ji,jj,ikb) = 1._wp          ! bottom
571            zwi (ji,jj,ikb) = 0._wp
572            zws (ji,jj,ikb) = 0._wp
573            zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )           
574         END DO
575      END DO   
576      !
577      !                       !==  tridiagonal solver  ==!
578      !
579      DO jj = 2, jpjm1              !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
580         DO ji = fs_2, fs_jpim1
581            zwt(ji,jj,2) = zwd(ji,jj,2)
582         END DO
583      END DO
584      DO jk = 3, jpkm1
585         DO jj = 2, jpjm1
586            DO ji = fs_2, fs_jpim1
587               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
588            END DO
589         END DO
590      END DO
591      !
592      DO jj = 2, jpjm1              !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
593         DO ji = fs_2, fs_jpim1
594            pt_out(ji,jj,2) = zwrm(ji,jj,2)
595         END DO
596      END DO
597      DO jk = 3, jpkm1
598         DO jj = 2, jpjm1
599            DO ji = fs_2, fs_jpim1
600               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
601            END DO
602         END DO
603      END DO
604
605      DO jj = 2, jpjm1              !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
606         DO ji = fs_2, fs_jpim1
607            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
608         END DO
609      END DO
610      DO jk = jpk-2, 2, -1
611         DO jj = 2, jpjm1
612            DO ji = fs_2, fs_jpim1
613               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
614            END DO
615         END DO
616      END DO
617      !   
618   END SUBROUTINE interp_4th_cpt
619
620
621   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
622      !!----------------------------------------------------------------------
623      !!                  ***  ROUTINE tridia_solver  ***
624      !!
625      !! **  Purpose :   solve a symmetric 3diagonal system
626      !!
627      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
628      !!     
629      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
630      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
631      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
632      !!             (        ...          )( ... )   ( ...  )
633      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
634      !!     
635      !!        M is decomposed in the product of an upper and lower triangular matrix.
636      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
637      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
638      !!        The solution is pta.
639      !!        The 3d array zwt is used as a work space array.
640      !!----------------------------------------------------------------------
641      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
642      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
643      REAL(wp),DIMENSION(:,:,:), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
644      INTEGER                  , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
645      !                                                           ! =0 pt at t-level
646      INTEGER ::   ji, jj, jk   ! dummy loop integers
647      INTEGER ::   kstart       ! local indices
648      REAL(wp),DIMENSION(jpi,jpj,jpk) ::   zwt   ! 3D work array
649      !!----------------------------------------------------------------------
650      !
651      kstart =  1  + klev
652      !
653      DO jj = 2, jpjm1              !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1
654         DO ji = fs_2, fs_jpim1
655            zwt(ji,jj,kstart) = pD(ji,jj,kstart)
656         END DO
657      END DO
658      DO jk = kstart+1, jpkm1
659         DO jj = 2, jpjm1
660            DO ji = fs_2, fs_jpim1
661               zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
662            END DO
663         END DO
664      END DO
665      !
666      DO jj = 2, jpjm1              !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
667         DO ji = fs_2, fs_jpim1
668            pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
669         END DO
670      END DO
671      DO jk = kstart+1, jpkm1
672         DO jj = 2, jpjm1
673            DO ji = fs_2, fs_jpim1
674               pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
675            END DO
676         END DO
677      END DO
678
679      DO jj = 2, jpjm1              !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk
680         DO ji = fs_2, fs_jpim1
681            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
682         END DO
683      END DO
684      DO jk = jpk-2, kstart, -1
685         DO jj = 2, jpjm1
686            DO ji = fs_2, fs_jpim1
687               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
688            END DO
689         END DO
690      END DO
691      !
692   END SUBROUTINE tridia_solver
693
694   !!======================================================================
695END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.