New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_triad.F90 in NEMO/branches/2018/dev_r9838_ENHANCE04_MLF/src/OCE/TRA – NEMO

source: NEMO/branches/2018/dev_r9838_ENHANCE04_MLF/src/OCE/TRA/traldf_triad.F90 @ 9923

Last change on this file since 9923 was 9923, checked in by gm, 6 years ago

#1911 (ENHANCE-04): step I.2: dev_r9838_ENHANCE04_MLF

  • Property svn:keywords set to Id
File size: 23.2 KB
Line 
1MODULE traldf_triad
2   !!======================================================================
3   !!                   ***  MODULE  traldf_triad  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec)  Griffies operator (original code)
7   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and active tracers
14   USE dom_oce        ! ocean space and time domain
15   USE phycst         ! physical constants
16   USE trc_oce        ! share passive tracers/Ocean variables
17   USE zdf_oce        ! ocean vertical physics
18   USE ldftra         ! lateral physics: eddy diffusivity
19   USE ldfslp         ! lateral physics: iso-neutral slopes
20   USE traldf_iso     ! lateral diffusion (Madec operator)         (tra_ldf_iso routine)
21   USE diaptr         ! poleward transport diagnostics
22   USE diaar5         ! AR5 diagnostics
23   USE zpshde         ! partial step: hor. derivative     (zps_hde routine)
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! I/O library
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_ldf_triad   ! routine called by traldf.F90
34
35   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zdkt3d   !: vertical tracer gradient at 2 levels
36
37   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
38   LOGICAL  ::   l_hst   ! flag to compute heat transport
39
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50  SUBROUTINE tra_ldf_triad( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
51      &                                                     pgui, pgvi,   &
52      &                                         ptb , ptbb, pta , kjpt, kpass )
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_triad  ***
55      !!
56      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
57      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
58      !!      add it to the general trend of tracer equation.
59      !!
60      !! ** Method  :   The horizontal component of the lateral diffusive trends
61      !!      is provided by a 2nd order operator rotated along neural or geopo-
62      !!      tential surfaces to which an eddy induced advection can be added
63      !!      It is computed using before fields (forward in time) and isopyc-
64      !!      nal or geopotential slopes computed in routine ldfslp.
65      !!
66      !!      see documentation for the desciption
67      !!
68      !! ** Action :   pta   updated with the before rotated diffusion
69      !!               ah_wslp2 ....
70      !!               akz   stabilizing vertical diffusivity coefficient (used in trazdf_imp)
71      !!----------------------------------------------------------------------
72      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
76      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
77      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
78      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu , pgv  ! tracer gradient at pstep levels
79      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! tracer (kpass=1) or laplacian of tracer (kpass=2)
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptbb       ! tracer (only used in kpass=2)
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
83      !
84      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
85      INTEGER  ::  ip,jp,kp         ! dummy loop indices
86      INTEGER  ::  ierr            ! local integer
87      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
88      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
89      REAL(wp) ::  zcoef0, ze3w_2, zsign         !   -      -
90      !
91      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
92      REAL(wp) ::   ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt
93      REAL(wp) ::   zah, zah_slp, zaei_slp
94      REAL(wp), DIMENSION(jpi,jpj    ) ::   z2d                                              ! 2D workspace
95      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw   ! 3D     -
96      !!----------------------------------------------------------------------
97      !
98      IF( .NOT.ALLOCATED(zdkt3d) )  THEN
99         ALLOCATE( zdkt3d(jpi,jpj,0:1) , STAT=ierr )
100         IF( lk_mpp   )   CALL mpp_sum ( ierr )
101         IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_triad: unable to allocate arrays')
102      ENDIF
103     !
104      IF( kpass == 1 .AND. kt == kit000 )  THEN
105         IF(lwp) WRITE(numout,*)
106         IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype
107         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
108      ENDIF
109      !   
110      l_hst = .FALSE.
111      l_ptr = .FALSE.
112      IF( cdtype == 'TRA' ) THEN
113         IF ( ln_diaptr )                                                 l_ptr = .TRUE. 
114         IF ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
115            & iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")      )   l_hst = .TRUE.
116      ENDIF
117      !
118      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
119      ELSE                    ;   zsign = -1._wp
120      ENDIF
121      !   
122      !!----------------------------------------------------------------------
123      !!   0 - calculate  ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw
124      !!----------------------------------------------------------------------
125      !
126      IF( kpass == 1 ) THEN         !==  first pass only  and whatever the tracer is  ==!
127         !
128         akz     (:,:,:) = 0._wp     
129         ah_wslp2(:,:,:) = 0._wp
130         IF( ln_ldfeiv_dia ) THEN
131            zpsi_uw(:,:,:) = 0._wp
132            zpsi_vw(:,:,:) = 0._wp
133         ENDIF
134         !
135         DO ip = 0, 1                            ! i-k triads
136            DO kp = 0, 1
137               DO jk = 1, jpkm1
138                  DO jj = 1, jpjm1
139                     DO ji = 1, fs_jpim1
140                        ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp)
141                        zbu   = e1e2u(ji,jj) * e3u_n(ji,jj,jk)
142                        zah   = 0.25_wp * pahu(ji,jj,jk)
143                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
144                        ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth)
145                        zslope2 = zslope_skew + ( gdept_n(ji+1,jj,jk) - gdept_n(ji,jj,jk) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp)
146                        zslope2 = zslope2 *zslope2
147                        ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji+ip,jj) * zslope2
148                        akz     (ji+ip,jj,jk+kp) = akz     (ji+ip,jj,jk+kp) + zah * r1_e1u(ji,jj)       &
149                           &                                                      * r1_e1u(ji,jj) * umask(ji,jj,jk+kp)
150                           !
151                       IF( ln_ldfeiv_dia )   zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp)   &
152                           &                                       + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * zslope_skew
153                     END DO
154                  END DO
155               END DO
156            END DO
157         END DO
158         !
159         DO jp = 0, 1                            ! j-k triads
160            DO kp = 0, 1
161               DO jk = 1, jpkm1
162                  DO jj = 1, jpjm1
163                     DO ji = 1, fs_jpim1
164                        ze3wr = 1.0_wp / e3w_n(ji,jj+jp,jk+kp)
165                        zbv   = e1e2v(ji,jj) * e3v_n(ji,jj,jk)
166                        zah   = 0.25_wp * pahv(ji,jj,jk)
167                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
168                        ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
169                        !    (do this by *adding* gradient of depth)
170                        zslope2 = zslope_skew + ( gdept_n(ji,jj+1,jk) - gdept_n(ji,jj,jk) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp)
171                        zslope2 = zslope2 * zslope2
172                        ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj+jp) * zslope2
173                        akz     (ji,jj+jp,jk+kp) = akz     (ji,jj+jp,jk+kp) + zah * r1_e2v(ji,jj)     &
174                           &                                                      * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp)
175                        !
176                        IF( ln_ldfeiv_dia )   zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp)   &
177                           &                                       + 0.25 * aeiv(ji,jj,jk) * e1v(ji,jj) * zslope_skew
178                     END DO
179                  END DO
180               END DO
181            END DO
182         END DO
183         !
184         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
185            !
186            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
187               DO jk = 2, jpkm1
188                  DO jj = 1, jpjm1
189                     DO ji = 1, fs_jpim1
190                        akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
191                           &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) )  )
192                     END DO
193                  END DO
194               END DO
195            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
196               DO jk = 2, jpkm1
197                  DO jj = 1, jpjm1
198                     DO ji = 1, fs_jpim1
199                        ze3w_2 = e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk)
200                        zcoef0 = rDt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
201                        akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * r1_Dt
202                     END DO
203                  END DO
204               END DO
205           ENDIF
206           !
207         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
208            akz(:,:,:) = ah_wslp2(:,:,:)     
209         ENDIF
210         !
211         IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' )   CALL ldf_eiv_dia( zpsi_uw, zpsi_vw )
212         !
213      ENDIF                                  !==  end 1st pass only  ==!
214      !
215      !                                                           ! ===========
216      DO jn = 1, kjpt                                             ! tracer loop
217         !                                                        ! ===========
218         ! Zero fluxes for each tracer
219!!gm  this should probably be done outside the jn loop
220         ztfw(:,:,:) = 0._wp
221         zftu(:,:,:) = 0._wp
222         zftv(:,:,:) = 0._wp
223         !
224         DO jk = 1, jpkm1        !==  before lateral T & S gradients at T-level jk  ==!
225            DO jj = 1, jpjm1
226               DO ji = 1, fs_jpim1   ! vector opt.
227                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
228                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
229               END DO
230            END DO
231         END DO
232         IF( ln_zps .AND. l_grad_zps ) THEN    ! partial steps: correction at top/bottom ocean level
233            DO jj = 1, jpjm1                       ! bottom level
234               DO ji = 1, fs_jpim1   ! vector opt.
235                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)
236                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
237               END DO
238            END DO
239            IF( ln_isfcav ) THEN                   ! top level (ocean cavities only)
240               DO jj = 1, jpjm1
241                  DO ji = 1, fs_jpim1   ! vector opt.
242                     IF( miku(ji,jj)  > 1 )   zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) 
243                     IF( mikv(ji,jj)  > 1 )   zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) 
244                  END DO
245               END DO
246            ENDIF
247         ENDIF
248         !
249         !!----------------------------------------------------------------------
250         !!   II - horizontal trend  (full)
251         !!----------------------------------------------------------------------
252         !
253         DO jk = 1, jpkm1
254            !                    !==  Vertical tracer gradient at level jk and jk+1
255            zdkt3d(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
256            !
257            !                    ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1)
258            IF( jk == 1 ) THEN   ;   zdkt3d(:,:,0) = zdkt3d(:,:,1)
259            ELSE                 ;   zdkt3d(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
260            ENDIF
261            !
262            zaei_slp = 0._wp
263            !
264            IF( ln_botmix_triad ) THEN
265               DO ip = 0, 1              !==  Horizontal & vertical fluxes
266                  DO kp = 0, 1
267                     DO jj = 1, jpjm1
268                        DO ji = 1, fs_jpim1
269                           ze1ur = r1_e1u(ji,jj)
270                           zdxt  = zdit(ji,jj,jk) * ze1ur
271                           ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp)
272                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
273                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
274                           zslope_iso  = triadi  (ji+ip,jj,jk,1-ip,kp)
275                           !
276                           zbu = 0.25_wp * e1e2u(ji,jj) * e3u_n(ji,jj,jk)
277                           ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????   ahu is masked....
278                           zah = pahu(ji,jj,jk)
279                           zah_slp  = zah * zslope_iso
280                           IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew
281                           zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
282                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt                 * zbu * ze3wr
283                        END DO
284                     END DO
285                  END DO
286               END DO
287               !
288               DO jp = 0, 1
289                  DO kp = 0, 1
290                     DO jj = 1, jpjm1
291                        DO ji = 1, fs_jpim1
292                           ze2vr = r1_e2v(ji,jj)
293                           zdyt  = zdjt(ji,jj,jk) * ze2vr
294                           ze3wr = 1._wp / e3w_n(ji,jj+jp,jk+kp)
295                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
296                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
297                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
298                           zbv = 0.25_wp * e1e2v(ji,jj) * e3v_n(ji,jj,jk)
299                           ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????  ahv is masked...
300                           zah = pahv(ji,jj,jk)
301                           zah_slp = zah * zslope_iso
302                           IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew
303                           zftv(ji,jj   ,jk   ) = zftv(ji,jj   ,jk   ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
304                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt                * zbv * ze3wr
305                        END DO
306                     END DO
307                  END DO
308               END DO
309               !
310            ELSE
311               !
312               DO ip = 0, 1               !==  Horizontal & vertical fluxes
313                  DO kp = 0, 1
314                     DO jj = 1, jpjm1
315                        DO ji = 1, fs_jpim1
316                           ze1ur = r1_e1u(ji,jj)
317                           zdxt  = zdit(ji,jj,jk) * ze1ur
318                           ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp)
319                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
320                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
321                           zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
322                           !
323                           zbu = 0.25_wp * e1e2u(ji,jj) * e3u_n(ji,jj,jk)
324                           ! ln_botmix_triad is .F. mask zah for bottom half cells
325                           zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp)         ! pahu(ji+ip,jj,jk)   ===>>  ????
326                           zah_slp  = zah * zslope_iso
327                           IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew        ! aeit(ji+ip,jj,jk)*zslope_skew
328                           zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
329                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
330                        END DO
331                     END DO
332                  END DO
333               END DO
334               !
335               DO jp = 0, 1
336                  DO kp = 0, 1
337                     DO jj = 1, jpjm1
338                        DO ji = 1, fs_jpim1
339                           ze2vr = r1_e2v(ji,jj)
340                           zdyt  = zdjt(ji,jj,jk) * ze2vr
341                           ze3wr = 1._wp / e3w_n(ji,jj+jp,jk+kp)
342                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
343                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
344                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
345                           zbv = 0.25_wp * e1e2v(ji,jj) * e3v_n(ji,jj,jk)
346                           ! ln_botmix_triad is .F. mask zah for bottom half cells
347                           zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp)         ! pahv(ji,jj+jp,jk)  ????
348                           zah_slp = zah * zslope_iso
349                           IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew        ! aeit(ji,jj+jp,jk)*zslope_skew
350                           zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
351                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
352                        END DO
353                     END DO
354                  END DO
355               END DO
356            ENDIF
357            !                             !==  horizontal divergence and add to the general trend  ==!
358            DO jj = 2 , jpjm1
359               DO ji = fs_2, fs_jpim1  ! vector opt.
360                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  zftu(ji-1,jj,jk) - zftu(ji,jj,jk)       &
361                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )   &
362                     &                                        / (  e1e2t(ji,jj) * e3t_n(ji,jj,jk)  )
363               END DO
364            END DO
365            !
366         END DO
367         !
368         !                                !==  add the vertical 33 flux  ==!
369         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
370            DO jk = 2, jpkm1       
371               DO jj = 1, jpjm1
372                  DO ji = fs_2, fs_jpim1
373                     ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk)   &
374                        &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
375                        &                            * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) )
376                  END DO
377               END DO
378            END DO
379         ELSE                                   ! bilaplacian
380            SELECT CASE( kpass )
381            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
382               DO jk = 2, jpkm1 
383                  DO jj = 1, jpjm1
384                     DO ji = fs_2, fs_jpim1
385                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk)             &
386                           &                            * ah_wslp2(ji,jj,jk) * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) )
387                     END DO
388                  END DO
389               END DO
390            CASE(  2  )                            ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb  and ptbb gradients, resp.
391               DO jk = 2, jpkm1 
392                  DO jj = 1, jpjm1
393                     DO ji = fs_2, fs_jpim1
394                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk)                      &
395                           &                            * (  ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) )   &
396                           &                               + akz     (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) )   )
397                     END DO
398                  END DO
399               END DO
400            END SELECT
401         ENDIF
402         !
403         DO jk = 1, jpkm1                 !==  Divergence of vertical fluxes added to pta  ==!
404            DO jj = 2, jpjm1
405               DO ji = fs_2, fs_jpim1  ! vector opt.
406                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
407                     &                                        / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) )
408               END DO
409            END DO
410         END DO
411         !
412         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
413             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
414            !
415            !                          ! "Poleward" diffusive heat or salt transports (T-S case only)
416            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:)  )
417            !                          ! Diffusive heat transports
418            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) )
419            !
420         ENDIF                                                    !== end pass selection  ==!
421         !
422         !                                                        ! ===============
423      END DO                                                      ! end tracer loop
424      !                                                           ! ===============
425   END SUBROUTINE tra_ldf_triad
426
427   !!==============================================================================
428END MODULE traldf_triad
Note: See TracBrowser for help on using the repository browser.