| 1 | MODULE bdylib |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE bdylib *** |
|---|
| 4 | !! Unstructured Open Boundary Cond. : Library module of generic boundary algorithms. |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.6 ! 2013 (D. Storkey) original code |
|---|
| 7 | !! 4.0 ! 2014 (T. Lovato) Generalize OBC structure |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! bdy_frs : Apply the Flow Relaxation Scheme (tracers) |
|---|
| 12 | !! bdy_spe : Apply a specified value (tracers) |
|---|
| 13 | !! bdy_orl : Apply Orlanski radiation (tracers) |
|---|
| 14 | !! bdy_orlanski_2d: 2D - - - |
|---|
| 15 | !! bdy_orlanski_3d: 3D - - - |
|---|
| 16 | !! bdy_nmn : Duplicate the value at open boundaries (zero gradient) |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce ! ocean dynamics and tracers |
|---|
| 19 | USE dom_oce ! ocean space and time domain |
|---|
| 20 | USE bdy_oce ! ocean open boundary conditions |
|---|
| 21 | USE phycst ! physical constants |
|---|
| 22 | ! |
|---|
| 23 | USE in_out_manager ! |
|---|
| 24 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 25 | |
|---|
| 26 | IMPLICIT NONE |
|---|
| 27 | PRIVATE |
|---|
| 28 | |
|---|
| 29 | PUBLIC bdy_frs, bdy_spe, bdy_nmn |
|---|
| 30 | PUBLIC bdy_orl, bdy_orlanski_2d, bdy_orlanski_3d |
|---|
| 31 | |
|---|
| 32 | !!---------------------------------------------------------------------- |
|---|
| 33 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 34 | !! $Id$ |
|---|
| 35 | !! Software governed by the CeCILL licence (./LICENSE) |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | CONTAINS |
|---|
| 38 | |
|---|
| 39 | SUBROUTINE bdy_frs( idx, pta, dta ) |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| 41 | !! *** SUBROUTINE bdy_frs *** |
|---|
| 42 | !! |
|---|
| 43 | !! ** Purpose : Apply the Flow Relaxation Scheme for tracers at open boundaries. |
|---|
| 44 | !! |
|---|
| 45 | !! Reference : Engedahl H., 1995, Tellus, 365-382. |
|---|
| 46 | !!---------------------------------------------------------------------- |
|---|
| 47 | TYPE(OBC_INDEX), INTENT(in) :: idx ! OBC indices |
|---|
| 48 | REAL(wp), DIMENSION(:,:), INTENT(in) :: dta ! OBC external data |
|---|
| 49 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: pta ! tracer trend |
|---|
| 50 | !! |
|---|
| 51 | REAL(wp) :: zwgt ! boundary weight |
|---|
| 52 | INTEGER :: ib, ik, igrd ! dummy loop indices |
|---|
| 53 | INTEGER :: ii, ij ! 2D addresses |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | ! |
|---|
| 56 | igrd = 1 ! Everything is at T-points here |
|---|
| 57 | DO ib = 1, idx%nblen(igrd) |
|---|
| 58 | DO ik = 1, jpkm1 |
|---|
| 59 | ii = idx%nbi(ib,igrd) |
|---|
| 60 | ij = idx%nbj(ib,igrd) |
|---|
| 61 | zwgt = idx%nbw(ib,igrd) |
|---|
| 62 | pta(ii,ij,ik) = ( pta(ii,ij,ik) + zwgt * (dta(ib,ik) - pta(ii,ij,ik) ) ) * tmask(ii,ij,ik) |
|---|
| 63 | END DO |
|---|
| 64 | END DO |
|---|
| 65 | ! |
|---|
| 66 | END SUBROUTINE bdy_frs |
|---|
| 67 | |
|---|
| 68 | |
|---|
| 69 | SUBROUTINE bdy_spe( idx, pta, dta ) |
|---|
| 70 | !!---------------------------------------------------------------------- |
|---|
| 71 | !! *** SUBROUTINE bdy_spe *** |
|---|
| 72 | !! |
|---|
| 73 | !! ** Purpose : Apply a specified value for tracers at open boundaries. |
|---|
| 74 | !! |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | TYPE(OBC_INDEX), INTENT(in) :: idx ! OBC indices |
|---|
| 77 | REAL(wp), DIMENSION(:,:), INTENT(in) :: dta ! OBC external data |
|---|
| 78 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: pta ! tracer trend |
|---|
| 79 | !! |
|---|
| 80 | REAL(wp) :: zwgt ! boundary weight |
|---|
| 81 | INTEGER :: ib, ik, igrd ! dummy loop indices |
|---|
| 82 | INTEGER :: ii, ij ! 2D addresses |
|---|
| 83 | !!---------------------------------------------------------------------- |
|---|
| 84 | ! |
|---|
| 85 | igrd = 1 ! Everything is at T-points here |
|---|
| 86 | DO ib = 1, idx%nblenrim(igrd) |
|---|
| 87 | ii = idx%nbi(ib,igrd) |
|---|
| 88 | ij = idx%nbj(ib,igrd) |
|---|
| 89 | DO ik = 1, jpkm1 |
|---|
| 90 | pta(ii,ij,ik) = dta(ib,ik) * tmask(ii,ij,ik) |
|---|
| 91 | END DO |
|---|
| 92 | END DO |
|---|
| 93 | ! |
|---|
| 94 | END SUBROUTINE bdy_spe |
|---|
| 95 | |
|---|
| 96 | |
|---|
| 97 | SUBROUTINE bdy_orl( idx, ptb, pta, dta, ll_npo ) |
|---|
| 98 | !!---------------------------------------------------------------------- |
|---|
| 99 | !! *** SUBROUTINE bdy_orl *** |
|---|
| 100 | !! |
|---|
| 101 | !! ** Purpose : Apply Orlanski radiation for tracers at open boundaries. |
|---|
| 102 | !! This is a wrapper routine for bdy_orlanski_3d below |
|---|
| 103 | !! |
|---|
| 104 | !!---------------------------------------------------------------------- |
|---|
| 105 | TYPE(OBC_INDEX), INTENT(in) :: idx ! OBC indices |
|---|
| 106 | REAL(wp), DIMENSION(:,:), INTENT(in) :: dta ! OBC external data |
|---|
| 107 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: ptb ! before tracer field |
|---|
| 108 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: pta ! tracer trend |
|---|
| 109 | LOGICAL, INTENT(in) :: ll_npo ! switch for NPO version |
|---|
| 110 | !! |
|---|
| 111 | INTEGER :: igrd ! grid index |
|---|
| 112 | !!---------------------------------------------------------------------- |
|---|
| 113 | ! |
|---|
| 114 | igrd = 1 ! Everything is at T-points here |
|---|
| 115 | ! |
|---|
| 116 | CALL bdy_orlanski_3d( idx, igrd, ptb(:,:,:), pta(:,:,:), dta, ll_npo ) |
|---|
| 117 | ! |
|---|
| 118 | END SUBROUTINE bdy_orl |
|---|
| 119 | |
|---|
| 120 | |
|---|
| 121 | SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext, ll_npo ) |
|---|
| 122 | !!---------------------------------------------------------------------- |
|---|
| 123 | !! *** SUBROUTINE bdy_orlanski_2d *** |
|---|
| 124 | !! |
|---|
| 125 | !! - Apply Orlanski radiation condition adaptively to 2D fields: |
|---|
| 126 | !! - radiation plus weak nudging at outflow points |
|---|
| 127 | !! - no radiation and strong nudging at inflow points |
|---|
| 128 | !! |
|---|
| 129 | !! |
|---|
| 130 | !! References: Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001) |
|---|
| 131 | !!---------------------------------------------------------------------- |
|---|
| 132 | TYPE(OBC_INDEX), INTENT(in ) :: idx ! BDY indices |
|---|
| 133 | INTEGER , INTENT(in ) :: igrd ! grid index |
|---|
| 134 | REAL(wp), DIMENSION(:,:), INTENT(in ) :: phib ! model before 2D field |
|---|
| 135 | REAL(wp), DIMENSION(:,:), INTENT(inout) :: phia ! model after 2D field (to be updated) |
|---|
| 136 | REAL(wp), DIMENSION(:) , INTENT(in ) :: phi_ext ! external forcing data |
|---|
| 137 | LOGICAL , INTENT(in ) :: ll_npo ! switch for NPO version |
|---|
| 138 | ! |
|---|
| 139 | INTEGER :: jb ! dummy loop indices |
|---|
| 140 | INTEGER :: ii, ij, iibm1, iibm2, ijbm1, ijbm2 ! 2D addresses |
|---|
| 141 | INTEGER :: iijm1, iijp1, ijjm1, ijjp1 ! 2D addresses |
|---|
| 142 | INTEGER :: iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses |
|---|
| 143 | INTEGER :: ii_offset, ij_offset ! offsets for mask indices |
|---|
| 144 | INTEGER :: flagu, flagv ! short cuts |
|---|
| 145 | REAL(wp) :: zmask_x, zmask_y1, zmask_y2 |
|---|
| 146 | REAL(wp) :: zex1, zex2, zey, zey1, zey2 |
|---|
| 147 | REAL(wp) :: zdt, zdx, zdy, znor2, zrx, zry ! intermediate calculations |
|---|
| 148 | REAL(wp) :: zout, zwgt, zdy_centred |
|---|
| 149 | REAL(wp) :: zdy_1, zdy_2, zsign_ups |
|---|
| 150 | REAL(wp), PARAMETER :: zepsilon = 1.e-30 ! local small value |
|---|
| 151 | REAL(wp), POINTER, DIMENSION(:,:) :: pmask ! land/sea mask for field |
|---|
| 152 | REAL(wp), POINTER, DIMENSION(:,:) :: pmask_xdif ! land/sea mask for x-derivatives |
|---|
| 153 | REAL(wp), POINTER, DIMENSION(:,:) :: pmask_ydif ! land/sea mask for y-derivatives |
|---|
| 154 | REAL(wp), POINTER, DIMENSION(:,:) :: pe_xdif ! scale factors for x-derivatives |
|---|
| 155 | REAL(wp), POINTER, DIMENSION(:,:) :: pe_ydif ! scale factors for y-derivatives |
|---|
| 156 | !!---------------------------------------------------------------------- |
|---|
| 157 | ! |
|---|
| 158 | ! ----------------------------------! |
|---|
| 159 | ! Orlanski boundary conditions :! |
|---|
| 160 | ! ----------------------------------! |
|---|
| 161 | |
|---|
| 162 | SELECT CASE(igrd) |
|---|
| 163 | CASE(1) |
|---|
| 164 | pmask => tmask(:,:,1) |
|---|
| 165 | pmask_xdif => umask(:,:,1) |
|---|
| 166 | pmask_ydif => vmask(:,:,1) |
|---|
| 167 | pe_xdif => e1u(:,:) |
|---|
| 168 | pe_ydif => e2v(:,:) |
|---|
| 169 | ii_offset = 0 |
|---|
| 170 | ij_offset = 0 |
|---|
| 171 | CASE(2) |
|---|
| 172 | pmask => umask(:,:,1) |
|---|
| 173 | pmask_xdif => tmask(:,:,1) |
|---|
| 174 | pmask_ydif => fmask(:,:,1) |
|---|
| 175 | pe_xdif => e1t(:,:) |
|---|
| 176 | pe_ydif => e2f(:,:) |
|---|
| 177 | ii_offset = 1 |
|---|
| 178 | ij_offset = 0 |
|---|
| 179 | CASE(3) |
|---|
| 180 | pmask => vmask(:,:,1) |
|---|
| 181 | pmask_xdif => fmask(:,:,1) |
|---|
| 182 | pmask_ydif => tmask(:,:,1) |
|---|
| 183 | pe_xdif => e1f(:,:) |
|---|
| 184 | pe_ydif => e2t(:,:) |
|---|
| 185 | ii_offset = 0 |
|---|
| 186 | ij_offset = 1 |
|---|
| 187 | CASE DEFAULT ; CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' ) |
|---|
| 188 | END SELECT |
|---|
| 189 | ! |
|---|
| 190 | DO jb = 1, idx%nblenrim(igrd) |
|---|
| 191 | ii = idx%nbi(jb,igrd) |
|---|
| 192 | ij = idx%nbj(jb,igrd) |
|---|
| 193 | flagu = int( idx%flagu(jb,igrd) ) |
|---|
| 194 | flagv = int( idx%flagv(jb,igrd) ) |
|---|
| 195 | ! |
|---|
| 196 | ! Calculate positions of b-1 and b-2 points for this rim point |
|---|
| 197 | ! also (b-1,j-1) and (b-1,j+1) points |
|---|
| 198 | iibm1 = ii + flagu ; iibm2 = ii + 2*flagu |
|---|
| 199 | ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv |
|---|
| 200 | ! |
|---|
| 201 | iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) |
|---|
| 202 | ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu) |
|---|
| 203 | ! |
|---|
| 204 | iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) |
|---|
| 205 | ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) |
|---|
| 206 | ! |
|---|
| 207 | ! Calculate scale factors for calculation of spatial derivatives. |
|---|
| 208 | zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1 ) & |
|---|
| 209 | & + abs(ijbm1-ijbm2) * pe_ydif(iibm1 ,ijbm1+ij_offset) ) |
|---|
| 210 | zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2 ) & |
|---|
| 211 | & + abs(ijbm1-ijbm2) * pe_ydif(iibm2 ,ijbm2+ij_offset) ) |
|---|
| 212 | zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1 ) & |
|---|
| 213 | & + (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1 ,ijbm1jm1+ij_offset) ) |
|---|
| 214 | zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1) & |
|---|
| 215 | & + (ijbm1jp1-ijbm1) * pe_ydif(iibm1 ,ijbm1+ij_offset) ) |
|---|
| 216 | ! make sure scale factors are nonzero |
|---|
| 217 | if( zey1 .lt. rsmall ) zey1 = zey2 |
|---|
| 218 | if( zey2 .lt. rsmall ) zey2 = zey1 |
|---|
| 219 | zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall) |
|---|
| 220 | zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); |
|---|
| 221 | ! |
|---|
| 222 | ! Calculate masks for calculation of spatial derivatives. |
|---|
| 223 | zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2 ) & |
|---|
| 224 | & + abs(ijbm1-ijbm2) * pmask_ydif(iibm2 ,ijbm2+ij_offset) ) |
|---|
| 225 | zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1 ) & |
|---|
| 226 | & + (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1 ,ijbm1jm1+ij_offset) ) |
|---|
| 227 | zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1) & |
|---|
| 228 | & + (ijbm1jp1-ijbm1) * pmask_ydif(iibm1 ,ijbm1+ij_offset) ) |
|---|
| 229 | |
|---|
| 230 | ! Calculation of terms required for both versions of the scheme. |
|---|
| 231 | ! Mask derivatives to ensure correct land boundary conditions for each variable. |
|---|
| 232 | ! Centred derivative is calculated as average of "left" and "right" derivatives for |
|---|
| 233 | ! this reason. |
|---|
| 234 | ! Note no rdt factor in expression for zdt because it cancels in the expressions for |
|---|
| 235 | ! zrx and zry. |
|---|
| 236 | zdt = phia(iibm1,ijbm1) - phib(iibm1,ijbm1) |
|---|
| 237 | zdx = ( ( phia(iibm1,ijbm1) - phia(iibm2,ijbm2) ) / zex2 ) * zmask_x |
|---|
| 238 | zdy_1 = ( ( phib(iibm1 ,ijbm1 ) - phib(iibm1jm1,ijbm1jm1) ) / zey1 ) * zmask_y1 |
|---|
| 239 | zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1) - phib(iibm1 ,ijbm1) ) / zey2 ) * zmask_y2 |
|---|
| 240 | zdy_centred = 0.5 * ( zdy_1 + zdy_2 ) |
|---|
| 241 | !!$ zdy_centred = phib(iibm1jp1,ijbm1jp1) - phib(iibm1jm1,ijbm1jm1) |
|---|
| 242 | ! upstream differencing for tangential derivatives |
|---|
| 243 | zsign_ups = sign( 1., zdt * zdy_centred ) |
|---|
| 244 | zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) ) |
|---|
| 245 | zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2 |
|---|
| 246 | znor2 = zdx * zdx + zdy * zdy |
|---|
| 247 | znor2 = max(znor2,zepsilon) |
|---|
| 248 | ! |
|---|
| 249 | zrx = zdt * zdx / ( zex1 * znor2 ) |
|---|
| 250 | !!$ zrx = min(zrx,2.0_wp) |
|---|
| 251 | zout = sign( 1., zrx ) |
|---|
| 252 | zout = 0.5*( zout + abs(zout) ) |
|---|
| 253 | zwgt = rDt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) ) |
|---|
| 254 | ! only apply radiation on outflow points |
|---|
| 255 | if( ll_npo ) then !! NPO version !! |
|---|
| 256 | phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) & |
|---|
| 257 | & + zout * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1) & |
|---|
| 258 | & + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) |
|---|
| 259 | else !! full oblique radiation !! |
|---|
| 260 | zsign_ups = sign( 1., zdt * zdy ) |
|---|
| 261 | zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) ) |
|---|
| 262 | zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 |
|---|
| 263 | zry = zdt * zdy / ( zey * znor2 ) |
|---|
| 264 | phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) & |
|---|
| 265 | & + zout * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1) & |
|---|
| 266 | & - zsign_ups * zry * ( phib(ii ,ij ) - phib(iijm1,ijjm1 ) ) & |
|---|
| 267 | & - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1) - phib(ii ,ij ) ) & |
|---|
| 268 | & + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) |
|---|
| 269 | end if |
|---|
| 270 | phia(ii,ij) = phia(ii,ij) * pmask(ii,ij) |
|---|
| 271 | END DO |
|---|
| 272 | ! |
|---|
| 273 | END SUBROUTINE bdy_orlanski_2d |
|---|
| 274 | |
|---|
| 275 | |
|---|
| 276 | SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext, ll_npo ) |
|---|
| 277 | !!---------------------------------------------------------------------- |
|---|
| 278 | !! *** SUBROUTINE bdy_orlanski_3d *** |
|---|
| 279 | !! |
|---|
| 280 | !! - Apply Orlanski radiation condition adaptively to 3D fields: |
|---|
| 281 | !! - radiation plus weak nudging at outflow points |
|---|
| 282 | !! - no radiation and strong nudging at inflow points |
|---|
| 283 | !! |
|---|
| 284 | !! |
|---|
| 285 | !! References: Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001) |
|---|
| 286 | !!---------------------------------------------------------------------- |
|---|
| 287 | TYPE(OBC_INDEX), INTENT(in ) :: idx ! BDY indices |
|---|
| 288 | INTEGER , INTENT(in ) :: igrd ! grid index |
|---|
| 289 | REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: phib ! model before 3D field |
|---|
| 290 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phia ! model after 3D field (to be updated) |
|---|
| 291 | REAL(wp), DIMENSION(:,:) , INTENT(in ) :: phi_ext ! external forcing data |
|---|
| 292 | LOGICAL , INTENT(in ) :: ll_npo ! switch for NPO version |
|---|
| 293 | ! |
|---|
| 294 | INTEGER :: jb, jk ! dummy loop indices |
|---|
| 295 | INTEGER :: ii, ij, iibm1, iibm2, ijbm1, ijbm2 ! 2D addresses |
|---|
| 296 | INTEGER :: iijm1, iijp1, ijjm1, ijjp1 ! 2D addresses |
|---|
| 297 | INTEGER :: iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses |
|---|
| 298 | INTEGER :: ii_offset, ij_offset ! offsets for mask indices |
|---|
| 299 | INTEGER :: flagu, flagv ! short cuts |
|---|
| 300 | REAL(wp) :: zmask_x, zmask_y1, zmask_y2 |
|---|
| 301 | REAL(wp) :: zex1, zex2, zey, zey1, zey2 |
|---|
| 302 | REAL(wp) :: zdt, zdx, zdy, znor2, zrx, zry ! intermediate calculations |
|---|
| 303 | REAL(wp) :: zout, zwgt, zdy_centred |
|---|
| 304 | REAL(wp) :: zdy_1, zdy_2, zsign_ups |
|---|
| 305 | REAL(wp), PARAMETER :: zepsilon = 1.e-30 ! local small value |
|---|
| 306 | REAL(wp), POINTER, DIMENSION(:,:,:) :: pmask ! land/sea mask for field |
|---|
| 307 | REAL(wp), POINTER, DIMENSION(:,:,:) :: pmask_xdif ! land/sea mask for x-derivatives |
|---|
| 308 | REAL(wp), POINTER, DIMENSION(:,:,:) :: pmask_ydif ! land/sea mask for y-derivatives |
|---|
| 309 | REAL(wp), POINTER, DIMENSION(:,:) :: pe_xdif ! scale factors for x-derivatives |
|---|
| 310 | REAL(wp), POINTER, DIMENSION(:,:) :: pe_ydif ! scale factors for y-derivatives |
|---|
| 311 | !!---------------------------------------------------------------------- |
|---|
| 312 | ! |
|---|
| 313 | ! ----------------------------------! |
|---|
| 314 | ! Orlanski boundary conditions :! |
|---|
| 315 | ! ----------------------------------! |
|---|
| 316 | ! |
|---|
| 317 | SELECT CASE(igrd) |
|---|
| 318 | CASE(1) |
|---|
| 319 | pmask => tmask(:,:,:) |
|---|
| 320 | pmask_xdif => umask(:,:,:) |
|---|
| 321 | pmask_ydif => vmask(:,:,:) |
|---|
| 322 | pe_xdif => e1u(:,:) |
|---|
| 323 | pe_ydif => e2v(:,:) |
|---|
| 324 | ii_offset = 0 |
|---|
| 325 | ij_offset = 0 |
|---|
| 326 | CASE(2) |
|---|
| 327 | pmask => umask(:,:,:) |
|---|
| 328 | pmask_xdif => tmask(:,:,:) |
|---|
| 329 | pmask_ydif => fmask(:,:,:) |
|---|
| 330 | pe_xdif => e1t(:,:) |
|---|
| 331 | pe_ydif => e2f(:,:) |
|---|
| 332 | ii_offset = 1 |
|---|
| 333 | ij_offset = 0 |
|---|
| 334 | CASE(3) |
|---|
| 335 | pmask => vmask(:,:,:) |
|---|
| 336 | pmask_xdif => fmask(:,:,:) |
|---|
| 337 | pmask_ydif => tmask(:,:,:) |
|---|
| 338 | pe_xdif => e1f(:,:) |
|---|
| 339 | pe_ydif => e2t(:,:) |
|---|
| 340 | ii_offset = 0 |
|---|
| 341 | ij_offset = 1 |
|---|
| 342 | CASE DEFAULT ; CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' ) |
|---|
| 343 | END SELECT |
|---|
| 344 | |
|---|
| 345 | DO jk = 1, jpk |
|---|
| 346 | ! |
|---|
| 347 | DO jb = 1, idx%nblenrim(igrd) |
|---|
| 348 | ii = idx%nbi(jb,igrd) |
|---|
| 349 | ij = idx%nbj(jb,igrd) |
|---|
| 350 | flagu = int( idx%flagu(jb,igrd) ) |
|---|
| 351 | flagv = int( idx%flagv(jb,igrd) ) |
|---|
| 352 | ! |
|---|
| 353 | ! calculate positions of b-1 and b-2 points for this rim point |
|---|
| 354 | ! also (b-1,j-1) and (b-1,j+1) points |
|---|
| 355 | iibm1 = ii + flagu ; iibm2 = ii + 2*flagu |
|---|
| 356 | ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv |
|---|
| 357 | ! |
|---|
| 358 | iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) |
|---|
| 359 | ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu) |
|---|
| 360 | ! |
|---|
| 361 | iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) |
|---|
| 362 | ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) |
|---|
| 363 | ! |
|---|
| 364 | ! Calculate scale factors for calculation of spatial derivatives. |
|---|
| 365 | zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1 ) & |
|---|
| 366 | & + abs(ijbm1-ijbm2) * pe_ydif(iibm1 ,ijbm1+ij_offset) ) |
|---|
| 367 | zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2 ) & |
|---|
| 368 | & + abs(ijbm1-ijbm2) * pe_ydif(iibm2 ,ijbm2+ij_offset) ) |
|---|
| 369 | zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1 ) & |
|---|
| 370 | & + (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1 ,ijbm1jm1+ij_offset) ) |
|---|
| 371 | zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1) & |
|---|
| 372 | & + (ijbm1jp1-ijbm1) * pe_ydif(iibm1 ,ijbm1+ij_offset) ) |
|---|
| 373 | ! make sure scale factors are nonzero |
|---|
| 374 | if( zey1 .lt. rsmall ) zey1 = zey2 |
|---|
| 375 | if( zey2 .lt. rsmall ) zey2 = zey1 |
|---|
| 376 | zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall); |
|---|
| 377 | zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); |
|---|
| 378 | ! |
|---|
| 379 | ! Calculate masks for calculation of spatial derivatives. |
|---|
| 380 | zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2 ,jk) & |
|---|
| 381 | & + abs(ijbm1-ijbm2) * pmask_ydif(iibm2 ,ijbm2+ij_offset,jk) ) |
|---|
| 382 | zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1 ,jk) & |
|---|
| 383 | & + (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1 ,ijbm1jm1+ij_offset,jk) ) |
|---|
| 384 | zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1 ,jk) & |
|---|
| 385 | & + (ijbm1jp1-ijbm1) * pmask_ydif(iibm1 ,ijbm1+ij_offset,jk) ) |
|---|
| 386 | ! |
|---|
| 387 | ! Calculate normal (zrx) and tangential (zry) components of radiation velocities. |
|---|
| 388 | ! Mask derivatives to ensure correct land boundary conditions for each variable. |
|---|
| 389 | ! Centred derivative is calculated as average of "left" and "right" derivatives for |
|---|
| 390 | ! this reason. |
|---|
| 391 | zdt = phia(iibm1,ijbm1,jk) - phib(iibm1,ijbm1,jk) |
|---|
| 392 | zdx = ( ( phia(iibm1,ijbm1,jk) - phia(iibm2,ijbm2,jk) ) / zex2 ) * zmask_x |
|---|
| 393 | zdy_1 = ( ( phib(iibm1 ,ijbm1 ,jk) - phib(iibm1jm1,ijbm1jm1,jk) ) / zey1 ) * zmask_y1 |
|---|
| 394 | zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1 ,ijbm1 ,jk) ) / zey2 ) * zmask_y2 |
|---|
| 395 | zdy_centred = 0.5 * ( zdy_1 + zdy_2 ) |
|---|
| 396 | !!$ zdy_centred = phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1jm1,ijbm1jm1,jk) |
|---|
| 397 | ! upstream differencing for tangential derivatives |
|---|
| 398 | zsign_ups = sign( 1., zdt * zdy_centred ) |
|---|
| 399 | zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) ) |
|---|
| 400 | zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2 |
|---|
| 401 | znor2 = zdx * zdx + zdy * zdy |
|---|
| 402 | znor2 = max(znor2,zepsilon) |
|---|
| 403 | ! |
|---|
| 404 | ! update boundary value: |
|---|
| 405 | zrx = zdt * zdx / ( zex1 * znor2 ) |
|---|
| 406 | !!$ zrx = min(zrx,2.0_wp) |
|---|
| 407 | zout = sign( 1., zrx ) |
|---|
| 408 | zout = 0.5 * ( zout + abs(zout) ) |
|---|
| 409 | zwgt = rDt * ( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) ) |
|---|
| 410 | ! only apply radiation on outflow points |
|---|
| 411 | if( ll_npo ) then !! NPO version !! |
|---|
| 412 | phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) & |
|---|
| 413 | & + zout * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk) & |
|---|
| 414 | & + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) |
|---|
| 415 | else !! full oblique radiation !! |
|---|
| 416 | zsign_ups = sign( 1., zdt * zdy ) |
|---|
| 417 | zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) ) |
|---|
| 418 | zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 |
|---|
| 419 | zry = zdt * zdy / ( zey * znor2 ) |
|---|
| 420 | phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) & |
|---|
| 421 | & + zout * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk) & |
|---|
| 422 | & - zsign_ups * zry * ( phib(ii ,ij ,jk) - phib(iijm1,ijjm1,jk) ) & |
|---|
| 423 | & - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1,jk) - phib(ii ,ij ,jk) ) & |
|---|
| 424 | & + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) |
|---|
| 425 | end if |
|---|
| 426 | phia(ii,ij,jk) = phia(ii,ij,jk) * pmask(ii,ij,jk) |
|---|
| 427 | END DO |
|---|
| 428 | ! |
|---|
| 429 | END DO |
|---|
| 430 | ! |
|---|
| 431 | END SUBROUTINE bdy_orlanski_3d |
|---|
| 432 | |
|---|
| 433 | |
|---|
| 434 | SUBROUTINE bdy_nmn( idx, igrd, phia ) |
|---|
| 435 | !!---------------------------------------------------------------------- |
|---|
| 436 | !! *** SUBROUTINE bdy_nmn *** |
|---|
| 437 | !! |
|---|
| 438 | !! ** Purpose : Duplicate the value at open boundaries, zero gradient. |
|---|
| 439 | !! |
|---|
| 440 | !!---------------------------------------------------------------------- |
|---|
| 441 | INTEGER, INTENT(in) :: igrd ! grid index |
|---|
| 442 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phia ! model after 3D field (to be updated) |
|---|
| 443 | TYPE(OBC_INDEX), INTENT(in) :: idx ! OBC indices |
|---|
| 444 | !! |
|---|
| 445 | REAL(wp) :: zcoef, zcoef1, zcoef2 |
|---|
| 446 | REAL(wp), POINTER, DIMENSION(:,:,:) :: pmask ! land/sea mask for field |
|---|
| 447 | REAL(wp), POINTER, DIMENSION(:,:) :: bdypmask ! land/sea mask for field |
|---|
| 448 | INTEGER :: ib, ik ! dummy loop indices |
|---|
| 449 | INTEGER :: ii, ij, ip, jp ! 2D addresses |
|---|
| 450 | !!---------------------------------------------------------------------- |
|---|
| 451 | ! |
|---|
| 452 | SELECT CASE(igrd) |
|---|
| 453 | CASE(1) |
|---|
| 454 | pmask => tmask(:,:,:) |
|---|
| 455 | bdypmask => bdytmask(:,:) |
|---|
| 456 | CASE(2) |
|---|
| 457 | pmask => umask(:,:,:) |
|---|
| 458 | bdypmask => bdyumask(:,:) |
|---|
| 459 | CASE(3) |
|---|
| 460 | pmask => vmask(:,:,:) |
|---|
| 461 | bdypmask => bdyvmask(:,:) |
|---|
| 462 | CASE DEFAULT ; CALL ctl_stop( 'unrecognised value for igrd in bdy_nmn' ) |
|---|
| 463 | END SELECT |
|---|
| 464 | DO ib = 1, idx%nblenrim(igrd) |
|---|
| 465 | ii = idx%nbi(ib,igrd) |
|---|
| 466 | ij = idx%nbj(ib,igrd) |
|---|
| 467 | DO ik = 1, jpkm1 |
|---|
| 468 | ! search the sense of the gradient |
|---|
| 469 | zcoef1 = bdypmask(ii-1,ij )*pmask(ii-1,ij,ik) + bdypmask(ii+1,ij )*pmask(ii+1,ij,ik) |
|---|
| 470 | zcoef2 = bdypmask(ii ,ij-1)*pmask(ii,ij-1,ik) + bdypmask(ii ,ij+1)*pmask(ii,ij+1,ik) |
|---|
| 471 | IF ( nint(zcoef1+zcoef2) == 0) THEN |
|---|
| 472 | ! corner **** we probably only want to set the tangentail component for the dynamics here |
|---|
| 473 | zcoef = pmask(ii-1,ij,ik) + pmask(ii+1,ij,ik) + pmask(ii,ij-1,ik) + pmask(ii,ij+1,ik) |
|---|
| 474 | IF (zcoef > .5_wp) THEN ! Only set none isolated points. |
|---|
| 475 | phia(ii,ij,ik) = phia(ii-1,ij ,ik) * pmask(ii-1,ij ,ik) + & |
|---|
| 476 | & phia(ii+1,ij ,ik) * pmask(ii+1,ij ,ik) + & |
|---|
| 477 | & phia(ii ,ij-1,ik) * pmask(ii ,ij-1,ik) + & |
|---|
| 478 | & phia(ii ,ij+1,ik) * pmask(ii ,ij+1,ik) |
|---|
| 479 | phia(ii,ij,ik) = ( phia(ii,ij,ik) / zcoef ) * pmask(ii,ij,ik) |
|---|
| 480 | ELSE |
|---|
| 481 | phia(ii,ij,ik) = phia(ii,ij ,ik) * pmask(ii,ij ,ik) |
|---|
| 482 | ENDIF |
|---|
| 483 | ELSEIF ( nint(zcoef1+zcoef2) == 2) THEN |
|---|
| 484 | ! oblique corner **** we probably only want to set the normal component for the dynamics here |
|---|
| 485 | zcoef = pmask(ii-1,ij,ik)*bdypmask(ii-1,ij ) + pmask(ii+1,ij,ik)*bdypmask(ii+1,ij ) + & |
|---|
| 486 | & pmask(ii,ij-1,ik)*bdypmask(ii,ij -1 ) + pmask(ii,ij+1,ik)*bdypmask(ii,ij+1 ) |
|---|
| 487 | phia(ii,ij,ik) = phia(ii-1,ij ,ik) * pmask(ii-1,ij ,ik)*bdypmask(ii-1,ij ) + & |
|---|
| 488 | & phia(ii+1,ij ,ik) * pmask(ii+1,ij ,ik)*bdypmask(ii+1,ij ) + & |
|---|
| 489 | & phia(ii ,ij-1,ik) * pmask(ii ,ij-1,ik)*bdypmask(ii,ij -1 ) + & |
|---|
| 490 | & phia(ii ,ij+1,ik) * pmask(ii ,ij+1,ik)*bdypmask(ii,ij+1 ) |
|---|
| 491 | |
|---|
| 492 | phia(ii,ij,ik) = ( phia(ii,ij,ik) / MAX(1._wp, zcoef) ) * pmask(ii,ij,ik) |
|---|
| 493 | ELSE |
|---|
| 494 | ip = nint(bdypmask(ii+1,ij )*pmask(ii+1,ij,ik) - bdypmask(ii-1,ij )*pmask(ii-1,ij,ik)) |
|---|
| 495 | jp = nint(bdypmask(ii ,ij+1)*pmask(ii,ij+1,ik) - bdypmask(ii ,ij-1)*pmask(ii,ij-1,ik)) |
|---|
| 496 | phia(ii,ij,ik) = phia(ii+ip,ij+jp,ik) * pmask(ii+ip,ij+jp,ik) |
|---|
| 497 | ENDIF |
|---|
| 498 | END DO |
|---|
| 499 | END DO |
|---|
| 500 | ! |
|---|
| 501 | END SUBROUTINE bdy_nmn |
|---|
| 502 | |
|---|
| 503 | !!====================================================================== |
|---|
| 504 | END MODULE bdylib |
|---|
