New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in NEMO/branches/2018/dev_r9838_ENHANCE04_RK3/src/OCE/TRA – NEMO

source: NEMO/branches/2018/dev_r9838_ENHANCE04_RK3/src/OCE/TRA/traadv.F90 @ 9939

Last change on this file since 9939 was 9939, checked in by gm, 6 years ago

#1911 (ENHANCE-04): RK3 branche phased with MLF@9937 branche
  • Property svn:keywords set to Id
File size: 15.1 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv       : compute ocean tracer advection trend
16   !!   tra_adv_init  : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! variable vertical scale factors
21   USE sbcwave        ! wave module
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE traadv_cen     ! centered scheme            (tra_adv_cen  routine)
24   USE traadv_fct     ! FCT      scheme            (tra_adv_fct  routine)
25   USE traadv_mus     ! MUSCL    scheme            (tra_adv_mus  routine)
26   USE traadv_ubs     ! UBS      scheme            (tra_adv_ubs  routine)
27   USE traadv_qck     ! QUICKEST scheme            (tra_adv_qck  routine)
28   USE tramle         ! Mixed Layer Eddy transport (tra_mle_trp  routine)
29   USE ldftra         ! Eddy Induced transport     (ldf_eiv_trp  routine)
30   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
31   USE trd_oce        ! trends: ocean variables
32   USE trdtra         ! trends manager: tracers
33   USE diaptr         ! Poleward heat transport
34   !
35   USE in_out_manager ! I/O manager
36   USE iom            ! I/O module
37   USE prtctl         ! Print control
38   USE lib_mpp        ! MPP library
39   USE timing         ! Timing
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   tra_adv        ! called by step.F90
45   PUBLIC   tra_adv_init   ! called by nemogcm.F90
46
47   !                            !!* Namelist namtra_adv *
48   LOGICAL ::   ln_traadv_OFF    ! no advection on T and S
49   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
50   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
51   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
52   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
53   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
54   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
55   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
56   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
57   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
58
59   INTEGER ::   nadv             ! choice of the type of advection scheme
60   !                             ! associated indices:
61   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
62   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
63   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
64   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
65   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
66   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
67   
68   !! * Substitutions
69#  include "vectopt_loop_substitute.h90"
70   !!----------------------------------------------------------------------
71   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
72   !! $Id$
73   !! Software governed by the CeCILL licence     (./LICENSE)
74   !!----------------------------------------------------------------------
75CONTAINS
76
77   SUBROUTINE tra_adv( kt )
78      !!----------------------------------------------------------------------
79      !!                  ***  ROUTINE tra_adv  ***
80      !!
81      !! ** Purpose :   compute the ocean tracer advection trend.
82      !!
83      !! ** Method  : - Update (ua,va) with the advection term following nadv
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      !
87      INTEGER ::   jk   ! dummy loop index
88      REAL(wp), DIMENSION(jpi,jpj,jpk)        :: zun, zvn, zwn   ! 3D workspace
89      REAL(wp), DIMENSION(:,:,:,:), ALLOCATABLE ::   ztrd
90      !!----------------------------------------------------------------------
91      !
92      IF( ln_timing )   CALL timing_start('tra_adv')
93      !
94      !                                         !==  effective transport  ==!
95      zun(:,:,jpk) = 0._wp
96      zvn(:,:,jpk) = 0._wp
97      zwn(:,:,jpk) = 0._wp
98      IF( ln_wave .AND. ln_sdw )  THEN
99         DO jk = 1, jpkm1                                                       ! eulerian transport + Stokes Drift
100            zun(:,:,jk) = e2u  (:,:) * e3u_n(:,:,jk) * ( un(:,:,jk) + usd(:,:,jk) )
101            zvn(:,:,jk) = e1v  (:,:) * e3v_n(:,:,jk) * ( vn(:,:,jk) + vsd(:,:,jk) )
102            zwn(:,:,jk) = e1e2t(:,:)                 * ( wn(:,:,jk) + wsd(:,:,jk) )
103         END DO
104      ELSE
105         DO jk = 1, jpkm1
106            zun(:,:,jk) = e2u  (:,:) * e3u_n(:,:,jk) * un(:,:,jk)               ! eulerian transport only
107            zvn(:,:,jk) = e1v  (:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
108            zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
109         END DO
110      ENDIF
111      !
112      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
113         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
114         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
115      ENDIF
116      !
117      zun(:,:,jpk) = 0._wp                                                      ! no transport trough the bottom
118      zvn(:,:,jpk) = 0._wp
119      zwn(:,:,jpk) = 0._wp
120      !
121      IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
122         &              CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' )   ! add the eiv transport (if necessary)
123      !
124      IF( ln_mle    )   CALL tra_mle_trp( kt, nit000, zun, zvn, zwn, 'TRA' )   ! add the mle transport (if necessary)
125      !
126      CALL iom_put( "uocetr_eff", zun )                                        ! output effective transport     
127      CALL iom_put( "vocetr_eff", zvn )
128      CALL iom_put( "wocetr_eff", zwn )
129      !
130!!gm ???
131      IF( ln_diaptr )   CALL dia_ptr( zvn )                                    ! diagnose the effective MSF
132!!gm ???
133      !
134      IF( l_trdtra )   THEN                    !* Save ta and sa trends
135         ALLOCATE( ztrd(jpi,jpj,jpk,jpts) )
136         ztrd(:,:,:,:) = tsa(:,:,:,:)
137      ENDIF
138      !
139      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
140      !
141      CASE ( np_CEN )                                 ! Centered scheme : 2nd / 4th order
142         CALL tra_adv_cen    ( kt, nit000, 'TRA',      zun, zvn, zwn     , tsn, tsa, jpts, nn_cen_h, nn_cen_v )
143      CASE ( np_FCT )                                 ! FCT scheme      : 2nd / 4th order
144         CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zun, zvn, zwn, tsb, tsn, tsa, jpts, nn_fct_h, nn_fct_v )
145      CASE ( np_MUS )                                 ! MUSCL
146         CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zun, zvn, zwn, tsb,      tsa, jpts        , ln_mus_ups ) 
147      CASE ( np_UBS )                                 ! UBS
148         CALL tra_adv_ubs    ( kt, nit000, 'TRA', rDt, zun, zvn, zwn, tsb, tsn, tsa, jpts        , nn_ubs_v   )
149      CASE ( np_QCK )                                 ! QUICKEST
150         CALL tra_adv_qck    ( kt, nit000, 'TRA', rDt, zun, zvn, zwn, tsb, tsn, tsa, jpts                     )
151      !
152      END SELECT
153      !
154      IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
155         DO jk = 1, jpkm1
156            ztrd(:,:,jk,:) = tsa(:,:,jk,:) - ztrd(:,:,jk,:)
157         END DO
158         CALL trd_tra( kt, 'TRA', jp_tem, jptra_totad, ztrd(:,:,:,jp_tem) )
159         CALL trd_tra( kt, 'TRA', jp_sal, jptra_totad, ztrd(:,:,:,jp_sal) )
160         DEALLOCATE( ztrd )
161      ENDIF
162      !                                              ! print mean trends (used for debugging)
163      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
164         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
165      !
166      IF( ln_timing )   CALL timing_stop( 'tra_adv' )
167      !
168   END SUBROUTINE tra_adv
169
170
171   SUBROUTINE tra_adv_init
172      !!---------------------------------------------------------------------
173      !!                  ***  ROUTINE tra_adv_init  ***
174      !!               
175      !! ** Purpose :   Control the consistency between namelist options for
176      !!              tracer advection schemes and set nadv
177      !!----------------------------------------------------------------------
178      INTEGER ::   ioptio, ios   ! Local integers
179      !
180      NAMELIST/namtra_adv/ ln_traadv_OFF,                        &   ! No advection
181         &                 ln_traadv_cen , nn_cen_h, nn_cen_v,   &   ! CEN
182         &                 ln_traadv_fct , nn_fct_h, nn_fct_v,   &   ! FCT
183         &                 ln_traadv_mus , ln_mus_ups,           &   ! MUSCL
184         &                 ln_traadv_ubs ,           nn_ubs_v,   &   ! UBS
185         &                 ln_traadv_qck                             ! QCK
186      !!----------------------------------------------------------------------
187      !
188      !                                !==  Namelist  ==!
189      REWIND( numnam_ref )                   ! Namelist namtra_adv in reference namelist : Tracer advection scheme
190      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
191901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
192      !
193      REWIND( numnam_cfg )                   ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
194      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
195902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
196      IF(lwm) WRITE( numond, namtra_adv )
197      !
198      IF(lwp) THEN                           ! Namelist print
199         WRITE(numout,*)
200         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
201         WRITE(numout,*) '~~~~~~~~~~~~'
202         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
203         WRITE(numout,*) '      No advection on T & S                     ln_traadv_OFF = ', ln_traadv_OFF
204         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
205         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
206         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
207         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
208         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
209         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
210         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
211         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
212         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
213         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
214         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
215      ENDIF
216      !
217      !                                !==  Parameter control & set nadv ==!
218      ioptio = 0                       
219      IF( ln_traadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
220      IF( ln_traadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
221      IF( ln_traadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
222      IF( ln_traadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
223      IF( ln_traadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
224      IF( ln_traadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
225      !
226      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection option in namelist namtra_adv' )
227      !
228      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
229                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
230        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
231      ENDIF
232      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
233                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
234        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
235      ENDIF
236      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
237        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
238      ENDIF
239      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
240         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
241      ENDIF
242      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
243         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
244            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
245      ENDIF
246      !
247      !                                !==  Print the choice  ==! 
248      IF(lwp) THEN
249         WRITE(numout,*)
250         SELECT CASE ( nadv )
251         CASE( np_NO_adv  )   ;   WRITE(numout,*) '   ==>>>   NO T-S advection'
252         CASE( np_CEN     )   ;   WRITE(numout,*) '   ==>>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
253            &                                                                        ' Vertical   order: ', nn_cen_v
254         CASE( np_FCT     )   ;   WRITE(numout,*) '   ==>>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
255            &                                                                        ' Vertical   order: ', nn_fct_v
256         CASE( np_MUS     )   ;   WRITE(numout,*) '   ==>>>   MUSCL    scheme is used'
257         CASE( np_UBS     )   ;   WRITE(numout,*) '   ==>>>   UBS      scheme is used'
258         CASE( np_QCK     )   ;   WRITE(numout,*) '   ==>>>   QUICKEST scheme is used'
259         END SELECT
260      ENDIF
261      !
262      CALL tra_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
263      !
264   END SUBROUTINE tra_adv_init
265
266  !!======================================================================
267END MODULE traadv
Note: See TracBrowser for help on using the repository browser.