New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in NEMO/branches/2018/dev_r9838_ENHANCE04_RK3/src/OCE/TRA – NEMO

source: NEMO/branches/2018/dev_r9838_ENHANCE04_RK3/src/OCE/TRA/traldf_iso.F90 @ 9939

Last change on this file since 9939 was 9939, checked in by gm, 6 years ago

#1911 (ENHANCE-04): RK3 branche phased with MLF@9937 branche
  • Property svn:keywords set to Id
File size: 20.9 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  ! 1994-08  (G. Madec, M. Imbard)
7   !!            8.0  ! 1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO ! 2002-08  (G. Madec)  Free form, F90
9   !!            1.0  ! 2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  ! 2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.7  ! 2014-01  (G. Madec, S. Masson)  restructuration/simplification of aht/aeiv specification
12   !!             -   ! 2014-02  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso   : update the tracer trend with the horizontal component of a iso-neutral laplacian operator
17   !!                   and with the vertical part of the isopycnal or geopotential s-coord. operator
18   !!----------------------------------------------------------------------
19   USE oce            ! ocean dynamics and active tracers
20   USE dom_oce        ! ocean space and time domain
21   USE trc_oce        ! share passive tracers/Ocean variables
22   USE zdf_oce        ! ocean vertical physics
23   USE ldftra         ! lateral diffusion: tracer eddy coefficients
24   USE ldfslp         ! iso-neutral slopes
25   USE diaptr         ! poleward transport diagnostics
26   USE diaar5         ! AR5 diagnostics
27   !
28   USE in_out_manager ! I/O manager
29   USE iom            ! I/O library
30   USE phycst         ! physical constants
31   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_ldf_iso   ! routine called by step.F90
37
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat transport
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50  SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
51      &                                                   pgui, pgvi,   &
52      &                                       ptb , ptbb, pta , kjpt, kpass )
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_iso  ***
55      !!
56      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
57      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
58      !!      add it to the general trend of tracer equation.
59      !!
60      !! ** Method  :   The horizontal component of the lateral diffusive trends
61      !!      is provided by a 2nd order operator rotated along neural or geopo-
62      !!      tential surfaces to which an eddy induced advection can be added
63      !!      It is computed using before fields (forward in time) and isopyc-
64      !!      nal or geopotential slopes computed in routine ldfslp.
65      !!
66      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
67      !!      ========    with partial cell update if ln_zps=T
68      !!                  with top     cell update if ln_isfcav
69      !!
70      !!      2nd part :  horizontal fluxes of the lateral mixing operator
71      !!      ========   
72      !!         zftu =  pahu e2u*e3u/e1u di[ tb ]
73      !!               - pahu e2u*uslp    dk[ mi(mk(tb)) ]
74      !!         zftv =  pahv e1v*e3v/e2v dj[ tb ]
75      !!               - pahv e2u*vslp    dk[ mj(mk(tb)) ]
76      !!      take the horizontal divergence of the fluxes:
77      !!         difft = 1/(e1e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
78      !!      Add this trend to the general trend (ta,sa):
79      !!         ta = ta + difft
80      !!
81      !!      3rd part: vertical trends of the lateral mixing operator
82      !!      ========  (excluding the vertical flux proportional to dk[t] )
83      !!      vertical fluxes associated with the rotated lateral mixing:
84      !!         zftw = - {  mi(mk(pahu)) * e2t*wslpi di[ mi(mk(tb)) ]
85      !!                   + mj(mk(pahv)) * e1t*wslpj dj[ mj(mk(tb)) ]  }
86      !!      take the horizontal divergence of the fluxes:
87      !!         difft = 1/(e1e2t*e3t) dk[ zftw ]
88      !!      Add this trend to the general trend (ta,sa):
89      !!         pta = pta + difft
90      !!
91      !! ** Action :   Update pta arrays with the before rotated diffusion
92      !!----------------------------------------------------------------------
93      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
94      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
95      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
96      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
97      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
98      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
99      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
100      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! tracer (kpass=1) or laplacian of tracer (kpass=2)
102      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptbb       ! tracer (only used in kpass=2)
103      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
104      !
105      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
106      INTEGER  ::  ikt
107      INTEGER  ::  ierr             ! local integer
108      REAL(wp) ::  zmsku, zahu_w, zabe1, zcof1, zcoef3   ! local scalars
109      REAL(wp) ::  zmskv, zahv_w, zabe2, zcof2, zcoef4   !   -      -
110      REAL(wp) ::  zcoef0, ze3w_2, zsign                 !   -      -
111      REAL(wp), DIMENSION(jpi,jpj)     ::   zdkt, zdk1t, z2d
112      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, zftu, zftv, ztfw 
113      !!----------------------------------------------------------------------
114      !
115      IF( kpass == 1 .AND. kt == kit000 )  THEN
116         IF(lwp) WRITE(numout,*)
117         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
118         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
119         !
120         akz     (:,:,:) = 0._wp     
121         ah_wslp2(:,:,:) = 0._wp
122      ENDIF
123      !   
124      l_hst = .FALSE.
125      l_ptr = .FALSE.
126      IF( cdtype == 'TRA' .AND. ln_diaptr )                                                 l_ptr = .TRUE. 
127      IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
128         &                        iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )   l_hst = .TRUE.
129      !
130      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
131      ELSE                    ;   zsign = -1._wp
132      ENDIF
133         
134      !!----------------------------------------------------------------------
135      !!   0 - calculate  ah_wslp2 and akz
136      !!----------------------------------------------------------------------
137      !
138      IF( kpass == 1 ) THEN                  !==  first pass only  ==!
139         !
140         DO jk = 2, jpkm1
141            DO jj = 2, jpjm1
142               DO ji = fs_2, fs_jpim1   ! vector opt.
143                  !
144                  zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
145                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
146                  zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
147                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
148                     !
149                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
150                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
151                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
152                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
153                     !
154                  ah_wslp2(ji,jj,jk) = zahu_w * wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
155                     &               + zahv_w * wslpj(ji,jj,jk) * wslpj(ji,jj,jk)
156               END DO
157            END DO
158         END DO
159         !
160         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
161            DO jk = 2, jpkm1
162               DO jj = 2, jpjm1
163                  DO ji = fs_2, fs_jpim1
164                     akz(ji,jj,jk) = 0.25_wp * (                                                                     &
165                        &              ( pahu(ji  ,jj,jk) + pahu(ji  ,jj,jk-1) ) / ( e1u(ji  ,jj) * e1u(ji  ,jj) )   &
166                        &            + ( pahu(ji-1,jj,jk) + pahu(ji-1,jj,jk-1) ) / ( e1u(ji-1,jj) * e1u(ji-1,jj) )   &
167                        &            + ( pahv(ji,jj  ,jk) + pahv(ji,jj  ,jk-1) ) / ( e2v(ji,jj  ) * e2v(ji,jj  ) )   &
168                        &            + ( pahv(ji,jj-1,jk) + pahv(ji,jj-1,jk-1) ) / ( e2v(ji,jj-1) * e2v(ji,jj-1) )   )
169                  END DO
170               END DO
171            END DO
172            !
173            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
174               DO jk = 2, jpkm1
175                  DO jj = 1, jpjm1
176                     DO ji = 1, fs_jpim1
177                        akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
178                           &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) )  )
179                     END DO
180                  END DO
181               END DO
182            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
183               DO jk = 2, jpkm1
184                  DO jj = 1, jpjm1
185                     DO ji = 1, fs_jpim1
186                        ze3w_2 = e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk)
187                        zcoef0 = rDt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
188                        akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * r1_Dt
189                     END DO
190                  END DO
191               END DO
192           ENDIF
193           !
194         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
195            akz(:,:,:) = ah_wslp2(:,:,:)     
196         ENDIF
197      ENDIF
198      !
199      !                                                          ! ===========
200      DO jn = 1, kjpt                                            ! tracer loop
201         !                                                       ! ===========
202         !                                               
203         !!----------------------------------------------------------------------
204         !!   I - masked horizontal derivative
205         !!----------------------------------------------------------------------
206!!gm : bug.... why (x,:,:)?   (1,jpj,:) and (jpi,1,:) should be sufficient....
207         zdit (1,:,:) = 0._wp     ;     zdit (jpi,:,:) = 0._wp
208         zdjt (1,:,:) = 0._wp     ;     zdjt (jpi,:,:) = 0._wp
209         !!end
210
211         ! Horizontal tracer gradient
212         DO jk = 1, jpkm1
213            DO jj = 1, jpjm1
214               DO ji = 1, fs_jpim1   ! vector opt.
215                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
216                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
217               END DO
218            END DO
219         END DO
220         IF( ln_zps ) THEN      ! botton and surface ocean correction of the horizontal gradient
221            DO jj = 1, jpjm1              ! bottom correction (partial bottom cell)
222               DO ji = 1, fs_jpim1   ! vector opt.
223                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
224                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
225               END DO
226            END DO
227            IF( ln_isfcav ) THEN      ! first wet level beneath a cavity
228               DO jj = 1, jpjm1
229                  DO ji = 1, fs_jpim1   ! vector opt.
230                     IF( miku(ji,jj) > 1 )   zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
231                     IF( mikv(ji,jj) > 1 )   zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
232                  END DO
233               END DO
234            ENDIF
235         ENDIF
236         !
237         !!----------------------------------------------------------------------
238         !!   II - horizontal trend  (full)
239         !!----------------------------------------------------------------------
240         !
241         DO jk = 1, jpkm1                                 ! Horizontal slab
242            !
243            !                             !== Vertical tracer gradient
244            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * wmask(:,:,jk+1)     ! level jk+1
245            !
246            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)                          ! surface: zdkt(jk=1)=zdkt(jk=2)
247            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * wmask(:,:,jk)
248            ENDIF
249            DO jj = 1 , jpjm1            !==  Horizontal fluxes
250               DO ji = 1, fs_jpim1   ! vector opt.
251                  zabe1 = pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u_n(ji,jj,jk)
252                  zabe2 = pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v_n(ji,jj,jk)
253                  !
254                  zmsku = 1. / MAX(  wmask(ji+1,jj,jk  ) + wmask(ji,jj,jk+1)   &
255                     &             + wmask(ji+1,jj,jk+1) + wmask(ji,jj,jk  ), 1. )
256                  !
257                  zmskv = 1. / MAX(  wmask(ji,jj+1,jk  ) + wmask(ji,jj,jk+1)   &
258                     &             + wmask(ji,jj+1,jk+1) + wmask(ji,jj,jk  ), 1. )
259                  !
260                  zcof1 = - pahu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
261                  zcof2 = - pahv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
262                  !
263                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
264                     &               + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
265                     &                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
266                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
267                     &               + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
268                     &                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
269               END DO
270            END DO
271            !
272            DO jj = 2 , jpjm1          !== horizontal divergence and add to pta
273               DO ji = fs_2, fs_jpim1   ! vector opt.
274                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  zftu(ji,jj,jk) - zftu(ji-1,jj,jk)      &
275                     &                                           + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )   &
276                     &                                        * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
277               END DO
278            END DO
279         END DO                                        !   End of slab 
280
281         !!----------------------------------------------------------------------
282         !!   III - vertical trend (full)
283         !!----------------------------------------------------------------------
284         !
285         ztfw(1,:,:) = 0._wp     ;     ztfw(jpi,:,:) = 0._wp
286         !
287         ! Vertical fluxes
288         ! ---------------
289         !                          ! Surface and bottom vertical fluxes set to zero
290         ztfw(:,:, 1 ) = 0._wp      ;      ztfw(:,:,jpk) = 0._wp
291         
292         DO jk = 2, jpkm1           ! interior (2=<jk=<jpk-1)
293            DO jj = 2, jpjm1
294               DO ji = fs_2, fs_jpim1   ! vector opt.
295                  !
296                  zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
297                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
298                  zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
299                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
300                     !
301                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
302                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
303                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
304                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
305                     !
306                  zcoef3 = - zahu_w * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)   !wslpi & j are already w-masked
307                  zcoef4 = - zahv_w * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
308                  !
309                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
310                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
311                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
312                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
313               END DO
314            END DO
315         END DO
316         !                                !==  add the vertical 33 flux  ==!
317         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
318            DO jk = 2, jpkm1       
319               DO jj = 1, jpjm1
320                  DO ji = fs_2, fs_jpim1
321                     ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w_n(ji,jj,jk) * wmask(ji,jj,jk)   &
322                        &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
323                        &                            * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) )
324                  END DO
325               END DO
326            END DO
327            !
328         ELSE                                   ! bilaplacian
329            SELECT CASE( kpass )
330            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
331               DO jk = 2, jpkm1 
332                  DO jj = 1, jpjm1
333                     DO ji = fs_2, fs_jpim1
334                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk)    &
335                           &           + ah_wslp2(ji,jj,jk) * e1e2t(ji,jj)   &
336                           &           * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) / e3w_n(ji,jj,jk) * wmask(ji,jj,jk)
337                     END DO
338                  END DO
339               END DO
340            CASE(  2  )                         ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb  and ptbb gradients, resp.
341               DO jk = 2, jpkm1 
342                  DO jj = 1, jpjm1
343                     DO ji = fs_2, fs_jpim1
344                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w_n(ji,jj,jk) * wmask(ji,jj,jk)                      &
345                           &                            * (  ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) )   &
346                           &                               + akz     (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) )   )
347                     END DO
348                  END DO
349               END DO
350            END SELECT
351         ENDIF
352         !         
353         DO jk = 1, jpkm1                 !==  Divergence of vertical fluxes added to pta  ==!
354            DO jj = 2, jpjm1
355               DO ji = fs_2, fs_jpim1   ! vector opt.
356                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  ztfw (ji,jj,jk) - ztfw(ji,jj,jk+1)  )   &
357                     &                                        * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
358               END DO
359            END DO
360         END DO
361         !
362         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
363             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
364            !
365            !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
366               ! note sign is reversed to give down-gradient diffusive transports )
367            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', -zftv(:,:,:)  )
368            !                          ! Diffusive heat transports
369            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', -zftu(:,:,:), -zftv(:,:,:) )
370            !
371         ENDIF                                                    !== end pass selection  ==!
372         !
373         !                                                        ! ===============
374      END DO                                                      ! end tracer loop
375      !
376   END SUBROUTINE tra_ldf_iso
377
378   !!==============================================================================
379END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.