New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2018/dev_r9838_ENHANCE04_RK3/src/OCE – NEMO

source: NEMO/branches/2018/dev_r9838_ENHANCE04_RK3/src/OCE/nemogcm.F90 @ 10001

Last change on this file since 10001 was 10001, checked in by gm, 6 years ago

#1911 (ENHANCE-04): RK3 branch - step I.1 and I.2 (see wiki page)

  • Property svn:keywords set to Id
File size: 33.9 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_MLF      : Modified Leap-Frog time stepping loop
39   !!   nemo_RK3      : 3rd order Runge-Kutta time stepping loop
40   !!   nemo_init     : initialization of the NEMO system
41   !!   nemo_ctl      : initialisation of the contol print
42   !!   nemo_closefile: close remaining open files
43   !!   nemo_alloc    : dynamical allocation
44   !!----------------------------------------------------------------------
45   USE step_oce       ! module used in the ocean time stepping module (step.F90)
46   USE phycst         ! physical constant                  (par_cst routine)
47   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
48   USE closea         ! treatment of closed seas (for ln_closea)
49   USE usrdef_nam     ! user defined configuration
50   USE tideini        ! tidal components initialization   (tide_ini routine)
51   USE bdy_oce,  ONLY : ln_bdy
52   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
53   USE istate         ! initial state setting          (istate_init routine)
54   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
55   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
56   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
57   USE asminc         ! assimilation increments     
58   USE asmbkg         ! writing out state trajectory
59   USE diaptr         ! poleward transports           (dia_ptr_init routine)
60   USE diadct         ! sections transports           (dia_dct_init routine)
61   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
62   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
63   USE step           ! NEMO time-stepping                 (stp     routine)
64   USE stpRK3         ! NEMO time-stepping                 (stp     routine)
65   USE icbini         ! handle bergs, initialisation
66   USE icbstp         ! handle bergs, calving, themodynamics and transport
67   USE cpl_oasis3     ! OASIS3 coupling
68   USE c1d            ! 1D configuration
69   USE step_c1d       ! Time stepping loop for the 1D configuration
70   USE dyndmp         ! Momentum damping
71   USE stopar         ! Stochastic param.: ???
72   USE stopts         ! Stochastic param.: ???
73   USE diurnal_bulk   ! diurnal bulk SST
74   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
75   USE crsini         ! initialise grid coarsening utility
76   USE diatmb         ! Top,middle,bottom output
77   USE dia25h         ! 25h mean output
78   USE sbc_oce , ONLY : lk_oasis
79   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
80#if defined key_top
81   USE trcini         ! passive tracer initialisation
82#endif
83#if defined key_nemocice_decomp
84   USE ice_domain_size, only: nx_global, ny_global
85#endif
86   !
87   USE lib_mpp        ! distributed memory computing
88   USE mppini         ! shared/distributed memory setting (mpp_init routine)
89   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
90   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
91#if defined key_iomput
92   USE xios           ! xIOserver
93#endif
94#if defined key_agrif
95   USE agrif_all_update   ! Master Agrif update
96#endif
97
98   IMPLICIT NONE
99   PRIVATE
100
101   PUBLIC   nemo_gcm    ! called by model.F90
102   PUBLIC   nemo_init   ! needed by AGRIF
103   PUBLIC   nemo_alloc  ! needed by TAM
104
105   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
106
107   !!----------------------------------------------------------------------
108   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
109   !! $Id$
110   !! Software governed by the CeCILL licence     (./LICENSE)
111   !!----------------------------------------------------------------------
112CONTAINS
113
114   SUBROUTINE nemo_gcm
115      !!----------------------------------------------------------------------
116      !!                     ***  ROUTINE nemo_gcm  ***
117      !!
118      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
119      !!              curvilinear mesh on the sphere.
120      !!
121      !! ** Method  : - model general initialization
122      !!              - launch the time-stepping (stp routine)
123      !!              - finalize the run by closing files and communications
124      !!
125      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
126      !!              Madec, 2008, internal report, IPSL.
127      !!----------------------------------------------------------------------
128      !
129#if defined key_agrif
130      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
131#endif
132      !                            !-----------------------!
133      CALL nemo_init               !==  Initialisations  ==!
134      !                            !-----------------------!
135#if defined key_agrif
136      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
137      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
138# if defined key_top
139      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
140# endif
141# if defined key_si3
142      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
143# endif
144#endif
145      ! check that all process are still there... If some process have an error,
146      ! they will never enter in step and other processes will wait until the end of the cpu time!
147      IF( lk_mpp )   CALL mpp_max( nstop )
148
149      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
150
151      !                            !-----------------------!
152      !                            !==   time stepping   ==!
153      !                            !-----------------------!
154      !
155      IF( ln_MLF )   CALL nemo_MLF        ! Modified Leap-Frog
156      !
157      IF( ln_RK3 )   CALL nemo_RK3        ! 3rd order Runge-Kutta
158      !
159      !
160      IF( ln_diaobs   )   CALL dia_obs_wri
161      !
162      IF( ln_icebergs )   CALL icb_end( nitend )
163
164      !                            !------------------------!
165      !                            !==  finalize the run  ==!
166      !                            !------------------------!
167      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
168      !
169      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
170         WRITE(numout,cform_err)
171         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
172         WRITE(numout,*)
173      ENDIF
174      !
175      IF( ln_timing )   CALL timing_finalize
176      !
177      CALL nemo_closefile
178      !
179#if defined key_iomput
180                                    CALL xios_finalize  ! end mpp communications with xios
181      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
182#else
183      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
184      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
185      ENDIF
186#endif
187      !
188   END SUBROUTINE nemo_gcm
189
190
191   SUBROUTINE nemo_MLF
192      !!----------------------------------------------------------------------
193      !!                     ***  ROUTINE nemo_MLF  ***
194      !!
195      !! ** Purpose :   Modified Leap-Frog time stepping loop
196      !!----------------------------------------------------------------------
197      INTEGER ::   istp   ! time step index
198      !!----------------------------------------------------------------------
199      !                                               !== set the MLF time-step  ==!
200      !
201      IF( l_1st_euler ) THEN   ;   rDt =         rn_Dt   ;   l_1st_euler = .TRUE.    ! start or restart with Euler 1st time-step
202      ELSE                     ;   rDt = 2._wp * rn_Dt   ;   l_1st_euler = .FALSE.   ! restart with leapfrog
203      ENDIF
204      r1_Dt = 1._wp / rDt
205      ! NB: if l_1st_euler=T, rDt will be set to 2*rn_Dt at the end of the 1st time-step (in step.F90)
206      !     Done here (not in domain.F90) as in ASM initialization an Euler 1st time step can be forced
207      !
208      !
209      istp = nit000
210      !
211#if defined key_c1d
212      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
213         CALL stp_c1d( istp )
214         istp = istp + 1
215      END DO
216#else
217      !
218# if defined key_agrif
219      !                                               !==  AGRIF time-stepping  ==!
220      CALL Agrif_Regrid()
221      !
222      ! Recursive update from highest nested level to lowest:
223      CALL Agrif_step_child_adj(Agrif_Update_All)
224      !
225      DO WHILE( istp <= nitend .AND. nstop == 0 )
226         CALL stp
227         istp = istp + 1
228      END DO
229      !
230      IF( .NOT. Agrif_Root() ) THEN
231         CALL Agrif_ParentGrid_To_ChildGrid()
232         IF( ln_diaobs )   CALL dia_obs_wri
233         IF( ln_timing )   CALL timing_finalize
234         CALL Agrif_ChildGrid_To_ParentGrid()
235      ENDIF
236      !
237# else
238      !
239      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
240         !
241         DO WHILE( istp <= nitend .AND. nstop == 0 )
242            CALL stp        ( istp ) 
243            istp = istp + 1
244         END DO
245         !
246      ELSE                                            !==  diurnal SST time-steeping only  ==!
247         !
248         DO WHILE( istp <= nitend .AND. nstop == 0 )
249            CALL stp_diurnal( istp )   ! time step only the diurnal SST
250            istp = istp + 1
251         END DO
252         !
253      ENDIF
254      !
255# endif
256      !
257#endif
258      !
259   END SUBROUTINE nemo_MLF
260
261
262   SUBROUTINE nemo_RK3
263      !!----------------------------------------------------------------------
264      !!                     ***  ROUTINE nemo_RK3  ***
265      !!
266      !! ** Purpose :   3rd order Runge-Kutta time stepping loop
267      !!----------------------------------------------------------------------
268      INTEGER ::   istp   ! time step index
269      !!----------------------------------------------------------------------
270      !
271      !                                         !== set the model time-step  ==!
272      rDt = rn_Dt
273      r1_Dt = 1._wp / rDt
274      istp = nit000
275      !
276#if defined key_agrif
277      !                                         !==  AGRIF time-stepping  ==!
278      CALL Agrif_Regrid()
279      !
280      CALL Agrif_step_child_adj(Agrif_Update_All)        ! Recursive update from highest to lowest nested levels
281      !
282      DO WHILE( istp <= nitend .AND. nstop == 0 )
283         CALL stp_RK3
284         istp = istp + 1
285      END DO
286      !
287      IF( .NOT. Agrif_Root() ) THEN
288         CALL Agrif_ParentGrid_To_ChildGrid()
289         IF( ln_diaobs )   CALL dia_obs_wri
290         IF( ln_timing )   CALL timing_finalize
291         CALL Agrif_ChildGrid_To_ParentGrid()
292      ENDIF
293      !
294#else
295      !                                         !==  Standard time-stepping  ==!
296      !
297      DO WHILE( istp <= nitend .AND. nstop == 0 )
298         CALL stp_RK3( istp ) 
299         istp = istp + 1
300      END DO
301      !
302#endif
303      !
304   END SUBROUTINE nemo_RK3
305
306
307   SUBROUTINE nemo_init
308      !!----------------------------------------------------------------------
309      !!                     ***  ROUTINE nemo_init  ***
310      !!
311      !! ** Purpose :   initialization of the NEMO GCM
312      !!----------------------------------------------------------------------
313      INTEGER  ::   ji                 ! dummy loop indices
314      INTEGER  ::   ios, ilocal_comm   ! local integers
315      CHARACTER(len=120), DIMENSION(60) ::   cltxt, cltxt2, clnam
316      !!
317      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
318         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
319         &             ln_timing, ln_diacfl
320      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
321      !!----------------------------------------------------------------------
322      !
323      cltxt  = ''
324      cltxt2 = ''
325      clnam  = '' 
326      cxios_context = 'nemo'
327      !
328      !                             ! Open reference namelist and configuration namelist files
329      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
330      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
331      !
332      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
333      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
334901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
335      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
336      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
337902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
338      !
339      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
340      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
341903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
342      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
343      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
344904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
345
346      !                             !--------------------------!
347      !                             !  Set global domain size  !   (control print return in cltxt2)
348      !                             !--------------------------!
349      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
350         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
351         !
352      ELSE                                ! user-defined namelist
353         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
354      ENDIF
355      !
356      !
357      !                             !--------------------------------------------!
358      !                             !  set communicator & select the local node  !
359      !                             !  NB: mynode also opens output.namelist.dyn !
360      !                             !      on unit number numond on first proc   !
361      !                             !--------------------------------------------!
362#if defined key_iomput
363      IF( Agrif_Root() ) THEN
364         IF( lk_oasis ) THEN
365            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
366            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
367         ELSE
368            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
369         ENDIF
370      ENDIF
371      ! Nodes selection (control print return in cltxt)
372      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
373#else
374      IF( lk_oasis ) THEN
375         IF( Agrif_Root() ) THEN
376            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
377         ENDIF
378         ! Nodes selection (control print return in cltxt)
379         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
380      ELSE
381         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
382         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
383      ENDIF
384#endif
385
386      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
387
388      lwm = (narea == 1)                                    ! control of output namelists
389      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
390
391      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
392         !                       ! now that the file has been opened in call to mynode.
393         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
394         WRITE( numond, namctl )
395         WRITE( numond, namcfg )
396         IF( .NOT.ln_read_cfg ) THEN
397            DO ji = 1, SIZE(clnam)
398               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
399            END DO
400         ENDIF
401      ENDIF
402
403      IF(lwp) THEN                            ! open listing units
404         !
405         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
406         !
407         WRITE(numout,*)
408         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
409         WRITE(numout,*) '                       NEMO team'
410         WRITE(numout,*) '            Ocean General Circulation Model'
411         WRITE(numout,*) '                NEMO version 4.0  (2017) '
412         WRITE(numout,*)
413         WRITE(numout,*)
414         DO ji = 1, SIZE(cltxt)
415            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
416         END DO
417         WRITE(numout,*)
418         WRITE(numout,*)
419         DO ji = 1, SIZE(cltxt2)
420            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
421         END DO
422         !
423         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
424         !
425      ENDIF
426      !                                      ! Domain decomposition
427      CALL mpp_init                          ! MPP
428
429      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
430      CALL nemo_alloc()
431
432      !                             !-------------------------------!
433      !                             !  NEMO general initialization  !
434      !                             !-------------------------------!
435
436      CALL nemo_ctl                          ! Control prints
437      !
438      !                                      ! General initialization
439      IF( ln_timing    )   CALL timing_init     ! timing
440      IF( ln_timing    )   CALL timing_start( 'nemo_init')
441      !
442                           CALL     phy_cst         ! Physical constants
443                           CALL     eos_init        ! Equation of state
444      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
445                           CALL     wad_init        ! Wetting and drying options
446                           CALL     dom_init("OPA") ! Domain
447      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
448      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
449     
450      CALL diurnal_sst_bulk_init                ! diurnal sst
451      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
452      !                           
453      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
454         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
455         CALL     sbc_init                            ! Forcings : surface module
456         CALL tra_qsr_init                            ! penetrative solar radiation qsr
457         IF( ln_diaobs ) THEN                         ! Observation & model comparison
458            CALL dia_obs_init                            ! Initialize observational data
459            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
460         ENDIF     
461         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
462         !
463         RETURN                                       ! end of initialization
464      ENDIF
465     
466                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
467
468      !                                      ! external forcing
469                           CALL    tide_init    ! tidal harmonics
470                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
471                           CALL     bdy_init    ! Open boundaries initialisation
472
473      !                                      ! Ocean physics
474                           CALL zdf_phy_init    ! Vertical physics
475                                     
476      !                                         ! Lateral physics
477                           CALL ldf_tra_init      ! Lateral ocean tracer physics
478                           CALL ldf_eiv_init      ! eddy induced velocity param.
479                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
480
481      !                                      ! Active tracers
482      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
483                           CALL tra_bbc_init      ! bottom heat flux
484      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
485                           CALL tra_dmp_init      ! internal tracer damping
486                           CALL tra_adv_init      ! horizontal & vertical advection
487                           CALL tra_ldf_init      ! lateral mixing
488
489      !                                      ! Dynamics
490      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
491                           CALL dyn_adv_init      ! advection (vector or flux form)
492                           CALL dyn_vor_init      ! vorticity term including Coriolis
493                           CALL dyn_ldf_init      ! lateral mixing
494                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
495                           CALL dyn_spg_init      ! surface pressure gradient
496
497#if defined key_top
498      !                                      ! Passive tracers
499                           CALL     trc_init
500#endif
501      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
502
503      !                                      ! Icebergs
504                           CALL icb_init( rn_Dt, nit000 )   ! initialise icebergs instance
505
506      !                                      ! Misc. options
507                           CALL sto_par_init    ! Stochastic parametrization
508      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
509     
510      !                                      ! Diagnostics
511      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
512      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
513                           CALL dia_ptr_init    ! Poleward TRansports initialization
514      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
515                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
516                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
517                           CALL dia_obs_init    ! Initialize observational data
518                           CALL dia_tmb_init    ! TMB outputs
519                           CALL dia_25h_init    ! 25h mean  outputs
520      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
521
522      !                                      ! Assimilation increments
523      IF( lk_asminc    ) THEN
524                           CALL asm_inc_init    ! Initialize assimilation increments
525                           l_dynasm = ln_asmiau .AND. ln_dyninc
526                           l_traasm = ln_asmiau .AND. ln_trainc
527      ELSE
528                           l_dynasm = .FALSE.
529                           l_traasm = .FALSE.
530      ENDIF
531      !
532      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
533      !
534      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
535      !
536   END SUBROUTINE nemo_init
537
538
539   SUBROUTINE nemo_ctl
540      !!----------------------------------------------------------------------
541      !!                     ***  ROUTINE nemo_ctl  ***
542      !!
543      !! ** Purpose :   control print setting
544      !!
545      !! ** Method  : - print namctl information and check some consistencies
546      !!----------------------------------------------------------------------
547      !
548      IF(lwp) THEN                  ! control print
549         WRITE(numout,*)
550         WRITE(numout,*) 'nemo_ctl: Control prints'
551         WRITE(numout,*) '~~~~~~~~'
552         WRITE(numout,*) '   Namelist namctl'
553         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
554         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
555         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
556         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
557         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
558         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
559         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
560         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
561         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
562         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
563      ENDIF
564      !
565      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
566      nictls    = nn_ictls
567      nictle    = nn_ictle
568      njctls    = nn_jctls
569      njctle    = nn_jctle
570      isplt     = nn_isplt
571      jsplt     = nn_jsplt
572
573      IF(lwp) THEN                  ! control print
574         WRITE(numout,*)
575         WRITE(numout,*) '   Namelist namcfg'
576         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
577         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
578         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
579         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
580         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
581         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
582      ENDIF
583      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
584      !
585      !                             ! Parameter control
586      !
587      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
588         IF( lk_mpp .AND. jpnij > 1 ) THEN
589            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
590         ELSE
591            IF( isplt == 1 .AND. jsplt == 1  ) THEN
592               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
593                  &           ' - the print control will be done over the whole domain' )
594            ENDIF
595            ijsplt = isplt * jsplt            ! total number of processors ijsplt
596         ENDIF
597         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
598         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
599         !
600         !                              ! indices used for the SUM control
601         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
602            lsp_area = .FALSE.
603         ELSE                                             ! print control done over a specific  area
604            lsp_area = .TRUE.
605            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
606               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
607               nictls = 1
608            ENDIF
609            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
610               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
611               nictle = jpiglo
612            ENDIF
613            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
614               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
615               njctls = 1
616            ENDIF
617            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
618               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
619               njctle = jpjglo
620            ENDIF
621         ENDIF
622      ENDIF
623      !
624      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
625         &                                                'Compile with key_nosignedzero enabled' )
626      !
627#if defined key_agrif
628      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
629#endif
630      !
631   END SUBROUTINE nemo_ctl
632
633
634   SUBROUTINE nemo_closefile
635      !!----------------------------------------------------------------------
636      !!                     ***  ROUTINE nemo_closefile  ***
637      !!
638      !! ** Purpose :   Close the files
639      !!----------------------------------------------------------------------
640      !
641      IF( lk_mpp )   CALL mppsync
642      !
643      CALL iom_close                                 ! close all input/output files managed by iom_*
644      !
645      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
646      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
647      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
648      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
649      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
650      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
651      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
652      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
653      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
654      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
655      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
656      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
657      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
658      !
659      numout = 6                                     ! redefine numout in case it is used after this point...
660      !
661   END SUBROUTINE nemo_closefile
662
663
664   SUBROUTINE nemo_alloc
665      !!----------------------------------------------------------------------
666      !!                     ***  ROUTINE nemo_alloc  ***
667      !!
668      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
669      !!
670      !! ** Method  :
671      !!----------------------------------------------------------------------
672      USE diawri    , ONLY : dia_wri_alloc
673      USE dom_oce   , ONLY : dom_oce_alloc
674      USE trc_oce   , ONLY : trc_oce_alloc
675      USE bdy_oce   , ONLY : bdy_oce_alloc
676#if defined key_diadct 
677      USE diadct    , ONLY : diadct_alloc 
678#endif 
679      !
680      INTEGER :: ierr
681      !!----------------------------------------------------------------------
682      !
683      ierr =        oce_alloc    ()    ! ocean
684      ierr = ierr + dia_wri_alloc()
685      ierr = ierr + dom_oce_alloc()    ! ocean domain
686      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
687      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
688      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
689      !
690#if defined key_diadct 
691      ierr = ierr + diadct_alloc ()    !
692#endif 
693      !
694      IF( lk_mpp    )   CALL mpp_sum( ierr )
695      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
696      !
697   END SUBROUTINE nemo_alloc
698
699   !!======================================================================
700END MODULE nemogcm
701
Note: See TracBrowser for help on using the repository browser.