New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2018/dev_r9838_ENHANCE04_RK3/src/OFF – NEMO

source: NEMO/branches/2018/dev_r9838_ENHANCE04_RK3/src/OFF/nemogcm.F90 @ 10009

Last change on this file since 10009 was 10009, checked in by gm, 6 years ago

#1911 (ENHANCE-04): RK3 branch - step II.1 time-level dimension on ssh

  • Property svn:keywords set to Id
File size: 25.0 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   nemo_gcm      : off-line: solve ocean tracer only
13   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14   !!   nemo_init     : initialization of the NEMO system
15   !!   nemo_ctl      : initialisation of the contol print
16   !!   nemo_closefile: close remaining open files
17   !!   nemo_alloc    : dynamical allocation
18   !!   istate_init   : simple initialization to zero of ocean fields
19   !!   stp_ctl       : reduced step control (no dynamics in off-line)
20   !!----------------------------------------------------------------------
21   USE dom_oce        ! ocean space domain variables
22   USE oce            ! dynamics and tracers variables
23   USE trc_oce        ! Shared ocean/passive tracers variables
24   USE c1d            ! 1D configuration
25   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
26   USE closea         ! treatment of closed seas (for ln_closea)
27   USE usrdef_nam     ! user defined configuration
28   USE eosbn2         ! equation of state            (eos bn2 routine)
29   !              ! ocean physics
30   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
31   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
32   USE traqsr         ! solar radiation penetration    (tra_qsr_init routine)
33   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
34   USE traldf         ! lateral physics                (tra_ldf_init routine)
35   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
36   USE phycst         ! physical constant                   (par_cst routine)
37   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
38   USE trcini         ! Initilization of the passive tracers
39   USE daymod         ! calendar                            (day     routine)
40   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
41   USE dtadyn         ! Lecture and interpolation of the dynamical fields
42   !              ! Passive tracers needs
43   USE trc            ! passive tracer : variables
44   USE trcnam         ! passive tracer : namelist
45   USE trcrst         ! passive tracer restart
46   USE diaptr         ! Need to initialise this as some variables are used in if statements later
47   USE sbc_oce , ONLY : ln_rnf
48   USE sbcrnf         ! surface boundary condition : runoffs
49   !              ! I/O & MPP
50   USE iom            ! I/O library
51   USE in_out_manager ! I/O manager
52   USE mppini         ! shared/distributed memory setting (mpp_init routine)
53   USE lib_mpp        ! distributed memory computing
54#if defined key_iomput
55   USE xios           ! xIOserver
56#endif
57   USE prtctl         ! Print control                    (prt_ctl_init routine)
58   USE timing         ! Timing
59   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
60   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
61
62   IMPLICIT NONE
63   PRIVATE
64   
65   PUBLIC   nemo_gcm   ! called by nemo.F90
66
67   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
68
69   !!----------------------------------------------------------------------
70   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
71   !! $Id$
72   !! Software governed by the CeCILL licence     (./LICENSE)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE nemo_gcm
77      !!----------------------------------------------------------------------
78      !!                     ***  ROUTINE nemo_gcm  ***
79      !!
80      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
81      !!              curvilinear mesh on the sphere.
82      !!
83      !! ** Method  : - model general initialization
84      !!              - launch the time-stepping (dta_dyn and trc_stp)
85      !!              - finalize the run by closing files and communications
86      !!
87      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
88      !!              Madec, 2008, internal report, IPSL.
89      !!----------------------------------------------------------------------
90      INTEGER :: istp, indic       ! time step index
91      !!----------------------------------------------------------------------
92
93      CALL nemo_init  ! Initializations
94
95      ! check that all process are still there... If some process have an error,
96      ! they will never enter in step and other processes will wait until the end of the cpu time!
97      IF( lk_mpp )   CALL mpp_max( nstop )
98
99      !                            !-----------------------!
100      !                            !==   time stepping   ==!
101      !                            !-----------------------!
102      !                                               !== set the model time-step  ==!
103      !
104      IF( l_1st_euler ) THEN   ;   rDt =         rn_Dt   ;   l_1st_euler = .TRUE.    ! start or restart with Euler 1st time-step
105      ELSE                     ;   rDt = 2._wp * rn_Dt   ;   l_1st_euler = .FALSE.   ! restart with leapfrog
106      ENDIF
107      r1_Dt = 1._wp / rDt
108      ! NB: if l_1st_euler=T, rDt will be set to 2*rn_Dt at the end of the 1st time-step (see the DO WHILE below)
109      !
110      !
111      istp = nit000
112      !
113      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
114      !
115      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
116      !
117      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
118         !
119         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
120                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
121                                CALL dta_dyn    ( istp )         ! Interpolation of the dynamical fields
122         IF( .NOT.ln_linssh )   CALL dta_dyn_swp( istp )         ! swap of sea  surface height and vertical scale factors
123
124                                CALL trc_stp    ( istp )         ! time-stepping
125                                CALL stp_ctl    ( istp, indic )  ! Time loop: control and print
126         IF( l_1st_euler ) THEN
127            rDt   = 2._wp * rDt                                  ! recover Leap-frog time-step
128            r1_Dt = 1._wp / rDt
129            l_1st_euler = .FALSE.
130         ENDIF
131         !
132         istp = istp + 1
133      END DO
134      !
135#if defined key_iomput
136      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
137#endif
138
139      !                            !------------------------!
140      !                            !==  finalize the run  ==!
141      !                            !------------------------!
142      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
143
144      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
145         WRITE(numout,cform_err)
146         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
147         WRITE(numout,*)
148      ENDIF
149      !
150      IF( ln_timing )   CALL timing_finalize
151      !
152      CALL nemo_closefile
153      !
154#if defined key_iomput
155                     CALL xios_finalize   ! end mpp communications with xios
156#else
157      IF( lk_mpp )   CALL mppstop         ! end mpp communications
158#endif
159      !
160   END SUBROUTINE nemo_gcm
161
162
163   SUBROUTINE nemo_init
164      !!----------------------------------------------------------------------
165      !!                     ***  ROUTINE nemo_init  ***
166      !!
167      !! ** Purpose :   initialization of the nemo model in off-line mode
168      !!----------------------------------------------------------------------
169      INTEGER  ::   ji                 ! dummy loop indices
170      INTEGER  ::   ios, ilocal_comm   ! local integers
171      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
172      !!
173      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
174         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
175         &             ln_timing, ln_diacfl
176      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
177      !!----------------------------------------------------------------------
178      !
179      cltxt  = ''
180      cltxt2 = ''
181      clnam  = '' 
182      cxios_context = 'nemo'
183      !
184      !                             ! Open reference namelist and configuration namelist files
185      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
186      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
187      !
188      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
189      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
190901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
191      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
192      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
193902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
194      !
195      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
196      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
197903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
198      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
199      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
200904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
201
202      !                             !--------------------------!
203      !                             !  Set global domain size  !   (control print return in cltxt2)
204      !                             !--------------------------!
205      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
206         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
207         !
208      ELSE                                ! user-defined namelist
209         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
210      ENDIF
211      !
212      l_offline = .true.                  ! passive tracers are run offline
213      !
214      !                             !--------------------------------------------!
215      !                             !  set communicator & select the local node  !
216      !                             !  NB: mynode also opens output.namelist.dyn !
217      !                             !      on unit number numond on first proc   !
218      !                             !--------------------------------------------!
219#if defined key_iomput
220      CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )
221      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
222#else
223      ilocal_comm = 0
224      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
225#endif
226
227      narea = narea + 1                       ! mynode return the rank of proc (0 --> jpnij -1 )
228
229      lwm = (narea == 1)                      ! control of output namelists
230      lwp = (narea == 1) .OR. ln_ctl          ! control of all listing output print
231
232      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
233         !                       ! now that the file has been opened in call to mynode.
234         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
235         WRITE( numond, namctl )
236         WRITE( numond, namcfg )
237         IF( .NOT.ln_read_cfg ) THEN
238            DO ji = 1, SIZE(clnam)
239               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
240            END DO
241         ENDIF
242      ENDIF
243
244      IF(lwp) THEN                            ! open listing units
245         !
246         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
247         !
248         WRITE(numout,*)
249         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
250         WRITE(numout,*) '                       NEMO team'
251         WRITE(numout,*) '                   Off-line TOP Model'
252         WRITE(numout,*) '                NEMO version 4.0  (2017) '
253         WRITE(numout,*)
254         WRITE(numout,*)
255         DO ji = 1, SIZE(cltxt)
256            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
257         END DO
258         WRITE(numout,*)
259         WRITE(numout,*)
260         DO ji = 1, SIZE(cltxt2)
261            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
262         END DO
263         !
264         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
265         !
266      ENDIF
267      CALL mpp_init                          ! MPP domain decomposition
268
269      CALL dom_nam                           ! set the time (Nt) by reading namelist namrun and namdom
270
271      !                                      ! allocate arrays (here, as we know the dimensions of both
272      !                                      !                  the grid and number of time-level used, and
273      CALL nemo_alloc()                      !                  numout has been set: we can allocate arrays)
274
275      !                             !-------------------------------!
276      !                             !  NEMO general initialization  !
277      !                             !-------------------------------!
278
279      CALL nemo_ctl                          ! Control prints
280      !
281      !                                      ! General initialization
282      IF( ln_timing    )   CALL timing_init
283      IF( ln_timing    )   CALL timing_start( 'nemo_init')
284      !
285                           CALL     phy_cst         ! Physical constants
286                           CALL     eos_init        ! Equation of state
287      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
288                           CALL     dom_init("OPA") ! Domain
289      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
290
291                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
292
293                           CALL     sbc_init    ! Forcings : surface module
294
295      !                                      ! Tracer physics
296                           CALL ldf_tra_init    ! Lateral ocean tracer physics
297                           CALL ldf_eiv_init    ! Eddy induced velocity param
298                           CALL tra_ldf_init    ! lateral mixing
299      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
300      IF( ln_traqsr    )   CALL tra_qsr_init    ! penetrative solar radiation
301      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
302
303      !                                      ! Passive tracers
304                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
305                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
306                           CALL dta_dyn_init   ! Initialization for the dynamics
307
308                           CALL     trc_init   ! Passive tracers initialization
309                           CALL dia_ptr_init   ! Poleward TRansports initialization
310                           
311      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
312      !
313      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
314      !
315   END SUBROUTINE nemo_init
316
317
318   SUBROUTINE nemo_ctl
319      !!----------------------------------------------------------------------
320      !!                     ***  ROUTINE nemo_ctl  ***
321      !!
322      !! ** Purpose :   control print setting
323      !!
324      !! ** Method  : - print namctl information and check some consistencies
325      !!----------------------------------------------------------------------
326      !
327      IF(lwp) THEN                  ! control print
328         WRITE(numout,*)
329         WRITE(numout,*) 'nemo_ctl: Control prints'
330         WRITE(numout,*) '~~~~~~~~'
331         WRITE(numout,*) '   Namelist namctl'
332         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
333         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
334         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
335         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
336         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
337         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
338         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
339         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
340         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
341         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
342      ENDIF
343      !
344      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
345      nictls    = nn_ictls
346      nictle    = nn_ictle
347      njctls    = nn_jctls
348      njctle    = nn_jctle
349      isplt     = nn_isplt
350      jsplt     = nn_jsplt
351
352      IF(lwp) THEN                  ! control print
353         WRITE(numout,*)
354         WRITE(numout,*) '   Namelist namcfg'
355         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
356         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
357         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
358         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
359         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
360         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
361      ENDIF
362      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
363      !
364      !                             ! Parameter control
365      !
366      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
367         IF( lk_mpp .AND. jpnij > 1 ) THEN
368            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
369         ELSE
370            IF( isplt == 1 .AND. jsplt == 1  ) THEN
371               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
372                  &           ' - the print control will be done over the whole domain' )
373            ENDIF
374            ijsplt = isplt * jsplt            ! total number of processors ijsplt
375         ENDIF
376         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
377         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
378         !
379         !                              ! indices used for the SUM control
380         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
381            lsp_area = .FALSE.
382         ELSE                                             ! print control done over a specific  area
383            lsp_area = .TRUE.
384            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
385               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
386               nictls = 1
387            ENDIF
388            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
389               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
390               nictle = jpiglo
391            ENDIF
392            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
393               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
394               njctls = 1
395            ENDIF
396            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
397               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
398               njctle = jpjglo
399            ENDIF
400         ENDIF
401      ENDIF
402      !
403      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
404         &                                                'Compile with key_nosignedzero enabled' )
405      !
406   END SUBROUTINE nemo_ctl
407
408
409   SUBROUTINE nemo_closefile
410      !!----------------------------------------------------------------------
411      !!                     ***  ROUTINE nemo_closefile  ***
412      !!
413      !! ** Purpose :   Close the files
414      !!----------------------------------------------------------------------
415      !
416      IF( lk_mpp )   CALL mppsync
417      !
418      CALL iom_close                                 ! close all input/output files managed by iom_*
419      !
420      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
421      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
422      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
423      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
424      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
425      !
426      numout = 6                                     ! redefine numout in case it is used after this point...
427      !
428   END SUBROUTINE nemo_closefile
429
430
431   SUBROUTINE nemo_alloc
432      !!----------------------------------------------------------------------
433      !!                     ***  ROUTINE nemo_alloc  ***
434      !!
435      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
436      !!
437      !! ** Method  :
438      !!----------------------------------------------------------------------
439      USE diawri ,   ONLY : dia_wri_alloc
440      USE dom_oce,   ONLY : dom_oce_alloc
441      USE zdf_oce,   ONLY : zdf_oce_alloc
442      USE trc_oce,   ONLY : trc_oce_alloc
443      !
444      INTEGER :: ierr
445      !!----------------------------------------------------------------------
446      !
447      ierr =        oce_alloc    ()          ! ocean
448      ierr = ierr + dia_wri_alloc()
449      ierr = ierr + dom_oce_alloc()          ! ocean domain
450      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
451      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
452      !
453      IF( lk_mpp    )   CALL mpp_sum( ierr )
454      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
455      !
456   END SUBROUTINE nemo_alloc
457
458   SUBROUTINE istate_init
459      !!----------------------------------------------------------------------
460      !!                   ***  ROUTINE istate_init  ***
461      !!
462      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
463      !!----------------------------------------------------------------------
464      !
465      !     now fields         !     after fields      !
466      un   (:,:,:)   = 0._wp   ;   ua(:,:,:) = 0._wp   !
467      vn   (:,:,:)   = 0._wp   ;   va(:,:,:) = 0._wp   !
468      wn   (:,:,:)   = 0._wp   !                       !
469      hdivn(:,:,:)   = 0._wp   !                       !
470      tsn  (:,:,:,:) = 0._wp   !                       !
471      !
472      rhd  (:,:,:) = 0.e0
473      rhop (:,:,:) = 0.e0
474      rn2  (:,:,:) = 0.e0
475      !
476   END SUBROUTINE istate_init
477
478
479   SUBROUTINE stp_ctl( kt, kindic )
480      !!----------------------------------------------------------------------
481      !!                    ***  ROUTINE stp_ctl  ***
482      !!
483      !! ** Purpose :   Control the run
484      !!
485      !! ** Method  : - Save the time step in numstp
486      !!
487      !! ** Actions :   'time.step' file containing the last ocean time-step
488      !!----------------------------------------------------------------------
489      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
490      INTEGER, INTENT(inout) ::   kindic  ! indicator of solver convergence
491      !!----------------------------------------------------------------------
492      !
493      IF( kt == nit000 .AND. lwp ) THEN
494         WRITE(numout,*)
495         WRITE(numout,*) 'stp_ctl : time-stepping control'
496         WRITE(numout,*) '~~~~~~~'
497         ! open time.step file
498         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
499      ENDIF
500      !
501      IF(lwp) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
502      IF(lwp) REWIND( numstp )                       ! --------------------------
503      !
504   END SUBROUTINE stp_ctl
505   !!======================================================================
506END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.