New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzdf.F90 in NEMO/branches/2018/dev_r9956_ENHANCE05_ZAD_AIMP/src/OCE/DYN – NEMO

source: NEMO/branches/2018/dev_r9956_ENHANCE05_ZAD_AIMP/src/OCE/DYN/dynzdf.F90 @ 9957

Last change on this file since 9957 was 9957, checked in by acc, 6 years ago

New development branch for the adaptive-implicit vertical advection (05_Gurvan-Vertical_advection)

  • Property svn:keywords set to Id
File size: 20.1 KB
Line 
1MODULE dynzdf
2   !!==============================================================================
3   !!                 ***  MODULE  dynzdf  ***
4   !! Ocean dynamics :  vertical component of the momentum mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
8   !!            4.0  !  2017-06  (G. Madec) remove the explicit time-stepping option + avm at t-point
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_zdf       : compute the after velocity through implicit calculation of vertical mixing
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE phycst         ! physical constants
16   USE dom_oce        ! ocean space and time domain variables
17   USE sbc_oce        ! surface boundary condition: ocean
18   USE zdf_oce        ! ocean vertical physics variables
19   USE zdfdrg         ! vertical physics: top/bottom drag coef.
20   USE dynadv    ,ONLY: ln_dynadv_vec    ! dynamics: advection form
21   USE dynldf_iso,ONLY: akzu, akzv       ! dynamics: vertical component of rotated lateral mixing
22   USE ldfdyn         ! lateral diffusion: eddy viscosity coef. and type of operator
23   USE trd_oce        ! trends: ocean variables
24   USE trddyn         ! trend manager: dynamics
25   !
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! MPP library
28   USE prtctl         ! Print control
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   dyn_zdf   !  routine called by step.F90
35
36   REAL(wp) ::  r_vvl     ! non-linear free surface indicator: =0 if ln_linssh=T, =1 otherwise
37
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL licence (./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46   
47   SUBROUTINE dyn_zdf( kt )
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE dyn_zdf  ***
50      !!
51      !! ** Purpose :   compute the trend due to the vert. momentum diffusion
52      !!              together with the Leap-Frog time stepping using an
53      !!              implicit scheme.
54      !!
55      !! ** Method  :  - Leap-Frog time stepping on all trends but the vertical mixing
56      !!         ua =         ub + 2*dt *       ua             vector form or linear free surf.
57      !!         ua = ( e3u_b*ub + 2*dt * e3u_n*ua ) / e3u_a   otherwise
58      !!               - update the after velocity with the implicit vertical mixing.
59      !!      This requires to solver the following system:
60      !!         ua = ua + 1/e3u_a dk+1[ mi(avm) / e3uw_a dk[ua] ]
61      !!      with the following surface/top/bottom boundary condition:
62      !!      surface: wind stress input (averaged over kt-1/2 & kt+1/2)
63      !!      top & bottom : top stress (iceshelf-ocean) & bottom stress (cf zdfdrg.F90)
64      !!
65      !! ** Action :   (ua,va)   after velocity
66      !!---------------------------------------------------------------------
67      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
68      !
69      INTEGER  ::   ji, jj, jk         ! dummy loop indices
70      INTEGER  ::   iku, ikv           ! local integers
71      REAL(wp) ::   zzwi, ze3ua, zdt   ! local scalars
72      REAL(wp) ::   zzws, ze3va        !   -      -
73      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::  zwi, zwd, zws   ! 3D workspace
74      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdu, ztrdv   !  -      -
75      !!---------------------------------------------------------------------
76      !
77      IF( ln_timing )   CALL timing_start('dyn_zdf')
78      !
79      IF( kt == nit000 ) THEN       !* initialization
80         IF(lwp) WRITE(numout,*)
81         IF(lwp) WRITE(numout,*) 'dyn_zdf_imp : vertical momentum diffusion implicit operator'
82         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
83         !
84         If( ln_linssh ) THEN   ;    r_vvl = 0._wp    ! non-linear free surface indicator
85         ELSE                   ;    r_vvl = 1._wp
86         ENDIF
87      ENDIF
88      !                             !* set time step
89      IF( neuler == 0 .AND. kt == nit000     ) THEN   ;   r2dt =      rdt   ! = rdt (restart with Euler time stepping)
90      ELSEIF(               kt <= nit000 + 1 ) THEN   ;   r2dt = 2. * rdt   ! = 2 rdt (leapfrog)
91      ENDIF
92      !
93      !                             !* explicit top/bottom drag case
94      IF( .NOT.ln_drgimp )   CALL zdf_drg_exp( kt, ub, vb, ua, va )  ! add top/bottom friction trend to (ua,va)
95      !
96      !
97      IF( l_trddyn )   THEN         !* temporary save of ta and sa trends
98         ALLOCATE( ztrdu(jpi,jpj,jpk), ztrdv(jpi,jpj,jpk) ) 
99         ztrdu(:,:,:) = ua(:,:,:)
100         ztrdv(:,:,:) = va(:,:,:)
101      ENDIF
102      !
103      !              !==  RHS: Leap-Frog time stepping on all trends but the vertical mixing  ==!   (put in ua,va)
104      !
105      !                    ! time stepping except vertical diffusion
106      IF( ln_dynadv_vec .OR. ln_linssh ) THEN   ! applied on velocity
107         DO jk = 1, jpkm1
108            ua(:,:,jk) = ( ub(:,:,jk) + r2dt * ua(:,:,jk) ) * umask(:,:,jk)
109            va(:,:,jk) = ( vb(:,:,jk) + r2dt * va(:,:,jk) ) * vmask(:,:,jk)
110         END DO
111      ELSE                                      ! applied on thickness weighted velocity
112         DO jk = 1, jpkm1
113            ua(:,:,jk) = (         e3u_b(:,:,jk) * ub(:,:,jk)  &
114               &          + r2dt * e3u_n(:,:,jk) * ua(:,:,jk)  ) / e3u_a(:,:,jk) * umask(:,:,jk)
115            va(:,:,jk) = (         e3v_b(:,:,jk) * vb(:,:,jk)  &
116               &          + r2dt * e3v_n(:,:,jk) * va(:,:,jk)  ) / e3v_a(:,:,jk) * vmask(:,:,jk)
117         END DO
118      ENDIF
119      !                    ! add top/bottom friction
120      !     With split-explicit free surface, barotropic stress is treated explicitly Update velocities at the bottom.
121      !     J. Chanut: The bottom stress is computed considering after barotropic velocities, which does
122      !                not lead to the effective stress seen over the whole barotropic loop.
123      !     G. Madec : in linear free surface, e3u_a = e3u_n = e3u_0, so systematic use of e3u_a
124      IF( ln_drgimp .AND. ln_dynspg_ts ) THEN
125         DO jk = 1, jpkm1        ! remove barotropic velocities
126            ua(:,:,jk) = ( ua(:,:,jk) - ua_b(:,:) ) * umask(:,:,jk)
127            va(:,:,jk) = ( va(:,:,jk) - va_b(:,:) ) * vmask(:,:,jk)
128         END DO
129         DO jj = 2, jpjm1        ! Add bottom/top stress due to barotropic component only
130            DO ji = fs_2, fs_jpim1   ! vector opt.
131               iku = mbku(ji,jj)         ! ocean bottom level at u- and v-points
132               ikv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
133               ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,iku) + r_vvl * e3u_a(ji,jj,iku)
134               ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,ikv) + r_vvl * e3v_a(ji,jj,ikv)
135               ua(ji,jj,iku) = ua(ji,jj,iku) + r2dt * 0.5*( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) * ua_b(ji,jj) / ze3ua
136               va(ji,jj,ikv) = va(ji,jj,ikv) + r2dt * 0.5*( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) * va_b(ji,jj) / ze3va
137            END DO
138         END DO
139         IF( ln_isfcav ) THEN    ! Ocean cavities (ISF)
140            DO jj = 2, jpjm1       
141               DO ji = fs_2, fs_jpim1   ! vector opt.
142                  iku = miku(ji,jj)         ! top ocean level at u- and v-points
143                  ikv = mikv(ji,jj)         ! (first wet ocean u- and v-points)
144                  ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,iku) + r_vvl * e3u_a(ji,jj,iku)
145                  ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,ikv) + r_vvl * e3v_a(ji,jj,ikv)
146                  ua(ji,jj,iku) = ua(ji,jj,iku) + r2dt * 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) * ua_b(ji,jj) / ze3ua
147                  va(ji,jj,ikv) = va(ji,jj,ikv) + r2dt * 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) * va_b(ji,jj) / ze3va
148               END DO
149            END DO
150         END IF
151      ENDIF
152      !
153      !              !==  Vertical diffusion on u  ==!
154      !
155      !                    !* Matrix construction
156      zdt = r2dt * 0.5
157      SELECT CASE( nldf_dyn )
158      CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
159         DO jk = 1, jpkm1
160            DO jj = 2, jpjm1 
161               DO ji = fs_2, fs_jpim1   ! vector opt.
162                  ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,jk) + r_vvl * e3u_a(ji,jj,jk)   ! after scale factor at T-point
163                  zzwi = - zdt * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) + akzu(ji,jj,jk  ) )   &
164                     &         / ( ze3ua * e3uw_n(ji,jj,jk  ) ) * wumask(ji,jj,jk  )
165                  zzws = - zdt * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) + akzu(ji,jj,jk+1) )   &
166                     &         / ( ze3ua * e3uw_n(ji,jj,jk+1) ) * wumask(ji,jj,jk+1)
167                  zwi(ji,jj,jk) = zzwi
168                  zws(ji,jj,jk) = zzws
169                  zwd(ji,jj,jk) = 1._wp - zzwi - zzws
170               END DO
171            END DO
172         END DO
173      CASE DEFAULT               ! iso-level lateral mixing
174         DO jk = 1, jpkm1
175            DO jj = 2, jpjm1 
176               DO ji = fs_2, fs_jpim1   ! vector opt.
177                  ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,jk) + r_vvl * e3u_a(ji,jj,jk)   ! after scale factor at T-point
178                  zzwi = - zdt * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) ) / ( ze3ua * e3uw_n(ji,jj,jk  ) ) * wumask(ji,jj,jk  )
179                  zzws = - zdt * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) ) / ( ze3ua * e3uw_n(ji,jj,jk+1) ) * wumask(ji,jj,jk+1)
180                  zwi(ji,jj,jk) = zzwi
181                  zws(ji,jj,jk) = zzws
182                  zwd(ji,jj,jk) = 1._wp - zzwi - zzws
183               END DO
184            END DO
185         END DO
186      END SELECT
187      !
188      DO jj = 2, jpjm1     !* Surface boundary conditions
189         DO ji = fs_2, fs_jpim1   ! vector opt.
190            zwi(ji,jj,1) = 0._wp
191            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
192         END DO
193      END DO
194      !
195      !              !==  Apply semi-implicit bottom friction  ==!
196      !
197      !     Only needed for semi-implicit bottom friction setup. The explicit
198      !     bottom friction has been included in "u(v)a" which act as the R.H.S
199      !     column vector of the tri-diagonal matrix equation
200      !
201      IF ( ln_drgimp ) THEN      ! implicit bottom friction
202         DO jj = 2, jpjm1
203            DO ji = 2, jpim1
204               iku = mbku(ji,jj)       ! ocean bottom level at u- and v-points
205               ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,iku) + r_vvl * e3u_a(ji,jj,iku)   ! after scale factor at T-point
206               zwd(ji,jj,iku) = zwd(ji,jj,iku) - r2dt * 0.5*( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) / ze3ua
207            END DO
208         END DO
209         IF ( ln_isfcav ) THEN   ! top friction (always implicit)
210            DO jj = 2, jpjm1
211               DO ji = 2, jpim1
212                  !!gm   top Cd is masked (=0 outside cavities) no need of test on mik>=2  ==>> it has been suppressed
213                  iku = miku(ji,jj)       ! ocean top level at u- and v-points
214                  ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,iku) + r_vvl * e3u_a(ji,jj,iku)   ! after scale factor at T-point
215                  zwd(ji,jj,iku) = zwd(ji,jj,iku) - r2dt * 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) / ze3ua
216               END DO
217            END DO
218         END IF
219      ENDIF
220      !
221      ! Matrix inversion starting from the first level
222      !-----------------------------------------------------------------------
223      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
224      !
225      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
226      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
227      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
228      !        (        ...               )( ...  ) ( ...  )
229      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
230      !
231      !   m is decomposed in the product of an upper and a lower triangular matrix
232      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
233      !   The solution (the after velocity) is in ua
234      !-----------------------------------------------------------------------
235      !
236      DO jk = 2, jpkm1        !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
237         DO jj = 2, jpjm1   
238            DO ji = fs_2, fs_jpim1   ! vector opt.
239               zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
240            END DO
241         END DO
242      END DO
243      !
244      DO jj = 2, jpjm1        !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
245         DO ji = fs_2, fs_jpim1   ! vector opt.
246            ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,1) + r_vvl * e3u_a(ji,jj,1) 
247            ua(ji,jj,1) = ua(ji,jj,1) + r2dt * 0.5_wp * ( utau_b(ji,jj) + utau(ji,jj) )   &
248               &                                      / ( ze3ua * rau0 ) * umask(ji,jj,1) 
249         END DO
250      END DO
251      DO jk = 2, jpkm1
252         DO jj = 2, jpjm1
253            DO ji = fs_2, fs_jpim1
254               ua(ji,jj,jk) = ua(ji,jj,jk) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * ua(ji,jj,jk-1)
255            END DO
256         END DO
257      END DO
258      !
259      DO jj = 2, jpjm1        !==  thrid recurrence : SOLk = ( Lk - Uk * Ek+1 ) / Dk  ==!
260         DO ji = fs_2, fs_jpim1   ! vector opt.
261            ua(ji,jj,jpkm1) = ua(ji,jj,jpkm1) / zwd(ji,jj,jpkm1)
262         END DO
263      END DO
264      DO jk = jpk-2, 1, -1
265         DO jj = 2, jpjm1
266            DO ji = fs_2, fs_jpim1
267               ua(ji,jj,jk) = ( ua(ji,jj,jk) - zws(ji,jj,jk) * ua(ji,jj,jk+1) ) / zwd(ji,jj,jk)
268            END DO
269         END DO
270      END DO
271      !
272      !              !==  Vertical diffusion on v  ==!
273      !
274      !                       !* Matrix construction
275      zdt = r2dt * 0.5
276      SELECT CASE( nldf_dyn )
277      CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
278         DO jk = 1, jpkm1
279            DO jj = 2, jpjm1   
280               DO ji = fs_2, fs_jpim1   ! vector opt.
281                  ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,jk) + r_vvl * e3v_a(ji,jj,jk)   ! after scale factor at T-point
282                  zzwi = - zdt * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) + akzv(ji,jj,jk  ) )   &
283                     &         / ( ze3va * e3vw_n(ji,jj,jk  ) ) * wvmask(ji,jj,jk  )
284                  zzws = - zdt * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) + akzv(ji,jj,jk+1) )   &
285                     &         / ( ze3va * e3vw_n(ji,jj,jk+1) ) * wvmask(ji,jj,jk+1)
286                  zwi(ji,jj,jk) = zzwi * wvmask(ji,jj,jk  )
287                  zws(ji,jj,jk) = zzws * wvmask(ji,jj,jk+1)
288                  zwd(ji,jj,jk) = 1._wp - zzwi - zzws
289               END DO
290            END DO
291         END DO
292      CASE DEFAULT               ! iso-level lateral mixing
293         DO jk = 1, jpkm1
294            DO jj = 2, jpjm1   
295               DO ji = fs_2, fs_jpim1   ! vector opt.
296                  ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,jk) + r_vvl * e3v_a(ji,jj,jk)   ! after scale factor at T-point
297                  zzwi = - zdt * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) ) / ( ze3va * e3vw_n(ji,jj,jk  ) ) * wvmask(ji,jj,jk  )
298                  zzws = - zdt * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) ) / ( ze3va * e3vw_n(ji,jj,jk+1) ) * wvmask(ji,jj,jk+1)
299                  zwi(ji,jj,jk) = zzwi * wvmask(ji,jj,jk  )
300                  zws(ji,jj,jk) = zzws * wvmask(ji,jj,jk+1)
301                  zwd(ji,jj,jk) = 1._wp - zzwi - zzws
302               END DO
303            END DO
304         END DO
305      END SELECT
306      !
307      DO jj = 2, jpjm1        !* Surface boundary conditions
308         DO ji = fs_2, fs_jpim1   ! vector opt.
309            zwi(ji,jj,1) = 0._wp
310            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
311         END DO
312      END DO
313      !              !==  Apply semi-implicit top/bottom friction  ==!
314      !
315      !     Only needed for semi-implicit bottom friction setup. The explicit
316      !     bottom friction has been included in "u(v)a" which act as the R.H.S
317      !     column vector of the tri-diagonal matrix equation
318      !
319      IF( ln_drgimp ) THEN
320         DO jj = 2, jpjm1
321            DO ji = 2, jpim1
322               ikv = mbkv(ji,jj)       ! (deepest ocean u- and v-points)
323               ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,ikv) + r_vvl * e3v_a(ji,jj,ikv)   ! after scale factor at T-point
324               zwd(ji,jj,ikv) = zwd(ji,jj,ikv) - r2dt * 0.5*( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) / ze3va           
325            END DO
326         END DO
327         IF ( ln_isfcav ) THEN
328            DO jj = 2, jpjm1
329               DO ji = 2, jpim1
330                  ikv = mikv(ji,jj)       ! (first wet ocean u- and v-points)
331                  ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,ikv) + r_vvl * e3v_a(ji,jj,ikv)   ! after scale factor at T-point
332                  zwd(ji,jj,iku) = zwd(ji,jj,iku) - r2dt * 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) / ze3va
333               END DO
334            END DO
335         ENDIF
336      ENDIF
337
338      ! Matrix inversion
339      !-----------------------------------------------------------------------
340      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
341      !
342      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
343      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
344      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
345      !        (        ...               )( ...  ) ( ...  )
346      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
347      !
348      !   m is decomposed in the product of an upper and lower triangular matrix
349      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
350      !   The solution (after velocity) is in 2d array va
351      !-----------------------------------------------------------------------
352      !
353      DO jk = 2, jpkm1        !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
354         DO jj = 2, jpjm1   
355            DO ji = fs_2, fs_jpim1   ! vector opt.
356               zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
357            END DO
358         END DO
359      END DO
360      !
361      DO jj = 2, jpjm1        !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
362         DO ji = fs_2, fs_jpim1   ! vector opt.         
363            ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,1) + r_vvl * e3v_a(ji,jj,1) 
364            va(ji,jj,1) = va(ji,jj,1) + r2dt * 0.5_wp * ( vtau_b(ji,jj) + vtau(ji,jj) )   &
365               &                                      / ( ze3va * rau0 ) * vmask(ji,jj,1) 
366         END DO
367      END DO
368      DO jk = 2, jpkm1
369         DO jj = 2, jpjm1
370            DO ji = fs_2, fs_jpim1   ! vector opt.
371               va(ji,jj,jk) = va(ji,jj,jk) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * va(ji,jj,jk-1)
372            END DO
373         END DO
374      END DO
375      !
376      DO jj = 2, jpjm1        !==  third recurrence : SOLk = ( Lk - Uk * SOLk+1 ) / Dk  ==!
377         DO ji = fs_2, fs_jpim1   ! vector opt.
378            va(ji,jj,jpkm1) = va(ji,jj,jpkm1) / zwd(ji,jj,jpkm1)
379         END DO
380      END DO
381      DO jk = jpk-2, 1, -1
382         DO jj = 2, jpjm1
383            DO ji = fs_2, fs_jpim1
384               va(ji,jj,jk) = ( va(ji,jj,jk) - zws(ji,jj,jk) * va(ji,jj,jk+1) ) / zwd(ji,jj,jk)
385            END DO
386         END DO
387      END DO
388      !
389      IF( l_trddyn )   THEN                      ! save the vertical diffusive trends for further diagnostics
390         ztrdu(:,:,:) = ( ua(:,:,:) - ub(:,:,:) ) / r2dt - ztrdu(:,:,:)
391         ztrdv(:,:,:) = ( va(:,:,:) - vb(:,:,:) ) / r2dt - ztrdv(:,:,:)
392         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zdf, kt )
393         DEALLOCATE( ztrdu, ztrdv ) 
394      ENDIF
395      !                                          ! print mean trends (used for debugging)
396      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' zdf  - Ua: ', mask1=umask,               &
397         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
398         !
399      IF( ln_timing )   CALL timing_stop('dyn_zdf')
400      !
401   END SUBROUTINE dyn_zdf
402
403   !!==============================================================================
404END MODULE dynzdf
Note: See TracBrowser for help on using the repository browser.