source: NEMO/branches/2019/ENHANCE-02_ISF_nemo/src/OCE/DYN/divhor.F90 @ 11423

Last change on this file since 11423 was 11423, checked in by mathiot, 15 months ago

ENHANCE-02_ISF_nemo : add UKESM ice sheet coupling method (ticket #2142)

  • Property svn:keywords set to Id
File size: 5.1 KB
Line 
1MODULE divhor
2   !!==============================================================================
3   !!                       ***  MODULE  divhor  ***
4   !! Ocean diagnostic variable : now horizontal divergence
5   !!==============================================================================
6   !! History :  1.0  ! 2002-09  (G. Madec, E. Durand)  Free form, F90
7   !!             -   ! 2005-01  (J. Chanut) Unstructured open boundaries
8   !!             -   ! 2003-08  (G. Madec)  merged of cur and div, free form, F90
9   !!             -   ! 2005-01  (J. Chanut, A. Sellar) unstructured open boundaries
10   !!            3.3  ! 2010-09  (D.Storkey and E.O'Dea) bug fixes for BDY module
11   !!             -   ! 2010-10  (R. Furner, G. Madec) runoff and cla added directly here
12   !!            3.7  ! 2014-01  (G. Madec) suppression of velocity curl from in-core memory
13   !!             -   ! 2014-12  (G. Madec) suppression of cross land advection option
14   !!             -   ! 2015-10  (G. Madec) add velocity and rnf flag in argument of div_hor
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   div_hor    : Compute the horizontal divergence field
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_oce, ONLY : ln_rnf, ln_isf ! surface boundary condition: ocean
23   USE sbcrnf          ! river runoff
24   USE isfhdiv         ! ice shelf
25#if defined key_asminc   
26   USE asminc          ! Assimilation increment
27#endif
28   !
29   USE in_out_manager  ! I/O manager
30   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
31   USE lib_mpp         ! MPP library
32   USE timing          ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   div_hor    ! routine called by step.F90 and istate.F90
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE div_hor( kt )
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE div_hor  ***
51      !!                   
52      !! ** Purpose :   compute the horizontal divergence at now time-step
53      !!
54      !! ** Method  :   the now divergence is computed as :
55      !!         hdivn = 1/(e1e2t*e3t) ( di[e2u*e3u un] + dj[e1v*e3v vn] )
56      !!      and correct with runoff inflow (div_rnf) and cross land flow (div_cla)
57      !!
58      !! ** Action  : - update hdivn, the now horizontal divergence
59      !!----------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
61      !
62      INTEGER  ::   ji, jj, jk    ! dummy loop indices
63      REAL(wp) ::   zraur, zdep   ! local scalars
64      !!----------------------------------------------------------------------
65      !
66      IF( ln_timing )   CALL timing_start('div_hor')
67      !
68      IF( kt == nit000 ) THEN
69         IF(lwp) WRITE(numout,*)
70         IF(lwp) WRITE(numout,*) 'div_hor : horizontal velocity divergence '
71         IF(lwp) WRITE(numout,*) '~~~~~~~   '
72      ENDIF
73      !
74      DO jk = 1, jpkm1                                      !==  Horizontal divergence  ==!
75         DO jj = 2, jpjm1
76            DO ji = fs_2, fs_jpim1   ! vector opt.
77               hdivn(ji,jj,jk) = (  e2u(ji  ,jj) * e3u_n(ji  ,jj,jk) * un(ji  ,jj,jk)      &
78                  &               - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * un(ji-1,jj,jk)      &
79                  &               + e1v(ji,jj  ) * e3v_n(ji,jj  ,jk) * vn(ji,jj  ,jk)      &
80                  &               - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vn(ji,jj-1,jk)  )   &
81                  &            * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
82            END DO 
83         END DO 
84      END DO
85#if defined key_agrif
86      IF( .NOT. Agrif_Root() ) THEN
87         IF( nbondi == -1 .OR. nbondi == 2 )   hdivn(   2   ,  :   ,:) = 0._wp      ! west
88         IF( nbondi ==  1 .OR. nbondi == 2 )   hdivn( nlci-1,  :   ,:) = 0._wp      ! east
89         IF( nbondj == -1 .OR. nbondj == 2 )   hdivn(   :   ,  2   ,:) = 0._wp      ! south
90         IF( nbondj ==  1 .OR. nbondj == 2 )   hdivn(   :   ,nlcj-1,:) = 0._wp      ! north
91      ENDIF
92#endif
93      !
94      IF( ln_rnf )   CALL sbc_rnf_div( hdivn )              !==  runoffs    ==!   (update hdivn field)
95      !
96#if defined key_asminc 
97      IF( ln_sshinc .AND. ln_asmiau )   CALL ssh_asm_div( kt, hdivn )   !==  SSH assimilation  ==!   (update hdivn field)
98      !
99#endif
100      IF( ln_isf )   CALL isf_hdiv( kt, hdivn )      !==  ice shelf  ==!   (update hdivn field)
101      !
102      CALL lbc_lnk( 'divhor', hdivn, 'T', 1. )   !   (no sign change)
103      !
104      IF( ln_timing )   CALL timing_stop('div_hor')
105      !
106   END SUBROUTINE div_hor
107   
108   !!======================================================================
109END MODULE divhor
Note: See TracBrowser for help on using the repository browser.