source: NEMO/branches/2019/ENHANCE-02_ISF_nemo/src/OCE/DYN/dynhpg.F90 @ 11987

Last change on this file since 11987 was 11987, checked in by mathiot, 10 months ago

ENHANCE-02_ISF_nemo: changes needed after Dave's review

  • Property svn:keywords set to Id
File size: 70.3 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE isf_oce , ONLY : risfload  ! ice shelf  (risfload variable)
34   USE isfload , ONLY : isf_load  ! ice shelf  (isf_load routine )
35   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
36   USE dom_oce         ! ocean space and time domain
37   USE wet_dry         ! wetting and drying
38   USE phycst          ! physical constants
39   USE trd_oce         ! trends: ocean variables
40   USE trddyn          ! trend manager: dynamics
41!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE prtctl          ! Print control
45   USE lbclnk          ! lateral boundary condition
46   USE lib_mpp         ! MPP library
47   USE eosbn2          ! compute density
48   USE timing          ! Timing
49   USE iom
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   dyn_hpg        ! routine called by step module
55   PUBLIC   dyn_hpg_init   ! routine called by opa module
56
57   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
58   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
59   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
60   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
61   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
62   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
63   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
64
65   !                                !! Flag to control the type of hydrostatic pressure gradient
66   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
67   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
68   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
69   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
70   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
71   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
72   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
73   !
74   INTEGER, PUBLIC ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
75
76   !! * Substitutions
77#  include "vectopt_loop_substitute.h90"
78   !!----------------------------------------------------------------------
79   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
80   !! $Id$
81   !! Software governed by the CeCILL license (see ./LICENSE)
82   !!----------------------------------------------------------------------
83CONTAINS
84
85   SUBROUTINE dyn_hpg( kt )
86      !!---------------------------------------------------------------------
87      !!                  ***  ROUTINE dyn_hpg  ***
88      !!
89      !! ** Method  :   Call the hydrostatic pressure gradient routine
90      !!              using the scheme defined in the namelist
91      !!
92      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
93      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
94      !!----------------------------------------------------------------------
95      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
96      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
97      !!----------------------------------------------------------------------
98      !
99      IF( ln_timing )   CALL timing_start('dyn_hpg')
100      !
101      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
102         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
103         ztrdu(:,:,:) = ua(:,:,:)
104         ztrdv(:,:,:) = va(:,:,:)
105      ENDIF
106      !
107      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
108      CASE ( np_zco )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
109      CASE ( np_zps )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
110      CASE ( np_sco )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
111      CASE ( np_djc )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
112      CASE ( np_prj )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
113      CASE ( np_isf )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
114      END SELECT
115      !
116      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
117         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
118         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
119         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
120         DEALLOCATE( ztrdu , ztrdv )
121      ENDIF
122      !
123      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
124         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
125      !
126      IF( ln_timing )   CALL timing_stop('dyn_hpg')
127      !
128   END SUBROUTINE dyn_hpg
129
130
131   SUBROUTINE dyn_hpg_init
132      !!----------------------------------------------------------------------
133      !!                 ***  ROUTINE dyn_hpg_init  ***
134      !!
135      !! ** Purpose :   initializations for the hydrostatic pressure gradient
136      !!              computation and consistency control
137      !!
138      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
139      !!      with the type of vertical coordinate used (zco, zps, sco)
140      !!----------------------------------------------------------------------
141      INTEGER ::   ioptio = 0      ! temporary integer
142      INTEGER ::   ios             ! Local integer output status for namelist read
143      !!
144      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
145      REAL(wp) ::   znad
146      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
147      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
148      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
149      !!
150      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
151         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
152      !!----------------------------------------------------------------------
153      !
154      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
155      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
156901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
157      !
158      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
159      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
160902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
161      IF(lwm) WRITE ( numond, namdyn_hpg )
162      !
163      IF(lwp) THEN                   ! Control print
164         WRITE(numout,*)
165         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
166         WRITE(numout,*) '~~~~~~~~~~~~'
167         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
168         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
169         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
170         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
171         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
172         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
173         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
174      ENDIF
175      !
176      IF( ln_hpg_djc )   &
177         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method',   &
178         &                 '   currently disabled (bugs under investigation).'        ,   &
179         &                 '   Please select either  ln_hpg_sco or  ln_hpg_prj instead' )
180         !
181      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )          &
182         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ',   &
183         &                 '   the standard jacobian formulation hpg_sco    or '    ,   &
184         &                 '   the pressure jacobian formulation hpg_prj'             )
185         !
186      IF( ln_hpg_isf ) THEN
187         IF( .NOT. ln_isfcav )   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
188       ELSE
189         IF(       ln_isfcav )   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
190      ENDIF
191      !
192      !                               ! Set nhpg from ln_hpg_... flags & consistency check
193      nhpg   = np_ERROR
194      ioptio = 0
195      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
196      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
197      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
198      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
199      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
200      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
201      !
202      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
203      !
204      IF(lwp) THEN
205         WRITE(numout,*)
206         SELECT CASE( nhpg )
207         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
208         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
209         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
210         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
211         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
212         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
213         END SELECT
214         WRITE(numout,*)
215      ENDIF
216      !                         
217   END SUBROUTINE dyn_hpg_init
218
219   SUBROUTINE hpg_zco( kt )
220      !!---------------------------------------------------------------------
221      !!                  ***  ROUTINE hpg_zco  ***
222      !!
223      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
224      !!      The now hydrostatic pressure gradient at a given level, jk,
225      !!      is computed by taking the vertical integral of the in-situ
226      !!      density gradient along the model level from the suface to that
227      !!      level:    zhpi = grav .....
228      !!                zhpj = grav .....
229      !!      add it to the general momentum trend (ua,va).
230      !!            ua = ua - 1/e1u * zhpi
231      !!            va = va - 1/e2v * zhpj
232      !!
233      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
234      !!----------------------------------------------------------------------
235      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
236      !
237      INTEGER  ::   ji, jj, jk       ! dummy loop indices
238      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
239      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
240      !!----------------------------------------------------------------------
241      !
242      IF( kt == nit000 ) THEN
243         IF(lwp) WRITE(numout,*)
244         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
245         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
246      ENDIF
247
248      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
249
250      ! Surface value
251      DO jj = 2, jpjm1
252         DO ji = fs_2, fs_jpim1   ! vector opt.
253            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
254            ! hydrostatic pressure gradient
255            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
256            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
257            ! add to the general momentum trend
258            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
259            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
260         END DO
261      END DO
262
263      !
264      ! interior value (2=<jk=<jpkm1)
265      DO jk = 2, jpkm1
266         DO jj = 2, jpjm1
267            DO ji = fs_2, fs_jpim1   ! vector opt.
268               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
269               ! hydrostatic pressure gradient
270               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
271                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
272                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
273
274               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
275                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
276                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
277               ! add to the general momentum trend
278               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
279               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
280            END DO
281         END DO
282      END DO
283      !
284   END SUBROUTINE hpg_zco
285
286
287   SUBROUTINE hpg_zps( kt )
288      !!---------------------------------------------------------------------
289      !!                 ***  ROUTINE hpg_zps  ***
290      !!
291      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
292      !!
293      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
294      !!----------------------------------------------------------------------
295      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
296      !!
297      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
298      INTEGER  ::   iku, ikv                         ! temporary integers
299      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
300      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
301      !!----------------------------------------------------------------------
302      !
303      IF( kt == nit000 ) THEN
304         IF(lwp) WRITE(numout,*)
305         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
306         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
307      ENDIF
308
309      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
310!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
311
312      ! Local constant initialization
313      zcoef0 = - grav * 0.5_wp
314
315      !  Surface value (also valid in partial step case)
316      DO jj = 2, jpjm1
317         DO ji = fs_2, fs_jpim1   ! vector opt.
318            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
319            ! hydrostatic pressure gradient
320            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
321            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
322            ! add to the general momentum trend
323            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
324            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
325         END DO
326      END DO
327
328      ! interior value (2=<jk=<jpkm1)
329      DO jk = 2, jpkm1
330         DO jj = 2, jpjm1
331            DO ji = fs_2, fs_jpim1   ! vector opt.
332               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
333               ! hydrostatic pressure gradient
334               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
335                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
336                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
337
338               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
339                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
340                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
341               ! add to the general momentum trend
342               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
343               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
344            END DO
345         END DO
346      END DO
347
348      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
349      DO jj = 2, jpjm1
350         DO ji = 2, jpim1
351            iku = mbku(ji,jj)
352            ikv = mbkv(ji,jj)
353            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
354            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
355            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
356               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
357               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
358                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
359               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
360            ENDIF
361            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
362               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
363               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
364                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
365               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
366            ENDIF
367         END DO
368      END DO
369      !
370   END SUBROUTINE hpg_zps
371
372
373   SUBROUTINE hpg_sco( kt )
374      !!---------------------------------------------------------------------
375      !!                  ***  ROUTINE hpg_sco  ***
376      !!
377      !! ** Method  :   s-coordinate case. Jacobian scheme.
378      !!      The now hydrostatic pressure gradient at a given level, jk,
379      !!      is computed by taking the vertical integral of the in-situ
380      !!      density gradient along the model level from the suface to that
381      !!      level. s-coordinates (ln_sco): a corrective term is added
382      !!      to the horizontal pressure gradient :
383      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
384      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
385      !!      add it to the general momentum trend (ua,va).
386      !!         ua = ua - 1/e1u * zhpi
387      !!         va = va - 1/e2v * zhpj
388      !!
389      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
390      !!----------------------------------------------------------------------
391      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
392      !!
393      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
394      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
395      LOGICAL  ::   ll_tmp1, ll_tmp2                     ! local logical variables
396      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
397      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
398      !!----------------------------------------------------------------------
399      !
400      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
401      !
402      IF( kt == nit000 ) THEN
403         IF(lwp) WRITE(numout,*)
404         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
405         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
406      ENDIF
407      !
408      zcoef0 = - grav * 0.5_wp
409      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
410      ELSE                    ;   znad = 1._wp         ! Variable volume: density
411      ENDIF
412      !
413      IF( ln_wd_il ) THEN
414        DO jj = 2, jpjm1
415           DO ji = 2, jpim1 
416             ll_tmp1 = MIN(  sshn(ji,jj)               ,  sshn(ji+1,jj) ) >                &
417                  &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
418                  &    MAX(  sshn(ji,jj) +  ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
419                  &                                                       > rn_wdmin1 + rn_wdmin2
420             ll_tmp2 = ( ABS( sshn(ji,jj)              -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (       &
421                  &    MAX(   sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
422                  &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
423
424             IF(ll_tmp1) THEN
425               zcpx(ji,jj) = 1.0_wp
426             ELSE IF(ll_tmp2) THEN
427               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
428               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
429                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
430             ELSE
431               zcpx(ji,jj) = 0._wp
432             END IF
433     
434             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
435                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
436                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
437                  &                                                      > rn_wdmin1 + rn_wdmin2
438             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
439                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
440                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
441
442             IF(ll_tmp1) THEN
443               zcpy(ji,jj) = 1.0_wp
444             ELSE IF(ll_tmp2) THEN
445               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
446               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
447                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
448             ELSE
449               zcpy(ji,jj) = 0._wp
450             END IF
451           END DO
452        END DO
453        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
454      END IF
455
456      ! Surface value
457      DO jj = 2, jpjm1
458         DO ji = fs_2, fs_jpim1   ! vector opt.
459            ! hydrostatic pressure gradient along s-surfaces
460            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
461               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
462            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
463               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
464            ! s-coordinate pressure gradient correction
465            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
466               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
467            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
468               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
469            !
470            IF( ln_wd_il ) THEN
471               zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
472               zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
473               zuap = zuap * zcpx(ji,jj)
474               zvap = zvap * zcpy(ji,jj)
475            ENDIF
476            !
477            ! add to the general momentum trend
478            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
479            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
480         END DO
481      END DO
482
483      ! interior value (2=<jk=<jpkm1)
484      DO jk = 2, jpkm1
485         DO jj = 2, jpjm1
486            DO ji = fs_2, fs_jpim1   ! vector opt.
487               ! hydrostatic pressure gradient along s-surfaces
488               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
489                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
490                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
491               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
492                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
493                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
494               ! s-coordinate pressure gradient correction
495               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
496                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
497               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
498                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
499               !
500               IF( ln_wd_il ) THEN
501                  zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
502                  zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
503                  zuap = zuap * zcpx(ji,jj)
504                  zvap = zvap * zcpy(ji,jj)
505               ENDIF
506               !
507               ! add to the general momentum trend
508               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
509               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
510            END DO
511         END DO
512      END DO
513      !
514      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
515      !
516   END SUBROUTINE hpg_sco
517
518
519   SUBROUTINE hpg_isf( kt )
520      !!---------------------------------------------------------------------
521      !!                  ***  ROUTINE hpg_isf  ***
522      !!
523      !! ** Method  :   s-coordinate case. Jacobian scheme.
524      !!      The now hydrostatic pressure gradient at a given level, jk,
525      !!      is computed by taking the vertical integral of the in-situ
526      !!      density gradient along the model level from the suface to that
527      !!      level. s-coordinates (ln_sco): a corrective term is added
528      !!      to the horizontal pressure gradient :
529      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
530      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
531      !!      add it to the general momentum trend (ua,va).
532      !!         ua = ua - 1/e1u * zhpi
533      !!         va = va - 1/e2v * zhpj
534      !!      iceload is added
535      !!     
536      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
537      !!----------------------------------------------------------------------
538      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
539      !!
540      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
541      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
542      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
543      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
544      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
545      !!----------------------------------------------------------------------
546      !
547      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
548      !
549      znad=1._wp                 ! To use density and not density anomaly
550      !
551      !                          ! iniitialised to 0. zhpi zhpi
552      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
553
554      ! compute rhd at the ice/oce interface (ocean side)
555      ! usefull to reduce residual current in the test case ISOMIP with no melting
556      DO ji = 1, jpi
557        DO jj = 1, jpj
558          ikt = mikt(ji,jj)
559          zts_top(ji,jj,1) = tsn(ji,jj,ikt,1)
560          zts_top(ji,jj,2) = tsn(ji,jj,ikt,2)
561        END DO
562      END DO
563      CALL eos( zts_top, risfdep, zrhdtop_oce )
564
565!==================================================================================     
566!===== Compute surface value =====================================================
567!==================================================================================
568      DO jj = 2, jpjm1
569         DO ji = fs_2, fs_jpim1   ! vector opt.
570            ikt    = mikt(ji,jj)
571            iktp1i = mikt(ji+1,jj)
572            iktp1j = mikt(ji,jj+1)
573            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
574            ! we assume ISF is in isostatic equilibrium
575            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
576               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
577               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
578               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
579               &                                  + ( risfload(ji+1,jj) - risfload(ji,jj))                            ) 
580            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
581               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
582               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
583               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
584               &                                  + ( risfload(ji,jj+1) - risfload(ji,jj))                            ) 
585            ! s-coordinate pressure gradient correction (=0 if z coordinate)
586            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
587               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
588            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
589               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
590            ! add to the general momentum trend
591            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
592            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
593         END DO
594      END DO
595!==================================================================================     
596!===== Compute interior value =====================================================
597!==================================================================================
598      ! interior value (2=<jk=<jpkm1)
599      DO jk = 2, jpkm1
600         DO jj = 2, jpjm1
601            DO ji = fs_2, fs_jpim1   ! vector opt.
602               ! hydrostatic pressure gradient along s-surfaces
603               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
604                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
605                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
606               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
607                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
608                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
609               ! s-coordinate pressure gradient correction
610               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
611                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
612               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
613                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
614               ! add to the general momentum trend
615               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
616               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
617            END DO
618         END DO
619      END DO
620      !
621   END SUBROUTINE hpg_isf
622
623
624   SUBROUTINE hpg_djc( kt )
625      !!---------------------------------------------------------------------
626      !!                  ***  ROUTINE hpg_djc  ***
627      !!
628      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
629      !!
630      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
631      !!----------------------------------------------------------------------
632      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
633      !!
634      INTEGER  ::   ji, jj, jk          ! dummy loop indices
635      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
636      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
637      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
638      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
639      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
640      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   dzx, dzy, dzz, dzu, dzv, dzw
641      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, drhoy, drhoz, drhou, drhov, drhow
642      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   rho_i, rho_j, rho_k
643      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
644      !!----------------------------------------------------------------------
645      !
646      IF( ln_wd_il ) THEN
647         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
648        DO jj = 2, jpjm1
649           DO ji = 2, jpim1 
650             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
651                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
652                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
653                  &                                                      > rn_wdmin1 + rn_wdmin2
654             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (        &
655                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
656                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
657             IF(ll_tmp1) THEN
658               zcpx(ji,jj) = 1.0_wp
659             ELSE IF(ll_tmp2) THEN
660               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
661               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
662                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
663             ELSE
664               zcpx(ji,jj) = 0._wp
665             END IF
666     
667             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
668                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
669                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
670                  &                                                      > rn_wdmin1 + rn_wdmin2
671             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
672                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
673                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
674
675             IF(ll_tmp1) THEN
676               zcpy(ji,jj) = 1.0_wp
677             ELSE IF(ll_tmp2) THEN
678               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
679               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
680                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
681             ELSE
682               zcpy(ji,jj) = 0._wp
683             END IF
684           END DO
685        END DO
686        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
687      END IF
688
689      IF( kt == nit000 ) THEN
690         IF(lwp) WRITE(numout,*)
691         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
692         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
693      ENDIF
694
695      ! Local constant initialization
696      zcoef0 = - grav * 0.5_wp
697      z1_10  = 1._wp / 10._wp
698      z1_12  = 1._wp / 12._wp
699
700      !----------------------------------------------------------------------------------------
701      !  compute and store in provisional arrays elementary vertical and horizontal differences
702      !----------------------------------------------------------------------------------------
703
704!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
705
706      DO jk = 2, jpkm1
707         DO jj = 2, jpjm1
708            DO ji = fs_2, fs_jpim1   ! vector opt.
709               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
710               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
711               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
712               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
713               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
714               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
715            END DO
716         END DO
717      END DO
718
719      !-------------------------------------------------------------------------
720      ! compute harmonic averages using eq. 5.18
721      !-------------------------------------------------------------------------
722      zep = 1.e-15
723
724!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
725!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
726
727      DO jk = 2, jpkm1
728         DO jj = 2, jpjm1
729            DO ji = fs_2, fs_jpim1   ! vector opt.
730               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
731
732               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
733               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
734
735               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
736               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
737
738               IF( cffw > zep) THEN
739                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
740                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
741               ELSE
742                  drhow(ji,jj,jk) = 0._wp
743               ENDIF
744
745               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
746                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
747
748               IF( cffu > zep ) THEN
749                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
750                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
751               ELSE
752                  drhou(ji,jj,jk ) = 0._wp
753               ENDIF
754
755               IF( cffx > zep ) THEN
756                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
757                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
758               ELSE
759                  dzu(ji,jj,jk) = 0._wp
760               ENDIF
761
762               IF( cffv > zep ) THEN
763                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
764                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
765               ELSE
766                  drhov(ji,jj,jk) = 0._wp
767               ENDIF
768
769               IF( cffy > zep ) THEN
770                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
771                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
772               ELSE
773                  dzv(ji,jj,jk) = 0._wp
774               ENDIF
775
776            END DO
777         END DO
778      END DO
779
780      !----------------------------------------------------------------------------------
781      ! apply boundary conditions at top and bottom using 5.36-5.37
782      !----------------------------------------------------------------------------------
783      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
784      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
785      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
786
787      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
788      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
789      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
790
791
792      !--------------------------------------------------------------
793      ! Upper half of top-most grid box, compute and store
794      !-------------------------------------------------------------
795
796!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
797!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
798
799      DO jj = 2, jpjm1
800         DO ji = fs_2, fs_jpim1   ! vector opt.
801            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
802               &                   * (  rhd(ji,jj,1)                                     &
803               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
804               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
805               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
806         END DO
807      END DO
808
809!!bug gm    : here also, simplification is possible
810!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
811
812      DO jk = 2, jpkm1
813         DO jj = 2, jpjm1
814            DO ji = fs_2, fs_jpim1   ! vector opt.
815
816               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
817                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
818                  &            - grav * z1_10 * (                                                                   &
819                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
820                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
821                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
822                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
823                  &                             )
824
825               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
826                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
827                  &            - grav* z1_10 * (                                                                    &
828                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
829                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
830                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
831                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
832                  &                            )
833
834               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
835                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
836                  &            - grav* z1_10 * (                                                                    &
837                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
838                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
839                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
840                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
841                  &                            )
842
843            END DO
844         END DO
845      END DO
846      CALL lbc_lnk_multi( 'dynhpg', rho_k, 'W', 1., rho_i, 'U', 1., rho_j, 'V', 1. )
847
848      ! ---------------
849      !  Surface value
850      ! ---------------
851      DO jj = 2, jpjm1
852         DO ji = fs_2, fs_jpim1   ! vector opt.
853            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
854            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
855            IF( ln_wd_il ) THEN
856              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
857              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
858            ENDIF
859            ! add to the general momentum trend
860            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
861            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
862         END DO
863      END DO
864
865      ! ----------------
866      !  interior value   (2=<jk=<jpkm1)
867      ! ----------------
868      DO jk = 2, jpkm1
869         DO jj = 2, jpjm1
870            DO ji = fs_2, fs_jpim1   ! vector opt.
871               ! hydrostatic pressure gradient along s-surfaces
872               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
873                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
874                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
875               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
876                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
877                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
878               IF( ln_wd_il ) THEN
879                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
880                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
881               ENDIF
882               ! add to the general momentum trend
883               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
884               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
885            END DO
886         END DO
887      END DO
888      !
889      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
890      !
891   END SUBROUTINE hpg_djc
892
893
894   SUBROUTINE hpg_prj( kt )
895      !!---------------------------------------------------------------------
896      !!                  ***  ROUTINE hpg_prj  ***
897      !!
898      !! ** Method  :   s-coordinate case.
899      !!      A Pressure-Jacobian horizontal pressure gradient method
900      !!      based on the constrained cubic-spline interpolation for
901      !!      all vertical coordinate systems
902      !!
903      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
904      !!----------------------------------------------------------------------
905      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
906      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
907      !!
908      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
909      REAL(wp) ::   zcoef0, znad                    ! local scalars
910      !
911      !! The local variables for the correction term
912      INTEGER  :: jk1, jis, jid, jjs, jjd
913      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
914      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
915      REAL(wp) :: zrhdt1
916      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
917      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
918      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
919      REAL(wp), DIMENSION(jpi,jpj)   ::   zsshu_n, zsshv_n
920      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
921      !!----------------------------------------------------------------------
922      !
923      IF( kt == nit000 ) THEN
924         IF(lwp) WRITE(numout,*)
925         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
926         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
927      ENDIF
928
929      ! Local constant initialization
930      zcoef0 = - grav
931      znad = 1._wp
932      IF( ln_linssh )   znad = 0._wp
933
934      IF( ln_wd_il ) THEN
935         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
936         DO jj = 2, jpjm1
937           DO ji = 2, jpim1 
938             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
939                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
940                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
941                  &                                                      > rn_wdmin1 + rn_wdmin2
942             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (         &
943                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
944                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
945
946             IF(ll_tmp1) THEN
947               zcpx(ji,jj) = 1.0_wp
948             ELSE IF(ll_tmp2) THEN
949               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
950               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
951                           &    / (sshn(ji+1,jj) -  sshn(ji  ,jj)) )
952             
953                zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
954             ELSE
955               zcpx(ji,jj) = 0._wp
956             END IF
957     
958             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
959                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
960                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
961                  &                                                      > rn_wdmin1 + rn_wdmin2
962             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (      &
963                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
964                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
965
966             IF(ll_tmp1) THEN
967               zcpy(ji,jj) = 1.0_wp
968             ELSE IF(ll_tmp2) THEN
969               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
970               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
971                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
972                zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
973
974               ELSE
975                  zcpy(ji,jj) = 0._wp
976               ENDIF
977            END DO
978         END DO
979         CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
980      ENDIF
981
982      ! Clean 3-D work arrays
983      zhpi(:,:,:) = 0._wp
984      zrhh(:,:,:) = rhd(:,:,:)
985
986      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
987      DO jj = 1, jpj
988        DO ji = 1, jpi
989          jk = mbkt(ji,jj)+1
990          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
991          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
992          ELSEIF( jk < jpkm1 ) THEN
993             DO jkk = jk+1, jpk
994                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
995                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
996             END DO
997          ENDIF
998        END DO
999      END DO
1000
1001      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1002      DO jj = 1, jpj
1003         DO ji = 1, jpi
1004            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1005         END DO
1006      END DO
1007
1008      DO jk = 2, jpk
1009         DO jj = 1, jpj
1010            DO ji = 1, jpi
1011               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1012            END DO
1013         END DO
1014      END DO
1015
1016      fsp(:,:,:) = zrhh (:,:,:)
1017      xsp(:,:,:) = zdept(:,:,:)
1018
1019      ! Construct the vertical density profile with the
1020      ! constrained cubic spline interpolation
1021      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1022      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1023
1024      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1025      DO jj = 2, jpj
1026        DO ji = 2, jpi
1027          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1028             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1029
1030          ! assuming linear profile across the top half surface layer
1031          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1032        END DO
1033      END DO
1034
1035      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1036      DO jk = 2, jpkm1
1037        DO jj = 2, jpj
1038          DO ji = 2, jpi
1039            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1040               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1041               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1042               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1043          END DO
1044        END DO
1045      END DO
1046
1047      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1048
1049      ! Prepare zsshu_n and zsshv_n
1050      DO jj = 2, jpjm1
1051        DO ji = 2, jpim1
1052!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1053!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1054!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1055!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1056!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1057!!gm not this:
1058          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1059                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1060          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1061                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1062        END DO
1063      END DO
1064
1065      CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1., zsshv_n, 'V', 1. )
1066
1067      DO jj = 2, jpjm1
1068        DO ji = 2, jpim1
1069          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1070          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1071        END DO
1072      END DO
1073
1074      DO jk = 2, jpkm1
1075        DO jj = 2, jpjm1
1076          DO ji = 2, jpim1
1077            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1078            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1079          END DO
1080        END DO
1081      END DO
1082
1083      DO jk = 1, jpkm1
1084        DO jj = 2, jpjm1
1085          DO ji = 2, jpim1
1086            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1087            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1088          END DO
1089        END DO
1090      END DO
1091
1092      DO jk = 1, jpkm1
1093        DO jj = 2, jpjm1
1094          DO ji = 2, jpim1
1095            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1096            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1097            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1098            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1099          END DO
1100        END DO
1101      END DO
1102
1103
1104      DO jk = 1, jpkm1
1105        DO jj = 2, jpjm1
1106          DO ji = 2, jpim1
1107            zpwes = 0._wp; zpwed = 0._wp
1108            zpnss = 0._wp; zpnsd = 0._wp
1109            zuijk = zu(ji,jj,jk)
1110            zvijk = zv(ji,jj,jk)
1111
1112            !!!!!     for u equation
1113            IF( jk <= mbku(ji,jj) ) THEN
1114               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1115                 jis = ji + 1; jid = ji
1116               ELSE
1117                 jis = ji;     jid = ji +1
1118               ENDIF
1119
1120               ! integrate the pressure on the shallow side
1121               jk1 = jk
1122               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1123                 IF( jk1 == mbku(ji,jj) ) THEN
1124                   zuijk = -zdept(jis,jj,jk1)
1125                   EXIT
1126                 ENDIF
1127                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1128                 zpwes = zpwes +                                    &
1129                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1130                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1131                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1132                 jk1 = jk1 + 1
1133               END DO
1134
1135               ! integrate the pressure on the deep side
1136               jk1 = jk
1137               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1138                 IF( jk1 == 1 ) THEN
1139                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1140                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1141                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1142                                                     dsp(jid,jj,1)) * zdeps
1143                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1144                   EXIT
1145                 ENDIF
1146                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1147                 zpwed = zpwed +                                        &
1148                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1149                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1150                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1151                 jk1 = jk1 - 1
1152               END DO
1153
1154               ! update the momentum trends in u direction
1155
1156               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1157               IF( .NOT.ln_linssh ) THEN
1158                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1159                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1160                ELSE
1161                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1162               ENDIF
1163               IF( ln_wd_il ) THEN
1164                  zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1165                  zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1166               ENDIF
1167               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1168            ENDIF
1169
1170            !!!!!     for v equation
1171            IF( jk <= mbkv(ji,jj) ) THEN
1172               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1173                 jjs = jj + 1; jjd = jj
1174               ELSE
1175                 jjs = jj    ; jjd = jj + 1
1176               ENDIF
1177
1178               ! integrate the pressure on the shallow side
1179               jk1 = jk
1180               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1181                 IF( jk1 == mbkv(ji,jj) ) THEN
1182                   zvijk = -zdept(ji,jjs,jk1)
1183                   EXIT
1184                 ENDIF
1185                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1186                 zpnss = zpnss +                                      &
1187                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1188                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1189                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1190                 jk1 = jk1 + 1
1191               END DO
1192
1193               ! integrate the pressure on the deep side
1194               jk1 = jk
1195               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1196                 IF( jk1 == 1 ) THEN
1197                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1198                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1199                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1200                                                     dsp(ji,jjd,1) ) * zdeps
1201                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1202                   EXIT
1203                 ENDIF
1204                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1205                 zpnsd = zpnsd +                                        &
1206                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1207                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1208                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1209                 jk1 = jk1 - 1
1210               END DO
1211
1212
1213               ! update the momentum trends in v direction
1214
1215               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1216               IF( .NOT.ln_linssh ) THEN
1217                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1218                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1219               ELSE
1220                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1221               ENDIF
1222               IF( ln_wd_il ) THEN
1223                  zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1224                  zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1225               ENDIF
1226
1227               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1228            ENDIF
1229               !
1230            END DO
1231         END DO
1232      END DO
1233      !
1234      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1235      !
1236   END SUBROUTINE hpg_prj
1237
1238
1239   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1240      !!----------------------------------------------------------------------
1241      !!                 ***  ROUTINE cspline  ***
1242      !!
1243      !! ** Purpose :   constrained cubic spline interpolation
1244      !!
1245      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1246      !!
1247      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1248      !!----------------------------------------------------------------------
1249      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1250      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1251      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1252      !
1253      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1254      INTEGER  ::   jpi, jpj, jpkm1
1255      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1256      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1257      REAL(wp) ::   zdf(size(fsp,3))
1258      !!----------------------------------------------------------------------
1259      !
1260!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1261      jpi   = size(fsp,1)
1262      jpj   = size(fsp,2)
1263      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1264      !
1265      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1266         DO ji = 1, jpi
1267            DO jj = 1, jpj
1268           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1269           !    DO jk = 2, jpkm1-1
1270           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1271           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1272           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1273           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1274           !
1275           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1276           !
1277           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1278           !           zdf(jk) = 0._wp
1279           !       ELSE
1280           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1281           !       ENDIF
1282           !    END DO
1283
1284           !!Simply geometric average
1285               DO jk = 2, jpkm1-1
1286                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1287                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1288
1289                  IF(zdf1 * zdf2 <= 0._wp) THEN
1290                     zdf(jk) = 0._wp
1291                  ELSE
1292                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1293                  ENDIF
1294               END DO
1295
1296               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1297                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1298               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1299                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1300
1301               DO jk = 1, jpkm1 - 1
1302                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1303                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1304                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1305                 zddf1  = -2._wp * ztmp1 + ztmp2
1306                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1307                 zddf2  =  2._wp * ztmp1 - ztmp2
1308
1309                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1310                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1311                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1312                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1313                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1314                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1315                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1316                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1317                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1318               END DO
1319            END DO
1320         END DO
1321
1322      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1323         DO ji = 1, jpi
1324            DO jj = 1, jpj
1325               DO jk = 1, jpkm1-1
1326                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1327                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1328
1329                  dsp(ji,jj,jk) = 0._wp
1330                  csp(ji,jj,jk) = 0._wp
1331                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1332                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1333               END DO
1334            END DO
1335         END DO
1336         !
1337      ELSE
1338         CALL ctl_stop( 'invalid polynomial type in cspline' )
1339      ENDIF
1340      !
1341   END SUBROUTINE cspline
1342
1343
1344   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1345      !!----------------------------------------------------------------------
1346      !!                 ***  ROUTINE interp1  ***
1347      !!
1348      !! ** Purpose :   1-d linear interpolation
1349      !!
1350      !! ** Method  :   interpolation is straight forward
1351      !!                extrapolation is also permitted (no value limit)
1352      !!----------------------------------------------------------------------
1353      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1354      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1355      REAL(wp)             ::  zdeltx
1356      !!----------------------------------------------------------------------
1357      !
1358      zdeltx = xr - xl
1359      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1360         f = 0.5_wp * (fl + fr)
1361      ELSE
1362         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1363      ENDIF
1364      !
1365   END FUNCTION interp1
1366
1367
1368   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1369      !!----------------------------------------------------------------------
1370      !!                 ***  ROUTINE interp1  ***
1371      !!
1372      !! ** Purpose :   1-d constrained cubic spline interpolation
1373      !!
1374      !! ** Method  :  cubic spline interpolation
1375      !!
1376      !!----------------------------------------------------------------------
1377      REAL(wp), INTENT(in) ::  x, a, b, c, d
1378      REAL(wp)             ::  f ! value from the interpolation
1379      !!----------------------------------------------------------------------
1380      !
1381      f = a + x* ( b + x * ( c + d * x ) )
1382      !
1383   END FUNCTION interp2
1384
1385
1386   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1387      !!----------------------------------------------------------------------
1388      !!                 ***  ROUTINE interp1  ***
1389      !!
1390      !! ** Purpose :   Calculate the first order of derivative of
1391      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1392      !!
1393      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1394      !!
1395      !!----------------------------------------------------------------------
1396      REAL(wp), INTENT(in) ::  x, a, b, c, d
1397      REAL(wp)             ::  f ! value from the interpolation
1398      !!----------------------------------------------------------------------
1399      !
1400      f = b + x * ( 2._wp * c + 3._wp * d * x)
1401      !
1402   END FUNCTION interp3
1403
1404
1405   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1406      !!----------------------------------------------------------------------
1407      !!                 ***  ROUTINE interp1  ***
1408      !!
1409      !! ** Purpose :   1-d constrained cubic spline integration
1410      !!
1411      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1412      !!
1413      !!----------------------------------------------------------------------
1414      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1415      REAL(wp)             ::  za1, za2, za3
1416      REAL(wp)             ::  f                   ! integration result
1417      !!----------------------------------------------------------------------
1418      !
1419      za1 = 0.5_wp * b
1420      za2 = c / 3.0_wp
1421      za3 = 0.25_wp * d
1422      !
1423      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1424         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1425      !
1426   END FUNCTION integ_spline
1427
1428   !!======================================================================
1429END MODULE dynhpg
1430
Note: See TracBrowser for help on using the repository browser.