New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
isfpar.F90 in NEMO/branches/2019/ENHANCE-02_ISF_nemo/src/OCE/ISF – NEMO

source: NEMO/branches/2019/ENHANCE-02_ISF_nemo/src/OCE/ISF/isfpar.F90 @ 11987

Last change on this file since 11987 was 11987, checked in by mathiot, 4 years ago

ENHANCE-02_ISF_nemo: changes needed after Dave's review

File size: 7.6 KB
Line 
1MODULE isfpar
2   !!======================================================================
3   !!                       ***  MODULE  isfpar  ***
4   !! ice shelf module :  update ocean boundary condition under ice
5   !!                   shelf
6   !!======================================================================
7   !! History :  3.2  !  2011-02  (C.Harris  ) Original code isf cav
8   !!            X.X  !  2006-02  (C. Wang   ) Original code bg03
9   !!            3.4  !  2013-03  (P. Mathiot) Merging + parametrization
10   !!            4.1  !  2019-09  (P. Mathiot) Restructuration
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   isfpar       : compute ice shelf melt using a prametrisation of ice shelf cavities
15   !!----------------------------------------------------------------------
16   USE isf_oce        ! ice shelf
17   !
18   USE isfrst   , ONLY: isfrst_write, isfrst_read ! ice shelf restart read/write subroutine
19   USE isftbl   , ONLY: isf_tbl_ktop, isf_tbl_lvl ! ice shelf top boundary layer properties subroutine
20   USE isfparmlt, ONLY: isfpar_mlt                ! ice shelf melt formulation subroutine
21   USE isfdiags , ONLY: isf_diags_flx             ! ice shelf diags subroutine
22   USE isfutils , ONLY: debug, read_2dcstdta      ! ice shelf debug subroutine
23   !
24   USE dom_oce  , ONLY: bathy          ! ocean space and time domain
25   USE par_oce  , ONLY: jpi,jpj        ! ocean space and time domain
26   USE phycst   , ONLY: r1_rau0_rcp    ! physical constants
27   !
28   USE in_out_manager ! I/O manager
29   USE iom            ! I/O library
30   USE fldread        ! read input field at current time step
31   USE lbclnk         ! lbc_lnk
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   isf_par, isf_par_init
37
38   !!----------------------------------------------------------------------
39   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
40   !! $Id: sbcisf.F90 10536 2019-01-16 19:21:09Z mathiot $
41   !! Software governed by the CeCILL license (see ./LICENSE)
42   !!----------------------------------------------------------------------
43CONTAINS
44 
45   SUBROUTINE isf_par( kt, ptsc, pqfwf )
46      !!---------------------------------------------------------------------
47      !!                     ***  ROUTINE isf_par ***     
48      !!
49      !! ** Purpose : compute the heat and fresh water due to ice shelf melting/freezing using a parametrisation
50      !!
51      !!---------------------------------------------------------------------
52      !!-------------------------- OUT --------------------------------------
53      REAL(wp), DIMENSION(jpi,jpj)     , INTENT(inout) :: pqfwf
54      REAL(wp), DIMENSION(jpi,jpj,jpts), INTENT(inout) :: ptsc
55      !!-------------------------- IN  --------------------------------------
56      INTEGER, INTENT(in) ::   kt                                           ! ocean time step
57      !!---------------------------------------------------------------------
58      REAL(wp), DIMENSION(jpi,jpj) :: zqoce, zqhc, zqlat, zqh
59      !!---------------------------------------------------------------------
60      !
61      ! compute heat content, latent heat and melt fluxes (2d)
62      CALL isfpar_mlt( kt, zqhc, zqoce, pqfwf  )
63      !
64      ! compute heat and water flux ( > 0 out )
65      pqfwf(:,:) = pqfwf(:,:) * mskisf_par(:,:)
66      zqoce(:,:) = zqoce(:,:) * mskisf_par(:,:)
67      zqhc (:,:) = zqhc(:,:)  * mskisf_par(:,:)
68      !
69      ! compute heat content flux ( > 0 out )
70      zqlat(:,:) = pqfwf(:,:) * rLfusisf    ! 2d latent heat flux (W/m2)
71      !
72      ! total heat flux ( > 0 out )
73      zqh(:,:) = ( zqhc (:,:) + zqoce(:,:) )
74      !
75      ! lbclnk on melt and heat fluxes
76      CALL lbc_lnk_multi( 'isfmlt', zqh, 'T', 1., pqfwf, 'T', 1.)
77      !
78      ! output fluxes
79      CALL isf_diags_flx( misfkt_par, misfkb_par, rhisf_tbl_par, rfrac_tbl_par, 'par', pqfwf, zqoce, zqlat, zqhc)
80      !
81      ! set temperature content
82      ptsc(:,:,jp_tem) = zqh(:,:) * r1_rau0_rcp
83      !
84      ! write restart variables (qoceisf, qhcisf, fwfisf for now and before)
85      IF (lrst_oce) CALL isfrst_write(kt, 'par', ptsc, pqfwf)
86      !
87      IF ( ln_isfdebug ) THEN
88         CALL debug('isf_par: ptsc T',ptsc(:,:,1))
89         CALL debug('isf_par: ptsc S',ptsc(:,:,2))
90         CALL debug('isf_par: pqfwf fwf',pqfwf(:,:))
91      END IF
92      !
93   END SUBROUTINE isf_par
94
95   SUBROUTINE isf_par_init
96      !!---------------------------------------------------------------------
97      !!                  ***  ROUTINE isf_par_init  ***
98      !!
99      !! ** Purpose : initialisation of the variable needed for the parametrisation of ice shelf melt
100      !!
101      !!----------------------------------------------------------------------
102      INTEGER               :: ierr
103      REAL(wp), DIMENSION(jpi,jpj) :: ztblmax, ztblmin
104      !!----------------------------------------------------------------------
105      !
106      ! allocation
107      CALL isf_alloc_par()
108      !
109      ! initialisation
110      misfkt_par(:,:)     = 1         ; misfkb_par(:,:)       = 1         
111      rhisf_tbl_par(:,:)  = 1e-20     ; rfrac_tbl_par(:,:)    = 0.0_wp
112      !
113      ! define isf tbl tickness, top and bottom indice
114      CALL read_2dcstdta(TRIM(sn_isfpar_zmax%clname), TRIM(sn_isfpar_zmax%clvar), ztblmax)
115      CALL read_2dcstdta(TRIM(sn_isfpar_zmin%clname), TRIM(sn_isfpar_zmin%clvar), ztblmin)
116      !
117      ! mask ice shelf parametrisation location
118      ztblmax(:,:) = ztblmax(:,:) * ssmask(:,:)
119      ztblmin(:,:) = ztblmin(:,:) * ssmask(:,:)
120      !
121      ! if param used under an ice shelf overwrite ztblmin by the ice shelf draft
122      WHERE ( risfdep > 0._wp .AND. ztblmin > 0._wp )
123         ztblmin(:,:) = risfdep(:,:)
124      END WHERE
125      !
126      ! ensure ztblmax <= bathy
127      WHERE ( ztblmax(:,:) > bathy(:,:) )
128         ztblmax(:,:) = bathy(:,:)
129      END WHERE
130      !
131      ! compute ktop and update ztblmin to gdepw_0(misfkt_par)
132      CALL isf_tbl_ktop(ztblmin, misfkt_par) !   out: misfkt_par
133      !                                      ! inout: ztblmin
134      !
135      ! initial tbl thickness
136      rhisf0_tbl_par(:,:) = ztblmax(:,:) - ztblmin(:,:)
137      !
138      ! define iceshelf parametrisation mask
139      mskisf_par = 0
140      WHERE ( rhisf0_tbl_par(:,:) > 0._wp )
141         mskisf_par(:,:) = 1._wp
142      END WHERE
143      !
144      ! read par variable from restart
145      IF ( ln_rstart ) CALL isfrst_read('par', risf_par_tsc, fwfisf_par, risf_par_tsc_b, fwfisf_par_b)
146      !
147      SELECT CASE ( TRIM(cn_isfpar_mlt) )
148         !
149      CASE ( 'spe' )
150         !
151         ALLOCATE( sf_isfpar_fwf(1), STAT=ierr )
152         ALLOCATE( sf_isfpar_fwf(1)%fnow(jpi,jpj,1), sf_isfpar_fwf(1)%fdta(jpi,jpj,1,2) )
153         CALL fld_fill( sf_isfpar_fwf, (/ sn_isfpar_fwf /), cn_isfdir, 'isf_par_init', 'read fresh water flux isf data', 'namisf' )
154         !
155         IF(lwp) WRITE(numout,*)
156         IF(lwp) WRITE(numout,*) '      ==>>>   ice melt read from forcing field (cn_isfmlt_par = spe)'
157         !
158      CASE ( 'bg03' )
159         !
160         IF(lwp) WRITE(numout,*)
161         IF(lwp) WRITE(numout,*) '      ==>>>   bg03 parametrisation (cn_isfmlt_par = bg03)'
162         !
163         ! read effective length
164         CALL read_2dcstdta(TRIM(sn_isfpar_Leff%clname), TRIM(sn_isfpar_Leff%clvar), risfLeff)
165         risfLeff = risfLeff*1000.0_wp           !: convertion in m
166         !
167      CASE ( 'oasis' )
168         !
169         IF(lwp) WRITE(numout,*)
170         IF(lwp) WRITE(numout,*) '      ==>>>    isf melt provided by OASIS (cn_isfmlt_par = oasis)'
171         !
172      CASE DEFAULT
173         CALL ctl_stop( 'sbc_isf_init: wrong value of nn_isf' )
174      END SELECT
175      !
176   END SUBROUTINE isf_par_init
177
178END MODULE isfpar
Note: See TracBrowser for help on using the repository browser.