New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in NEMO/branches/2019/ENHANCE-02_ISF_nemo/src/OCE/SBC – NEMO

source: NEMO/branches/2019/ENHANCE-02_ISF_nemo/src/OCE/SBC/sbcssm.F90 @ 11987

Last change on this file since 11987 was 11987, checked in by mathiot, 4 years ago

ENHANCE-02_ISF_nemo: changes needed after Dave's review

  • Property svn:keywords set to Id
File size: 14.0 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   USE traqsr, ONLY: ln_traqsr
21   !
22   USE in_out_manager ! I/O manager
23   USE prtctl         ! Print control
24   USE iom            ! IOM library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_ssm        ! routine called by step.F90
30   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
31
32   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
33   
34   !!----------------------------------------------------------------------
35   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE sbc_ssm( kt )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE sbc_oce  ***
44      !!                     
45      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
46      !!                condition computation
47      !!               
48      !! ** Method  :   compute mean surface velocity (2 components at U and
49      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
50      !!      the periode (kt - nn_fsbc) to kt
51      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
52      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt   ! ocean time step
55      !
56      INTEGER  ::   ji, jj               ! loop index
57      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
58      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
59      !!---------------------------------------------------------------------
60      !
61      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
62      zts(:,:,jp_tem) = tsn(:,:,1,jp_tem)
63      zts(:,:,jp_sal) = tsn(:,:,1,jp_sal)
64      !
65      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
66         !                                                ! ---------------------------------------- !
67         ssu_m(:,:) = ub(:,:,1)
68         ssv_m(:,:) = vb(:,:,1)
69         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
70         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
71         ENDIF
72         sss_m(:,:) = zts(:,:,jp_sal)
73         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
74         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
75         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
76         ENDIF
77         !
78         e3t_m(:,:) = e3t_n(:,:,1)
79         !
80         frq_m(:,:) = fraqsr_1lev(:,:)
81         !
82      ELSE
83         !                                                ! ----------------------------------------------- !
84         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
85            !                                             ! ----------------------------------------------- !
86            IF(lwp) WRITE(numout,*)
87            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
88            IF(lwp) WRITE(numout,*) '~~~~~~~   '
89            zcoef = REAL( nn_fsbc - 1, wp )
90            ssu_m(:,:) = zcoef * ub(:,:,1)
91            ssv_m(:,:) = zcoef * vb(:,:,1)
92            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
93            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
94            ENDIF
95            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
96            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
97            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
98            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
99            ENDIF
100            !
101            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
102            !
103            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
104            !                                             ! ---------------------------------------- !
105         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
106            !                                             ! ---------------------------------------- !
107            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
108            ssv_m(:,:) = 0._wp
109            sst_m(:,:) = 0._wp
110            sss_m(:,:) = 0._wp
111            ssh_m(:,:) = 0._wp
112            e3t_m(:,:) = 0._wp
113            frq_m(:,:) = 0._wp
114         ENDIF
115         !                                                ! ---------------------------------------- !
116         !                                                !        Cumulate at each time step        !
117         !                                                ! ---------------------------------------- !
118         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
119         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
120         IF( l_useCT )  THEN     ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
121         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
122         ENDIF
123         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
124         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
125         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
126         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
127         ENDIF
128         !
129         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
130         !
131         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
132
133         !                                                ! ---------------------------------------- !
134         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
135            !                                             ! ---------------------------------------- !
136            zcoef = 1. / REAL( nn_fsbc, wp )
137            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celsius]
138            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
139            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
140            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
141            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
142            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
143            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
144            !
145         ENDIF
146         !                                                ! ---------------------------------------- !
147         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
148            !                                             ! ---------------------------------------- !
149            IF(lwp) WRITE(numout,*)
150            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
151               &                    'at it= ', kt,' date= ', ndastp
152            IF(lwp) WRITE(numout,*) '~~~~~~~'
153            zf_sbc = REAL( nn_fsbc, wp )
154            IF( lwxios ) CALL iom_swap(      cwxios_context          )
155            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc, ldxios = lwxios )    ! sbc frequency
156            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m, ldxios = lwxios  )    ! sea surface mean fields
157            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m, ldxios = lwxios  )
158            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m, ldxios = lwxios  )
159            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m, ldxios = lwxios  )
160            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m, ldxios = lwxios  )
161            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m, ldxios = lwxios  )
162            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m, ldxios = lwxios  )
163            !
164            IF( lwxios ) CALL iom_swap(      cxios_context          )
165         ENDIF
166         !
167      ENDIF
168      !
169      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
170         CALL iom_put( 'ssu_m', ssu_m )
171         CALL iom_put( 'ssv_m', ssv_m )
172         CALL iom_put( 'sst_m', sst_m )
173         CALL iom_put( 'sss_m', sss_m )
174         CALL iom_put( 'ssh_m', ssh_m )
175         CALL iom_put( 'e3t_m', e3t_m )
176         CALL iom_put( 'frq_m', frq_m )
177      ENDIF
178      !
179   END SUBROUTINE sbc_ssm
180
181
182   SUBROUTINE sbc_ssm_init
183      !!----------------------------------------------------------------------
184      !!                  ***  ROUTINE sbc_ssm_init  ***
185      !!
186      !! ** Purpose :   Initialisation of the sbc data
187      !!
188      !! ** Action  : - read parameters
189      !!----------------------------------------------------------------------
190      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
191      !!----------------------------------------------------------------------
192      !
193      IF( nn_fsbc == 1 ) THEN
194         !
195         IF(lwp) WRITE(numout,*)
196         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
197         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
198         !
199      ELSE
200         !               
201         IF(lwp) WRITE(numout,*)
202         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
203         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
204         !
205         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
206            l_ssm_mean = .TRUE.
207            CALL iom_get( numror               , 'nn_fsbc', zf_sbc, ldxios = lrxios )    ! sbc frequency of previous run
208            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m, ldxios = lrxios  )    ! sea surface mean velocity    (U-point)
209            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m, ldxios = lrxios  )    !   "         "    velocity    (V-point)
210            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m, ldxios = lrxios  )    !   "         "    temperature (T-point)
211            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m, ldxios = lrxios  )    !   "         "    salinity    (T-point)
212            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m, ldxios = lrxios  )    !   "         "    height      (T-point)
213            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m, ldxios = lrxios  )    ! 1st level thickness          (T-point)
214            ! fraction of solar net radiation absorbed in 1st T level
215            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
216               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m, ldxios = lrxios  )
217            ELSE
218               frq_m(:,:) = 1._wp   ! default definition
219            ENDIF
220            !
221            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
222               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
223               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
224               ssu_m(:,:) = zcoef * ssu_m(:,:) 
225               ssv_m(:,:) = zcoef * ssv_m(:,:)
226               sst_m(:,:) = zcoef * sst_m(:,:)
227               sss_m(:,:) = zcoef * sss_m(:,:)
228               ssh_m(:,:) = zcoef * ssh_m(:,:)
229               e3t_m(:,:) = zcoef * e3t_m(:,:)
230               frq_m(:,:) = zcoef * frq_m(:,:)
231            ELSE
232               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
233            ENDIF
234         ENDIF
235      ENDIF
236      !
237      IF( .NOT.l_ssm_mean ) THEN   ! default initialisation. needed by iceistate
238         !
239         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
240         ssu_m(:,:) = ub(:,:,1)
241         ssv_m(:,:) = vb(:,:,1)
242         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
243         ELSE                   ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
244         ENDIF
245         sss_m(:,:) = tsn  (:,:,1,jp_sal)
246         ssh_m(:,:) = sshn (:,:)
247         e3t_m(:,:) = e3t_n(:,:,1)
248         frq_m(:,:) = 1._wp
249         !
250      ENDIF
251      !
252      IF( .NOT. ln_traqsr )   fraqsr_1lev(:,:) = 1._wp   ! default definition: qsr 100% in the fisrt level
253      !
254      IF( lwxios.AND.nn_fsbc > 1 ) THEN
255         CALL iom_set_rstw_var_active('nn_fsbc')
256         CALL iom_set_rstw_var_active('ssu_m')
257         CALL iom_set_rstw_var_active('ssv_m')
258         CALL iom_set_rstw_var_active('sst_m')
259         CALL iom_set_rstw_var_active('sss_m')
260         CALL iom_set_rstw_var_active('ssh_m')
261         CALL iom_set_rstw_var_active('e3t_m')
262         CALL iom_set_rstw_var_active('frq_m')
263      ENDIF
264
265   END SUBROUTINE sbc_ssm_init
266
267   !!======================================================================
268END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.