| 1 | MODULE trasbc |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE trasbc *** |
|---|
| 4 | !! Ocean active tracers: surface boundary condition |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : OPA ! 1998-10 (G. Madec, G. Roullet, M. Imbard) Original code |
|---|
| 7 | !! 8.2 ! 2001-02 (D. Ludicone) sea ice and free surface |
|---|
| 8 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 9 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 10 | !! - ! 2010-09 (C. Ethe, G. Madec) Merge TRA-TRC |
|---|
| 11 | !! 3.6 ! 2014-11 (P. Mathiot) isf melting forcing |
|---|
| 12 | !! 4.1 ! 2019-09 (P. Mathiot) isf moved in traisf |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! tra_sbc : update the tracer trend at ocean surface |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce ! ocean dynamics and active tracers |
|---|
| 19 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 20 | USE dom_oce ! ocean space domain variables |
|---|
| 21 | USE phycst ! physical constant |
|---|
| 22 | USE eosbn2 ! Equation Of State |
|---|
| 23 | USE sbcmod ! ln_rnf |
|---|
| 24 | USE sbcrnf ! River runoff |
|---|
| 25 | USE traqsr ! solar radiation penetration |
|---|
| 26 | USE trd_oce ! trends: ocean variables |
|---|
| 27 | USE trdtra ! trends manager: tracers |
|---|
| 28 | #if defined key_asminc |
|---|
| 29 | USE asminc ! Assimilation increment |
|---|
| 30 | #endif |
|---|
| 31 | ! |
|---|
| 32 | USE in_out_manager ! I/O manager |
|---|
| 33 | USE prtctl ! Print control |
|---|
| 34 | USE iom ! xIOS server |
|---|
| 35 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 36 | USE timing ! Timing |
|---|
| 37 | |
|---|
| 38 | IMPLICIT NONE |
|---|
| 39 | PRIVATE |
|---|
| 40 | |
|---|
| 41 | PUBLIC tra_sbc ! routine called by step.F90 |
|---|
| 42 | |
|---|
| 43 | !! * Substitutions |
|---|
| 44 | # include "vectopt_loop_substitute.h90" |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 47 | !! $Id$ |
|---|
| 48 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | CONTAINS |
|---|
| 51 | |
|---|
| 52 | SUBROUTINE tra_sbc ( kt ) |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | !! *** ROUTINE tra_sbc *** |
|---|
| 55 | !! |
|---|
| 56 | !! ** Purpose : Compute the tracer surface boundary condition trend of |
|---|
| 57 | !! (flux through the interface, concentration/dilution effect) |
|---|
| 58 | !! and add it to the general trend of tracer equations. |
|---|
| 59 | !! |
|---|
| 60 | !! ** Method : The (air+ice)-sea flux has two components: |
|---|
| 61 | !! (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface); |
|---|
| 62 | !! (2) Fwe , tracer carried with the water that is exchanged with air+ice. |
|---|
| 63 | !! The input forcing fields (emp, rnf, sfx) contain Fext+Fwe, |
|---|
| 64 | !! they are simply added to the tracer trend (tsa). |
|---|
| 65 | !! In linear free surface case (ln_linssh=T), the volume of the |
|---|
| 66 | !! ocean does not change with the water exchanges at the (air+ice)-sea |
|---|
| 67 | !! interface. Therefore another term has to be added, to mimic the |
|---|
| 68 | !! concentration/dilution effect associated with water exchanges. |
|---|
| 69 | !! |
|---|
| 70 | !! ** Action : - Update tsa with the surface boundary condition trend |
|---|
| 71 | !! - send trends to trdtra module for further diagnostics(l_trdtra=T) |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 74 | ! |
|---|
| 75 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 76 | INTEGER :: ikt, ikb ! local integers |
|---|
| 77 | REAL(wp) :: zfact, z1_e3t, zdep, ztim ! local scalar |
|---|
| 78 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdt, ztrds |
|---|
| 79 | !!---------------------------------------------------------------------- |
|---|
| 80 | ! |
|---|
| 81 | IF( ln_timing ) CALL timing_start('tra_sbc') |
|---|
| 82 | ! |
|---|
| 83 | IF( kt == nit000 ) THEN |
|---|
| 84 | IF(lwp) WRITE(numout,*) |
|---|
| 85 | IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition' |
|---|
| 86 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
|---|
| 87 | ENDIF |
|---|
| 88 | ! |
|---|
| 89 | IF( l_trdtra ) THEN !* Save ta and sa trends |
|---|
| 90 | ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) ) |
|---|
| 91 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 92 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) |
|---|
| 93 | ENDIF |
|---|
| 94 | ! |
|---|
| 95 | !!gm This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist) |
|---|
| 96 | IF( .NOT.ln_traqsr ) THEN ! no solar radiation penetration |
|---|
| 97 | qns(:,:) = qns(:,:) + qsr(:,:) ! total heat flux in qns |
|---|
| 98 | qsr(:,:) = 0._wp ! qsr set to zero |
|---|
| 99 | ENDIF |
|---|
| 100 | |
|---|
| 101 | !---------------------------------------- |
|---|
| 102 | ! EMP, SFX and QNS effects |
|---|
| 103 | !---------------------------------------- |
|---|
| 104 | ! !== Set before sbc tracer content fields ==! |
|---|
| 105 | IF( kt == nit000 ) THEN !* 1st time-step |
|---|
| 106 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 107 | & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 108 | IF(lwp) WRITE(numout,*) ' nit000-1 sbc tracer content field read in the restart file' |
|---|
| 109 | zfact = 0.5_wp |
|---|
| 110 | sbc_tsc(:,:,:) = 0._wp |
|---|
| 111 | CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem), ldxios = lrxios ) ! before heat content sbc trend |
|---|
| 112 | CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal), ldxios = lrxios ) ! before salt content sbc trend |
|---|
| 113 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 114 | zfact = 1._wp |
|---|
| 115 | sbc_tsc(:,:,:) = 0._wp |
|---|
| 116 | sbc_tsc_b(:,:,:) = 0._wp |
|---|
| 117 | ENDIF |
|---|
| 118 | ELSE !* other time-steps: swap of forcing fields |
|---|
| 119 | zfact = 0.5_wp |
|---|
| 120 | sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:) |
|---|
| 121 | ENDIF |
|---|
| 122 | ! !== Now sbc tracer content fields ==! |
|---|
| 123 | DO jj = 2, jpj |
|---|
| 124 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 125 | sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj) ! non solar heat flux |
|---|
| 126 | sbc_tsc(ji,jj,jp_sal) = r1_rau0 * sfx(ji,jj) ! salt flux due to freezing/melting |
|---|
| 127 | END DO |
|---|
| 128 | END DO |
|---|
| 129 | IF( ln_linssh ) THEN !* linear free surface |
|---|
| 130 | DO jj = 2, jpj !==>> add concentration/dilution effect due to constant volume cell |
|---|
| 131 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 132 | sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem) |
|---|
| 133 | sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal) |
|---|
| 134 | END DO |
|---|
| 135 | END DO !==>> output c./d. term |
|---|
| 136 | IF( iom_use('emp_x_sst') ) CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) ) |
|---|
| 137 | IF( iom_use('emp_x_sss') ) CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) ) |
|---|
| 138 | ENDIF |
|---|
| 139 | ! |
|---|
| 140 | DO jn = 1, jpts !== update tracer trend ==! |
|---|
| 141 | DO jj = 2, jpj |
|---|
| 142 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 143 | tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1) |
|---|
| 144 | END DO |
|---|
| 145 | END DO |
|---|
| 146 | END DO |
|---|
| 147 | ! |
|---|
| 148 | IF( lrst_oce ) THEN !== write sbc_tsc in the ocean restart file ==! |
|---|
| 149 | IF( lwxios ) CALL iom_swap( cwxios_context ) |
|---|
| 150 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem), ldxios = lwxios ) |
|---|
| 151 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal), ldxios = lwxios ) |
|---|
| 152 | IF( lwxios ) CALL iom_swap( cxios_context ) |
|---|
| 153 | ENDIF |
|---|
| 154 | ! |
|---|
| 155 | !---------------------------------------- |
|---|
| 156 | ! River Runoff effects |
|---|
| 157 | !---------------------------------------- |
|---|
| 158 | ! |
|---|
| 159 | IF( ln_rnf ) THEN ! input of heat and salt due to river runoff |
|---|
| 160 | zfact = 0.5_wp |
|---|
| 161 | DO jj = 2, jpj |
|---|
| 162 | DO ji = fs_2, fs_jpim1 |
|---|
| 163 | IF( rnf(ji,jj) /= 0._wp ) THEN |
|---|
| 164 | zdep = zfact / h_rnf(ji,jj) |
|---|
| 165 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 166 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 167 | & + ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep |
|---|
| 168 | IF( ln_rnf_sal ) tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) & |
|---|
| 169 | & + ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep |
|---|
| 170 | END DO |
|---|
| 171 | ENDIF |
|---|
| 172 | END DO |
|---|
| 173 | END DO |
|---|
| 174 | ENDIF |
|---|
| 175 | |
|---|
| 176 | IF( iom_use('rnf_x_sst') ) CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) ) ! runoff term on sst |
|---|
| 177 | IF( iom_use('rnf_x_sss') ) CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) ) ! runoff term on sss |
|---|
| 178 | |
|---|
| 179 | #if defined key_asminc |
|---|
| 180 | ! |
|---|
| 181 | !---------------------------------------- |
|---|
| 182 | ! Assmilation effects |
|---|
| 183 | !---------------------------------------- |
|---|
| 184 | ! |
|---|
| 185 | IF( ln_sshinc ) THEN ! input of heat and salt due to assimilation |
|---|
| 186 | ! |
|---|
| 187 | IF( ln_linssh ) THEN |
|---|
| 188 | DO jj = 2, jpj |
|---|
| 189 | DO ji = fs_2, fs_jpim1 |
|---|
| 190 | ztim = ssh_iau(ji,jj) / e3t_n(ji,jj,1) |
|---|
| 191 | tsa(ji,jj,1,jp_tem) = tsa(ji,jj,1,jp_tem) + tsn(ji,jj,1,jp_tem) * ztim |
|---|
| 192 | tsa(ji,jj,1,jp_sal) = tsa(ji,jj,1,jp_sal) + tsn(ji,jj,1,jp_sal) * ztim |
|---|
| 193 | END DO |
|---|
| 194 | END DO |
|---|
| 195 | ELSE |
|---|
| 196 | DO jj = 2, jpj |
|---|
| 197 | DO ji = fs_2, fs_jpim1 |
|---|
| 198 | ztim = ssh_iau(ji,jj) / ( ht_n(ji,jj) + 1. - ssmask(ji, jj) ) |
|---|
| 199 | tsa(ji,jj,:,jp_tem) = tsa(ji,jj,:,jp_tem) + tsn(ji,jj,:,jp_tem) * ztim |
|---|
| 200 | tsa(ji,jj,:,jp_sal) = tsa(ji,jj,:,jp_sal) + tsn(ji,jj,:,jp_sal) * ztim |
|---|
| 201 | END DO |
|---|
| 202 | END DO |
|---|
| 203 | ENDIF |
|---|
| 204 | ! |
|---|
| 205 | ENDIF |
|---|
| 206 | ! |
|---|
| 207 | #endif |
|---|
| 208 | ! |
|---|
| 209 | IF( l_trdtra ) THEN ! save the horizontal diffusive trends for further diagnostics |
|---|
| 210 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 211 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:) |
|---|
| 212 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt ) |
|---|
| 213 | CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds ) |
|---|
| 214 | DEALLOCATE( ztrdt , ztrds ) |
|---|
| 215 | ENDIF |
|---|
| 216 | ! |
|---|
| 217 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc - Ta: ', mask1=tmask, & |
|---|
| 218 | & tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' ) |
|---|
| 219 | ! |
|---|
| 220 | IF( ln_timing ) CALL timing_stop('tra_sbc') |
|---|
| 221 | ! |
|---|
| 222 | END SUBROUTINE tra_sbc |
|---|
| 223 | |
|---|
| 224 | !!====================================================================== |
|---|
| 225 | END MODULE trasbc |
|---|
