New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zmicro.F90 in NEMO/branches/2019/ENHANCE-02_ISF_nemo/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/ENHANCE-02_ISF_nemo/src/TOP/PISCES/P4Z/p5zmicro.F90 @ 12143

Last change on this file since 12143 was 12143, checked in by mathiot, 4 years ago

update ENHANCE-02_ISF_nemo to 12072 (sette in progress)

  • Property svn:keywords set to Id
File size: 22.6 KB
Line 
1MODULE p5zmicro
2   !!======================================================================
3   !!                         ***  MODULE p5zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_micro       :   Compute the sources/sinks for microzooplankton
12   !!   p5z_micro_init  :   Initialize and read the appropriate namelist
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zlim
18   USE p5zlim          !  Phytoplankton limitation terms
19   USE iom             !  I/O manager
20   USE prtctl_trc      !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p5z_micro         ! called in p5zbio.F90
26   PUBLIC   p5z_micro_init    ! called in trcsms_pisces.F90
27
28   !! * Shared module variables
29   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
30   REAL(wp), PUBLIC ::  xprefc     !: microzoo preference for POC
31   REAL(wp), PUBLIC ::  xprefn     !: microzoo preference for nanophyto
32   REAL(wp), PUBLIC ::  xprefp     !: microzoo preference for picophyto
33   REAL(wp), PUBLIC ::  xprefd     !: microzoo preference for diatoms
34   REAL(wp), PUBLIC ::  xprefz     !: microzoo preference for microzoo
35   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::  xthreshpic  !: picophyto feeding threshold for microzooplankton
37   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
38   REAL(wp), PUBLIC ::  xthreshzoo  !: microzoo threshold for microzooplankton
39   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
40   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
41   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
42   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
43   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
44   REAL(wp), PUBLIC ::  xkgraz      !: Half-saturation constant of assimilation
45   REAL(wp), PUBLIC ::  unassc      !: Non-assimilated part of food
46   REAL(wp), PUBLIC ::  unassn      !: Non-assimilated part of food
47   REAL(wp), PUBLIC ::  unassp      !: Non-assimilated part of food
48   REAL(wp), PUBLIC ::  epsher      !: Growth efficiency for microzoo
49   REAL(wp), PUBLIC ::  epshermin   !: Minimum growth efficiency for microzoo
50   REAL(wp), PUBLIC ::  srespir     !: half sturation constant for grazing 1
51   REAL(wp), PUBLIC ::  ssigma      !: Fraction excreted as semi-labile DOM
52   LOGICAL,  PUBLIC ::  bmetexc     !: Use of excess carbon for respiration
53
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p5z_micro( kt, knt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p5z_micro  ***
65      !!
66      !! ** Purpose :   Compute the sources/sinks for microzooplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in) ::  kt  ! ocean time step
71      INTEGER, INTENT(in) ::  knt 
72      !
73      INTEGER  :: ji, jj, jk
74      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc, zcompapon, zcompapop
75      REAL(wp) :: zcompapi, zgraze  , zdenom, zfact, zfood, zfoodlim
76      REAL(wp) :: ztmp1, ztmp2, ztmp3, ztmp4, ztmp5, ztmptot
77      REAL(wp) :: zepsherf, zepshert, zepsherv, zrespirc, zrespirn, zrespirp, zbasresb, zbasresi
78      REAL(wp) :: zgraztotc, zgraztotn, zgraztotp, zgraztotf, zbasresn, zbasresp, zbasresf
79      REAL(wp) :: zgradoc, zgradon, zgradop, zgraref, zgradoct, zgradont, zgradopt, zgrareft
80      REAL(wp) :: zexcess, zgraren, zgrarep, zgrarem
81      REAL(wp) :: zgrapoc, zgrapon, zgrapop, zgrapof, zprcaca, zmortz
82      REAL(wp) :: zrespz, ztortz, zgrasratf, zgrasratn, zgrasratp
83      REAL(wp) :: zgraznc, zgraznn, zgraznp, zgrazpoc, zgrazpon, zgrazpop, zgrazpof
84      REAL(wp) :: zgrazdc, zgrazdn, zgrazdp, zgrazdf, zgraznf, zgrazz
85      REAL(wp) :: zgrazpc, zgrazpn, zgrazpp, zgrazpf, zbeta, zrfact2, zmetexcess
86      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo
87      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d, zzligprod
88      CHARACTER (len=25) :: charout
89      !!---------------------------------------------------------------------
90      !
91      IF( ln_timing )   CALL timing_start('p5z_micro')
92      !
93      IF (ln_ligand) THEN
94         ALLOCATE( zzligprod(jpi,jpj,jpk) )
95         zzligprod(:,:,:) = 0._wp
96      ENDIF
97      !
98      zmetexcess = 0.0
99      IF ( bmetexc ) zmetexcess = 1.0
100      !
101      DO jk = 1, jpkm1
102         DO jj = 1, jpj
103            DO ji = 1, jpi
104               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
105               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
106
107               !   Michaelis-Menten mortality rates of microzooplankton
108               !   -----------------------------------------------------
109               zrespz = resrat * zfact * ( trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
110               &        + 3. * nitrfac(ji,jj,jk) )
111
112               !   Zooplankton mortality. A square function has been selected with
113               !   no real reason except that it seems to be more stable and may mimic predation.
114               !   ------------------------------------------------------------------------------
115               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
116
117               !   Computation of the abundance of the preys
118               !   A threshold can be specified in the namelist
119               !   --------------------------------------------
120               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
121               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
122               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthreshzoo ), 0.e0 )
123               zcompapi  = MAX( ( trb(ji,jj,jk,jppic) - xthreshpic ), 0.e0 )
124               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
125               
126               !   Microzooplankton grazing
127               !   ------------------------
128               zfood     = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi   &
129               &           + xprefz * zcompaz + xprefp * zcompapi
130               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
131               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
132               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk)) 
133
134               !   An active switching parameterization is used here.
135               !   We don't use the KTW parameterization proposed by
136               !   Vallina et al. because it tends to produce to steady biomass
137               !   composition and the variance of Chl is too low as it grazes
138               !   too strongly on winning organisms. Thus, instead of a square
139               !   a 1.5 power value is used which decreases the pressure on the
140               !   most abundant species
141               !   ------------------------------------------------------------ 
142               ztmp1 = xprefn * zcompaph**1.5
143               ztmp2 = xprefp * zcompapi**1.5
144               ztmp3 = xprefc * zcompapoc**1.5
145               ztmp4 = xprefd * zcompadi**1.5
146               ztmp5 = xprefz * zcompaz**1.5
147               ztmptot = ztmp1 + ztmp2 + ztmp3 + ztmp4 + ztmp5 + rtrn
148               ztmp1 = ztmp1 / ztmptot
149               ztmp2 = ztmp2 / ztmptot
150               ztmp3 = ztmp3 / ztmptot
151               ztmp4 = ztmp4 / ztmptot
152               ztmp5 = ztmp5 / ztmptot
153
154               !   Microzooplankton regular grazing on the different preys
155               !   -------------------------------------------------------
156               zgraznc   = zgraze  * ztmp1  * zdenom
157               zgraznn   = zgraznc * trb(ji,jj,jk,jpnph) / (trb(ji,jj,jk,jpphy) + rtrn)
158               zgraznp   = zgraznc * trb(ji,jj,jk,jppph) / (trb(ji,jj,jk,jpphy) + rtrn)
159               zgraznf   = zgraznc * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
160               zgrazpc   = zgraze  * ztmp2  * zdenom
161               zgrazpn   = zgrazpc * trb(ji,jj,jk,jpnpi) / (trb(ji,jj,jk,jppic) + rtrn)
162               zgrazpp   = zgrazpc * trb(ji,jj,jk,jpppi) / (trb(ji,jj,jk,jppic) + rtrn)
163               zgrazpf   = zgrazpc * trb(ji,jj,jk,jppfe) / (trb(ji,jj,jk,jppic) + rtrn)
164               zgrazz    = zgraze  * ztmp5   * zdenom
165               zgrazpoc  = zgraze  * ztmp3   * zdenom
166               zgrazpon  = zgrazpoc * trb(ji,jj,jk,jppon) / ( trb(ji,jj,jk,jppoc) + rtrn )
167               zgrazpop  = zgrazpoc * trb(ji,jj,jk,jppop) / ( trb(ji,jj,jk,jppoc) + rtrn )
168               zgrazpof  = zgrazpoc* trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
169               zgrazdc   = zgraze  * ztmp4  * zdenom
170               zgrazdn   = zgrazdc * trb(ji,jj,jk,jpndi) / (trb(ji,jj,jk,jpdia) + rtrn)
171               zgrazdp   = zgrazdc * trb(ji,jj,jk,jppdi) / (trb(ji,jj,jk,jpdia) + rtrn)
172               zgrazdf   = zgrazdc * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
173               !
174               zgraztotc = zgraznc + zgrazpoc + zgrazdc + zgrazz + zgrazpc
175               zgraztotn = zgraznn + zgrazpn + zgrazpon + zgrazdn + zgrazz * no3rat3
176               zgraztotp = zgraznp + zgrazpp + zgrazpop + zgrazdp + zgrazz * po4rat3
177               zgraztotf = zgraznf + zgrazpf + zgrazpof + zgrazdf + zgrazz * ferat3
178               !
179               ! Grazing by microzooplankton
180               zgrazing(ji,jj,jk) = zgraztotc
181
182               !   Stoichiometruc ratios of the food ingested by zooplanton
183               !   --------------------------------------------------------
184               zgrasratf =  (zgraztotf + rtrn) / ( zgraztotc + rtrn )
185               zgrasratn =  (zgraztotn + rtrn) / ( zgraztotc + rtrn )
186               zgrasratp =  (zgraztotp + rtrn) / ( zgraztotc + rtrn )
187
188               !   Growth efficiency is made a function of the quality
189               !   and the quantity of the preys
190               !   ---------------------------------------------------
191               zepshert  = MIN( 1., zgrasratn/ no3rat3, zgrasratp/ po4rat3, zgrasratf / ferat3)
192               zbeta     = MAX( 0., (epsher - epshermin) )
193               zepsherf  = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
194               zepsherv  = zepsherf * zepshert
195
196               !   Respiration of microzooplankton
197               !   Excess carbon in the food is used preferentially
198               !   ------------------------------------------------
199               zexcess  = zgraztotc * zepsherf * (1.0 - zepshert) * zmetexcess
200               zbasresb = MAX(0., zrespz - zexcess)
201               zbasresi = zexcess + MIN(0., zrespz - zexcess) 
202               zrespirc = srespir * zepsherv * zgraztotc + zbasresb
203               
204               !   When excess carbon is used, the other elements in excess
205               !   are also used proportionally to their abundance
206               !   --------------------------------------------------------
207               zexcess  = ( zgrasratn/ no3rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
208               zbasresn = zbasresi * zexcess * zgrasratn 
209               zexcess  = ( zgrasratp/ po4rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
210               zbasresp = zbasresi * zexcess * zgrasratp
211               zexcess  = ( zgrasratf/ ferat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
212               zbasresf = zbasresi * zexcess * zgrasratf
213
214               !   Voiding of the excessive elements as DOM
215               !   ----------------------------------------
216               zgradoct   = (1. - unassc - zepsherv) * zgraztotc - zbasresi 
217               zgradont   = (1. - unassn) * zgraztotn - zepsherv * no3rat3 * zgraztotc - zbasresn
218               zgradopt   = (1. - unassp) * zgraztotp - zepsherv * po4rat3 * zgraztotc - zbasresp
219               zgrareft   = (1. - unassc) * zgraztotf - zepsherv * ferat3 * zgraztotc - zbasresf
220
221               !  Since only semilabile DOM is represented in PISCES
222               !  part of DOM is in fact labile and is then released
223               !  as dissolved inorganic compounds (ssigma)
224               !  --------------------------------------------------
225               zgradoc =  zgradoct * ssigma
226               zgradon =  zgradont * ssigma
227               zgradop =  zgradopt * ssigma
228               zgrarem = (1.0 - ssigma) * zgradoct
229               zgraren = (1.0 - ssigma) * zgradont
230               zgrarep = (1.0 - ssigma) * zgradopt
231               zgraref = zgrareft
232
233               !   Defecation as a result of non assimilated products
234               !   --------------------------------------------------
235               zgrapoc   = zgraztotc * unassc
236               zgrapon   = zgraztotn * unassn
237               zgrapop   = zgraztotp * unassp
238               zgrapof   = zgraztotf * unassc
239
240               !  Addition of respiration to the release of inorganic nutrients
241               !  -------------------------------------------------------------
242               zgrarem = zgrarem + zbasresi + zrespirc
243               zgraren = zgraren + zbasresn + zrespirc * no3rat3
244               zgrarep = zgrarep + zbasresp + zrespirc * po4rat3
245               zgraref = zgraref + zbasresf + zrespirc * ferat3
246
247               !   Update of the TRA arrays
248               !   ------------------------
249               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarep
250               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgraren
251               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgradoc
252               !
253               IF( ln_ligand ) THEN
254                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zgradoc * ldocz
255                  zzligprod(ji,jj,jk) = zgradoc * ldocz
256               ENDIF
257               !
258               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zgradon
259               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zgradop
260               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem 
261               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgraref
262               zfezoo(ji,jj,jk)    = zgraref
263               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) + zepsherv * zgraztotc - zrespirc - ztortz - zgrazz
264               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgraznc
265               tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) - zgraznn
266               tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) - zgraznp
267               tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) - zgrazpc
268               tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) - zgrazpn
269               tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) - zgrazpp
270               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazdc
271               tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) - zgrazdn
272               tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) - zgrazdp
273               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgraznc * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
274               tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) - zgrazpc * trb(ji,jj,jk,jppch)/(trb(ji,jj,jk,jppic)+rtrn)
275               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazdc * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
276               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
277               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
278               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
279               tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) - zgrazpf
280               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazdf
281               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ztortz + zgrapoc - zgrazpoc 
282               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + ztortz + zgrapoc
283               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc
284               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + no3rat3 * ztortz + zgrapon - zgrazpon
285               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + po4rat3 * ztortz + zgrapop - zgrazpop
286               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * ztortz  + zgrapof - zgrazpof
287               !
288               ! calcite production
289               zprcaca = xfracal(ji,jj,jk) * zgraznc
290               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
291               !
292               zprcaca = part * zprcaca
293               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem - zprcaca
294               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca     &
295               &                     + rno3 * zgraren
296               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
297            END DO
298         END DO
299      END DO
300      !
301      IF( lk_iomput ) THEN
302         IF( knt == nrdttrc ) THEN
303            ALLOCATE( zw3d(jpi,jpj,jpk) )
304            IF( iom_use( "GRAZ1" ) ) THEN
305               zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
306               CALL iom_put( "GRAZ1", zw3d )
307            ENDIF
308            IF( iom_use( "FEZOO" ) ) THEN
309               zw3d(:,:,:) = zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
310               CALL iom_put( "FEZOO", zw3d )
311            ENDIF
312            IF( iom_use( "LPRODZ" ) .AND. ln_ligand )  THEN
313               zw3d(:,:,:) = zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
314               CALL iom_put( "LPRODZ"  , zw3d )
315            ENDIF
316            DEALLOCATE( zw3d )
317         ENDIF
318      ENDIF
319      !
320      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
321         WRITE(charout, FMT="('micro')")
322         CALL prt_ctl_trc_info(charout)
323         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
324      ENDIF
325      !
326      IF( ln_timing )   CALL timing_stop('p5z_micro')
327      !
328   END SUBROUTINE p5z_micro
329
330
331   SUBROUTINE p5z_micro_init
332      !!----------------------------------------------------------------------
333      !!                  ***  ROUTINE p5z_micro_init  ***
334      !!
335      !! ** Purpose :   Initialization of microzooplankton parameters
336      !!
337      !! ** Method  :   Read the nampiszoo namelist and check the parameters
338      !!                called at the first timestep (nittrc000)
339      !!
340      !! ** input   :   Namelist nampiszoo
341      !!
342      !!----------------------------------------------------------------------
343      INTEGER ::   ios   ! Local integer
344      !!
345      NAMELIST/namp5zzoo/ part, grazrat, bmetexc, resrat, mzrat, xprefc, xprefn, &
346         &                xprefp, xprefd, xprefz, xthreshdia, xthreshphy, &
347         &                xthreshpic, xthreshpoc, xthreshzoo, xthresh, xkgraz, &
348         &                epsher, epshermin, ssigma, srespir, unassc, unassn, unassp
349      !!----------------------------------------------------------------------
350      !
351      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
352      READ  ( numnatp_ref, namp5zzoo, IOSTAT = ios, ERR = 901)
353901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zzoo in reference namelist' )
354      !
355      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
356      READ  ( numnatp_cfg, namp5zzoo, IOSTAT = ios, ERR = 902 )
357902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zzoo in configuration namelist' )
358      IF(lwm) WRITE ( numonp, namp5zzoo )
359      !
360      IF(lwp) THEN                         ! control print
361         WRITE(numout,*) ' '
362         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszooq'
363         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
364         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
365         WRITE(numout,*) '    microzoo preference for POC                     xprefc     =', xprefc
366         WRITE(numout,*) '    microzoo preference for nano                    xprefn     =', xprefn
367         WRITE(numout,*) '    microzoo preference for pico                    xprefp     =', xprefp
368         WRITE(numout,*) '    microzoo preference for diatoms                 xprefd     =', xprefd
369         WRITE(numout,*) '    microzoo preference for microzoo                xprefz     =', xprefz
370         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
371         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
372         WRITE(numout,*) '    picophyto feeding threshold for microzoo        xthreshpic  =', xthreshpic
373         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
374         WRITE(numout,*) '    microzoo feeding threshold for microzoo         xthreshzoo  =', xthreshzoo
375         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
376         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
377         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
378         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
379         WRITE(numout,*) '    C egested fraction of fodd by microzoo          unassc      =', unassc
380         WRITE(numout,*) '    N egested fraction of fodd by microzoo          unassn      =', unassn
381         WRITE(numout,*) '    P egested fraction of fodd by microzoo          unassp      =', unassp
382         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
383         WRITE(numout,*) '    Minimum Efficiency of Microzoo growth           epshermin   =', epshermin
384         WRITE(numout,*) '    Fraction excreted as semi-labile DOM            ssigma      =', ssigma
385         WRITE(numout,*) '    Active respiration                              srespir     =', srespir
386         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
387         WRITE(numout,*) '    Use of excess carbon for respiration            bmetexc     =', bmetexc
388      ENDIF
389      !
390   END SUBROUTINE p5z_micro_init
391
392   !!======================================================================
393END MODULE p5zmicro
Note: See TracBrowser for help on using the repository browser.