source: NEMO/branches/2019/ENHANCE-02_ISF_nemo/tests/ISOMIP+/MY_SRC/sbcfwb.F90 @ 11889

Last change on this file since 11889 was 11889, checked in by mathiot, 9 months ago

ENHANCE-02_ISF_nemo: add ISOMIP+ test case configuration

File size: 12.1 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
20   USE phycst         ! physical constants
21   USE sbcrnf         ! ocean runoffs
22   USE isf            ! ice shelf melting contribution
23   USE sbcssr         ! Sea-Surface damping terms
24   USE tradmp         !
25   !
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! distribued memory computing library
28   USE timing         ! Timing
29   USE lbclnk         ! ocean lateral boundary conditions
30   USE lib_fortran    !
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_fwb    ! routine called by step
36
37   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
38   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
39   REAL(wp) ::   fwfold    ! fwfold to be suppressed
40   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
41
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
46   !! $Id: sbcfwb.F90 11395 2019-08-02 14:19:00Z mathiot $
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
52      !!---------------------------------------------------------------------
53      !!                  ***  ROUTINE sbc_fwb  ***
54      !!
55      !! ** Purpose :   Control the mean sea surface drift
56      !!
57      !! ** Method  :   several ways  depending on kn_fwb
58      !!                =0 no control
59      !!                =1 global mean of emp set to zero at each nn_fsbc time step
60      !!                =2 annual global mean corrected from previous year
61      !!                =3 global mean of emp set to zero at each nn_fsbc time step
62      !!                   & spread out over erp area depending its sign
63      !! Note: if sea ice is embedded it is taken into account when computing the budget
64      !!----------------------------------------------------------------------
65      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
66      INTEGER, INTENT( in ) ::   kn_fsbc  !
67      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
68      !
69      INTEGER  ::   inum, ikty, iyear     ! local integers
70      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
71      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
72      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
73      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
74      REAL(wp)   ,DIMENSION(1) ::   z_fwfprv 
75      COMPLEX(wp),DIMENSION(1) ::   y_fwfnow 
76      !!----------------------------------------------------------------------
77      !
78      IF( kt == nit000 ) THEN
79         IF(lwp) THEN
80            WRITE(numout,*)
81            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
82            WRITE(numout,*) '~~~~~~~'
83            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
84            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
85            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
86         ENDIF
87         !
88         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
89         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
90         !
91         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
92         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
93         ! and in case of no melt, it can generate HSSW.
94         !
95#if ! defined key_si3 && ! defined key_cice
96         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
97         snwice_mass  (:,:) = 0.e0
98#endif
99         !
100      ENDIF
101
102      SELECT CASE ( kn_fwb )
103      !
104      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
105         !
106         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
107            z_fwf = glob_sum( 'sbcfwb',  e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) )
108            z_fwf = z_fwf / area
109            zcoef = z_fwf * rcp
110            emp(:,:) = emp(:,:) - z_fwf              * tmask(:,:,1)
111            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
112            sfx(:,:) = sfx(:,:) + z_fwf * sss_m(:,:) * tmask(:,:,1)
113         ENDIF
114         !
115      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
116         !
117         IF( kt == nit000 ) THEN                      ! initialisation
118            !                                         ! Read the corrective factor on precipitations (fwfold)
119            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
120            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
121            CLOSE( inum )
122            fwfold = a_fwb                            ! current year freshwater budget correction
123            !                                         ! estimate from the previous year budget
124            IF(lwp)WRITE(numout,*)
125            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
126            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
127            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
128         ENDIF   
129         !                                         ! Update fwfold if new year start
130         ikty = 365 * 86400 / rdt                  !!bug  use of 365 days leap year or 360d year !!!!!!!
131         IF( MOD( kt, ikty ) == 0 ) THEN
132            a_fwb_b = a_fwb                           ! mean sea level taking into account the ice+snow
133                                                      ! sum over the global domain
134            a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) )
135            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
136!!gm        !                                                      !!bug 365d year
137            fwfold =  a_fwb                           ! current year freshwater budget correction
138            !                                         ! estimate from the previous year budget
139         ENDIF
140         !
141         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
142            zcoef = fwfold * rcp
143            emp(:,:) = emp(:,:) + fwfold             * tmask(:,:,1)
144            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
145         ENDIF
146         !
147         IF( kt == nitend .AND. lwm ) THEN            ! save fwfold value in a file (only one required)
148            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
149            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
150            CLOSE( inum )
151         ENDIF
152         !
153      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
154         !
155         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
156         !
157         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
158            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
159            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
160            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
161            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
162            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) ) / area
163            !           
164            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
165               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
166               zsurf_tospread      = zsurf_pos
167               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
168            ELSE                             ! spread out over <0 erp area to increase precipitation
169               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
170               zsurf_tospread      = zsurf_neg
171               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
172            ENDIF
173            !
174            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
175!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
176            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
177            !                                                  ! weight to respect erp field 2D structure
178            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
179            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
180            !                                                  ! final correction term to apply
181            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
182            !
183!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
184            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1. )
185            !
186            emp(:,:) = emp(:,:) + zerp_cor(:,:)
187            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
188            erp(:,:) = erp(:,:) + zerp_cor(:,:)
189            !
190            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
191               IF( z_fwf < 0._wp ) THEN
192                  WRITE(numout,*)'   z_fwf < 0'
193                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
194               ELSE
195                  WRITE(numout,*)'   z_fwf >= 0'
196                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
197               ENDIF
198               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
199               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
200               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
201               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
202               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
203            ENDIF
204         ENDIF
205         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
206         !
207      CASE DEFAULT                           !==  you should never be there  ==!
208         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
209         !
210      END SELECT
211      !
212   END SUBROUTINE sbc_fwb
213
214   !!======================================================================
215END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.