source: NEMO/branches/2019/ENHANCE-02_ISF_nemo/tests/ISOMIP+/MY_SRC/sbcfwb.F90 @ 11987

Last change on this file since 11987 was 11987, checked in by mathiot, 11 months ago

ENHANCE-02_ISF_nemo: changes needed after Dave's review

File size: 14.1 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE isf_oce        ! ice shelf melting contribution
20   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
21   USE phycst         ! physical constants
22   USE sbcrnf         ! ocean runoffs
23   USE sbcssr         ! Sea-Surface damping terms
24   !
25   USE in_out_manager ! I/O manager
26   USE lib_mpp        ! distribued memory computing library
27   USE timing         ! Timing
28   USE lbclnk         ! ocean lateral boundary conditions
29   USE lib_fortran    !
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_fwb    ! routine called by step
35
36   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
37   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
38   REAL(wp) ::   fwfold    ! fwfold to be suppressed
39   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id: sbcfwb.F90 11395 2019-08-02 14:19:00Z mathiot $
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
51      !!---------------------------------------------------------------------
52      !!                  ***  ROUTINE sbc_fwb  ***
53      !!
54      !! ** Purpose :   Control the mean sea surface drift
55      !!
56      !! ** Method  :   several ways  depending on kn_fwb
57      !!                =0 no control
58      !!                =1 global mean of emp set to zero at each nn_fsbc time step
59      !!                =2 annual global mean corrected from previous year
60      !!                =3 global mean of emp set to zero at each nn_fsbc time step
61      !!                   & spread out over erp area depending its sign
62      !! Note: if sea ice is embedded it is taken into account when computing the budget
63      !!----------------------------------------------------------------------
64      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
65      INTEGER, INTENT( in ) ::   kn_fsbc  !
66      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
67      !
68      INTEGER  ::   inum, ikty, iyear     ! local integers
69      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
70      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
71      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
72      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
73      REAL(wp)   ,DIMENSION(1) ::   z_fwfprv 
74      COMPLEX(wp),DIMENSION(1) ::   y_fwfnow 
75      !!----------------------------------------------------------------------
76      !
77      IF( kt == nit000 ) THEN
78         IF(lwp) THEN
79            WRITE(numout,*)
80            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
81            WRITE(numout,*) '~~~~~~~'
82            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
83            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
84            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
85            IF( kn_fwb == 4 )   WRITE(numout,*) '          instantaneously set to zero with heat and salt flux correction (ISOMIP+)'
86         ENDIF
87         !
88         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
89         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
90         !
91         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
92         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
93         ! and in case of no melt, it can generate HSSW.
94         !
95#if ! defined key_si3 && ! defined key_cice
96         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
97         snwice_mass  (:,:) = 0.e0
98#endif
99         !
100      ENDIF
101
102      SELECT CASE ( kn_fwb )
103      !
104      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
105         !
106         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
107            y_fwfnow(1) = local_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) )
108            CALL mpp_delay_sum( 'sbcfwb', 'fwb', y_fwfnow(:), z_fwfprv(:), kt == nitend - nn_fsbc + 1 )
109            z_fwfprv(1) = z_fwfprv(1) / area
110            zcoef = z_fwfprv(1) * rcp
111            emp(:,:) = emp(:,:) - z_fwfprv(1)        * tmask(:,:,1)
112            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
113         ENDIF
114         !
115      CASE ( 4 )                             !==  global mean fwf set to zero (ISOMIP case) ==!
116         !
117         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
118            z_fwf = glob_sum( 'sbcfwb',  e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) )
119            !
120            ! correction for ice sheet coupling testing (ie remove the excess through the surface)
121            ! test impact on the melt as conservation correction made in depth
122            ! test conservation level as sbcfwb is conserving
123            ! avoid the model to blow up for large ssh drop (isomip OCEAN3 with melt switch off and uniform T/S)
124            IF (ln_isfcpl .AND. ln_isfcpl_cons) THEN
125               z_fwf = z_fwf + glob_sum( 'sbcfwb',  e1e2t(:,:) * risfcpl_cons_ssh(:,:) * rau0 )
126            END IF
127            !
128            z_fwf = z_fwf / area
129            zcoef = z_fwf * rcp
130            emp(:,:) = emp(:,:) - z_fwf              * tmask(:,:,1) ! (Eq. 34 AD2015)
131            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! (Eq. 35 AD2015) ! use sst_m to avoid generation of any bouyancy fluxes
132            sfx(:,:) = sfx(:,:) + z_fwf * sss_m(:,:) * tmask(:,:,1) ! (Eq. 36 AD2015) ! use sss_m to avoid generation of any bouyancy fluxes
133            !qns(:,:) = qns(:,:) + zcoef * ( -1.9 ) * tmask(:,:,1) ! (Eq. 35 AD2015) ! could be sst_m if we don't want any bouyancy fluxes
134            !sfx(:,:) = sfx(:,:) + z_fwf * ( 33.8 ) * tmask(:,:,1) ! (Eq. 36 AD2015) ! could be sss_m if we don't want any bouyancy fluxes
135            !qns(:,:) = qns(:,:) + zcoef * ( -1.0 ) * tmask(:,:,1) ! use for ISOMIP+ coupling sanity check (keep ssh cst while playing with cpl conservation option)
136            !sfx(:,:) = sfx(:,:) + z_fwf * ( 34.2 ) * tmask(:,:,1) ! use for ISOMIP+ coupling sanity check (keep ssh cst while playing with cpl conservation option)
137         ENDIF
138         !
139      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
140         !
141         IF( kt == nit000 ) THEN                      ! initialisation
142            !                                         ! Read the corrective factor on precipitations (fwfold)
143            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
144            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
145            CLOSE( inum )
146            fwfold = a_fwb                            ! current year freshwater budget correction
147            !                                         ! estimate from the previous year budget
148            IF(lwp)WRITE(numout,*)
149            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
150            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
151            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
152         ENDIF   
153         !                                         ! Update fwfold if new year start
154         ikty = 365 * 86400 / rdt                  !!bug  use of 365 days leap year or 360d year !!!!!!!
155         IF( MOD( kt, ikty ) == 0 ) THEN
156            a_fwb_b = a_fwb                           ! mean sea level taking into account the ice+snow
157                                                      ! sum over the global domain
158            a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) )
159            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
160!!gm        !                                                      !!bug 365d year
161            fwfold =  a_fwb                           ! current year freshwater budget correction
162            !                                         ! estimate from the previous year budget
163         ENDIF
164         !
165         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
166            zcoef = fwfold * rcp
167            emp(:,:) = emp(:,:) + fwfold             * tmask(:,:,1)
168            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
169         ENDIF
170         !
171         IF( kt == nitend .AND. lwm ) THEN            ! save fwfold value in a file (only one required)
172            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
173            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
174            CLOSE( inum )
175         ENDIF
176         !
177      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
178         !
179         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
180         !
181         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
182            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
183            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
184            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
185            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
186            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) ) / area
187            !           
188            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
189               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
190               zsurf_tospread      = zsurf_pos
191               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
192            ELSE                             ! spread out over <0 erp area to increase precipitation
193               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
194               zsurf_tospread      = zsurf_neg
195               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
196            ENDIF
197            !
198            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
199!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
200            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
201            !                                                  ! weight to respect erp field 2D structure
202            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
203            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
204            !                                                  ! final correction term to apply
205            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
206            !
207!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
208            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1. )
209            !
210            emp(:,:) = emp(:,:) + zerp_cor(:,:)
211            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
212            erp(:,:) = erp(:,:) + zerp_cor(:,:)
213            !
214            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
215               IF( z_fwf < 0._wp ) THEN
216                  WRITE(numout,*)'   z_fwf < 0'
217                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
218               ELSE
219                  WRITE(numout,*)'   z_fwf >= 0'
220                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
221               ENDIF
222               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
223               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
224               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
225               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
226               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
227            ENDIF
228         ENDIF
229         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
230         !
231      CASE DEFAULT                           !==  you should never be there  ==!
232         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
233         !
234      END SELECT
235      !
236   END SUBROUTINE sbc_fwb
237
238   !!======================================================================
239END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.