New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in NEMO/branches/2019/ENHANCE-02_ISF_nemo_TEST_MERGE/src/OCE/DYN – NEMO

source: NEMO/branches/2019/ENHANCE-02_ISF_nemo_TEST_MERGE/src/OCE/DYN/dynhpg.F90 @ 11967

Last change on this file since 11967 was 11967, checked in by davestorkey, 4 years ago

2019/ENHANCE-02_ISF_nemo_TEST_MERGE : Update to rev 11953.
  • Property svn:keywords set to Id
File size: 70.3 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE isf             ! ice shelf  (risfload variable)
34   USE isfload         ! ice shelf  (isf_load routine )
35   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
36   USE dom_oce         ! ocean space and time domain
37   USE wet_dry         ! wetting and drying
38   USE phycst          ! physical constants
39   USE trd_oce         ! trends: ocean variables
40   USE trddyn          ! trend manager: dynamics
41   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE prtctl          ! Print control
45   USE lbclnk          ! lateral boundary condition
46   USE lib_mpp         ! MPP library
47   USE eosbn2          ! compute density
48   USE timing          ! Timing
49   USE iom
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   dyn_hpg        ! routine called by step module
55   PUBLIC   dyn_hpg_init   ! routine called by opa module
56
57   !                                !!* Namelist namdyn_hpg : hydrostatic pressure gradient
58   LOGICAL, PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
59   LOGICAL, PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
60   LOGICAL, PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
61   LOGICAL, PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
62   LOGICAL, PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
63   LOGICAL, PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
64
65   !                                !! Flag to control the type of hydrostatic pressure gradient
66   INTEGER, PARAMETER ::   np_ERROR  =-10   ! error in specification of lateral diffusion
67   INTEGER, PARAMETER ::   np_zco    =  0   ! z-coordinate - full steps
68   INTEGER, PARAMETER ::   np_zps    =  1   ! z-coordinate - partial steps (interpolation)
69   INTEGER, PARAMETER ::   np_sco    =  2   ! s-coordinate (standard jacobian formulation)
70   INTEGER, PARAMETER ::   np_djc    =  3   ! s-coordinate (Density Jacobian with Cubic polynomial)
71   INTEGER, PARAMETER ::   np_prj    =  4   ! s-coordinate (Pressure Jacobian scheme)
72   INTEGER, PARAMETER ::   np_isf    =  5   ! s-coordinate similar to sco modify for isf
73   !
74   INTEGER, PUBLIC ::   nhpg         !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
75
76   !! * Substitutions
77#  include "vectopt_loop_substitute.h90"
78   !!----------------------------------------------------------------------
79   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
80   !! $Id$
81   !! Software governed by the CeCILL license (see ./LICENSE)
82   !!----------------------------------------------------------------------
83CONTAINS
84
85   SUBROUTINE dyn_hpg( kt )
86      !!---------------------------------------------------------------------
87      !!                  ***  ROUTINE dyn_hpg  ***
88      !!
89      !! ** Method  :   Call the hydrostatic pressure gradient routine
90      !!              using the scheme defined in the namelist
91      !!
92      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
93      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
94      !!----------------------------------------------------------------------
95      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
96      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
97      !!----------------------------------------------------------------------
98      !
99      IF( ln_timing )   CALL timing_start('dyn_hpg')
100      !
101      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
102         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
103         ztrdu(:,:,:) = ua(:,:,:)
104         ztrdv(:,:,:) = va(:,:,:)
105      ENDIF
106      !
107      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
108      CASE ( np_zco )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
109      CASE ( np_zps )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
110      CASE ( np_sco )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
111      CASE ( np_djc )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
112      CASE ( np_prj )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
113      CASE ( np_isf )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
114      END SELECT
115      !
116      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
117         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
118         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
119         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
120         DEALLOCATE( ztrdu , ztrdv )
121      ENDIF
122      !
123      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
124         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
125      !
126      IF( ln_timing )   CALL timing_stop('dyn_hpg')
127      !
128   END SUBROUTINE dyn_hpg
129
130
131   SUBROUTINE dyn_hpg_init
132      !!----------------------------------------------------------------------
133      !!                 ***  ROUTINE dyn_hpg_init  ***
134      !!
135      !! ** Purpose :   initializations for the hydrostatic pressure gradient
136      !!              computation and consistency control
137      !!
138      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
139      !!      with the type of vertical coordinate used (zco, zps, sco)
140      !!----------------------------------------------------------------------
141      INTEGER ::   ioptio = 0      ! temporary integer
142      INTEGER ::   ios             ! Local integer output status for namelist read
143      !!
144      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
145      REAL(wp) ::   znad
146      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zts_top, zrhd   ! hypothesys on isf density
147      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  zrhdtop_isf    ! density at bottom of ISF
148      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  ziceload       ! density at bottom of ISF
149      !!
150      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
151         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
152      !!----------------------------------------------------------------------
153      !
154      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
155      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
156901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist' )
157      !
158      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
159      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
160902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist' )
161      IF(lwm) WRITE ( numond, namdyn_hpg )
162      !
163      IF(lwp) THEN                   ! Control print
164         WRITE(numout,*)
165         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
166         WRITE(numout,*) '~~~~~~~~~~~~'
167         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
168         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
169         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
170         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
171         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
172         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
173         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
174      ENDIF
175      !
176      IF( ln_hpg_djc )   &
177         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method',   &
178         &                 '   currently disabled (bugs under investigation).'        ,   &
179         &                 '   Please select either  ln_hpg_sco or  ln_hpg_prj instead' )
180         !
181      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )          &
182         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ',   &
183         &                 '   the standard jacobian formulation hpg_sco    or '    ,   &
184         &                 '   the pressure jacobian formulation hpg_prj'             )
185         !
186      IF( ln_hpg_isf ) THEN
187         IF( .NOT. ln_isfcav )   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
188       ELSE
189         IF(       ln_isfcav )   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
190      ENDIF
191      !
192      !                               ! Set nhpg from ln_hpg_... flags & consistency check
193      nhpg   = np_ERROR
194      ioptio = 0
195      IF( ln_hpg_zco ) THEN   ;   nhpg = np_zco   ;   ioptio = ioptio +1   ;   ENDIF
196      IF( ln_hpg_zps ) THEN   ;   nhpg = np_zps   ;   ioptio = ioptio +1   ;   ENDIF
197      IF( ln_hpg_sco ) THEN   ;   nhpg = np_sco   ;   ioptio = ioptio +1   ;   ENDIF
198      IF( ln_hpg_djc ) THEN   ;   nhpg = np_djc   ;   ioptio = ioptio +1   ;   ENDIF
199      IF( ln_hpg_prj ) THEN   ;   nhpg = np_prj   ;   ioptio = ioptio +1   ;   ENDIF
200      IF( ln_hpg_isf ) THEN   ;   nhpg = np_isf   ;   ioptio = ioptio +1   ;   ENDIF
201      !
202      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
203      !
204      IF(lwp) THEN
205         WRITE(numout,*)
206         SELECT CASE( nhpg )
207         CASE( np_zco )   ;   WRITE(numout,*) '   ==>>>   z-coord. - full steps '
208         CASE( np_zps )   ;   WRITE(numout,*) '   ==>>>   z-coord. - partial steps (interpolation)'
209         CASE( np_sco )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation)'
210         CASE( np_djc )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Density Jacobian: Cubic polynomial)'
211         CASE( np_prj )   ;   WRITE(numout,*) '   ==>>>   s-coord. (Pressure Jacobian: Cubic polynomial)'
212         CASE( np_isf )   ;   WRITE(numout,*) '   ==>>>   s-coord. (standard jacobian formulation) for isf'
213         END SELECT
214         WRITE(numout,*)
215      ENDIF
216      !                         
217   END SUBROUTINE dyn_hpg_init
218
219   SUBROUTINE hpg_zco( kt )
220      !!---------------------------------------------------------------------
221      !!                  ***  ROUTINE hpg_zco  ***
222      !!
223      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
224      !!      The now hydrostatic pressure gradient at a given level, jk,
225      !!      is computed by taking the vertical integral of the in-situ
226      !!      density gradient along the model level from the suface to that
227      !!      level:    zhpi = grav .....
228      !!                zhpj = grav .....
229      !!      add it to the general momentum trend (ua,va).
230      !!            ua = ua - 1/e1u * zhpi
231      !!            va = va - 1/e2v * zhpj
232      !!
233      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
234      !!----------------------------------------------------------------------
235      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
236      !
237      INTEGER  ::   ji, jj, jk       ! dummy loop indices
238      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
239      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
240      !!----------------------------------------------------------------------
241      !
242      IF( kt == nit000 ) THEN
243         IF(lwp) WRITE(numout,*)
244         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
245         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
246      ENDIF
247
248      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
249
250      ! Surface value
251      DO jj = 2, jpjm1
252         DO ji = fs_2, fs_jpim1   ! vector opt.
253            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
254            ! hydrostatic pressure gradient
255            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
256            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
257            ! add to the general momentum trend
258            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
259            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
260         END DO
261      END DO
262
263      !
264      ! interior value (2=<jk=<jpkm1)
265      DO jk = 2, jpkm1
266         DO jj = 2, jpjm1
267            DO ji = fs_2, fs_jpim1   ! vector opt.
268               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
269               ! hydrostatic pressure gradient
270               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
271                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
272                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
273
274               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
275                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
276                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
277               ! add to the general momentum trend
278               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
279               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
280            END DO
281         END DO
282      END DO
283      !
284   END SUBROUTINE hpg_zco
285
286
287   SUBROUTINE hpg_zps( kt )
288      !!---------------------------------------------------------------------
289      !!                 ***  ROUTINE hpg_zps  ***
290      !!
291      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
292      !!
293      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
294      !!----------------------------------------------------------------------
295      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
296      !!
297      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
298      INTEGER  ::   iku, ikv                         ! temporary integers
299      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
300      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zhpi, zhpj
301      REAL(wp), DIMENSION(jpi,jpj) :: zgtsu, zgtsv, zgru, zgrv
302      !!----------------------------------------------------------------------
303      !
304      IF( kt == nit000 ) THEN
305         IF(lwp) WRITE(numout,*)
306         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
307         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
308      ENDIF
309
310      ! Partial steps: Compute NOW horizontal gradient of t, s, rd at the last ocean level
311      CALL zps_hde( kt, jpts, tsn, zgtsu, zgtsv, rhd, zgru , zgrv )
312
313      ! Local constant initialization
314      zcoef0 = - grav * 0.5_wp
315
316      !  Surface value (also valid in partial step case)
317      DO jj = 2, jpjm1
318         DO ji = fs_2, fs_jpim1   ! vector opt.
319            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
320            ! hydrostatic pressure gradient
321            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
322            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
323            ! add to the general momentum trend
324            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
325            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
326         END DO
327      END DO
328
329      ! interior value (2=<jk=<jpkm1)
330      DO jk = 2, jpkm1
331         DO jj = 2, jpjm1
332            DO ji = fs_2, fs_jpim1   ! vector opt.
333               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
334               ! hydrostatic pressure gradient
335               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
336                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
337                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
338
339               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
340                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
341                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
342               ! add to the general momentum trend
343               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
344               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
345            END DO
346         END DO
347      END DO
348
349      ! partial steps correction at the last level  (use zgru & zgrv computed in zpshde.F90)
350      DO jj = 2, jpjm1
351         DO ji = 2, jpim1
352            iku = mbku(ji,jj)
353            ikv = mbkv(ji,jj)
354            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
355            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
356            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
357               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
358               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
359                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + zgru(ji,jj) ) * r1_e1u(ji,jj)
360               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
361            ENDIF
362            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
363               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
364               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
365                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + zgrv(ji,jj) ) * r1_e2v(ji,jj)
366               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
367            ENDIF
368         END DO
369      END DO
370      !
371   END SUBROUTINE hpg_zps
372
373
374   SUBROUTINE hpg_sco( kt )
375      !!---------------------------------------------------------------------
376      !!                  ***  ROUTINE hpg_sco  ***
377      !!
378      !! ** Method  :   s-coordinate case. Jacobian scheme.
379      !!      The now hydrostatic pressure gradient at a given level, jk,
380      !!      is computed by taking the vertical integral of the in-situ
381      !!      density gradient along the model level from the suface to that
382      !!      level. s-coordinates (ln_sco): a corrective term is added
383      !!      to the horizontal pressure gradient :
384      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
385      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
386      !!      add it to the general momentum trend (ua,va).
387      !!         ua = ua - 1/e1u * zhpi
388      !!         va = va - 1/e2v * zhpj
389      !!
390      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
391      !!----------------------------------------------------------------------
392      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
393      !!
394      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
395      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
396      LOGICAL  ::   ll_tmp1, ll_tmp2                     ! local logical variables
397      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zhpi, zhpj
398      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
399      !!----------------------------------------------------------------------
400      !
401      IF( ln_wd_il ) ALLOCATE(zcpx(jpi,jpj), zcpy(jpi,jpj))
402      !
403      IF( kt == nit000 ) THEN
404         IF(lwp) WRITE(numout,*)
405         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
406         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
407      ENDIF
408      !
409      zcoef0 = - grav * 0.5_wp
410      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
411      ELSE                    ;   znad = 1._wp         ! Variable volume: density
412      ENDIF
413      !
414      IF( ln_wd_il ) THEN
415        DO jj = 2, jpjm1
416           DO ji = 2, jpim1 
417             ll_tmp1 = MIN(  sshn(ji,jj)               ,  sshn(ji+1,jj) ) >                &
418                  &    MAX( -ht_0(ji,jj)               , -ht_0(ji+1,jj) ) .AND.            &
419                  &    MAX(  sshn(ji,jj) +  ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
420                  &                                                       > rn_wdmin1 + rn_wdmin2
421             ll_tmp2 = ( ABS( sshn(ji,jj)              -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (       &
422                  &    MAX(   sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
423                  &    MAX(  -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
424
425             IF(ll_tmp1) THEN
426               zcpx(ji,jj) = 1.0_wp
427             ELSE IF(ll_tmp2) THEN
428               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
429               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
430                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
431             ELSE
432               zcpx(ji,jj) = 0._wp
433             END IF
434     
435             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
436                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
437                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
438                  &                                                      > rn_wdmin1 + rn_wdmin2
439             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
440                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
441                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
442
443             IF(ll_tmp1) THEN
444               zcpy(ji,jj) = 1.0_wp
445             ELSE IF(ll_tmp2) THEN
446               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
447               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
448                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
449             ELSE
450               zcpy(ji,jj) = 0._wp
451             END IF
452           END DO
453        END DO
454        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
455      END IF
456
457      ! Surface value
458      DO jj = 2, jpjm1
459         DO ji = fs_2, fs_jpim1   ! vector opt.
460            ! hydrostatic pressure gradient along s-surfaces
461            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
462               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
463            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
464               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
465            ! s-coordinate pressure gradient correction
466            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
467               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
468            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
469               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
470            !
471            IF( ln_wd_il ) THEN
472               zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
473               zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
474               zuap = zuap * zcpx(ji,jj)
475               zvap = zvap * zcpy(ji,jj)
476            ENDIF
477            !
478            ! add to the general momentum trend
479            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
480            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
481         END DO
482      END DO
483
484      ! interior value (2=<jk=<jpkm1)
485      DO jk = 2, jpkm1
486         DO jj = 2, jpjm1
487            DO ji = fs_2, fs_jpim1   ! vector opt.
488               ! hydrostatic pressure gradient along s-surfaces
489               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
490                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
491                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
492               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
493                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
494                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
495               ! s-coordinate pressure gradient correction
496               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
497                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
498               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
499                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
500               !
501               IF( ln_wd_il ) THEN
502                  zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
503                  zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
504                  zuap = zuap * zcpx(ji,jj)
505                  zvap = zvap * zcpy(ji,jj)
506               ENDIF
507               !
508               ! add to the general momentum trend
509               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
510               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
511            END DO
512         END DO
513      END DO
514      !
515      IF( ln_wd_il )  DEALLOCATE( zcpx , zcpy )
516      !
517   END SUBROUTINE hpg_sco
518
519
520   SUBROUTINE hpg_isf( kt )
521      !!---------------------------------------------------------------------
522      !!                  ***  ROUTINE hpg_isf  ***
523      !!
524      !! ** Method  :   s-coordinate case. Jacobian scheme.
525      !!      The now hydrostatic pressure gradient at a given level, jk,
526      !!      is computed by taking the vertical integral of the in-situ
527      !!      density gradient along the model level from the suface to that
528      !!      level. s-coordinates (ln_sco): a corrective term is added
529      !!      to the horizontal pressure gradient :
530      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
531      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
532      !!      add it to the general momentum trend (ua,va).
533      !!         ua = ua - 1/e1u * zhpi
534      !!         va = va - 1/e2v * zhpj
535      !!      iceload is added
536      !!     
537      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
538      !!----------------------------------------------------------------------
539      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
540      !!
541      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
542      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
543      REAL(wp), DIMENSION(jpi,jpj,jpk ) ::  zhpi, zhpj
544      REAL(wp), DIMENSION(jpi,jpj,jpts) ::  zts_top
545      REAL(wp), DIMENSION(jpi,jpj)      ::  zrhdtop_oce
546      !!----------------------------------------------------------------------
547      !
548      zcoef0 = - grav * 0.5_wp   ! Local constant initialization
549      !
550      znad=1._wp                 ! To use density and not density anomaly
551      !
552      !                          ! iniitialised to 0. zhpi zhpi
553      zhpi(:,:,:) = 0._wp   ;   zhpj(:,:,:) = 0._wp
554
555      ! compute rhd at the ice/oce interface (ocean side)
556      ! usefull to reduce residual current in the test case ISOMIP with no melting
557      DO ji = 1, jpi
558        DO jj = 1, jpj
559          ikt = mikt(ji,jj)
560          zts_top(ji,jj,1) = tsn(ji,jj,ikt,1)
561          zts_top(ji,jj,2) = tsn(ji,jj,ikt,2)
562        END DO
563      END DO
564      CALL eos( zts_top, risfdep, zrhdtop_oce )
565
566!==================================================================================     
567!===== Compute surface value =====================================================
568!==================================================================================
569      DO jj = 2, jpjm1
570         DO ji = fs_2, fs_jpim1   ! vector opt.
571            ikt    = mikt(ji,jj)
572            iktp1i = mikt(ji+1,jj)
573            iktp1j = mikt(ji,jj+1)
574            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
575            ! we assume ISF is in isostatic equilibrium
576            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
577               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
578               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
579               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
580               &                                  + ( risfload(ji+1,jj) - risfload(ji,jj))                            ) 
581            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
582               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
583               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
584               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
585               &                                  + ( risfload(ji,jj+1) - risfload(ji,jj))                            ) 
586            ! s-coordinate pressure gradient correction (=0 if z coordinate)
587            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
588               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
589            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
590               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
591            ! add to the general momentum trend
592            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
593            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
594         END DO
595      END DO
596!==================================================================================     
597!===== Compute interior value =====================================================
598!==================================================================================
599      ! interior value (2=<jk=<jpkm1)
600      DO jk = 2, jpkm1
601         DO jj = 2, jpjm1
602            DO ji = fs_2, fs_jpim1   ! vector opt.
603               ! hydrostatic pressure gradient along s-surfaces
604               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
605                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
606                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
607               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
608                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
609                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
610               ! s-coordinate pressure gradient correction
611               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
612                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
613               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
614                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
615               ! add to the general momentum trend
616               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
617               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
618            END DO
619         END DO
620      END DO
621      !
622   END SUBROUTINE hpg_isf
623
624
625   SUBROUTINE hpg_djc( kt )
626      !!---------------------------------------------------------------------
627      !!                  ***  ROUTINE hpg_djc  ***
628      !!
629      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
630      !!
631      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
632      !!----------------------------------------------------------------------
633      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
634      !!
635      INTEGER  ::   ji, jj, jk          ! dummy loop indices
636      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
637      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
638      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
639      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
640      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zhpj
641      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   dzx, dzy, dzz, dzu, dzv, dzw
642      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, drhoy, drhoz, drhou, drhov, drhow
643      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   rho_i, rho_j, rho_k
644      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
645      !!----------------------------------------------------------------------
646      !
647      IF( ln_wd_il ) THEN
648         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
649        DO jj = 2, jpjm1
650           DO ji = 2, jpim1 
651             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
652                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
653                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
654                  &                                                      > rn_wdmin1 + rn_wdmin2
655             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (        &
656                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
657                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
658             IF(ll_tmp1) THEN
659               zcpx(ji,jj) = 1.0_wp
660             ELSE IF(ll_tmp2) THEN
661               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
662               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
663                           &    / (sshn(ji+1,jj) - sshn(ji  ,jj)) )
664             ELSE
665               zcpx(ji,jj) = 0._wp
666             END IF
667     
668             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
669                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
670                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
671                  &                                                      > rn_wdmin1 + rn_wdmin2
672             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (        &
673                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
674                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
675
676             IF(ll_tmp1) THEN
677               zcpy(ji,jj) = 1.0_wp
678             ELSE IF(ll_tmp2) THEN
679               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
680               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
681                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
682             ELSE
683               zcpy(ji,jj) = 0._wp
684             END IF
685           END DO
686        END DO
687        CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
688      END IF
689
690      IF( kt == nit000 ) THEN
691         IF(lwp) WRITE(numout,*)
692         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
693         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
694      ENDIF
695
696      ! Local constant initialization
697      zcoef0 = - grav * 0.5_wp
698      z1_10  = 1._wp / 10._wp
699      z1_12  = 1._wp / 12._wp
700
701      !----------------------------------------------------------------------------------------
702      !  compute and store in provisional arrays elementary vertical and horizontal differences
703      !----------------------------------------------------------------------------------------
704
705!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
706
707      DO jk = 2, jpkm1
708         DO jj = 2, jpjm1
709            DO ji = fs_2, fs_jpim1   ! vector opt.
710               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
711               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
712               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
713               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
714               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
715               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
716            END DO
717         END DO
718      END DO
719
720      !-------------------------------------------------------------------------
721      ! compute harmonic averages using eq. 5.18
722      !-------------------------------------------------------------------------
723      zep = 1.e-15
724
725!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
726!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
727
728      DO jk = 2, jpkm1
729         DO jj = 2, jpjm1
730            DO ji = fs_2, fs_jpim1   ! vector opt.
731               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
732
733               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
734               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
735
736               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
737               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
738
739               IF( cffw > zep) THEN
740                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
741                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
742               ELSE
743                  drhow(ji,jj,jk) = 0._wp
744               ENDIF
745
746               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
747                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
748
749               IF( cffu > zep ) THEN
750                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
751                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
752               ELSE
753                  drhou(ji,jj,jk ) = 0._wp
754               ENDIF
755
756               IF( cffx > zep ) THEN
757                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
758                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
759               ELSE
760                  dzu(ji,jj,jk) = 0._wp
761               ENDIF
762
763               IF( cffv > zep ) THEN
764                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
765                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
766               ELSE
767                  drhov(ji,jj,jk) = 0._wp
768               ENDIF
769
770               IF( cffy > zep ) THEN
771                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
772                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
773               ELSE
774                  dzv(ji,jj,jk) = 0._wp
775               ENDIF
776
777            END DO
778         END DO
779      END DO
780
781      !----------------------------------------------------------------------------------
782      ! apply boundary conditions at top and bottom using 5.36-5.37
783      !----------------------------------------------------------------------------------
784      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
785      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
786      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
787
788      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
789      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
790      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
791
792
793      !--------------------------------------------------------------
794      ! Upper half of top-most grid box, compute and store
795      !-------------------------------------------------------------
796
797!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
798!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
799
800      DO jj = 2, jpjm1
801         DO ji = fs_2, fs_jpim1   ! vector opt.
802            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
803               &                   * (  rhd(ji,jj,1)                                     &
804               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
805               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
806               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
807         END DO
808      END DO
809
810!!bug gm    : here also, simplification is possible
811!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
812
813      DO jk = 2, jpkm1
814         DO jj = 2, jpjm1
815            DO ji = fs_2, fs_jpim1   ! vector opt.
816
817               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
818                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
819                  &            - grav * z1_10 * (                                                                   &
820                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
821                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
822                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
823                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
824                  &                             )
825
826               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
827                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
828                  &            - grav* z1_10 * (                                                                    &
829                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
830                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
831                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
832                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
833                  &                            )
834
835               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
836                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
837                  &            - grav* z1_10 * (                                                                    &
838                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
839                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
840                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
841                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
842                  &                            )
843
844            END DO
845         END DO
846      END DO
847      CALL lbc_lnk_multi( 'dynhpg', rho_k, 'W', 1., rho_i, 'U', 1., rho_j, 'V', 1. )
848
849      ! ---------------
850      !  Surface value
851      ! ---------------
852      DO jj = 2, jpjm1
853         DO ji = fs_2, fs_jpim1   ! vector opt.
854            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
855            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
856            IF( ln_wd_il ) THEN
857              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
858              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
859            ENDIF
860            ! add to the general momentum trend
861            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
862            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
863         END DO
864      END DO
865
866      ! ----------------
867      !  interior value   (2=<jk=<jpkm1)
868      ! ----------------
869      DO jk = 2, jpkm1
870         DO jj = 2, jpjm1
871            DO ji = fs_2, fs_jpim1   ! vector opt.
872               ! hydrostatic pressure gradient along s-surfaces
873               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
874                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
875                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
876               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
877                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
878                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
879               IF( ln_wd_il ) THEN
880                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
881                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
882               ENDIF
883               ! add to the general momentum trend
884               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
885               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
886            END DO
887         END DO
888      END DO
889      !
890      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
891      !
892   END SUBROUTINE hpg_djc
893
894
895   SUBROUTINE hpg_prj( kt )
896      !!---------------------------------------------------------------------
897      !!                  ***  ROUTINE hpg_prj  ***
898      !!
899      !! ** Method  :   s-coordinate case.
900      !!      A Pressure-Jacobian horizontal pressure gradient method
901      !!      based on the constrained cubic-spline interpolation for
902      !!      all vertical coordinate systems
903      !!
904      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
905      !!----------------------------------------------------------------------
906      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
907      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
908      !!
909      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
910      REAL(wp) ::   zcoef0, znad                    ! local scalars
911      !
912      !! The local variables for the correction term
913      INTEGER  :: jk1, jis, jid, jjs, jjd
914      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
915      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
916      REAL(wp) :: zrhdt1
917      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
918      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdept, zrhh
919      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
920      REAL(wp), DIMENSION(jpi,jpj)   ::   zsshu_n, zsshv_n
921      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zcpx, zcpy   !W/D pressure filter
922      !!----------------------------------------------------------------------
923      !
924      IF( kt == nit000 ) THEN
925         IF(lwp) WRITE(numout,*)
926         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
927         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
928      ENDIF
929
930      ! Local constant initialization
931      zcoef0 = - grav
932      znad = 1._wp
933      IF( ln_linssh )   znad = 0._wp
934
935      IF( ln_wd_il ) THEN
936         ALLOCATE( zcpx(jpi,jpj) , zcpy(jpi,jpj) )
937         DO jj = 2, jpjm1
938           DO ji = 2, jpim1 
939             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji+1,jj) ) >                &
940                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji+1,jj) ) .AND.            &
941                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji+1,jj) + ht_0(ji+1,jj) )  &
942                  &                                                      > rn_wdmin1 + rn_wdmin2
943             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji+1,jj) ) > 1.E-12 ) .AND. (         &
944                  &    MAX(   sshn(ji,jj)             ,  sshn(ji+1,jj) ) >                &
945                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
946
947             IF(ll_tmp1) THEN
948               zcpx(ji,jj) = 1.0_wp
949             ELSE IF(ll_tmp2) THEN
950               ! no worries about  sshn(ji+1,jj) -  sshn(ji  ,jj) = 0, it won't happen ! here
951               zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
952                           &    / (sshn(ji+1,jj) -  sshn(ji  ,jj)) )
953             
954                zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
955             ELSE
956               zcpx(ji,jj) = 0._wp
957             END IF
958     
959             ll_tmp1 = MIN(  sshn(ji,jj)              ,  sshn(ji,jj+1) ) >                &
960                  &    MAX( -ht_0(ji,jj)              , -ht_0(ji,jj+1) ) .AND.            &
961                  &    MAX(  sshn(ji,jj) + ht_0(ji,jj),  sshn(ji,jj+1) + ht_0(ji,jj+1) )  &
962                  &                                                      > rn_wdmin1 + rn_wdmin2
963             ll_tmp2 = ( ABS( sshn(ji,jj)             -  sshn(ji,jj+1) ) > 1.E-12 ) .AND. (      &
964                  &    MAX(   sshn(ji,jj)             ,  sshn(ji,jj+1) ) >                &
965                  &    MAX(  -ht_0(ji,jj)             , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
966
967             IF(ll_tmp1) THEN
968               zcpy(ji,jj) = 1.0_wp
969             ELSE IF(ll_tmp2) THEN
970               ! no worries about  sshn(ji,jj+1) -  sshn(ji,jj  ) = 0, it won't happen ! here
971               zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
972                           &    / (sshn(ji,jj+1) - sshn(ji,jj  )) )
973                zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
974
975               ELSE
976                  zcpy(ji,jj) = 0._wp
977               ENDIF
978            END DO
979         END DO
980         CALL lbc_lnk_multi( 'dynhpg', zcpx, 'U', 1., zcpy, 'V', 1. )
981      ENDIF
982
983      ! Clean 3-D work arrays
984      zhpi(:,:,:) = 0._wp
985      zrhh(:,:,:) = rhd(:,:,:)
986
987      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
988      DO jj = 1, jpj
989        DO ji = 1, jpi
990          jk = mbkt(ji,jj)+1
991          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
992          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
993          ELSEIF( jk < jpkm1 ) THEN
994             DO jkk = jk+1, jpk
995                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
996                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
997             END DO
998          ENDIF
999        END DO
1000      END DO
1001
1002      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1003      DO jj = 1, jpj
1004         DO ji = 1, jpi
1005            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1006         END DO
1007      END DO
1008
1009      DO jk = 2, jpk
1010         DO jj = 1, jpj
1011            DO ji = 1, jpi
1012               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1013            END DO
1014         END DO
1015      END DO
1016
1017      fsp(:,:,:) = zrhh (:,:,:)
1018      xsp(:,:,:) = zdept(:,:,:)
1019
1020      ! Construct the vertical density profile with the
1021      ! constrained cubic spline interpolation
1022      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1023      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1024
1025      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1026      DO jj = 2, jpj
1027        DO ji = 2, jpi
1028          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1029             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1030
1031          ! assuming linear profile across the top half surface layer
1032          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1033        END DO
1034      END DO
1035
1036      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1037      DO jk = 2, jpkm1
1038        DO jj = 2, jpj
1039          DO ji = 2, jpi
1040            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1041               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1042               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1043               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1044          END DO
1045        END DO
1046      END DO
1047
1048      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1049
1050      ! Prepare zsshu_n and zsshv_n
1051      DO jj = 2, jpjm1
1052        DO ji = 2, jpim1
1053!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1054!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1055!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1056!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1057!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1058!!gm not this:
1059          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1060                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1061          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1062                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1063        END DO
1064      END DO
1065
1066      CALL lbc_lnk_multi ('dynhpg', zsshu_n, 'U', 1., zsshv_n, 'V', 1. )
1067
1068      DO jj = 2, jpjm1
1069        DO ji = 2, jpim1
1070          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1071          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1072        END DO
1073      END DO
1074
1075      DO jk = 2, jpkm1
1076        DO jj = 2, jpjm1
1077          DO ji = 2, jpim1
1078            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1079            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1080          END DO
1081        END DO
1082      END DO
1083
1084      DO jk = 1, jpkm1
1085        DO jj = 2, jpjm1
1086          DO ji = 2, jpim1
1087            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1088            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1089          END DO
1090        END DO
1091      END DO
1092
1093      DO jk = 1, jpkm1
1094        DO jj = 2, jpjm1
1095          DO ji = 2, jpim1
1096            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1097            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1098            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1099            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1100          END DO
1101        END DO
1102      END DO
1103
1104
1105      DO jk = 1, jpkm1
1106        DO jj = 2, jpjm1
1107          DO ji = 2, jpim1
1108            zpwes = 0._wp; zpwed = 0._wp
1109            zpnss = 0._wp; zpnsd = 0._wp
1110            zuijk = zu(ji,jj,jk)
1111            zvijk = zv(ji,jj,jk)
1112
1113            !!!!!     for u equation
1114            IF( jk <= mbku(ji,jj) ) THEN
1115               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1116                 jis = ji + 1; jid = ji
1117               ELSE
1118                 jis = ji;     jid = ji +1
1119               ENDIF
1120
1121               ! integrate the pressure on the shallow side
1122               jk1 = jk
1123               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1124                 IF( jk1 == mbku(ji,jj) ) THEN
1125                   zuijk = -zdept(jis,jj,jk1)
1126                   EXIT
1127                 ENDIF
1128                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1129                 zpwes = zpwes +                                    &
1130                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1131                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1132                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1133                 jk1 = jk1 + 1
1134               END DO
1135
1136               ! integrate the pressure on the deep side
1137               jk1 = jk
1138               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1139                 IF( jk1 == 1 ) THEN
1140                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1141                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1142                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1143                                                     dsp(jid,jj,1)) * zdeps
1144                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1145                   EXIT
1146                 ENDIF
1147                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1148                 zpwed = zpwed +                                        &
1149                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1150                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1151                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1152                 jk1 = jk1 - 1
1153               END DO
1154
1155               ! update the momentum trends in u direction
1156
1157               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1158               IF( .NOT.ln_linssh ) THEN
1159                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1160                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1161                ELSE
1162                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1163               ENDIF
1164               IF( ln_wd_il ) THEN
1165                  zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1166                  zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1167               ENDIF
1168               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1169            ENDIF
1170
1171            !!!!!     for v equation
1172            IF( jk <= mbkv(ji,jj) ) THEN
1173               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1174                 jjs = jj + 1; jjd = jj
1175               ELSE
1176                 jjs = jj    ; jjd = jj + 1
1177               ENDIF
1178
1179               ! integrate the pressure on the shallow side
1180               jk1 = jk
1181               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1182                 IF( jk1 == mbkv(ji,jj) ) THEN
1183                   zvijk = -zdept(ji,jjs,jk1)
1184                   EXIT
1185                 ENDIF
1186                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1187                 zpnss = zpnss +                                      &
1188                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1189                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1190                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1191                 jk1 = jk1 + 1
1192               END DO
1193
1194               ! integrate the pressure on the deep side
1195               jk1 = jk
1196               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1197                 IF( jk1 == 1 ) THEN
1198                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1199                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1200                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1201                                                     dsp(ji,jjd,1) ) * zdeps
1202                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1203                   EXIT
1204                 ENDIF
1205                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1206                 zpnsd = zpnsd +                                        &
1207                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1208                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1209                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1210                 jk1 = jk1 - 1
1211               END DO
1212
1213
1214               ! update the momentum trends in v direction
1215
1216               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1217               IF( .NOT.ln_linssh ) THEN
1218                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1219                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1220               ELSE
1221                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1222               ENDIF
1223               IF( ln_wd_il ) THEN
1224                  zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj) 
1225                  zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj) 
1226               ENDIF
1227
1228               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1229            ENDIF
1230               !
1231            END DO
1232         END DO
1233      END DO
1234      !
1235      IF( ln_wd_il )   DEALLOCATE( zcpx, zcpy )
1236      !
1237   END SUBROUTINE hpg_prj
1238
1239
1240   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1241      !!----------------------------------------------------------------------
1242      !!                 ***  ROUTINE cspline  ***
1243      !!
1244      !! ** Purpose :   constrained cubic spline interpolation
1245      !!
1246      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1247      !!
1248      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1249      !!----------------------------------------------------------------------
1250      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1251      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1252      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1253      !
1254      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1255      INTEGER  ::   jpi, jpj, jpkm1
1256      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1257      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1258      REAL(wp) ::   zdf(size(fsp,3))
1259      !!----------------------------------------------------------------------
1260      !
1261!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1262      jpi   = size(fsp,1)
1263      jpj   = size(fsp,2)
1264      jpkm1 = MAX( 1, size(fsp,3) - 1 )
1265      !
1266      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1267         DO ji = 1, jpi
1268            DO jj = 1, jpj
1269           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1270           !    DO jk = 2, jpkm1-1
1271           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1272           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1273           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1274           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1275           !
1276           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1277           !
1278           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1279           !           zdf(jk) = 0._wp
1280           !       ELSE
1281           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1282           !       ENDIF
1283           !    END DO
1284
1285           !!Simply geometric average
1286               DO jk = 2, jpkm1-1
1287                  zdf1 = (fsp(ji,jj,jk  ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk  ) - xsp(ji,jj,jk-1))
1288                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk  )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk  ))
1289
1290                  IF(zdf1 * zdf2 <= 0._wp) THEN
1291                     zdf(jk) = 0._wp
1292                  ELSE
1293                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1294                  ENDIF
1295               END DO
1296
1297               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1298                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1299               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1300                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1301
1302               DO jk = 1, jpkm1 - 1
1303                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1304                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1305                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1306                 zddf1  = -2._wp * ztmp1 + ztmp2
1307                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1308                 zddf2  =  2._wp * ztmp1 - ztmp2
1309
1310                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1311                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1312                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1313                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1314                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1315                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1316                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1317                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1318                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1319               END DO
1320            END DO
1321         END DO
1322
1323      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1324         DO ji = 1, jpi
1325            DO jj = 1, jpj
1326               DO jk = 1, jpkm1-1
1327                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1328                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1329
1330                  dsp(ji,jj,jk) = 0._wp
1331                  csp(ji,jj,jk) = 0._wp
1332                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1333                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1334               END DO
1335            END DO
1336         END DO
1337         !
1338      ELSE
1339         CALL ctl_stop( 'invalid polynomial type in cspline' )
1340      ENDIF
1341      !
1342   END SUBROUTINE cspline
1343
1344
1345   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1346      !!----------------------------------------------------------------------
1347      !!                 ***  ROUTINE interp1  ***
1348      !!
1349      !! ** Purpose :   1-d linear interpolation
1350      !!
1351      !! ** Method  :   interpolation is straight forward
1352      !!                extrapolation is also permitted (no value limit)
1353      !!----------------------------------------------------------------------
1354      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1355      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1356      REAL(wp)             ::  zdeltx
1357      !!----------------------------------------------------------------------
1358      !
1359      zdeltx = xr - xl
1360      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1361         f = 0.5_wp * (fl + fr)
1362      ELSE
1363         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1364      ENDIF
1365      !
1366   END FUNCTION interp1
1367
1368
1369   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1370      !!----------------------------------------------------------------------
1371      !!                 ***  ROUTINE interp1  ***
1372      !!
1373      !! ** Purpose :   1-d constrained cubic spline interpolation
1374      !!
1375      !! ** Method  :  cubic spline interpolation
1376      !!
1377      !!----------------------------------------------------------------------
1378      REAL(wp), INTENT(in) ::  x, a, b, c, d
1379      REAL(wp)             ::  f ! value from the interpolation
1380      !!----------------------------------------------------------------------
1381      !
1382      f = a + x* ( b + x * ( c + d * x ) )
1383      !
1384   END FUNCTION interp2
1385
1386
1387   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1388      !!----------------------------------------------------------------------
1389      !!                 ***  ROUTINE interp1  ***
1390      !!
1391      !! ** Purpose :   Calculate the first order of derivative of
1392      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1393      !!
1394      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1395      !!
1396      !!----------------------------------------------------------------------
1397      REAL(wp), INTENT(in) ::  x, a, b, c, d
1398      REAL(wp)             ::  f ! value from the interpolation
1399      !!----------------------------------------------------------------------
1400      !
1401      f = b + x * ( 2._wp * c + 3._wp * d * x)
1402      !
1403   END FUNCTION interp3
1404
1405
1406   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1407      !!----------------------------------------------------------------------
1408      !!                 ***  ROUTINE interp1  ***
1409      !!
1410      !! ** Purpose :   1-d constrained cubic spline integration
1411      !!
1412      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1413      !!
1414      !!----------------------------------------------------------------------
1415      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1416      REAL(wp)             ::  za1, za2, za3
1417      REAL(wp)             ::  f                   ! integration result
1418      !!----------------------------------------------------------------------
1419      !
1420      za1 = 0.5_wp * b
1421      za2 = c / 3.0_wp
1422      za3 = 0.25_wp * d
1423      !
1424      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1425         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1426      !
1427   END FUNCTION integ_spline
1428
1429   !!======================================================================
1430END MODULE dynhpg
1431
Note: See TracBrowser for help on using the repository browser.