New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in NEMO/branches/2019/ENHANCE-02_ISF_nemo_TEST_MERGE/src/OCE/SBC – NEMO

source: NEMO/branches/2019/ENHANCE-02_ISF_nemo_TEST_MERGE/src/OCE/SBC/sbcmod.F90 @ 11970

Last change on this file since 11970 was 11970, checked in by davestorkey, 4 years ago

2019/ENHANCE-02_ISF_nemo_TEST_MERGE : copy changes from Pierre's branch.

  • Property svn:keywords set to Id
File size: 33.6 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   sbc_init      : read namsbc namelist
21   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
22   !!   sbc_final     : Finalize CICE ice model (if used)
23   !!----------------------------------------------------------------------
24   USE oce            ! ocean dynamics and tracers
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE trc_oce        ! shared ocean-passive tracers variables
29   USE sbc_ice        ! Surface boundary condition: ice fields
30   USE sbcdcy         ! surface boundary condition: diurnal cycle
31   USE sbcssm         ! surface boundary condition: sea-surface mean variables
32   USE sbcflx         ! surface boundary condition: flux formulation
33   USE sbcblk         ! surface boundary condition: bulk formulation
34   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
35#if defined key_si3
36   USE icestp         ! surface boundary condition: SI3 sea-ice model
37#endif
38   USE sbcice_cice    ! surface boundary condition: CICE sea-ice model
39   USE sbccpl         ! surface boundary condition: coupled formulation
40   USE cpl_oasis3     ! OASIS routines for coupling
41   USE sbcssr         ! surface boundary condition: sea surface restoring
42   USE sbcrnf         ! surface boundary condition: runoffs
43   USE sbcapr         ! surface boundary condition: atmo pressure
44   USE sbcfwb         ! surface boundary condition: freshwater budget
45   USE icbstp         ! Icebergs
46   USE icb_oce  , ONLY : ln_passive_mode      ! iceberg interaction mode
47   USE traqsr         ! active tracers: light penetration
48   USE sbcwave        ! Wave module
49   USE bdy_oce   , ONLY: ln_bdy
50   USE usrdef_sbc     ! user defined: surface boundary condition
51   USE closea         ! closed sea
52   !
53   USE prtctl         ! Print control                    (prt_ctl routine)
54   USE iom            ! IOM library
55   USE in_out_manager ! I/O manager
56   USE lib_mpp        ! MPP library
57   USE timing         ! Timing
58   USE wet_dry
59   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
60
61   IMPLICIT NONE
62   PRIVATE
63
64   PUBLIC   sbc        ! routine called by step.F90
65   PUBLIC   sbc_init   ! routine called by opa.F90
66
67   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
68
69   !!----------------------------------------------------------------------
70   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
71   !! $Id$
72   !! Software governed by the CeCILL license (see ./LICENSE)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE sbc_init
77      !!---------------------------------------------------------------------
78      !!                    ***  ROUTINE sbc_init ***
79      !!
80      !! ** Purpose :   Initialisation of the ocean surface boundary computation
81      !!
82      !! ** Method  :   Read the namsbc namelist and set derived parameters
83      !!                Call init routines for all other SBC modules that have one
84      !!
85      !! ** Action  : - read namsbc parameters
86      !!              - nsbc: type of sbc
87      !!----------------------------------------------------------------------
88      INTEGER ::   ios, icpt                         ! local integer
89      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
90      !!
91      NAMELIST/namsbc/ nn_fsbc  ,                                                  &
92         &             ln_usr   , ln_flx     , ln_blk       ,                      &
93         &             ln_cpl   , ln_mixcpl  , nn_components,                      &
94         &             nn_ice   , ln_ice_embd,                                     &
95         &             ln_traqsr, ln_dm2dc   ,                                     &
96         &             ln_rnf   , nn_fwb     , ln_ssr   , ln_apr_dyn,              &
97         &             ln_wave  , ln_cdgw    , ln_sdw   , ln_tauwoc , ln_stcor,    &
98         &             ln_tauw  , nn_lsm     , nn_sdrift
99      !!----------------------------------------------------------------------
100      !
101      IF(lwp) THEN
102         WRITE(numout,*)
103         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
104         WRITE(numout,*) '~~~~~~~~ '
105      ENDIF
106      !
107      !                       !**  read Surface Module namelist
108      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
109      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
110901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
111      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
112      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
113902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
114      IF(lwm) WRITE( numond, namsbc )
115      !
116#if defined key_mpp_mpi
117      ncom_fsbc = nn_fsbc    ! make nn_fsbc available for lib_mpp
118#endif
119      !                             !* overwrite namelist parameter using CPP key information
120#if defined key_agrif
121      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
122         IF( lk_si3  )   nn_ice      = 2
123         IF( lk_cice )   nn_ice      = 3
124      ENDIF
125#else
126      IF( lk_si3  )   nn_ice      = 2
127      IF( lk_cice )   nn_ice      = 3
128#endif
129      !
130      IF(lwp) THEN                  !* Control print
131         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
132         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
133         WRITE(numout,*) '      Type of air-sea fluxes : '
134         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
135         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
136         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
137         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
138         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
139         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
140!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
141         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
142         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
143         WRITE(numout,*) '      Sea-ice : '
144         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
145         WRITE(numout,*) '         ice embedded into ocean                    ln_ice_embd   = ', ln_ice_embd
146         WRITE(numout,*) '      Misc. options of sbc : '
147         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
148         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
149         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
150         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
151         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
152         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
153         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
154         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
155         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
156         WRITE(numout,*) '                  vertical parametrization          nn_sdrift     = ', nn_sdrift
157         WRITE(numout,*) '               wave modified ocean stress           ln_tauwoc     = ', ln_tauwoc
158         WRITE(numout,*) '               wave modified ocean stress component ln_tauw       = ', ln_tauw
159         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
160         WRITE(numout,*) '               neutral drag coefficient (CORE,NCAR) ln_cdgw       = ', ln_cdgw
161      ENDIF
162      !
163      IF( .NOT.ln_wave ) THEN
164         ln_sdw = .false. ; ln_cdgw = .false. ; ln_tauwoc = .false. ; ln_tauw = .false. ; ln_stcor = .false.
165      ENDIF
166      IF( ln_sdw ) THEN
167         IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) &
168            CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' )
169      ENDIF
170      ll_st_bv2014  = ( nn_sdrift==jp_breivik_2014 )
171      ll_st_li2017  = ( nn_sdrift==jp_li_2017 )
172      ll_st_bv_li   = ( ll_st_bv2014 .OR. ll_st_li2017 )
173      ll_st_peakfr  = ( nn_sdrift==jp_peakfr )
174      IF( ln_tauwoc .AND. ln_tauw ) &
175         CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', &
176                                  '(ln_tauwoc=.true. and ln_tauw=.true.)' )
177      IF( ln_tauwoc ) &
178         CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' )
179      IF( ln_tauw ) &
180         CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', &
181                              'This will override any other specification of the ocean stress' )
182      !
183      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
184         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
185         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
186         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
187      ENDIF
188      !                       !**  check option consistency
189      !
190      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
191      SELECT CASE( nn_components )
192      CASE( jp_iam_nemo )
193         IF(lwp) WRITE(numout,*) '   ==>>>   NEMO configured as a single executable (i.e. including both OPA and Surface module)'
194      CASE( jp_iam_opa  )
195         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, OPA component'
196         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
197         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
198         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
199      CASE( jp_iam_sas  )
200         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, SAS component'
201         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
202         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
203      CASE DEFAULT
204         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
205      END SELECT
206      !                             !* coupled options
207      IF( ln_cpl ) THEN
208         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
209            &                                  '           required to defined key_oasis3' )
210      ENDIF
211      IF( ln_mixcpl ) THEN
212         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
213            &                                  '           required to defined key_oasis3' )
214         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
215         IF( nn_components /= jp_iam_nemo )    &
216            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
217            &                                   '          not yet working with sas-opa coupling via oasis' )
218      ENDIF
219      !                             !* sea-ice
220      SELECT CASE( nn_ice )
221      CASE( 0 )                        !- no ice in the domain
222      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
223      CASE( 2 )                        !- SI3  ice model
224      CASE( 3 )                        !- CICE ice model
225         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' )
226         IF( lk_agrif                    )   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
227      CASE DEFAULT                     !- not supported
228      END SELECT
229      !
230      !                       !**  allocate and set required variables
231      !
232      !                             !* allocate sbc arrays
233      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
234#if ! defined key_si3 && ! defined key_cice
235      IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' )
236#endif
237      !
238      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
239         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
240      ENDIF
241      !
242      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
243      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
244
245      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
246
247      !                          ! Choice of the Surface Boudary Condition (set nsbc)
248      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
249         nday_qsr = -1   ! allow initialization at the 1st call
250         IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa )   &
251            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' )
252      ENDIF
253      !                             !* Choice of the Surface Boudary Condition
254      !                             (set nsbc)
255      !
256      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
257      ll_opa      = nn_components == jp_iam_opa
258      ll_not_nemo = nn_components /= jp_iam_nemo
259      icpt = 0
260      !
261      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
262      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
263      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
264      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
265      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
266      !
267      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
268      !
269      IF(lwp) THEN                     !- print the choice of surface flux formulation
270         WRITE(numout,*)
271         SELECT CASE( nsbc )
272         CASE( jp_usr     )   ;   WRITE(numout,*) '   ==>>>   user defined forcing formulation'
273         CASE( jp_flx     )   ;   WRITE(numout,*) '   ==>>>   flux formulation'
274         CASE( jp_blk     )   ;   WRITE(numout,*) '   ==>>>   bulk formulation'
275         CASE( jp_purecpl )   ;   WRITE(numout,*) '   ==>>>   pure coupled formulation'
276!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
277         CASE( jp_none    )   ;   WRITE(numout,*) '   ==>>>   OPA coupled to SAS via oasis'
278            IF( ln_mixcpl )       WRITE(numout,*) '               + forced-coupled mixed formulation'
279         END SELECT
280         IF( ll_not_nemo  )       WRITE(numout,*) '               + OASIS coupled SAS'
281      ENDIF
282      !
283      !                             !* OASIS initialization
284      !
285      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
286      !                                              !                      (2) the use of nn_fsbc
287      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
288      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
289      IF( nn_components /= jp_iam_nemo ) THEN
290         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
291         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
292         !
293         IF(lwp)THEN
294            WRITE(numout,*)
295            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
296            WRITE(numout,*)
297         ENDIF
298      ENDIF
299      !
300      !                             !* check consistency between model timeline and nn_fsbc
301      IF( ln_rst_list .OR. nn_stock /= -1 ) THEN   ! we will do restart files
302         IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 ) THEN
303            WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
304            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
305         ENDIF
306         IF( .NOT. ln_rst_list .AND. MOD( nn_stock, nn_fsbc) /= 0 ) THEN   ! we don't use nn_stock if ln_rst_list
307            WRITE(ctmp1,*) 'sbc_init : nn_stock (', nn_stock, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
308            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
309         ENDIF
310      ENDIF
311      !
312      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
313         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
314      !
315      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
316         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
317      !
318   
319      !                       !**  associated modules : initialization
320      !
321                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
322      !
323      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
324
325      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
326      !
327                          CALL sbc_rnf_init            ! Runof initialization
328      !
329      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
330      !
331#if defined key_si3
332      IF( lk_agrif .AND. nn_ice == 0 ) THEN            ! allocate ice arrays in case agrif + ice-model + no-ice in child grid
333                          IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' )
334      ELSEIF( nn_ice == 2 ) THEN
335                          CALL ice_init                ! ICE initialization
336      ENDIF
337#endif
338      IF( nn_ice == 3 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
339      !
340      IF( ln_wave     )   CALL sbc_wave_init           ! surface wave initialisation
341      !
342      IF( lwxios ) THEN
343         CALL iom_set_rstw_var_active('utau_b')
344         CALL iom_set_rstw_var_active('vtau_b')
345         CALL iom_set_rstw_var_active('qns_b')
346         ! The 3D heat content due to qsr forcing is treated in traqsr
347         ! CALL iom_set_rstw_var_active('qsr_b')
348         CALL iom_set_rstw_var_active('emp_b')
349         CALL iom_set_rstw_var_active('sfx_b')
350      ENDIF
351
352   END SUBROUTINE sbc_init
353
354
355   SUBROUTINE sbc( kt )
356      !!---------------------------------------------------------------------
357      !!                    ***  ROUTINE sbc  ***
358      !!
359      !! ** Purpose :   provide at each time-step the ocean surface boundary
360      !!                condition (momentum, heat and freshwater fluxes)
361      !!
362      !! ** Method  :   blah blah  to be written ?????????
363      !!                CAUTION : never mask the surface stress field (tke sbc)
364      !!
365      !! ** Action  : - set the ocean surface boundary condition at before and now
366      !!                time step, i.e.
367      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
368      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
369      !!              - updte the ice fraction : fr_i
370      !!----------------------------------------------------------------------
371      INTEGER, INTENT(in) ::   kt   ! ocean time step
372      !
373      LOGICAL ::   ll_sas, ll_opa   ! local logical
374      !
375      REAL(wp) ::     zthscl        ! wd  tanh scale
376      REAL(wp), DIMENSION(jpi,jpj) ::  zwdht, zwght  ! wd dep over wd limit, wgt 
377
378      !!---------------------------------------------------------------------
379      !
380      IF( ln_timing )   CALL timing_start('sbc')
381      !
382      !                                            ! ---------------------------------------- !
383      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
384         !                                         ! ---------------------------------------- !
385         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
386         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
387         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
388         emp_b (:,:) = emp (:,:)
389         sfx_b (:,:) = sfx (:,:)
390         IF ( ln_rnf ) THEN
391            rnf_b    (:,:  ) = rnf    (:,:  )
392            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
393         ENDIF
394        !
395      ENDIF
396      !                                            ! ---------------------------------------- !
397      !                                            !        forcing field computation         !
398      !                                            ! ---------------------------------------- !
399      !
400      ll_sas = nn_components == jp_iam_sas               ! component flags
401      ll_opa = nn_components == jp_iam_opa
402      !
403      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
404      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
405
406      !
407      !                                            !==  sbc formulation  ==!
408      !                                                   
409      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
410      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
411      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
412      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
413      CASE( jp_blk     )
414         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
415                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
416                               !
417      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
418      CASE( jp_none    )
419         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
420      END SELECT
421      !
422      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
423      !
424      IF ( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( )      ! Wind stress provided by waves
425      !
426      !                                            !==  Misc. Options  ==!
427      !
428      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
429      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )             ! Ice-cover climatology ("Ice-if" model)
430#if defined key_si3
431      CASE(  2 )   ;         CALL ice_stp  ( kt, nsbc )           ! SI3 ice model
432#endif
433      CASE(  3 )   ;         CALL sbc_ice_cice ( kt, nsbc )       ! CICE ice model
434      END SELECT
435
436      IF( ln_icebergs    )   THEN
437                                     CALL icb_stp( kt )           ! compute icebergs
438         ! icebergs may advect into haloes during the icb step and alter emp.
439         ! A lbc_lnk is necessary here to ensure restartability (#2113)
440         IF( .NOT. ln_passive_mode ) CALL lbc_lnk( 'sbcmod', emp, 'T', 1. ) ! ensure restartability with icebergs
441      ENDIF
442
443      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
444
445      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
446
447      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
448
449      ! Special treatment of freshwater fluxes over closed seas in the model domain
450      ! Should not be run if ln_diurnal_only
451      IF( l_sbc_clo .AND. (.NOT. ln_diurnal_only) )   CALL sbc_clo( kt )   
452
453!!$!RBbug do not understand why see ticket 667
454!!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
455!!$      CALL lbc_lnk( 'sbcmod', emp, 'T', 1. )
456      IF ( ll_wd ) THEN     ! If near WAD point limit the flux for now
457         zthscl = atanh(rn_wd_sbcfra)                     ! taper frac default is .999
458         zwdht(:,:) = sshn(:,:) + ht_0(:,:) - rn_wdmin1   ! do this calc of water
459                                                     ! depth above wd limit once
460         WHERE( zwdht(:,:) <= 0.0 )
461            taum(:,:) = 0.0
462            utau(:,:) = 0.0
463            vtau(:,:) = 0.0
464            qns (:,:) = 0.0
465            qsr (:,:) = 0.0
466            emp (:,:) = min(emp(:,:),0.0) !can allow puddles to grow but not shrink
467            sfx (:,:) = 0.0
468         END WHERE
469         zwght(:,:) = tanh(zthscl*zwdht(:,:))
470         WHERE( zwdht(:,:) > 0.0  .and. zwdht(:,:) < rn_wd_sbcdep ) !  5 m hard limit here is arbitrary
471            qsr  (:,:) =  qsr(:,:)  * zwght(:,:)
472            qns  (:,:) =  qns(:,:)  * zwght(:,:)
473            taum (:,:) =  taum(:,:) * zwght(:,:)
474            utau (:,:) =  utau(:,:) * zwght(:,:)
475            vtau (:,:) =  vtau(:,:) * zwght(:,:)
476            sfx  (:,:) =  sfx(:,:)  * zwght(:,:)
477            emp  (:,:) =  emp(:,:)  * zwght(:,:)
478         END WHERE
479      ENDIF
480      !
481      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
482         !                                             ! ---------------------------------------- !
483         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
484            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
485            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
486            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, ldxios = lrxios )   ! before i-stress  (U-point)
487            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, ldxios = lrxios )   ! before j-stress  (V-point)
488            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b, ldxios = lrxios  )   ! before non solar heat flux (T-point)
489            ! The 3D heat content due to qsr forcing is treated in traqsr
490            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, ldxios = lrxios  ) ! before     solar heat flux (T-point)
491            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, ldxios = lrxios  )    ! before     freshwater flux (T-point)
492            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
493            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
494               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, ldxios = lrxios )  ! before salt flux (T-point)
495            ELSE
496               sfx_b (:,:) = sfx(:,:)
497            ENDIF
498         ELSE                                                   !* no restart: set from nit000 values
499            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
500            utau_b(:,:) = utau(:,:)
501            vtau_b(:,:) = vtau(:,:)
502            qns_b (:,:) = qns (:,:)
503            emp_b (:,:) = emp (:,:)
504            sfx_b (:,:) = sfx (:,:)
505         ENDIF
506      ENDIF
507      !                                                ! ---------------------------------------- !
508      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
509         !                                             ! ---------------------------------------- !
510         IF(lwp) WRITE(numout,*)
511         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
512            &                    'at it= ', kt,' date= ', ndastp
513         IF(lwp) WRITE(numout,*) '~~~~'
514         IF( lwxios ) CALL iom_swap(      cwxios_context          )
515         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios )
516         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios )
517         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns, ldxios = lwxios  )
518         ! The 3D heat content due to qsr forcing is treated in traqsr
519         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
520         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp, ldxios = lwxios  )
521         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx, ldxios = lwxios  )
522         IF( lwxios ) CALL iom_swap(      cxios_context          )
523      ENDIF
524      !                                                ! ---------------------------------------- !
525      !                                                !        Outputs and control print         !
526      !                                                ! ---------------------------------------- !
527      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
528         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
529         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
530         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
531         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
532         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
533         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
534         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
535         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
536         CALL iom_put( "taum"  , taum       )                   ! wind stress module
537         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
538      ENDIF
539      !
540      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
541      CALL iom_put( "vtau", vtau )   ! j-wind stress
542      !
543      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
544         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i     - : ', mask1=tmask )
545         CALL prt_ctl(tab2d_1=(emp-rnf)        , clinfo1=' emp-rnf  - : ', mask1=tmask )
546         CALL prt_ctl(tab2d_1=(sfx-rnf)        , clinfo1=' sfx-rnf  - : ', mask1=tmask )
547         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask )
548         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask )
549         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, kdim=jpk )
550         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, kdim=1   )
551         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, kdim=1   )
552         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
553            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask )
554      ENDIF
555
556      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
557      !
558      IF( ln_timing )   CALL timing_stop('sbc')
559      !
560   END SUBROUTINE sbc
561
562
563   SUBROUTINE sbc_final
564      !!---------------------------------------------------------------------
565      !!                    ***  ROUTINE sbc_final  ***
566      !!
567      !! ** Purpose :   Finalize CICE (if used)
568      !!---------------------------------------------------------------------
569      !
570      IF( nn_ice == 3 )   CALL cice_sbc_final
571      !
572   END SUBROUTINE sbc_final
573
574   !!======================================================================
575END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.