New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dommsk.F90 in NEMO/branches/2019/ENHANCE-03_domcfg/src – NEMO

source: NEMO/branches/2019/ENHANCE-03_domcfg/src/dommsk.F90 @ 11602

Last change on this file since 11602 was 11201, checked in by mathiot, 5 years ago

ENHANCE-03_domcfg : add management of closed seas in domain cfg by flood filling and lat/lon seed instead of i/j box definition (ticket #2143)

File size: 14.4 KB
Line 
1MODULE dommsk
2   !!======================================================================
3   !!                       ***  MODULE dommsk   ***
4   !! Ocean initialization : domain land/sea mask
5   !!======================================================================
6   !! History :  OPA  ! 1987-07  (G. Madec)  Original code
7   !!            6.0  ! 1993-03  (M. Guyon)  symetrical conditions (M. Guyon)
8   !!            7.0  ! 1996-01  (G. Madec)  suppression of common work arrays
9   !!             -   ! 1996-05  (G. Madec)  mask computed from tmask
10   !!            8.0  ! 1997-02  (G. Madec)  mesh information put in domhgr.F
11   !!            8.1  ! 1997-07  (G. Madec)  modification of kbat and fmask
12   !!             -   ! 1998-05  (G. Roullet)  free surface
13   !!            8.2  ! 2000-03  (G. Madec)  no slip accurate
14   !!             -   ! 2001-09  (J.-M. Molines)  Open boundaries
15   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and module
16   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
17   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
18   !!            3.6  ! 2015-05  (P. Mathiot) ISF: add wmask,wumask and wvmask
19   !!            4.0  ! 2016-06  (G. Madec, S. Flavoni)  domain configuration / user defined interface
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   dom_msk       : compute land/ocean mask
24   !!----------------------------------------------------------------------
25   USE dom_oce        ! ocean space and time domain
26   USE domwri         ! domain: write the meshmask file
27   USE bdy_oce        ! open boundary
28   !
29   USE in_out_manager ! I/O manager
30   USE iom            ! IOM library
31   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
32   USE lib_mpp        ! Massively Parallel Processing library
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   dom_msk    ! routine called by inidom.F90
38
39   !                            !!* Namelist namlbc : lateral boundary condition *
40   REAL(wp)        :: rn_shlat   ! type of lateral boundary condition on velocity
41   LOGICAL, PUBLIC :: ln_vorlat  !  consistency of vorticity boundary condition
42   !                                            with analytical eqs.
43
44   !! * Substitutions
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
48   !! $Id: dommsk.F90 10425 2018-12-19 21:54:16Z smasson $
49   !! Software governed by the CeCILL license (see ./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE dom_msk
54      !!---------------------------------------------------------------------
55      !!                 ***  ROUTINE dom_msk  ***
56      !!
57      !! ** Purpose :   Compute land/ocean mask arrays at tracer points, hori-
58      !!      zontal velocity points (u & v), vorticity points (f) points.
59      !!
60      !! ** Method  :   The ocean/land mask  at t-point is deduced from ko_top
61      !!      and ko_bot, the indices of the fist and last ocean t-levels which
62      !!      are either defined in usrdef_zgr or read in zgr_read.
63      !!                The velocity masks (umask, vmask)
64      !!      are deduced from a product of the two neighboring tmask.
65      !!                The vorticity mask (fmask) is deduced from tmask taking
66      !!      into account the choice of lateral boundary condition (rn_shlat) :
67      !!         rn_shlat = 0, free slip  (no shear along the coast)
68      !!         rn_shlat = 2, no slip  (specified zero velocity at the coast)
69      !!         0 < rn_shlat < 2, partial slip   | non-linear velocity profile
70      !!         2 < rn_shlat, strong slip        | in the lateral boundary layer
71      !!
72      !!      tmask_i : interior ocean mask at t-point, i.e. excluding duplicated
73      !!                rows/lines due to cyclic or North Fold boundaries as well
74      !!                as MPP halos.
75      !!      tmask_h : halo mask at t-point, i.e. excluding duplicated rows/lines
76      !!                due to cyclic or North Fold boundaries as well as MPP halos.
77      !!
78      !! ** Action :   tmask, umask, vmask, wmask : land/ocean mask
79      !!                         at t-, u-, v- w, wu-, and wv-points (=0. or 1.)
80      !!               fmask   : land/ocean mask at f-point (=0., or =1., or
81      !!                         =rn_shlat along lateral boundaries)
82      !!               tmask_i : interior ocean mask
83      !!               tmask_h : halo mask
84      !!               ssmask , ssumask, ssvmask, ssfmask : 2D ocean mask
85      !!----------------------------------------------------------------------
86      !
87      INTEGER  ::   ji, jj, jk     ! dummy loop indices
88      INTEGER  ::   iif, iil       ! local integers
89      INTEGER  ::   ijf, ijl       !   -       -
90      INTEGER  ::   iktop, ikbot   !   -       -
91      INTEGER  ::   ios, inum
92      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zwf   ! 2D workspace
93      !!
94      NAMELIST/namlbc/ rn_shlat, ln_vorlat
95      NAMELIST/nambdy/ ln_bdy ,nb_bdy, ln_coords_file, cn_coords_file,         &
96         &             ln_mask_file, cn_mask_file, cn_dyn2d, nn_dyn2d_dta,     &
97         &             cn_dyn3d, nn_dyn3d_dta, cn_tra, nn_tra_dta,             &
98         &             ln_tra_dmp, ln_dyn3d_dmp, rn_time_dmp, rn_time_dmp_out, &
99         &             cn_ice, nn_ice_dta,                                     &
100         &             rn_ice_tem, rn_ice_sal, rn_ice_age,                     &
101         &             ln_vol, nn_volctl, nn_rimwidth, nb_jpk_bdy
102      !!---------------------------------------------------------------------
103      !
104      REWIND( numnam_ref )              ! Namelist namlbc in reference namelist : Lateral momentum boundary condition
105      READ  ( numnam_ref, namlbc, IOSTAT = ios, ERR = 901 )
106901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namlbc in reference namelist', lwp )
107      REWIND( numnam_cfg )              ! Namelist namlbc in configuration namelist : Lateral momentum boundary condition
108      READ  ( numnam_cfg, namlbc, IOSTAT = ios, ERR = 902 )
109902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namlbc in configuration namelist', lwp )
110      IF(lwm) WRITE ( numond, namlbc )
111     
112      IF(lwp) THEN                  ! control print
113         WRITE(numout,*)
114         WRITE(numout,*) 'dommsk : ocean mask '
115         WRITE(numout,*) '~~~~~~'
116         WRITE(numout,*) '   Namelist namlbc'
117         WRITE(numout,*) '      lateral momentum boundary cond.    rn_shlat  = ',rn_shlat
118         WRITE(numout,*) '      consistency with analytical form   ln_vorlat = ',ln_vorlat 
119      ENDIF
120      !
121      IF(lwp) WRITE(numout,*)
122      IF     (      rn_shlat == 0.               ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  free-slip'
123      ELSEIF (      rn_shlat == 2.               ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  no-slip'
124      ELSEIF ( 0. < rn_shlat .AND. rn_shlat < 2. ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  partial-slip'
125      ELSEIF ( 2. < rn_shlat                     ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  strong-slip'
126      ELSE
127         CALL ctl_stop( 'dom_msk: wrong value for rn_shlat (i.e. a negalive value). We stop.' )
128      ENDIF
129
130     ! 1. Ocean/land mask at t-point (computed from mbathy)
131     ! -----------------------------
132     ! N.B. tmask has already the right boundary conditions since mbathy is ok
133     !
134      tmask(:,:,:) = 0._wp
135      DO jk = 1, jpk
136         DO jj = 1, jpj
137            DO ji = 1, jpi
138               IF(      ( REAL( mbathy (ji,jj) - jk, wp ) + 0.1_wp >= 0._wp )         &
139               &  .AND. ( REAL( misfdep(ji,jj) - jk, wp ) - 0.1_wp <= 0._wp ) ) THEN
140                  tmask(ji,jj,jk) = 1._wp
141               END IF 
142            END DO
143         END DO
144      END DO
145     
146!SF  add here lbc_lnk: bug not still understood : cause now domain configuration is read !
147!!gm I don't understand why... 
148      CALL lbc_lnk( 'dommsk', tmask  , 'T', 1._wp )      ! Lateral boundary conditions
149
150     ! Mask corrections for bdy (read in mppini2)
151      REWIND( numnam_ref )              ! Namelist nambdy in reference namelist :Unstructured open boundaries
152      READ  ( numnam_ref, nambdy, IOSTAT = ios, ERR = 903)
153903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy in reference namelist', lwp )
154      REWIND( numnam_cfg )              ! Namelist nambdy in configuration namelist :Unstructured open boundaries
155      READ  ( numnam_cfg, nambdy, IOSTAT = ios, ERR = 904 )
156904   IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy in configuration namelist', lwp )
157      ! ------------------------
158      IF ( ln_bdy .AND. ln_mask_file ) THEN
159         CALL iom_open( cn_mask_file, inum )
160         CALL iom_get ( inum, jpdom_data, 'bdy_msk', bdytmask(:,:) )
161         CALL iom_close( inum )
162         DO jk = 1, jpkm1
163            DO jj = 1, jpj
164               DO ji = 1, jpi
165                  tmask(ji,jj,jk) = tmask(ji,jj,jk) * bdytmask(ji,jj)
166               END DO
167            END DO
168         END DO
169      ENDIF
170         
171      !  Ocean/land mask at u-, v-, and f-points   (computed from tmask)
172      ! ----------------------------------------
173      ! NB: at this point, fmask is designed for free slip lateral boundary condition
174      DO jk = 1, jpk
175         DO jj = 1, jpjm1
176            DO ji = 1, fs_jpim1   ! vector loop
177               umask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji+1,jj  ,jk)
178               vmask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji  ,jj+1,jk)
179            END DO
180            DO ji = 1, jpim1      ! NO vector opt.
181               fmask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji+1,jj  ,jk)   &
182                  &            * tmask(ji,jj+1,jk) * tmask(ji+1,jj+1,jk)
183            END DO
184         END DO
185      END DO
186      CALL lbc_lnk_multi( 'dommsk', umask, 'U', 1., vmask, 'V', 1., fmask, 'F', 1. )      ! Lateral boundary conditions
187 
188      ! Ocean/land mask at wu-, wv- and w points    (computed from tmask)
189      !-----------------------------------------
190      wmask (:,:,1) = tmask(:,:,1)     ! surface
191      DO jk = 2, jpk                   ! interior values
192         wmask (:,:,jk) = tmask(:,:,jk) * tmask(:,:,jk-1)
193      END DO
194
195
196      ! Ocean/land column mask at t-, u-, and v-points   (i.e. at least 1 wet cell in the vertical)
197      ! ----------------------------------------------
198      ssmask (:,:) = MAXVAL( tmask(:,:,:), DIM=3 )
199      ssumask(:,:) = MAXVAL( umask(:,:,:), DIM=3 )
200      ssvmask(:,:) = MAXVAL( vmask(:,:,:), DIM=3 )
201
202      ! Interior domain mask  (used for global sum)
203      ! --------------------
204      !
205      iif = nn_hls   ;   iil = nlci - nn_hls + 1
206      ijf = nn_hls   ;   ijl = nlcj - nn_hls + 1
207      !
208      !                          ! halo mask : 0 on the halo and 1 elsewhere
209      tmask_h(:,:) = 1._wp                 
210      tmask_h( 1 :iif,   :   ) = 0._wp      ! first columns
211      tmask_h(iil:jpi,   :   ) = 0._wp      ! last  columns (including mpp extra columns)
212      tmask_h(   :   , 1 :ijf) = 0._wp      ! first rows
213      tmask_h(   :   ,ijl:jpj) = 0._wp      ! last  rows (including mpp extra rows)
214      !
215      !                          ! north fold mask
216      tpol(1:jpiglo) = 1._wp 
217      fpol(1:jpiglo) = 1._wp
218      IF( jperio == 3 .OR. jperio == 4 ) THEN      ! T-point pivot
219         tpol(jpiglo/2+1:jpiglo) = 0._wp
220         fpol(     1    :jpiglo) = 0._wp
221         IF( mjg(nlej) == jpjglo ) THEN                  ! only half of the nlcj-1 row for tmask_h
222            DO ji = iif+1, iil-1
223               tmask_h(ji,nlej-1) = tmask_h(ji,nlej-1) * tpol(mig(ji))
224            END DO
225         ENDIF
226      ENDIF
227      !
228      IF( jperio == 5 .OR. jperio == 6 ) THEN      ! F-point pivot
229         tpol(     1    :jpiglo) = 0._wp
230         fpol(jpiglo/2+1:jpiglo) = 0._wp
231      ENDIF
232      !
233      !                          ! interior mask : 2D ocean mask x halo mask
234      tmask_i(:,:) = ssmask(:,:) * tmask_h(:,:)
235
236
237      ! Lateral boundary conditions on velocity (modify fmask)
238      ! --------------------------------------- 
239      IF( rn_shlat /= 0 ) THEN      ! Not free-slip lateral boundary condition
240         !
241         ALLOCATE( zwf(jpi,jpj) )
242         !
243         DO jk = 1, jpk
244            zwf(:,:) = fmask(:,:,jk)         
245            DO jj = 2, jpjm1
246               DO ji = fs_2, fs_jpim1   ! vector opt.
247                  IF( fmask(ji,jj,jk) == 0._wp ) THEN
248                     fmask(ji,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,jj), zwf(ji,jj+1),   &
249                        &                                           zwf(ji-1,jj), zwf(ji,jj-1)  )  )
250                  ENDIF
251               END DO
252            END DO
253            DO jj = 2, jpjm1
254               IF( fmask(1,jj,jk) == 0._wp ) THEN
255                  fmask(1  ,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(2,jj), zwf(1,jj+1), zwf(1,jj-1) ) )
256               ENDIF
257               IF( fmask(jpi,jj,jk) == 0._wp ) THEN
258                  fmask(jpi,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(jpi,jj+1), zwf(jpim1,jj), zwf(jpi,jj-1) ) )
259               ENDIF
260            END DO         
261            DO ji = 2, jpim1
262               IF( fmask(ji,1,jk) == 0._wp ) THEN
263                  fmask(ji, 1 ,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,1), zwf(ji,2), zwf(ji-1,1) ) )
264               ENDIF
265               IF( fmask(ji,jpj,jk) == 0._wp ) THEN
266                  fmask(ji,jpj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,jpj), zwf(ji-1,jpj), zwf(ji,jpjm1) ) )
267               ENDIF
268            END DO
269#if defined key_agrif 
270            IF( .NOT. AGRIF_Root() ) THEN
271               IF ((nbondi ==  1).OR.(nbondi == 2)) fmask(nlci-1 , :     ,jk) = 0.e0      ! east
272               IF ((nbondi == -1).OR.(nbondi == 2)) fmask(1      , :     ,jk) = 0.e0      ! west
273               IF ((nbondj ==  1).OR.(nbondj == 2)) fmask(:      ,nlcj-1 ,jk) = 0.e0      ! north
274               IF ((nbondj == -1).OR.(nbondj == 2)) fmask(:      ,1      ,jk) = 0.e0      ! south
275            ENDIF 
276#endif
277         END DO
278         !
279         DEALLOCATE( zwf )
280         !
281         CALL lbc_lnk( 'dommsk', fmask, 'F', 1._wp )      ! Lateral boundary conditions on fmask
282         !
283         ! CAUTION : The fmask may be further modified in dyn_vor_init ( dynvor.F90 ) depending on ln_vorlat
284         !
285      ENDIF
286      !
287      ! write out mesh mask
288      IF ( nn_msh > 0 ) CALL dom_wri
289      !
290   END SUBROUTINE dom_msk
291   
292   !!======================================================================
293END MODULE dommsk
Note: See TracBrowser for help on using the repository browser.