| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice) |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec) |
|---|
| 8 | !! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
|---|
| 9 | !! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1 |
|---|
| 10 | !! - ! 1992-06 (L.Terray) coupling implementation |
|---|
| 11 | !! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice |
|---|
| 12 | !! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
|---|
| 13 | !! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0 |
|---|
| 14 | !! 8.1 ! 1997-06 (M. Imbard, G. Madec) |
|---|
| 15 | !! 8.2 ! 1999-11 (M. Imbard, H. Goosse) sea-ice model |
|---|
| 16 | !! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP |
|---|
| 17 | !! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER) |
|---|
| 18 | !! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules |
|---|
| 19 | !! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces |
|---|
| 20 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 21 | !! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility |
|---|
| 22 | !! - ! 2005-11 (V. Garnier) Surface pressure gradient organization |
|---|
| 23 | !! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 24 | !! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization |
|---|
| 25 | !! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY) |
|---|
| 26 | !! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp |
|---|
| 27 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 28 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 29 | !! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 30 | !! - ! 2011-11 (C. Harris) decomposition changes for running with CICE |
|---|
| 31 | !! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening |
|---|
| 32 | !! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla) |
|---|
| 33 | !! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
|---|
| 38 | !! nemo_init : initialization of the NEMO system |
|---|
| 39 | !! nemo_ctl : initialisation of the contol print |
|---|
| 40 | !! nemo_closefile: close remaining open files |
|---|
| 41 | !! nemo_alloc : dynamical allocation |
|---|
| 42 | !!---------------------------------------------------------------------- |
|---|
| 43 | USE step_oce ! module used in the ocean time stepping module (step.F90) |
|---|
| 44 | USE phycst ! physical constant (par_cst routine) |
|---|
| 45 | USE domain ! domain initialization (dom_init & dom_cfg routines) |
|---|
| 46 | USE closea ! treatment of closed seas (for ln_closea) |
|---|
| 47 | USE usrdef_nam ! user defined configuration |
|---|
| 48 | USE tideini ! tidal components initialization (tide_ini routine) |
|---|
| 49 | USE bdy_oce, ONLY : ln_bdy |
|---|
| 50 | USE bdyini ! open boundary cond. setting (bdy_init routine) |
|---|
| 51 | USE istate ! initial state setting (istate_init routine) |
|---|
| 52 | USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine) |
|---|
| 53 | USE ldftra ! lateral diffusivity setting (ldftra_init routine) |
|---|
| 54 | USE trdini ! dyn/tra trends initialization (trd_init routine) |
|---|
| 55 | USE asminc ! assimilation increments |
|---|
| 56 | USE asmbkg ! writing out state trajectory |
|---|
| 57 | USE diaptr ! poleward transports (dia_ptr_init routine) |
|---|
| 58 | USE diadct ! sections transports (dia_dct_init routine) |
|---|
| 59 | USE diaobs ! Observation diagnostics (dia_obs_init routine) |
|---|
| 60 | USE diacfl ! CFL diagnostics (dia_cfl_init routine) |
|---|
| 61 | USE diaharm ! tidal harmonics diagnostics (dia_harm_init routine) |
|---|
| 62 | USE step ! NEMO time-stepping (stp routine) |
|---|
| 63 | USE isfstp ! ice shelf (isf_stp_init routine) |
|---|
| 64 | USE icbini ! handle bergs, initialisation |
|---|
| 65 | USE icbstp ! handle bergs, calving, themodynamics and transport |
|---|
| 66 | USE cpl_oasis3 ! OASIS3 coupling |
|---|
| 67 | USE c1d ! 1D configuration |
|---|
| 68 | USE step_c1d ! Time stepping loop for the 1D configuration |
|---|
| 69 | USE dyndmp ! Momentum damping |
|---|
| 70 | USE stopar ! Stochastic param.: ??? |
|---|
| 71 | USE stopts ! Stochastic param.: ??? |
|---|
| 72 | USE diu_layers ! diurnal bulk SST and coolskin |
|---|
| 73 | USE step_diu ! diurnal bulk SST timestepping (called from here if run offline) |
|---|
| 74 | USE crsini ! initialise grid coarsening utility |
|---|
| 75 | USE diatmb ! Top,middle,bottom output |
|---|
| 76 | USE dia25h ! 25h mean output |
|---|
| 77 | USE sbc_oce , ONLY : lk_oasis |
|---|
| 78 | USE wet_dry ! Wetting and drying setting (wad_init routine) |
|---|
| 79 | #if defined key_top |
|---|
| 80 | USE trcini ! passive tracer initialisation |
|---|
| 81 | #endif |
|---|
| 82 | #if defined key_nemocice_decomp |
|---|
| 83 | USE ice_domain_size, only: nx_global, ny_global |
|---|
| 84 | #endif |
|---|
| 85 | ! |
|---|
| 86 | USE lib_mpp ! distributed memory computing |
|---|
| 87 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 88 | USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges |
|---|
| 89 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 90 | #if defined key_iomput |
|---|
| 91 | USE xios ! xIOserver |
|---|
| 92 | #endif |
|---|
| 93 | #if defined key_agrif |
|---|
| 94 | USE agrif_all_update ! Master Agrif update |
|---|
| 95 | #endif |
|---|
| 96 | |
|---|
| 97 | IMPLICIT NONE |
|---|
| 98 | PRIVATE |
|---|
| 99 | |
|---|
| 100 | PUBLIC nemo_gcm ! called by model.F90 |
|---|
| 101 | PUBLIC nemo_init ! needed by AGRIF |
|---|
| 102 | PUBLIC nemo_alloc ! needed by TAM |
|---|
| 103 | |
|---|
| 104 | CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 105 | |
|---|
| 106 | #if defined key_mpp_mpi |
|---|
| 107 | ! need MPI_Wtime |
|---|
| 108 | INCLUDE 'mpif.h' |
|---|
| 109 | #endif |
|---|
| 110 | |
|---|
| 111 | !!---------------------------------------------------------------------- |
|---|
| 112 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 113 | !! $Id$ |
|---|
| 114 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 115 | !!---------------------------------------------------------------------- |
|---|
| 116 | CONTAINS |
|---|
| 117 | |
|---|
| 118 | SUBROUTINE nemo_gcm |
|---|
| 119 | !!---------------------------------------------------------------------- |
|---|
| 120 | !! *** ROUTINE nemo_gcm *** |
|---|
| 121 | !! |
|---|
| 122 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
|---|
| 123 | !! curvilinear mesh on the sphere. |
|---|
| 124 | !! |
|---|
| 125 | !! ** Method : - model general initialization |
|---|
| 126 | !! - launch the time-stepping (stp routine) |
|---|
| 127 | !! - finalize the run by closing files and communications |
|---|
| 128 | !! |
|---|
| 129 | !! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL. |
|---|
| 130 | !! Madec, 2008, internal report, IPSL. |
|---|
| 131 | !!---------------------------------------------------------------------- |
|---|
| 132 | INTEGER :: istp ! time step index |
|---|
| 133 | REAL(wp):: zstptiming ! elapsed time for 1 time step |
|---|
| 134 | !!---------------------------------------------------------------------- |
|---|
| 135 | ! |
|---|
| 136 | #if defined key_agrif |
|---|
| 137 | CALL Agrif_Init_Grids() ! AGRIF: set the meshes |
|---|
| 138 | #endif |
|---|
| 139 | ! !-----------------------! |
|---|
| 140 | CALL nemo_init !== Initialisations ==! |
|---|
| 141 | ! !-----------------------! |
|---|
| 142 | #if defined key_agrif |
|---|
| 143 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 144 | CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM |
|---|
| 145 | CALL Agrif_Declare_Var ! " " " " " DYN/TRA |
|---|
| 146 | # if defined key_top |
|---|
| 147 | CALL Agrif_Declare_Var_top ! " " " " " TOP |
|---|
| 148 | # endif |
|---|
| 149 | # if defined key_si3 |
|---|
| 150 | CALL Agrif_Declare_Var_ice ! " " " " " Sea ice |
|---|
| 151 | # endif |
|---|
| 152 | #endif |
|---|
| 153 | ! check that all process are still there... If some process have an error, |
|---|
| 154 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
|---|
| 155 | CALL mpp_max( 'nemogcm', nstop ) |
|---|
| 156 | |
|---|
| 157 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 158 | |
|---|
| 159 | ! !-----------------------! |
|---|
| 160 | ! !== time stepping ==! |
|---|
| 161 | ! !-----------------------! |
|---|
| 162 | istp = nit000 |
|---|
| 163 | ! |
|---|
| 164 | #if defined key_c1d |
|---|
| 165 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== C1D time-stepping ==! |
|---|
| 166 | CALL stp_c1d( istp ) |
|---|
| 167 | istp = istp + 1 |
|---|
| 168 | END DO |
|---|
| 169 | #else |
|---|
| 170 | ! |
|---|
| 171 | # if defined key_agrif |
|---|
| 172 | ! !== AGRIF time-stepping ==! |
|---|
| 173 | CALL Agrif_Regrid() |
|---|
| 174 | ! |
|---|
| 175 | ! Recursive update from highest nested level to lowest: |
|---|
| 176 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 177 | CALL Agrif_step_child_adj(Agrif_Update_All) |
|---|
| 178 | ! |
|---|
| 179 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 180 | CALL stp |
|---|
| 181 | istp = istp + 1 |
|---|
| 182 | END DO |
|---|
| 183 | ! |
|---|
| 184 | IF( .NOT. Agrif_Root() ) THEN |
|---|
| 185 | CALL Agrif_ParentGrid_To_ChildGrid() |
|---|
| 186 | IF( ln_diaobs ) CALL dia_obs_wri |
|---|
| 187 | IF( ln_timing ) CALL timing_finalize |
|---|
| 188 | CALL Agrif_ChildGrid_To_ParentGrid() |
|---|
| 189 | ENDIF |
|---|
| 190 | ! |
|---|
| 191 | # else |
|---|
| 192 | ! |
|---|
| 193 | IF( .NOT.ln_diurnal_only ) THEN !== Standard time-stepping ==! |
|---|
| 194 | ! |
|---|
| 195 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 196 | |
|---|
| 197 | ncom_stp = istp |
|---|
| 198 | IF( ln_timing ) THEN |
|---|
| 199 | zstptiming = MPI_Wtime() |
|---|
| 200 | IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming |
|---|
| 201 | IF ( istp == nitend ) elapsed_time = zstptiming - elapsed_time |
|---|
| 202 | ENDIF |
|---|
| 203 | |
|---|
| 204 | CALL stp ( istp ) |
|---|
| 205 | istp = istp + 1 |
|---|
| 206 | |
|---|
| 207 | IF( lwp .AND. ln_timing ) WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming |
|---|
| 208 | |
|---|
| 209 | END DO |
|---|
| 210 | ! |
|---|
| 211 | ELSE !== diurnal SST time-steeping only ==! |
|---|
| 212 | ! |
|---|
| 213 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 214 | CALL stp_diurnal( istp ) ! time step only the diurnal SST |
|---|
| 215 | istp = istp + 1 |
|---|
| 216 | END DO |
|---|
| 217 | ! |
|---|
| 218 | ENDIF |
|---|
| 219 | ! |
|---|
| 220 | # endif |
|---|
| 221 | ! |
|---|
| 222 | #endif |
|---|
| 223 | ! |
|---|
| 224 | IF( ln_diaobs ) CALL dia_obs_wri |
|---|
| 225 | ! |
|---|
| 226 | IF( ln_icebergs ) CALL icb_end( nitend ) |
|---|
| 227 | |
|---|
| 228 | ! !------------------------! |
|---|
| 229 | ! !== finalize the run ==! |
|---|
| 230 | ! !------------------------! |
|---|
| 231 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 232 | ! |
|---|
| 233 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
|---|
| 234 | WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found' |
|---|
| 235 | CALL ctl_stop( ctmp1 ) |
|---|
| 236 | ENDIF |
|---|
| 237 | ! |
|---|
| 238 | IF( ln_timing ) CALL timing_finalize |
|---|
| 239 | ! |
|---|
| 240 | CALL nemo_closefile |
|---|
| 241 | ! |
|---|
| 242 | #if defined key_iomput |
|---|
| 243 | CALL xios_finalize ! end mpp communications with xios |
|---|
| 244 | IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS |
|---|
| 245 | #else |
|---|
| 246 | IF ( lk_oasis ) THEN ; CALL cpl_finalize ! end coupling and mpp communications with OASIS |
|---|
| 247 | ELSEIF( lk_mpp ) THEN ; CALL mppstop ! end mpp communications |
|---|
| 248 | ENDIF |
|---|
| 249 | #endif |
|---|
| 250 | ! |
|---|
| 251 | IF(lwm) THEN |
|---|
| 252 | IF( nstop == 0 ) THEN ; STOP 0 |
|---|
| 253 | ELSE ; STOP 123 |
|---|
| 254 | ENDIF |
|---|
| 255 | ENDIF |
|---|
| 256 | ! |
|---|
| 257 | END SUBROUTINE nemo_gcm |
|---|
| 258 | |
|---|
| 259 | |
|---|
| 260 | SUBROUTINE nemo_init |
|---|
| 261 | !!---------------------------------------------------------------------- |
|---|
| 262 | !! *** ROUTINE nemo_init *** |
|---|
| 263 | !! |
|---|
| 264 | !! ** Purpose : initialization of the NEMO GCM |
|---|
| 265 | !!---------------------------------------------------------------------- |
|---|
| 266 | INTEGER :: ios, ilocal_comm ! local integers |
|---|
| 267 | !! |
|---|
| 268 | NAMELIST/namctl/ ln_ctl , sn_cfctl, nn_print, nn_ictls, nn_ictle, & |
|---|
| 269 | & nn_isplt , nn_jsplt, nn_jctls, nn_jctle, & |
|---|
| 270 | & ln_timing, ln_diacfl |
|---|
| 271 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
|---|
| 272 | !!---------------------------------------------------------------------- |
|---|
| 273 | ! |
|---|
| 274 | cxios_context = 'nemo' |
|---|
| 275 | ! |
|---|
| 276 | ! !-------------------------------------------------! |
|---|
| 277 | ! ! set communicator & select the local rank ! |
|---|
| 278 | ! ! must be done as soon as possible to get narea ! |
|---|
| 279 | ! !-------------------------------------------------! |
|---|
| 280 | ! |
|---|
| 281 | #if defined key_iomput |
|---|
| 282 | IF( Agrif_Root() ) THEN |
|---|
| 283 | IF( lk_oasis ) THEN |
|---|
| 284 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 285 | CALL xios_initialize( "not used" , local_comm =ilocal_comm ) ! send nemo communicator to xios |
|---|
| 286 | ELSE |
|---|
| 287 | CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios |
|---|
| 288 | ENDIF |
|---|
| 289 | ENDIF |
|---|
| 290 | CALL mpp_start( ilocal_comm ) |
|---|
| 291 | #else |
|---|
| 292 | IF( lk_oasis ) THEN |
|---|
| 293 | IF( Agrif_Root() ) THEN |
|---|
| 294 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 295 | ENDIF |
|---|
| 296 | CALL mpp_start( ilocal_comm ) |
|---|
| 297 | ELSE |
|---|
| 298 | CALL mpp_start( ) |
|---|
| 299 | ENDIF |
|---|
| 300 | #endif |
|---|
| 301 | ! |
|---|
| 302 | narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 ) |
|---|
| 303 | lwm = (narea == 1) ! control of output namelists |
|---|
| 304 | ! |
|---|
| 305 | ! !---------------------------------------------------------------! |
|---|
| 306 | ! ! Open output files, reference and configuration namelist files ! |
|---|
| 307 | ! !---------------------------------------------------------------! |
|---|
| 308 | ! |
|---|
| 309 | ! open ocean.output as soon as possible to get all output prints (including errors messages) |
|---|
| 310 | IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 311 | ! open reference and configuration namelist files |
|---|
| 312 | CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 313 | CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 314 | IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 315 | ! open /dev/null file to be able to supress output write easily |
|---|
| 316 | CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 317 | ! |
|---|
| 318 | ! !--------------------! |
|---|
| 319 | ! ! Open listing units ! -> need ln_ctl from namctl to define lwp |
|---|
| 320 | ! !--------------------! |
|---|
| 321 | ! |
|---|
| 322 | REWIND( numnam_ref ) ! Namelist namctl in reference namelist |
|---|
| 323 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
|---|
| 324 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' ) |
|---|
| 325 | REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist |
|---|
| 326 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
|---|
| 327 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' ) |
|---|
| 328 | ! |
|---|
| 329 | lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print |
|---|
| 330 | ! |
|---|
| 331 | IF(lwp) THEN ! open listing units |
|---|
| 332 | ! |
|---|
| 333 | IF( .NOT. lwm ) & ! alreay opened for narea == 1 |
|---|
| 334 | & CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea ) |
|---|
| 335 | ! |
|---|
| 336 | WRITE(numout,*) |
|---|
| 337 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC' |
|---|
| 338 | WRITE(numout,*) ' NEMO team' |
|---|
| 339 | WRITE(numout,*) ' Ocean General Circulation Model' |
|---|
| 340 | WRITE(numout,*) ' NEMO version 4.0 (2019) ' |
|---|
| 341 | WRITE(numout,*) |
|---|
| 342 | WRITE(numout,*) " ._ ._ ._ ._ ._ " |
|---|
| 343 | WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ " |
|---|
| 344 | WRITE(numout,*) |
|---|
| 345 | WRITE(numout,*) " o _, _, " |
|---|
| 346 | WRITE(numout,*) " o .' ( .-' / " |
|---|
| 347 | WRITE(numout,*) " o _/..._'. .' / " |
|---|
| 348 | WRITE(numout,*) " ( o .-'` ` '-./ _.' " |
|---|
| 349 | WRITE(numout,*) " ) ( o) ;= <_ ( " |
|---|
| 350 | WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) " |
|---|
| 351 | WRITE(numout,*) " ) ) \) |`\ \) '. \ ( ( " |
|---|
| 352 | WRITE(numout,*) " ( ( \_/ '-._\ ) ) " |
|---|
| 353 | WRITE(numout,*) " ) ) jgs ` ( ( " |
|---|
| 354 | WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ " |
|---|
| 355 | WRITE(numout,*) |
|---|
| 356 | ! |
|---|
| 357 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 358 | ! |
|---|
| 359 | ENDIF |
|---|
| 360 | ! |
|---|
| 361 | ! finalize the definition of namctl variables |
|---|
| 362 | IF( sn_cfctl%l_config ) THEN |
|---|
| 363 | ! Activate finer control of report outputs |
|---|
| 364 | ! optionally switch off output from selected areas (note this only |
|---|
| 365 | ! applies to output which does not involve global communications) |
|---|
| 366 | IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax ) .OR. & |
|---|
| 367 | & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) ) & |
|---|
| 368 | & CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. ) |
|---|
| 369 | ELSE |
|---|
| 370 | ! Use ln_ctl to turn on or off all options. |
|---|
| 371 | CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. ) |
|---|
| 372 | ENDIF |
|---|
| 373 | ! |
|---|
| 374 | IF(lwm) WRITE( numond, namctl ) |
|---|
| 375 | ! |
|---|
| 376 | ! !------------------------------------! |
|---|
| 377 | ! ! Set global domain size parameters ! |
|---|
| 378 | ! !------------------------------------! |
|---|
| 379 | ! |
|---|
| 380 | REWIND( numnam_ref ) ! Namelist namcfg in reference namelist |
|---|
| 381 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
|---|
| 382 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' ) |
|---|
| 383 | REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist |
|---|
| 384 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
|---|
| 385 | 904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' ) |
|---|
| 386 | ! |
|---|
| 387 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
|---|
| 388 | CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio ) |
|---|
| 389 | ELSE ! user-defined namelist |
|---|
| 390 | CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio ) |
|---|
| 391 | ENDIF |
|---|
| 392 | ! |
|---|
| 393 | IF(lwm) WRITE( numond, namcfg ) |
|---|
| 394 | ! |
|---|
| 395 | ! !-----------------------------------------! |
|---|
| 396 | ! ! mpp parameters and domain decomposition ! |
|---|
| 397 | ! !-----------------------------------------! |
|---|
| 398 | CALL mpp_init |
|---|
| 399 | |
|---|
| 400 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
|---|
| 401 | CALL nemo_alloc() |
|---|
| 402 | |
|---|
| 403 | ! Initialise time level indices |
|---|
| 404 | Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa |
|---|
| 405 | |
|---|
| 406 | ! !-------------------------------! |
|---|
| 407 | ! ! NEMO general initialization ! |
|---|
| 408 | ! !-------------------------------! |
|---|
| 409 | |
|---|
| 410 | CALL nemo_ctl ! Control prints |
|---|
| 411 | ! |
|---|
| 412 | ! ! General initialization |
|---|
| 413 | IF( ln_timing ) CALL timing_init ! timing |
|---|
| 414 | IF( ln_timing ) CALL timing_start( 'nemo_init') |
|---|
| 415 | ! |
|---|
| 416 | CALL phy_cst ! Physical constants |
|---|
| 417 | CALL eos_init ! Equation of state |
|---|
| 418 | IF( lk_c1d ) CALL c1d_init ! 1D column configuration |
|---|
| 419 | CALL wad_init ! Wetting and drying options |
|---|
| 420 | CALL dom_init( Nbb, Nnn, Naa, "OPA") ! Domain |
|---|
| 421 | IF( ln_crs ) CALL crs_init( Nnn ) ! coarsened grid: domain initialization |
|---|
| 422 | IF( ln_ctl ) CALL prt_ctl_init ! Print control |
|---|
| 423 | |
|---|
| 424 | CALL diurnal_sst_bulk_init ! diurnal sst |
|---|
| 425 | IF( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin |
|---|
| 426 | ! |
|---|
| 427 | IF( ln_diurnal_only ) THEN ! diurnal only: a subset of the initialisation routines |
|---|
| 428 | CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 429 | CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module |
|---|
| 430 | CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 431 | IF( ln_diaobs ) THEN ! Observation & model comparison |
|---|
| 432 | CALL dia_obs_init( Nnn ) ! Initialize observational data |
|---|
| 433 | CALL dia_obs( nit000 - 1, Nnn ) ! Observation operator for restart |
|---|
| 434 | ENDIF |
|---|
| 435 | IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Assimilation increments |
|---|
| 436 | ! |
|---|
| 437 | RETURN ! end of initialization |
|---|
| 438 | ENDIF |
|---|
| 439 | ! |
|---|
| 440 | |
|---|
| 441 | CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 442 | |
|---|
| 443 | ! ! external forcing |
|---|
| 444 | CALL tide_init ! tidal harmonics |
|---|
| 445 | CALL sbc_init( Nbb, Nnn, Naa ) ! surface boundary conditions (including sea-ice) |
|---|
| 446 | CALL bdy_init ! Open boundaries initialisation |
|---|
| 447 | |
|---|
| 448 | ! ! Ocean physics |
|---|
| 449 | CALL zdf_phy_init( Nnn ) ! Vertical physics |
|---|
| 450 | |
|---|
| 451 | ! ! Lateral physics |
|---|
| 452 | CALL ldf_tra_init ! Lateral ocean tracer physics |
|---|
| 453 | CALL ldf_eiv_init ! eddy induced velocity param. |
|---|
| 454 | CALL ldf_dyn_init ! Lateral ocean momentum physics |
|---|
| 455 | |
|---|
| 456 | ! ! Active tracers |
|---|
| 457 | IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 458 | CALL tra_bbc_init ! bottom heat flux |
|---|
| 459 | CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 460 | CALL tra_dmp_init ! internal tracer damping |
|---|
| 461 | CALL tra_adv_init ! horizontal & vertical advection |
|---|
| 462 | CALL tra_ldf_init ! lateral mixing |
|---|
| 463 | |
|---|
| 464 | ! ! Dynamics |
|---|
| 465 | IF( lk_c1d ) CALL dyn_dmp_init ! internal momentum damping |
|---|
| 466 | CALL dyn_adv_init ! advection (vector or flux form) |
|---|
| 467 | CALL dyn_vor_init ! vorticity term including Coriolis |
|---|
| 468 | CALL dyn_ldf_init ! lateral mixing |
|---|
| 469 | CALL dyn_hpg_init( Nnn ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 470 | CALL dyn_spg_init ! surface pressure gradient |
|---|
| 471 | |
|---|
| 472 | #if defined key_top |
|---|
| 473 | ! ! Passive tracers |
|---|
| 474 | CALL trc_init( Nbb, Nnn, Naa ) |
|---|
| 475 | #endif |
|---|
| 476 | IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
|---|
| 477 | |
|---|
| 478 | ! ! Icebergs |
|---|
| 479 | CALL icb_init( rdt, nit000) ! initialise icebergs instance |
|---|
| 480 | |
|---|
| 481 | ! ice shelf |
|---|
| 482 | CALL isf_init( Nbb, Nnn, Naa ) |
|---|
| 483 | |
|---|
| 484 | ! ! Misc. options |
|---|
| 485 | CALL sto_par_init ! Stochastic parametrization |
|---|
| 486 | IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations |
|---|
| 487 | |
|---|
| 488 | ! ! Diagnostics |
|---|
| 489 | CALL flo_init( Nnn ) ! drifting Floats |
|---|
| 490 | IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics |
|---|
| 491 | CALL dia_ptr_init ! Poleward TRansports initialization |
|---|
| 492 | CALL dia_dct_init ! Sections tranports |
|---|
| 493 | CALL dia_hsb_init( Nnn ) ! heat content, salt content and volume budgets |
|---|
| 494 | CALL trd_init( Nnn ) ! Mixed-layer/Vorticity/Integral constraints trends |
|---|
| 495 | CALL dia_obs_init( Nnn ) ! Initialize observational data |
|---|
| 496 | CALL dia_tmb_init ! TMB outputs |
|---|
| 497 | CALL dia_25h_init( Nbb ) ! 25h mean outputs |
|---|
| 498 | CALL dia_harm_init ! tidal harmonics outputs |
|---|
| 499 | IF( ln_diaobs ) CALL dia_obs( nit000-1, Nnn ) ! Observation operator for restart |
|---|
| 500 | |
|---|
| 501 | ! ! Assimilation increments |
|---|
| 502 | IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Initialize assimilation increments |
|---|
| 503 | ! |
|---|
| 504 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 505 | ! |
|---|
| 506 | IF( ln_timing ) CALL timing_stop( 'nemo_init') |
|---|
| 507 | ! |
|---|
| 508 | END SUBROUTINE nemo_init |
|---|
| 509 | |
|---|
| 510 | |
|---|
| 511 | SUBROUTINE nemo_ctl |
|---|
| 512 | !!---------------------------------------------------------------------- |
|---|
| 513 | !! *** ROUTINE nemo_ctl *** |
|---|
| 514 | !! |
|---|
| 515 | !! ** Purpose : control print setting |
|---|
| 516 | !! |
|---|
| 517 | !! ** Method : - print namctl and namcfg information and check some consistencies |
|---|
| 518 | !!---------------------------------------------------------------------- |
|---|
| 519 | ! |
|---|
| 520 | IF(lwp) THEN ! control print |
|---|
| 521 | WRITE(numout,*) |
|---|
| 522 | WRITE(numout,*) 'nemo_ctl: Control prints' |
|---|
| 523 | WRITE(numout,*) '~~~~~~~~' |
|---|
| 524 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 525 | WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl |
|---|
| 526 | WRITE(numout,*) ' finer control over o/p sn_cfctl%l_config = ', sn_cfctl%l_config |
|---|
| 527 | WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat |
|---|
| 528 | WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat |
|---|
| 529 | WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout |
|---|
| 530 | WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout |
|---|
| 531 | WRITE(numout,*) ' sn_cfctl%l_mppout = ', sn_cfctl%l_mppout |
|---|
| 532 | WRITE(numout,*) ' sn_cfctl%l_mpptop = ', sn_cfctl%l_mpptop |
|---|
| 533 | WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin |
|---|
| 534 | WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax |
|---|
| 535 | WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr |
|---|
| 536 | WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr |
|---|
| 537 | WRITE(numout,*) ' level of print nn_print = ', nn_print |
|---|
| 538 | WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls |
|---|
| 539 | WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle |
|---|
| 540 | WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls |
|---|
| 541 | WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle |
|---|
| 542 | WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt |
|---|
| 543 | WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt |
|---|
| 544 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
|---|
| 545 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
|---|
| 546 | ENDIF |
|---|
| 547 | ! |
|---|
| 548 | nprint = nn_print ! convert DOCTOR namelist names into OLD names |
|---|
| 549 | nictls = nn_ictls |
|---|
| 550 | nictle = nn_ictle |
|---|
| 551 | njctls = nn_jctls |
|---|
| 552 | njctle = nn_jctle |
|---|
| 553 | isplt = nn_isplt |
|---|
| 554 | jsplt = nn_jsplt |
|---|
| 555 | |
|---|
| 556 | IF(lwp) THEN ! control print |
|---|
| 557 | WRITE(numout,*) |
|---|
| 558 | WRITE(numout,*) ' Namelist namcfg' |
|---|
| 559 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
|---|
| 560 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
|---|
| 561 | WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea |
|---|
| 562 | WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg |
|---|
| 563 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
|---|
| 564 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
|---|
| 565 | ENDIF |
|---|
| 566 | IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file |
|---|
| 567 | ! |
|---|
| 568 | ! ! Parameter control |
|---|
| 569 | ! |
|---|
| 570 | IF( ln_ctl ) THEN ! sub-domain area indices for the control prints |
|---|
| 571 | IF( lk_mpp .AND. jpnij > 1 ) THEN |
|---|
| 572 | isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain |
|---|
| 573 | ELSE |
|---|
| 574 | IF( isplt == 1 .AND. jsplt == 1 ) THEN |
|---|
| 575 | CALL ctl_warn( ' - isplt & jsplt are equal to 1', & |
|---|
| 576 | & ' - the print control will be done over the whole domain' ) |
|---|
| 577 | ENDIF |
|---|
| 578 | ijsplt = isplt * jsplt ! total number of processors ijsplt |
|---|
| 579 | ENDIF |
|---|
| 580 | IF(lwp) WRITE(numout,*)' - The total number of processors over which the' |
|---|
| 581 | IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt |
|---|
| 582 | ! |
|---|
| 583 | ! ! indices used for the SUM control |
|---|
| 584 | IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area |
|---|
| 585 | lsp_area = .FALSE. |
|---|
| 586 | ELSE ! print control done over a specific area |
|---|
| 587 | lsp_area = .TRUE. |
|---|
| 588 | IF( nictls < 1 .OR. nictls > jpiglo ) THEN |
|---|
| 589 | CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' ) |
|---|
| 590 | nictls = 1 |
|---|
| 591 | ENDIF |
|---|
| 592 | IF( nictle < 1 .OR. nictle > jpiglo ) THEN |
|---|
| 593 | CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' ) |
|---|
| 594 | nictle = jpiglo |
|---|
| 595 | ENDIF |
|---|
| 596 | IF( njctls < 1 .OR. njctls > jpjglo ) THEN |
|---|
| 597 | CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' ) |
|---|
| 598 | njctls = 1 |
|---|
| 599 | ENDIF |
|---|
| 600 | IF( njctle < 1 .OR. njctle > jpjglo ) THEN |
|---|
| 601 | CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' ) |
|---|
| 602 | njctle = jpjglo |
|---|
| 603 | ENDIF |
|---|
| 604 | ENDIF |
|---|
| 605 | ENDIF |
|---|
| 606 | ! |
|---|
| 607 | IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', & |
|---|
| 608 | & 'Compile with key_nosignedzero enabled:', & |
|---|
| 609 | & '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' ) |
|---|
| 610 | ! |
|---|
| 611 | #if defined key_agrif |
|---|
| 612 | IF( ln_timing ) CALL ctl_stop( 'AGRIF not implemented with ln_timing = true') |
|---|
| 613 | #endif |
|---|
| 614 | ! |
|---|
| 615 | END SUBROUTINE nemo_ctl |
|---|
| 616 | |
|---|
| 617 | |
|---|
| 618 | SUBROUTINE nemo_closefile |
|---|
| 619 | !!---------------------------------------------------------------------- |
|---|
| 620 | !! *** ROUTINE nemo_closefile *** |
|---|
| 621 | !! |
|---|
| 622 | !! ** Purpose : Close the files |
|---|
| 623 | !!---------------------------------------------------------------------- |
|---|
| 624 | ! |
|---|
| 625 | IF( lk_mpp ) CALL mppsync |
|---|
| 626 | ! |
|---|
| 627 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 628 | ! |
|---|
| 629 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 630 | IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file |
|---|
| 631 | IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist |
|---|
| 632 | IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist |
|---|
| 633 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
|---|
| 634 | IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist |
|---|
| 635 | IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist |
|---|
| 636 | IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist |
|---|
| 637 | IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution) |
|---|
| 638 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
|---|
| 639 | IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports |
|---|
| 640 | IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports |
|---|
| 641 | IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports |
|---|
| 642 | ! |
|---|
| 643 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 644 | ! |
|---|
| 645 | END SUBROUTINE nemo_closefile |
|---|
| 646 | |
|---|
| 647 | |
|---|
| 648 | SUBROUTINE nemo_alloc |
|---|
| 649 | !!---------------------------------------------------------------------- |
|---|
| 650 | !! *** ROUTINE nemo_alloc *** |
|---|
| 651 | !! |
|---|
| 652 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
|---|
| 653 | !! |
|---|
| 654 | !! ** Method : |
|---|
| 655 | !!---------------------------------------------------------------------- |
|---|
| 656 | USE diawri , ONLY : dia_wri_alloc |
|---|
| 657 | USE dom_oce , ONLY : dom_oce_alloc |
|---|
| 658 | USE trc_oce , ONLY : trc_oce_alloc |
|---|
| 659 | USE bdy_oce , ONLY : bdy_oce_alloc |
|---|
| 660 | ! |
|---|
| 661 | INTEGER :: ierr |
|---|
| 662 | !!---------------------------------------------------------------------- |
|---|
| 663 | ! |
|---|
| 664 | ierr = oce_alloc () ! ocean |
|---|
| 665 | ierr = ierr + dia_wri_alloc() |
|---|
| 666 | ierr = ierr + dom_oce_alloc() ! ocean domain |
|---|
| 667 | ierr = ierr + zdf_oce_alloc() ! ocean vertical physics |
|---|
| 668 | ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays |
|---|
| 669 | ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization) |
|---|
| 670 | ! |
|---|
| 671 | CALL mpp_sum( 'nemogcm', ierr ) |
|---|
| 672 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
|---|
| 673 | ! |
|---|
| 674 | END SUBROUTINE nemo_alloc |
|---|
| 675 | |
|---|
| 676 | |
|---|
| 677 | SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all ) |
|---|
| 678 | !!---------------------------------------------------------------------- |
|---|
| 679 | !! *** ROUTINE nemo_set_cfctl *** |
|---|
| 680 | !! |
|---|
| 681 | !! ** Purpose : Set elements of the output control structure to setto. |
|---|
| 682 | !! for_all should be .false. unless all areas are to be |
|---|
| 683 | !! treated identically. |
|---|
| 684 | !! |
|---|
| 685 | !! ** Method : Note this routine can be used to switch on/off some |
|---|
| 686 | !! types of output for selected areas but any output types |
|---|
| 687 | !! that involve global communications (e.g. mpp_max, glob_sum) |
|---|
| 688 | !! should be protected from selective switching by the |
|---|
| 689 | !! for_all argument |
|---|
| 690 | !!---------------------------------------------------------------------- |
|---|
| 691 | LOGICAL :: setto, for_all |
|---|
| 692 | TYPE(sn_ctl) :: sn_cfctl |
|---|
| 693 | !!---------------------------------------------------------------------- |
|---|
| 694 | IF( for_all ) THEN |
|---|
| 695 | sn_cfctl%l_runstat = setto |
|---|
| 696 | sn_cfctl%l_trcstat = setto |
|---|
| 697 | ENDIF |
|---|
| 698 | sn_cfctl%l_oceout = setto |
|---|
| 699 | sn_cfctl%l_layout = setto |
|---|
| 700 | sn_cfctl%l_mppout = setto |
|---|
| 701 | sn_cfctl%l_mpptop = setto |
|---|
| 702 | END SUBROUTINE nemo_set_cfctl |
|---|
| 703 | |
|---|
| 704 | !!====================================================================== |
|---|
| 705 | END MODULE nemogcm |
|---|
| 706 | |
|---|
