| 1 | MODULE step |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE step *** |
|---|
| 4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 7 | !! - ! 1991-11 (G. Madec) |
|---|
| 8 | !! - ! 1992-06 (M. Imbard) add a first output record |
|---|
| 9 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
|---|
| 10 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
|---|
| 11 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
|---|
| 12 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
|---|
| 13 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
|---|
| 14 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
|---|
| 15 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
|---|
| 16 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 17 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
|---|
| 18 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
|---|
| 19 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 20 | !! - ! 2006-07 (S. Masson) restart using iom |
|---|
| 21 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
|---|
| 22 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
|---|
| 23 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 24 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA |
|---|
| 25 | !! 3.4 ! 2011-04 (G. Madec, C. Ethe) Merge of dtatem and dtasal |
|---|
| 26 | !! 3.6 ! 2012-07 (J. Simeon, G. Madec. C. Ethe) Online coarsening of outputs |
|---|
| 27 | !! 3.6 ! 2014-04 (F. Roquet, G. Madec) New equations of state |
|---|
| 28 | !! 3.6 ! 2014-10 (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves |
|---|
| 29 | !! 3.7 ! 2014-10 (G. Madec) LDF simplication |
|---|
| 30 | !! - ! 2014-12 (G. Madec) remove KPP scheme |
|---|
| 31 | !! - ! 2015-11 (J. Chanut) free surface simplification (remove filtered free surface) |
|---|
| 32 | !! 4.0 ! 2017-05 (G. Madec) introduction of the vertical physics manager (zdfphy) |
|---|
| 33 | !! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! stp : OPA system time-stepping |
|---|
| 38 | !!---------------------------------------------------------------------- |
|---|
| 39 | USE step_oce ! time stepping definition modules |
|---|
| 40 | ! |
|---|
| 41 | USE iom ! xIOs server |
|---|
| 42 | |
|---|
| 43 | IMPLICIT NONE |
|---|
| 44 | PRIVATE |
|---|
| 45 | |
|---|
| 46 | PUBLIC stp ! called by nemogcm.F90 |
|---|
| 47 | |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | !! time level indices |
|---|
| 50 | !!---------------------------------------------------------------------- |
|---|
| 51 | INTEGER, PUBLIC :: Nbb, Nnn, Naa, Nrhs !! used by nemo_init |
|---|
| 52 | |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 55 | !! $Id$ |
|---|
| 56 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 57 | !!---------------------------------------------------------------------- |
|---|
| 58 | CONTAINS |
|---|
| 59 | |
|---|
| 60 | #if defined key_agrif |
|---|
| 61 | RECURSIVE SUBROUTINE stp( ) |
|---|
| 62 | INTEGER :: kstp ! ocean time-step index |
|---|
| 63 | #else |
|---|
| 64 | SUBROUTINE stp( kstp ) |
|---|
| 65 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
|---|
| 66 | #endif |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | !! *** ROUTINE stp *** |
|---|
| 69 | !! |
|---|
| 70 | !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.) |
|---|
| 71 | !! - Time stepping of SI3 (dynamic and thermodynamic eqs.) |
|---|
| 72 | !! - Time stepping of TRC (passive tracer eqs.) |
|---|
| 73 | !! |
|---|
| 74 | !! ** Method : -1- Update forcings and data |
|---|
| 75 | !! -2- Update ocean physics |
|---|
| 76 | !! -3- Compute the t and s trends |
|---|
| 77 | !! -4- Update t and s |
|---|
| 78 | !! -5- Compute the momentum trends |
|---|
| 79 | !! -6- Update the horizontal velocity |
|---|
| 80 | !! -7- Compute the diagnostics variables (rd,N2, hdiv,w) |
|---|
| 81 | !! -8- Outputs and diagnostics |
|---|
| 82 | !!---------------------------------------------------------------------- |
|---|
| 83 | INTEGER :: ji, jj, jk ! dummy loop indice |
|---|
| 84 | INTEGER :: indic ! error indicator if < 0 |
|---|
| 85 | !!gm kcall can be removed, I guess |
|---|
| 86 | INTEGER :: kcall ! optional integer argument (dom_vvl_sf_nxt) |
|---|
| 87 | !! --------------------------------------------------------------------- |
|---|
| 88 | #if defined key_agrif |
|---|
| 89 | kstp = nit000 + Agrif_Nb_Step() |
|---|
| 90 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 91 | IF( lk_agrif_debug ) THEN |
|---|
| 92 | IF( Agrif_Root() .and. lwp) WRITE(*,*) '---' |
|---|
| 93 | IF(lwp) WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint() |
|---|
| 94 | ENDIF |
|---|
| 95 | IF( kstp == nit000 + 1 ) lk_agrif_fstep = .FALSE. |
|---|
| 96 | # if defined key_iomput |
|---|
| 97 | IF( Agrif_Nbstepint() == 0 ) CALL iom_swap( cxios_context ) |
|---|
| 98 | # endif |
|---|
| 99 | #endif |
|---|
| 100 | ! |
|---|
| 101 | IF( ln_timing ) CALL timing_start('stp') |
|---|
| 102 | ! |
|---|
| 103 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 104 | ! update I/O and calendar |
|---|
| 105 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 106 | indic = 0 ! reset to no error condition |
|---|
| 107 | |
|---|
| 108 | IF( kstp == nit000 ) THEN ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 109 | CALL iom_init( cxios_context ) ! for model grid (including passible AGRIF zoom) |
|---|
| 110 | IF( ln_crs ) CALL iom_init( TRIM(cxios_context)//"_crs" ) ! for coarse grid |
|---|
| 111 | ENDIF |
|---|
| 112 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 113 | CALL iom_setkt( kstp - nit000 + 1, cxios_context ) ! tell IOM we are at time step kstp |
|---|
| 114 | IF( ln_crs ) CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" ) ! tell IOM we are at time step kstp |
|---|
| 115 | |
|---|
| 116 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 117 | ! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice) |
|---|
| 118 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 119 | IF( ln_tide ) CALL sbc_tide( kstp ) ! update tide potential |
|---|
| 120 | IF( ln_apr_dyn ) CALL sbc_apr ( kstp ) ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib) |
|---|
| 121 | IF( ln_bdy ) CALL bdy_dta ( kstp, Nnn, kt_offset = +1 ) ! update dynamic & tracer data at open boundaries |
|---|
| 122 | IF( ln_isf ) CALL isf_stp ( kstp, Nnn ) |
|---|
| 123 | CALL sbc ( kstp, Nbb, Nnn ) ! Sea Boundary Condition (including sea-ice) |
|---|
| 124 | |
|---|
| 125 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 126 | ! Update stochastic parameters and random T/S fluctuations |
|---|
| 127 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 128 | IF( ln_sto_eos ) CALL sto_par( kstp ) ! Stochastic parameters |
|---|
| 129 | IF( ln_sto_eos ) CALL sto_pts( ts(:,:,:,:,Nnn) ) ! Random T/S fluctuations |
|---|
| 130 | |
|---|
| 131 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 132 | ! Ocean physics update |
|---|
| 133 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 134 | ! THERMODYNAMICS |
|---|
| 135 | CALL eos_rab( ts(:,:,:,:,Nbb), rab_b, Nnn ) ! before local thermal/haline expension ratio at T-points |
|---|
| 136 | CALL eos_rab( ts(:,:,:,:,Nnn), rab_n, Nnn ) ! now local thermal/haline expension ratio at T-points |
|---|
| 137 | CALL bn2 ( ts(:,:,:,:,Nbb), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency |
|---|
| 138 | CALL bn2 ( ts(:,:,:,:,Nnn), rab_n, rn2, Nnn ) ! now Brunt-Vaisala frequency |
|---|
| 139 | |
|---|
| 140 | ! VERTICAL PHYSICS |
|---|
| 141 | CALL zdf_phy( kstp, Nbb, Nnn, Nrhs ) ! vertical physics update (top/bot drag, avt, avs, avm + MLD) |
|---|
| 142 | |
|---|
| 143 | ! LATERAL PHYSICS |
|---|
| 144 | ! |
|---|
| 145 | IF( l_ldfslp ) THEN ! slope of lateral mixing |
|---|
| 146 | CALL eos( ts(:,:,:,:,Nbb), rhd, gdept_0(:,:,:) ) ! before in situ density |
|---|
| 147 | |
|---|
| 148 | IF( ln_zps .AND. .NOT. ln_isfcav) & |
|---|
| 149 | & CALL zps_hde ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 150 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 151 | |
|---|
| 152 | IF( ln_zps .AND. ln_isfcav) & |
|---|
| 153 | & CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi, & ! Partial steps for top cell (ISF) |
|---|
| 154 | & rhd, gru , grv , grui, grvi ) ! of t, s, rd at the first ocean level |
|---|
| 155 | IF( ln_traldf_triad ) THEN |
|---|
| 156 | CALL ldf_slp_triad( kstp, Nbb, Nnn ) ! before slope for triad operator |
|---|
| 157 | ELSE |
|---|
| 158 | CALL ldf_slp ( kstp, rhd, rn2b, Nbb, Nnn ) ! before slope for standard operator |
|---|
| 159 | ENDIF |
|---|
| 160 | ENDIF |
|---|
| 161 | ! ! eddy diffusivity coeff. |
|---|
| 162 | IF( l_ldftra_time .OR. l_ldfeiv_time ) CALL ldf_tra( kstp, Nbb, Nnn ) ! and/or eiv coeff. |
|---|
| 163 | IF( l_ldfdyn_time ) CALL ldf_dyn( kstp, Nbb ) ! eddy viscosity coeff. |
|---|
| 164 | |
|---|
| 165 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 166 | ! Ocean dynamics : hdiv, ssh, e3, u, v, w |
|---|
| 167 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 168 | |
|---|
| 169 | CALL ssh_nxt ( kstp, Nbb, Nnn, ssh, Naa ) ! after ssh (includes call to div_hor) |
|---|
| 170 | IF( .NOT.ln_linssh ) CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa ) ! after vertical scale factors |
|---|
| 171 | CALL wzv ( kstp, Nbb, Nnn, ww, Naa ) ! now cross-level velocity |
|---|
| 172 | IF( ln_zad_Aimp ) CALL wAimp ( kstp, Nnn ) ! Adaptive-implicit vertical advection partitioning |
|---|
| 173 | CALL eos ( ts(:,:,:,:,Nnn), rhd, rhop, gdept(:,:,:,Nnn) ) ! now in situ density for hpg computation |
|---|
| 174 | |
|---|
| 175 | |
|---|
| 176 | uu(:,:,:,Nrhs) = 0._wp ! set dynamics trends to zero |
|---|
| 177 | vv(:,:,:,Nrhs) = 0._wp |
|---|
| 178 | |
|---|
| 179 | IF( lk_asminc .AND. ln_asmiau .AND. ln_dyninc ) & |
|---|
| 180 | & CALL dyn_asm_inc ( kstp, Nbb, Nnn, uu, vv, Nrhs ) ! apply dynamics assimilation increment |
|---|
| 181 | IF( ln_bdy ) CALL bdy_dyn3d_dmp ( kstp, Nbb, uu, vv, Nrhs ) ! bdy damping trends |
|---|
| 182 | #if defined key_agrif |
|---|
| 183 | IF(.NOT. Agrif_Root()) & |
|---|
| 184 | & CALL Agrif_Sponge_dyn ! momentum sponge |
|---|
| 185 | #endif |
|---|
| 186 | CALL dyn_adv( kstp, Nbb, Nnn , uu, vv, Nrhs ) ! advection (VF or FF) ==> RHS |
|---|
| 187 | CALL dyn_vor( kstp, Nnn , uu, vv, Nrhs ) ! vorticity ==> RHS |
|---|
| 188 | CALL dyn_ldf( kstp, Nbb, Nnn , uu, vv, Nrhs ) ! lateral mixing |
|---|
| 189 | IF( ln_zdfosm ) CALL dyn_osm( kstp, Nnn , uu, vv, Nrhs ) ! OSMOSIS non-local velocity fluxes ==> RHS |
|---|
| 190 | CALL dyn_hpg( kstp, Nnn , uu, vv, Nrhs ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 191 | CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa ) ! surface pressure gradient |
|---|
| 192 | |
|---|
| 193 | ! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs) as well |
|---|
| 194 | IF( ln_dynspg_ts ) THEN ! vertical scale factors and vertical velocity need to be updated |
|---|
| 195 | CALL div_hor ( kstp, Nbb, Nnn ) ! Horizontal divergence (2nd call in time-split case) |
|---|
| 196 | IF(.NOT.ln_linssh) CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa, kcall=2 ) ! after vertical scale factors (update depth average component) |
|---|
| 197 | ENDIF |
|---|
| 198 | CALL dyn_zdf( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa ) ! vertical diffusion ==> after |
|---|
| 199 | |
|---|
| 200 | IF( ln_dynspg_ts ) THEN |
|---|
| 201 | CALL wzv ( kstp, Nbb, Nnn, ww, Naa ) ! now cross-level velocity |
|---|
| 202 | IF( ln_zad_Aimp ) CALL wAimp ( kstp, Nnn ) ! Adaptive-implicit vertical advection partitioning |
|---|
| 203 | ENDIF |
|---|
| 204 | |
|---|
| 205 | |
|---|
| 206 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 207 | ! cool skin |
|---|
| 208 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 209 | IF ( ln_diurnal ) CALL diurnal_layers( kstp ) |
|---|
| 210 | |
|---|
| 211 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 212 | ! diagnostics and outputs |
|---|
| 213 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 214 | IF( ln_floats ) CALL flo_stp ( kstp, Nbb, Nnn ) ! drifting Floats |
|---|
| 215 | IF( ln_diacfl ) CALL dia_cfl ( kstp, Nnn ) ! Courant number diagnostics |
|---|
| 216 | IF( lk_diahth ) CALL dia_hth ( kstp, Nnn ) ! Thermocline depth (20 degres isotherm depth) |
|---|
| 217 | IF( ln_diadct ) CALL dia_dct ( kstp, Nnn ) ! Transports |
|---|
| 218 | CALL dia_ar5 ( kstp, Nnn ) ! ar5 diag |
|---|
| 219 | IF( ln_diaharm ) CALL dia_harm( kstp, Nnn ) ! Tidal harmonic analysis |
|---|
| 220 | CALL dia_wri ( kstp, Nnn ) ! ocean model: outputs |
|---|
| 221 | ! |
|---|
| 222 | IF( ln_crs ) CALL crs_fld ( kstp, Nnn ) ! ocean model: online field coarsening & output |
|---|
| 223 | |
|---|
| 224 | #if defined key_top |
|---|
| 225 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 226 | ! Passive Tracer Model |
|---|
| 227 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 228 | CALL trc_stp ( kstp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping |
|---|
| 229 | #endif |
|---|
| 230 | |
|---|
| 231 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 232 | ! Active tracers |
|---|
| 233 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 234 | ts(:,:,:,:,Nrhs) = 0._wp ! set tracer trends to zero |
|---|
| 235 | |
|---|
| 236 | IF( lk_asminc .AND. ln_asmiau .AND. & |
|---|
| 237 | & ln_trainc ) CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs ) ! apply tracer assimilation increment |
|---|
| 238 | CALL tra_sbc ( kstp, Nnn, ts, Nrhs ) ! surface boundary condition |
|---|
| 239 | IF( ln_traqsr ) CALL tra_qsr ( kstp, Nnn, ts, Nrhs ) ! penetrative solar radiation qsr |
|---|
| 240 | IF( ln_isf ) CALL tra_isf ( kstp, Nnn, ts, Nrhs ) ! ice shelf heat flux |
|---|
| 241 | IF( ln_trabbc ) CALL tra_bbc ( kstp, Nnn, ts, Nrhs ) ! bottom heat flux |
|---|
| 242 | IF( ln_trabbl ) CALL tra_bbl ( kstp, Nbb, Nnn, ts, Nrhs ) ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 243 | IF( ln_tradmp ) CALL tra_dmp ( kstp, Nbb, Nnn, ts, Nrhs ) ! internal damping trends |
|---|
| 244 | IF( ln_bdy ) CALL bdy_tra_dmp( kstp, Nbb, ts, Nrhs ) ! bdy damping trends |
|---|
| 245 | #if defined key_agrif |
|---|
| 246 | IF(.NOT. Agrif_Root()) & |
|---|
| 247 | & CALL Agrif_Sponge_tra ! tracers sponge |
|---|
| 248 | #endif |
|---|
| 249 | CALL tra_adv ( kstp, Nbb, Nnn, ts, Nrhs ) ! hor. + vert. advection ==> RHS |
|---|
| 250 | IF( ln_zdfosm ) CALL tra_osm ( kstp, Nnn, ts, Nrhs ) ! OSMOSIS non-local tracer fluxes ==> RHS |
|---|
| 251 | IF( lrst_oce .AND. ln_zdfosm ) & |
|---|
| 252 | & CALL osm_rst ( kstp, Nnn, 'WRITE' ) ! write OSMOSIS outputs + ww (so must do here) to restarts |
|---|
| 253 | CALL tra_ldf ( kstp, Nbb, Nnn, ts, Nrhs ) ! lateral mixing |
|---|
| 254 | |
|---|
| 255 | !!gm : why CALL to dia_ptr has been moved here??? (use trends info?) |
|---|
| 256 | IF( ln_diaptr ) CALL dia_ptr( Nnn ) ! Poleward adv/ldf TRansports diagnostics |
|---|
| 257 | !!gm |
|---|
| 258 | CALL tra_zdf ( kstp, Nbb, Nnn, Nrhs, ts, Naa ) ! vert. mixing & after tracer ==> after |
|---|
| 259 | IF( ln_zdfnpc ) CALL tra_npc ( kstp, Nnn, Nrhs, ts, Naa ) ! update after fields by non-penetrative convection |
|---|
| 260 | |
|---|
| 261 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 262 | ! Set boundary conditions, time filter and swap time levels |
|---|
| 263 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 264 | !!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap |
|---|
| 265 | !! (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields. |
|---|
| 266 | !! If so: |
|---|
| 267 | !! (i) no need to call agrif update at initialization time |
|---|
| 268 | !! (ii) no need to update "before" fields |
|---|
| 269 | !! |
|---|
| 270 | !! Apart from creating new tra_swp/dyn_swp routines, this however: |
|---|
| 271 | !! (i) makes boundary conditions at initialization time computed from updated fields which is not the case between |
|---|
| 272 | !! two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation", |
|---|
| 273 | !! e.g. a shift of the feedback interface inside child domain. |
|---|
| 274 | !! (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same |
|---|
| 275 | !! place. |
|---|
| 276 | !! |
|---|
| 277 | !!jc2: dynnxt must be the latest call. e3t(:,:,:,Nbb) are indeed updated in that routine |
|---|
| 278 | CALL tra_atf ( kstp, Nbb, Nnn, Naa, ts ) ! time filtering of "now" tracer arrays |
|---|
| 279 | CALL dyn_atf ( kstp, Nbb, Nnn, Naa, uu, vv, e3t, e3u, e3v ) ! time filtering of "now" velocities and scale factors |
|---|
| 280 | CALL ssh_atf ( kstp, Nbb, Nnn, Naa, ssh ) ! time filtering of "now" sea surface height |
|---|
| 281 | ! |
|---|
| 282 | ! Swap time levels |
|---|
| 283 | Nrhs = Nbb |
|---|
| 284 | Nbb = Nnn |
|---|
| 285 | Nnn = Naa |
|---|
| 286 | Naa = Nrhs |
|---|
| 287 | ! |
|---|
| 288 | IF(.NOT.ln_linssh) CALL dom_vvl_sf_update( kstp, Nbb, Nnn, Naa ) ! recompute vertical scale factors |
|---|
| 289 | ! |
|---|
| 290 | IF( ln_diahsb ) CALL dia_hsb ( kstp, Nbb, Nnn ) ! - ML - global conservation diagnostics |
|---|
| 291 | |
|---|
| 292 | !!gm : This does not only concern the dynamics ==>>> add a new title |
|---|
| 293 | !!gm2: why ouput restart before AGRIF update? |
|---|
| 294 | !! |
|---|
| 295 | !!jc: That would be better, but see comment above |
|---|
| 296 | !! |
|---|
| 297 | IF( lrst_oce ) CALL rst_write ( kstp, Nbb, Nnn ) ! write output ocean restart file |
|---|
| 298 | IF( ln_sto_eos ) CALL sto_rst_write( kstp ) ! write restart file for stochastic parameters |
|---|
| 299 | |
|---|
| 300 | #if defined key_agrif |
|---|
| 301 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 302 | ! AGRIF |
|---|
| 303 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 304 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 305 | CALL Agrif_Integrate_ChildGrids( stp ) ! allows to finish all the Child Grids before updating |
|---|
| 306 | |
|---|
| 307 | IF( Agrif_NbStepint() == 0 ) THEN |
|---|
| 308 | CALL Agrif_update_all( ) ! Update all components |
|---|
| 309 | ENDIF |
|---|
| 310 | #endif |
|---|
| 311 | IF( ln_diaobs ) CALL dia_obs ( kstp, Nnn ) ! obs-minus-model (assimilation) diagnostics (call after dynamics update) |
|---|
| 312 | |
|---|
| 313 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 314 | ! Control |
|---|
| 315 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 316 | CALL stp_ctl ( kstp, Nbb, Nnn, indic ) |
|---|
| 317 | |
|---|
| 318 | IF( kstp == nit000 ) THEN ! 1st time step only |
|---|
| 319 | CALL iom_close( numror ) ! close input ocean restart file |
|---|
| 320 | IF(lwm) CALL FLUSH ( numond ) ! flush output namelist oce |
|---|
| 321 | IF(lwm .AND. numoni /= -1 ) CALL FLUSH ( numoni ) ! flush output namelist ice (if exist) |
|---|
| 322 | ENDIF |
|---|
| 323 | |
|---|
| 324 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 325 | ! Coupled mode |
|---|
| 326 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 327 | !!gm why lk_oasis and not lk_cpl ???? |
|---|
| 328 | IF( lk_oasis ) CALL sbc_cpl_snd( kstp, Nbb, Nnn ) ! coupled mode : field exchanges |
|---|
| 329 | ! |
|---|
| 330 | #if defined key_iomput |
|---|
| 331 | IF( kstp == nitend .OR. indic < 0 ) THEN |
|---|
| 332 | CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF |
|---|
| 333 | IF(lrxios) CALL iom_context_finalize( crxios_context ) |
|---|
| 334 | IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) ! |
|---|
| 335 | ENDIF |
|---|
| 336 | #endif |
|---|
| 337 | ! |
|---|
| 338 | IF( ln_timing ) CALL timing_stop('stp') |
|---|
| 339 | ! |
|---|
| 340 | END SUBROUTINE stp |
|---|
| 341 | ! |
|---|
| 342 | !!====================================================================== |
|---|
| 343 | END MODULE step |
|---|
