source: NEMO/branches/2019/dev_ASINTER-01-05_merged/src/OCE/SBC/sbcmod.F90 @ 12015

Last change on this file since 12015 was 12015, checked in by gsamson, 4 months ago

dev_ASINTER-01-05_merged: merge dev_r11085_ASINTER-05_Brodeau_Advanced_Bulk branch @rev11988 with dev_r11265_ASINTER-01_Guillaume_ABL1D branch @rev11937 (tickets #2159 and #2131); ORCA2_ICE(_ABL) reproductibility OK

  • Property svn:keywords set to Id
File size: 35.7 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!            4.0  ! 2019-03  (F. Lemarié & G. Samson)  add ABL compatibility (ln_abl=TRUE)
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   sbc_init      : read namsbc namelist
22   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
23   !!   sbc_final     : Finalize CICE ice model (if used)
24   !!----------------------------------------------------------------------
25   USE oce            ! ocean dynamics and tracers
26   USE dom_oce        ! ocean space and time domain
27   USE phycst         ! physical constants
28   USE sbc_oce        ! Surface boundary condition: ocean fields
29   USE trc_oce        ! shared ocean-passive tracers variables
30   USE sbc_ice        ! Surface boundary condition: ice fields
31   USE sbcdcy         ! surface boundary condition: diurnal cycle
32   USE sbcssm         ! surface boundary condition: sea-surface mean variables
33   USE sbcflx         ! surface boundary condition: flux formulation
34   USE sbcblk         ! surface boundary condition: bulk formulation
35   USE sbcabl         ! atmospheric boundary layer
36   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
37#if defined key_si3
38   USE icestp         ! surface boundary condition: SI3 sea-ice model
39#endif
40   USE sbcice_cice    ! surface boundary condition: CICE sea-ice model
41   USE sbcisf         ! surface boundary condition: ice-shelf
42   USE sbccpl         ! surface boundary condition: coupled formulation
43   USE cpl_oasis3     ! OASIS routines for coupling
44   USE sbcssr         ! surface boundary condition: sea surface restoring
45   USE sbcrnf         ! surface boundary condition: runoffs
46   USE sbcapr         ! surface boundary condition: atmo pressure
47   USE sbcisf         ! surface boundary condition: ice shelf
48   USE sbcfwb         ! surface boundary condition: freshwater budget
49   USE icbstp         ! Icebergs
50   USE icb_oce  , ONLY : ln_passive_mode      ! iceberg interaction mode
51   USE traqsr         ! active tracers: light penetration
52   USE sbcwave        ! Wave module
53   USE bdy_oce   , ONLY: ln_bdy
54   USE usrdef_sbc     ! user defined: surface boundary condition
55   USE closea         ! closed sea
56   !
57   USE prtctl         ! Print control                    (prt_ctl routine)
58   USE iom            ! IOM library
59   USE in_out_manager ! I/O manager
60   USE lib_mpp        ! MPP library
61   USE timing         ! Timing
62   USE wet_dry
63   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
64
65   IMPLICIT NONE
66   PRIVATE
67
68   PUBLIC   sbc        ! routine called by step.F90
69   PUBLIC   sbc_init   ! routine called by opa.F90
70
71   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
72
73   !!----------------------------------------------------------------------
74   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
75   !! $Id$
76   !! Software governed by the CeCILL license (see ./LICENSE)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE sbc_init
81      !!---------------------------------------------------------------------
82      !!                    ***  ROUTINE sbc_init ***
83      !!
84      !! ** Purpose :   Initialisation of the ocean surface boundary computation
85      !!
86      !! ** Method  :   Read the namsbc namelist and set derived parameters
87      !!                Call init routines for all other SBC modules that have one
88      !!
89      !! ** Action  : - read namsbc parameters
90      !!              - nsbc: type of sbc
91      !!----------------------------------------------------------------------
92      INTEGER ::   ios, icpt                         ! local integer
93      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
94      !!
95      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
96         &             ln_usr   , ln_flx   , ln_blk   , ln_abl,                      &
97         &             ln_cpl   , ln_mixcpl, nn_components,                          &
98         &             nn_ice   , ln_ice_embd,                                       &
99         &             ln_traqsr, ln_dm2dc ,                                         &
100         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_isf    , ln_apr_dyn ,     &
101         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauwoc  , ln_stcor  ,     &
102         &             ln_tauw  , nn_lsm, nn_sdrift
103      !!----------------------------------------------------------------------
104      !
105      IF(lwp) THEN
106         WRITE(numout,*)
107         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
108         WRITE(numout,*) '~~~~~~~~ '
109      ENDIF
110      !
111      !                       !**  read Surface Module namelist
112      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
113      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
114901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
115      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
116      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
117902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
118      IF(lwm) WRITE( numond, namsbc )
119      !
120#if defined key_mpp_mpi
121      ncom_fsbc = nn_fsbc    ! make nn_fsbc available for lib_mpp
122#endif
123      !                             !* overwrite namelist parameter using CPP key information
124#if defined key_agrif
125      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
126         IF( lk_si3  )   nn_ice      = 2
127         IF( lk_cice )   nn_ice      = 3
128      ENDIF
129#else
130      !IF( lk_si3  )   nn_ice      = 2
131      IF( lk_cice )   nn_ice      = 3
132#endif
133      !
134      IF(lwp) THEN                  !* Control print
135         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
136         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
137         WRITE(numout,*) '      Type of air-sea fluxes : '
138         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
139         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
140         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
141         WRITE(numout,*) '         ABL          formulation                   ln_abl        = ', ln_abl
142         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
143         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
144         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
145!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
146         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
147         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
148         WRITE(numout,*) '      Sea-ice : '
149         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
150         WRITE(numout,*) '         ice embedded into ocean                    ln_ice_embd   = ', ln_ice_embd
151         WRITE(numout,*) '      Misc. options of sbc : '
152         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
153         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
154         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
155         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
156         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
157         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
158         WRITE(numout,*) '         iceshelf formulation                       ln_isf        = ', ln_isf
159         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
160         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
161         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
162         WRITE(numout,*) '                  vertical parametrization          nn_sdrift     = ', nn_sdrift
163         WRITE(numout,*) '               wave modified ocean stress           ln_tauwoc     = ', ln_tauwoc
164         WRITE(numout,*) '               wave modified ocean stress component ln_tauw       = ', ln_tauw
165         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
166         WRITE(numout,*) '               neutral drag coefficient (CORE,NCAR) ln_cdgw       = ', ln_cdgw
167      ENDIF
168      !
169      IF( .NOT.ln_wave ) THEN
170         ln_sdw = .false. ; ln_cdgw = .false. ; ln_tauwoc = .false. ; ln_tauw = .false. ; ln_stcor = .false.
171      ENDIF
172      IF( ln_sdw ) THEN
173         IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) &
174            CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' )
175      ENDIF
176      ll_st_bv2014  = ( nn_sdrift==jp_breivik_2014 )
177      ll_st_li2017  = ( nn_sdrift==jp_li_2017 )
178      ll_st_bv_li   = ( ll_st_bv2014 .OR. ll_st_li2017 )
179      ll_st_peakfr  = ( nn_sdrift==jp_peakfr )
180      IF( ln_tauwoc .AND. ln_tauw ) &
181         CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', &
182                                  '(ln_tauwoc=.true. and ln_tauw=.true.)' )
183      IF( ln_tauwoc ) &
184         CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' )
185      IF( ln_tauw ) &
186         CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', &
187                              'This will override any other specification of the ocean stress' )
188      !
189      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
190         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
191         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
192         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
193      ENDIF
194      !                       !**  check option consistency
195      !
196      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
197      SELECT CASE( nn_components )
198      CASE( jp_iam_nemo )
199         IF(lwp) WRITE(numout,*) '   ==>>>   NEMO configured as a single executable (i.e. including both OPA and Surface module)'
200      CASE( jp_iam_opa  )
201         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, OPA component'
202         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
203         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
204         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
205      CASE( jp_iam_sas  )
206         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, SAS component'
207         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
208         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
209      CASE DEFAULT
210         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
211      END SELECT
212      !                             !* coupled options
213      IF( ln_cpl ) THEN
214         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
215            &                                  '           required to defined key_oasis3' )
216      ENDIF
217      IF( ln_mixcpl ) THEN
218         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
219            &                                  '           required to defined key_oasis3' )
220         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
221         IF( nn_components /= jp_iam_nemo )    &
222            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
223            &                                   '          not yet working with sas-opa coupling via oasis' )
224      ENDIF
225      !                             !* sea-ice
226      SELECT CASE( nn_ice )
227      CASE( 0 )                        !- no ice in the domain
228      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
229      CASE( 2 )                        !- SI3  ice model
230         IF( .NOT.( ln_blk .OR. ln_cpl .OR. ln_abl ) )   &
231            &                   CALL ctl_stop( 'sbc_init : SI3 sea-ice model requires ln_blk or ln_cpl or ln_abl = T' )
232      CASE( 3 )                        !- CICE ice model
233         IF( .NOT.( ln_blk .OR. ln_cpl .OR. ln_abl ) )   &
234            &                   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl or ln_abl = T' )
235         IF( lk_agrif                                )   &
236            &                   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
237      CASE DEFAULT                     !- not supported
238      END SELECT
239      !
240      !                       !**  allocate and set required variables
241      !
242      !                             !* allocate sbc arrays
243      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
244#if ! defined key_si3 && ! defined key_cice
245      IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' )
246#endif
247      !
248      IF( .NOT.ln_isf ) THEN        !* No ice-shelf in the domain : allocate and set to zero
249         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
250         fwfisf  (:,:)   = 0._wp   ;   risf_tsc  (:,:,:) = 0._wp
251         fwfisf_b(:,:)   = 0._wp   ;   risf_tsc_b(:,:,:) = 0._wp
252      END IF
253      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
254         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
255      ENDIF
256      !
257      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
258      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
259
260      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
261
262      !                          ! Choice of the Surface Boudary Condition (set nsbc)
263      nday_qsr = -1   ! allow initialization at the 1st call !LB: now warm-layer of COARE* calls "sbc_dcy_param" of sbcdcy.F90!
264      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
265         !LB:nday_qsr = -1   ! allow initialization at the 1st call
266         IF( .NOT.( ln_flx .OR. ln_blk .OR. ln_abl ) .AND. nn_components /= jp_iam_opa )   &
267            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires flux, bulk or abl formulation' )
268      ENDIF
269      !                             !* Choice of the Surface Boudary Condition
270      !                             (set nsbc)
271      !
272      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
273      ll_opa      = nn_components == jp_iam_opa
274      ll_not_nemo = nn_components /= jp_iam_nemo
275      icpt = 0
276      !
277      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
278      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
279      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
280      IF( ln_abl          ) THEN   ;   nsbc = jp_abl     ; icpt = icpt + 1   ;   ENDIF       ! ABL                  formulation
281      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
282      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
283      !
284      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
285      !
286      IF(lwp) THEN                     !- print the choice of surface flux formulation
287         WRITE(numout,*)
288         SELECT CASE( nsbc )
289         CASE( jp_usr     )   ;   WRITE(numout,*) '   ==>>>   user defined forcing formulation'
290         CASE( jp_flx     )   ;   WRITE(numout,*) '   ==>>>   flux formulation'
291         CASE( jp_blk     )   ;   WRITE(numout,*) '   ==>>>   bulk formulation'
292         CASE( jp_abl     )   ;   WRITE(numout,*) '   ==>>>   ABL  formulation'
293         CASE( jp_purecpl )   ;   WRITE(numout,*) '   ==>>>   pure coupled formulation'
294!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
295         CASE( jp_none    )   ;   WRITE(numout,*) '   ==>>>   OPA coupled to SAS via oasis'
296            IF( ln_mixcpl )       WRITE(numout,*) '               + forced-coupled mixed formulation'
297         END SELECT
298         IF( ll_not_nemo  )       WRITE(numout,*) '               + OASIS coupled SAS'
299      ENDIF
300      !
301      !                             !* OASIS initialization
302      !
303      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
304      !                                              !                      (2) the use of nn_fsbc
305      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
306      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
307      IF( nn_components /= jp_iam_nemo ) THEN
308         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
309         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
310         !
311         IF(lwp)THEN
312            WRITE(numout,*)
313            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
314            WRITE(numout,*)
315         ENDIF
316      ENDIF
317      !
318      !                             !* check consistency between model timeline and nn_fsbc
319      IF( ln_rst_list .OR. nn_stock /= -1 ) THEN   ! we will do restart files
320         IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 ) THEN
321            WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
322            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
323         ENDIF
324         IF( .NOT. ln_rst_list .AND. MOD( nn_stock, nn_fsbc) /= 0 ) THEN   ! we don't use nn_stock if ln_rst_list
325            WRITE(ctmp1,*) 'sbc_init : nn_stock (', nn_stock, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
326            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
327         ENDIF
328      ENDIF
329      !
330      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
331         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
332      !
333      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
334         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
335      !
336   
337      !                       !**  associated modules : initialization
338      !
339                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
340      !
341      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
342
343      IF( ln_abl      )   CALL sbc_abl_init            ! Atmospheric Boundary Layer (ABL)
344
345      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
346      !
347      IF( ln_isf      )   CALL sbc_isf_init            ! Compute iceshelves
348      !
349                          CALL sbc_rnf_init            ! Runof initialization
350      !
351      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
352      !
353#if defined key_si3
354      IF( lk_agrif .AND. nn_ice == 0 ) THEN            ! allocate ice arrays in case agrif + ice-model + no-ice in child grid
355                          IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' )
356      ELSEIF( nn_ice == 2 ) THEN
357                          CALL ice_init                ! ICE initialization
358      ENDIF
359#endif
360      IF( nn_ice == 3 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
361      !
362      IF( ln_wave     )   CALL sbc_wave_init           ! surface wave initialisation
363      !
364      IF( lwxios ) THEN
365         CALL iom_set_rstw_var_active('utau_b')
366         CALL iom_set_rstw_var_active('vtau_b')
367         CALL iom_set_rstw_var_active('qns_b')
368         ! The 3D heat content due to qsr forcing is treated in traqsr
369         ! CALL iom_set_rstw_var_active('qsr_b')
370         CALL iom_set_rstw_var_active('emp_b')
371         CALL iom_set_rstw_var_active('sfx_b')
372      ENDIF
373
374   END SUBROUTINE sbc_init
375
376
377   SUBROUTINE sbc( kt )
378      !!---------------------------------------------------------------------
379      !!                    ***  ROUTINE sbc  ***
380      !!
381      !! ** Purpose :   provide at each time-step the ocean surface boundary
382      !!                condition (momentum, heat and freshwater fluxes)
383      !!
384      !! ** Method  :   blah blah  to be written ?????????
385      !!                CAUTION : never mask the surface stress field (tke sbc)
386      !!
387      !! ** Action  : - set the ocean surface boundary condition at before and now
388      !!                time step, i.e.
389      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
390      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
391      !!              - updte the ice fraction : fr_i
392      !!----------------------------------------------------------------------
393      INTEGER, INTENT(in) ::   kt   ! ocean time step
394      !
395      LOGICAL ::   ll_sas, ll_opa   ! local logical
396      !
397      REAL(wp) ::     zthscl        ! wd  tanh scale
398      REAL(wp), DIMENSION(jpi,jpj) ::  zwdht, zwght  ! wd dep over wd limit, wgt 
399
400      !!---------------------------------------------------------------------
401      !
402      IF( ln_timing )   CALL timing_start('sbc')
403      !
404      !                                            ! ---------------------------------------- !
405      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
406         !                                         ! ---------------------------------------- !
407         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
408         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
409         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
410         emp_b (:,:) = emp (:,:)
411         sfx_b (:,:) = sfx (:,:)
412         IF( ln_rnf ) THEN
413            rnf_b    (:,:  ) = rnf    (:,:  )
414            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
415         ENDIF
416         IF( ln_isf )  THEN
417            fwfisf_b  (:,:  ) = fwfisf  (:,:  )               
418            risf_tsc_b(:,:,:) = risf_tsc(:,:,:)             
419         ENDIF
420        !
421      ENDIF
422      !                                            ! ---------------------------------------- !
423      !                                            !        forcing field computation         !
424      !                                            ! ---------------------------------------- !
425      !
426      ll_sas = nn_components == jp_iam_sas               ! component flags
427      ll_opa = nn_components == jp_iam_opa
428      !
429      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
430      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
431
432      !
433      !                                            !==  sbc formulation  ==!
434      !                                                   
435      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
436      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
437      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
438      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
439      CASE( jp_blk     )
440         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
441                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
442                               !
443      CASE( jp_abl     )
444         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
445                               CALL sbc_abl       ( kt )                    ! ABL  formulation for the ocean
446                               !
447      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
448      CASE( jp_none    )
449         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
450      END SELECT
451      !
452      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
453      !
454      IF( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( )      ! Wind stress provided by waves
455      !
456      !                                            !==  Misc. Options  ==!
457      !
458      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
459      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )             ! Ice-cover climatology ("Ice-if" model)
460#if defined key_si3
461      CASE(  2 )   ;         CALL ice_stp  ( kt, nsbc )           ! SI3 ice model
462#endif
463      CASE(  3 )   ;         CALL sbc_ice_cice ( kt, nsbc )       ! CICE ice model
464      END SELECT
465
466      IF( ln_icebergs    )   THEN
467                                     CALL icb_stp( kt )           ! compute icebergs
468         ! icebergs may advect into haloes during the icb step and alter emp.
469         ! A lbc_lnk is necessary here to ensure restartability (#2113)
470         IF( .NOT. ln_passive_mode ) CALL lbc_lnk( 'sbcmod', emp, 'T', 1. ) ! ensure restartability with icebergs
471      ENDIF
472
473      IF( ln_isf         )   CALL sbc_isf( kt )                   ! compute iceshelves
474
475      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
476
477      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
478
479      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
480
481      ! Special treatment of freshwater fluxes over closed seas in the model domain
482      ! Should not be run if ln_diurnal_only
483      IF( l_sbc_clo .AND. (.NOT. ln_diurnal_only) )   CALL sbc_clo( kt )   
484
485!!$!RBbug do not understand why see ticket 667
486!!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
487!!$      CALL lbc_lnk( 'sbcmod', emp, 'T', 1. )
488      IF( ll_wd ) THEN     ! If near WAD point limit the flux for now
489         zthscl = atanh(rn_wd_sbcfra)                     ! taper frac default is .999
490         zwdht(:,:) = sshn(:,:) + ht_0(:,:) - rn_wdmin1   ! do this calc of water
491                                                     ! depth above wd limit once
492         WHERE( zwdht(:,:) <= 0.0 )
493            taum(:,:) = 0.0
494            utau(:,:) = 0.0
495            vtau(:,:) = 0.0
496            qns (:,:) = 0.0
497            qsr (:,:) = 0.0
498            emp (:,:) = min(emp(:,:),0.0) !can allow puddles to grow but not shrink
499            sfx (:,:) = 0.0
500         END WHERE
501         zwght(:,:) = tanh(zthscl*zwdht(:,:))
502         WHERE( zwdht(:,:) > 0.0  .and. zwdht(:,:) < rn_wd_sbcdep ) !  5 m hard limit here is arbitrary
503            qsr  (:,:) =  qsr(:,:)  * zwght(:,:)
504            qns  (:,:) =  qns(:,:)  * zwght(:,:)
505            taum (:,:) =  taum(:,:) * zwght(:,:)
506            utau (:,:) =  utau(:,:) * zwght(:,:)
507            vtau (:,:) =  vtau(:,:) * zwght(:,:)
508            sfx  (:,:) =  sfx(:,:)  * zwght(:,:)
509            emp  (:,:) =  emp(:,:)  * zwght(:,:)
510         END WHERE
511      ENDIF
512      !
513      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
514         !                                             ! ---------------------------------------- !
515         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
516            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
517            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
518            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, ldxios = lrxios )   ! before i-stress  (U-point)
519            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, ldxios = lrxios )   ! before j-stress  (V-point)
520            CALL iom_get( numror, jpdom_autoglo,  'qns_b',  qns_b, ldxios = lrxios )   ! before non solar heat flux (T-point)
521            ! The 3D heat content due to qsr forcing is treated in traqsr
522            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, ldxios = lrxios  ) ! before     solar heat flux (T-point)
523            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, ldxios = lrxios  )    ! before     freshwater flux (T-point)
524            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
525            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
526               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, ldxios = lrxios )  ! before salt flux (T-point)
527            ELSE
528               sfx_b (:,:) = sfx(:,:)
529            ENDIF
530         ELSE                                                   !* no restart: set from nit000 values
531            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
532            utau_b(:,:) = utau(:,:)
533            vtau_b(:,:) = vtau(:,:)
534            qns_b (:,:) = qns (:,:)
535            emp_b (:,:) = emp (:,:)
536            sfx_b (:,:) = sfx (:,:)
537         ENDIF
538      ENDIF
539      !                                                ! ---------------------------------------- !
540      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
541         !                                             ! ---------------------------------------- !
542         IF(lwp) WRITE(numout,*)
543         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
544            &                    'at it= ', kt,' date= ', ndastp
545         IF(lwp) WRITE(numout,*) '~~~~'
546         IF( lwxios ) CALL iom_swap(      cwxios_context          )
547         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios )
548         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios )
549         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns, ldxios = lwxios  )
550         ! The 3D heat content due to qsr forcing is treated in traqsr
551         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
552         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp, ldxios = lwxios  )
553         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx, ldxios = lwxios  )
554         IF( lwxios ) CALL iom_swap(      cxios_context          )
555      ENDIF
556      !                                                ! ---------------------------------------- !
557      !                                                !        Outputs and control print         !
558      !                                                ! ---------------------------------------- !
559      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
560         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
561         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
562         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
563         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
564         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
565         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
566         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
567         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
568         CALL iom_put( "taum"  , taum       )                   ! wind stress module
569         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
570      ENDIF
571      !
572      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
573      CALL iom_put( "vtau", vtau )   ! j-wind stress
574      !
575      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
576         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i    - : ', mask1=tmask )
577         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask )
578         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask )
579         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask )
580         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask )
581         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, kdim=jpk )
582         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, kdim=1   )
583         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, kdim=1   )
584         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
585            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask )
586      ENDIF
587
588      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
589      !
590      IF( ln_timing )   CALL timing_stop('sbc')
591      !
592   END SUBROUTINE sbc
593
594
595   SUBROUTINE sbc_final
596      !!---------------------------------------------------------------------
597      !!                    ***  ROUTINE sbc_final  ***
598      !!
599      !! ** Purpose :   Finalize CICE (if used)
600      !!---------------------------------------------------------------------
601      !
602      IF( nn_ice == 3 )   CALL cice_sbc_final
603      !
604   END SUBROUTINE sbc_final
605
606   !!======================================================================
607END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.