New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diacfl.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/DIA – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/DIA/diacfl.F90 @ 11822

Last change on this file since 11822 was 11822, checked in by acc, 4 years ago

Branch 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. Sette tested updates to branch to align with trunk changes between 10721 and 11740. Sette tests are passing but results differ from branch before these changes (except for GYRE_PISCES and VORTEX) and branch results already differed from trunk because of algorithmic fixes. Will need more checks to confirm correctness.
  • Property svn:keywords set to Id
File size: 8.3 KB
Line 
1MODULE diacfl
2   !!======================================================================
3   !!                       ***  MODULE  diacfl  ***
4   !! Output CFL diagnostics to ascii file
5   !!======================================================================
6   !! History :  3.4  !  2010-03  (E. Blockley)  Original code
7   !!            3.6  !  2014-06  (T. Graham)  Removed CPP key & Updated to vn3.6
8   !!            4.0  !  2017-09  (G. Madec)  style + comments
9   !!----------------------------------------------------------------------
10   !!   dia_cfl        : Compute and output Courant numbers at each timestep
11   !!----------------------------------------------------------------------
12   USE oce             ! ocean dynamics and active tracers
13   USE dom_oce         ! ocean space and time domain
14   USE domvvl          !
15   !
16   USE lib_mpp         ! distribued memory computing
17   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
18   USE in_out_manager  ! I/O manager
19   USE iom             !
20   USE timing          ! Performance output
21
22   IMPLICIT NONE
23   PRIVATE
24
25   CHARACTER(LEN=50) :: clname="cfl_diagnostics.ascii"    ! ascii filename
26   INTEGER           :: numcfl                            ! outfile unit
27   !
28   INTEGER, DIMENSION(3) ::   nCu_loc, nCv_loc, nCw_loc   ! U, V, and W run max locations in the global domain
29   REAL(wp)              ::   rCu_max, rCv_max, rCw_max   ! associated run max Courant number
30
31   PUBLIC   dia_cfl       ! routine called by step.F90
32   PUBLIC   dia_cfl_init  ! routine called by nemogcm
33
34   !! * Substitutions
35#  include "vectopt_loop_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
38   !! $Id$
39   !! Software governed by the CeCILL license (see ./LICENSE)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE dia_cfl ( kt, Kmm )
44      !!----------------------------------------------------------------------
45      !!                  ***  ROUTINE dia_cfl  ***
46      !!
47      !! ** Purpose :  Compute the Courant numbers Cu=u*dt/dx and Cv=v*dt/dy
48      !!               and output to ascii file 'cfl_diagnostics.ascii'
49      !!----------------------------------------------------------------------
50      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
51      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
52      !
53      INTEGER                          ::   ji, jj, jk                       ! dummy loop indices
54      REAL(wp)                         ::   z2dt, zCu_max, zCv_max, zCw_max  ! local scalars
55      INTEGER , DIMENSION(3)           ::   iloc_u , iloc_v , iloc_w , iloc  ! workspace
56      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zCu_cfl, zCv_cfl, zCw_cfl        ! workspace
57      !!----------------------------------------------------------------------
58      !
59      IF( ln_timing )   CALL timing_start('dia_cfl')
60      !
61      !                       ! setup timestep multiplier to account for initial Eulerian timestep
62      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;    z2dt = rdt
63      ELSE                                        ;    z2dt = rdt * 2._wp
64      ENDIF
65      !
66      !               
67      DO jk = 1, jpk       ! calculate Courant numbers
68         DO jj = 1, jpj
69            DO ji = 1, jpi
70               zCu_cfl(ji,jj,jk) = ABS( uu(ji,jj,jk,Kmm) ) * z2dt / e1u  (ji,jj)      ! for i-direction
71               zCv_cfl(ji,jj,jk) = ABS( vv(ji,jj,jk,Kmm) ) * z2dt / e2v  (ji,jj)      ! for j-direction
72               zCw_cfl(ji,jj,jk) = ABS( ww(ji,jj,jk) ) * z2dt / e3w(ji,jj,jk,Kmm)   ! for k-direction
73            END DO
74         END DO         
75      END DO
76      !
77      ! write outputs
78      IF( iom_use('cfl_cu') )   CALL iom_put( 'cfl_cu', MAXVAL( zCu_cfl, dim=3 ) )
79      IF( iom_use('cfl_cv') )   CALL iom_put( 'cfl_cv', MAXVAL( zCv_cfl, dim=3 ) )
80      IF( iom_use('cfl_cw') )   CALL iom_put( 'cfl_cw', MAXVAL( zCw_cfl, dim=3 ) )
81
82      !                    ! calculate maximum values and locations
83      IF( lk_mpp ) THEN
84         CALL mpp_maxloc( 'diacfl', zCu_cfl, umask, zCu_max, iloc_u )
85         CALL mpp_maxloc( 'diacfl', zCv_cfl, vmask, zCv_max, iloc_v )
86         CALL mpp_maxloc( 'diacfl', zCw_cfl, wmask, zCw_max, iloc_w )
87      ELSE
88         iloc = MAXLOC( ABS( zcu_cfl(:,:,:) ) )
89         iloc_u(1) = iloc(1) + nimpp - 1
90         iloc_u(2) = iloc(2) + njmpp - 1
91         iloc_u(3) = iloc(3)
92         zCu_max = zCu_cfl(iloc(1),iloc(2),iloc(3))
93         !
94         iloc = MAXLOC( ABS( zcv_cfl(:,:,:) ) )
95         iloc_v(1) = iloc(1) + nimpp - 1
96         iloc_v(2) = iloc(2) + njmpp - 1
97         iloc_v(3) = iloc(3)
98         zCv_max = zCv_cfl(iloc(1),iloc(2),iloc(3))
99         !
100         iloc = MAXLOC( ABS( zcw_cfl(:,:,:) ) )
101         iloc_w(1) = iloc(1) + nimpp - 1
102         iloc_w(2) = iloc(2) + njmpp - 1
103         iloc_w(3) = iloc(3)
104         zCw_max = zCw_cfl(iloc(1),iloc(2),iloc(3))
105      ENDIF
106      !
107      !                    ! write out to file
108      IF( lwp ) THEN
109         WRITE(numcfl,FMT='(2x,i6,3x,a6,4x,f7.4,1x,i4,1x,i4,1x,i4)') kt, 'Max Cu', zCu_max, iloc_u(1), iloc_u(2), iloc_u(3)
110         WRITE(numcfl,FMT='(11x,     a6,4x,f7.4,1x,i4,1x,i4,1x,i4)')     'Max Cv', zCv_max, iloc_v(1), iloc_v(2), iloc_v(3)
111         WRITE(numcfl,FMT='(11x,     a6,4x,f7.4,1x,i4,1x,i4,1x,i4)')     'Max Cw', zCw_max, iloc_w(1), iloc_w(2), iloc_w(3)
112      ENDIF
113      !
114      !                    ! update maximum Courant numbers from whole run if applicable
115      IF( zCu_max > rCu_max ) THEN   ;   rCu_max = zCu_max   ;   nCu_loc(:) = iloc_u(:)   ;   ENDIF
116      IF( zCv_max > rCv_max ) THEN   ;   rCv_max = zCv_max   ;   nCv_loc(:) = iloc_v(:)   ;   ENDIF
117      IF( zCw_max > rCw_max ) THEN   ;   rCw_max = zCw_max   ;   nCw_loc(:) = iloc_w(:)   ;   ENDIF
118
119      !                    ! at end of run output max Cu and Cv and close ascii file
120      IF( kt == nitend .AND. lwp ) THEN
121         ! to ascii file
122         WRITE(numcfl,*) '******************************************'
123         WRITE(numcfl,FMT='(3x,a12,6x,f7.4,1x,i4,1x,i4,1x,i4)') 'Run Max Cu', rCu_max, nCu_loc(1), nCu_loc(2), nCu_loc(3)
124         WRITE(numcfl,FMT='(3x,a8,11x,f15.1)') ' => dt/C', z2dt/rCu_max
125         WRITE(numcfl,*) '******************************************'
126         WRITE(numcfl,FMT='(3x,a12,6x,f7.4,1x,i4,1x,i4,1x,i4)') 'Run Max Cv', rCv_max, nCv_loc(1), nCv_loc(2), nCv_loc(3)
127         WRITE(numcfl,FMT='(3x,a8,11x,f15.1)') ' => dt/C', z2dt/rCv_max
128         WRITE(numcfl,*) '******************************************'
129         WRITE(numcfl,FMT='(3x,a12,6x,f7.4,1x,i4,1x,i4,1x,i4)') 'Run Max Cw', rCw_max, nCw_loc(1), nCw_loc(2), nCw_loc(3)
130         WRITE(numcfl,FMT='(3x,a8,11x,f15.1)') ' => dt/C', z2dt/rCw_max
131         CLOSE( numcfl ) 
132         !
133         ! to ocean output
134         WRITE(numout,*)
135         WRITE(numout,*) 'dia_cfl : Maximum Courant number information for the run '
136         WRITE(numout,*) '~~~~~~~'
137         WRITE(numout,*) '   Max Cu = ', rCu_max, ' at (i,j,k) = (',nCu_loc(1),nCu_loc(2),nCu_loc(3),') => dt/C = ', z2dt/rCu_max
138         WRITE(numout,*) '   Max Cv = ', rCv_max, ' at (i,j,k) = (',nCv_loc(1),nCv_loc(2),nCv_loc(3),') => dt/C = ', z2dt/rCv_max
139         WRITE(numout,*) '   Max Cw = ', rCw_max, ' at (i,j,k) = (',nCw_loc(1),nCw_loc(2),nCw_loc(3),') => dt/C = ', z2dt/rCw_max
140      ENDIF
141      !
142      IF( ln_timing )   CALL timing_stop('dia_cfl')
143      !
144   END SUBROUTINE dia_cfl
145
146
147   SUBROUTINE dia_cfl_init
148      !!----------------------------------------------------------------------
149      !!                  ***  ROUTINE dia_cfl_init  ***
150      !!                   
151      !! ** Purpose :   create output file, initialise arrays
152      !!----------------------------------------------------------------------
153      !
154      IF(lwp) THEN
155         WRITE(numout,*)
156         WRITE(numout,*) 'dia_cfl : Outputting CFL diagnostics to ',TRIM(clname), ' file'
157         WRITE(numout,*) '~~~~~~~'
158         WRITE(numout,*)
159         !
160         ! create output ascii file
161         CALL ctl_opn( numcfl, clname, 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', 1, numout, lwp, 1 )
162         WRITE(numcfl,*) 'Timestep  Direction  Max C     i    j    k'
163         WRITE(numcfl,*) '******************************************'
164      ENDIF
165      !
166      rCu_max = 0._wp
167      rCv_max = 0._wp
168      rCw_max = 0._wp
169      !
170   END SUBROUTINE dia_cfl_init
171
172   !!======================================================================
173END MODULE diacfl
Note: See TracBrowser for help on using the repository browser.