source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/DYN/dynadv_cen2.F90 @ 10789

Last change on this file since 10789 was 10789, checked in by davestorkey, 21 months ago

branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps: Convert first batch of DYN routines and "wn" → "ww".

  • Property svn:keywords set to Id
File size: 7.5 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2  : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme 
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
27
28   !! * Substitutions
29#  include "vectopt_loop_substitute.h90"
30   !!----------------------------------------------------------------------
31   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
32   !! $Id$
33   !! Software governed by the CeCILL license (see ./LICENSE)
34   !!----------------------------------------------------------------------
35CONTAINS
36
37   SUBROUTINE dyn_adv_cen2( kt, ktlev, pu_rhs, pv_rhs )
38      !!----------------------------------------------------------------------
39      !!                  ***  ROUTINE dyn_adv_cen2  ***
40      !!
41      !! ** Purpose :   Compute the now momentum advection trend in flux form
42      !!              and the general trend of the momentum equation.
43      !!
44      !! ** Method  :   Trend evaluated using now fields (centered in time)
45      !!
46      !! ** Action  :   (pu_rhs,pv_rhs) updated with the now vorticity term trend
47      !!----------------------------------------------------------------------
48      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index
49      INTEGER, INTENT( in ) ::   ktlev   ! time level index for source terms
50      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pu_rhs, pv_rhs ! momentum trends
51      !
52      INTEGER  ::   ji, jj, jk   ! dummy loop indices
53      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zfu_t, zfu_f, zfu_uw, zfu
54      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zfv_t, zfv_f, zfv_vw, zfv, zfw
55      !!----------------------------------------------------------------------
56      !
57      IF( kt == nit000 .AND. lwp ) THEN
58         WRITE(numout,*)
59         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
60         WRITE(numout,*) '~~~~~~~~~~~~'
61      ENDIF
62      !
63      IF( l_trddyn ) THEN           ! trends: store the input trends
64         zfu_uw(:,:,:) = pu_rhs(:,:,:)
65         zfv_vw(:,:,:) = pv_rhs(:,:,:)
66      ENDIF
67      !
68      !                             !==  Horizontal advection  ==!
69      !
70      DO jk = 1, jpkm1                    ! horizontal transport
71         zfu(:,:,jk) = 0.25_wp * e2u(:,:) * e3u(:,:,jk,ktlev) * uu(:,:,jk,ktlev)
72         zfv(:,:,jk) = 0.25_wp * e1v(:,:) * e3v(:,:,jk,ktlev) * vv(:,:,jk,ktlev)
73         DO jj = 1, jpjm1                 ! horizontal momentum fluxes (at T- and F-point)
74            DO ji = 1, fs_jpim1   ! vector opt.
75               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( uu(ji,jj,jk,ktlev) + uu(ji+1,jj  ,jk,ktlev) )
76               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( uu(ji,jj,jk,ktlev) + uu(ji  ,jj+1,jk,ktlev) )
77               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( vv(ji,jj,jk,ktlev) + vv(ji+1,jj  ,jk,ktlev) )
78               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( vv(ji,jj,jk,ktlev) + vv(ji  ,jj+1,jk,ktlev) )
79            END DO
80         END DO
81         DO jj = 2, jpjm1                 ! divergence of horizontal momentum fluxes
82            DO ji = fs_2, fs_jpim1   ! vector opt.
83               pu_rhs(ji,jj,jk) = pu_rhs(ji,jj,jk) - (  zfu_t(ji+1,jj,jk) - zfu_t(ji,jj  ,jk)    &
84                  &                           + zfv_f(ji  ,jj,jk) - zfv_f(ji,jj-1,jk)  ) * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,ktlev)
85               pv_rhs(ji,jj,jk) = pv_rhs(ji,jj,jk) - (  zfu_f(ji,jj  ,jk) - zfu_f(ji-1,jj,jk)    &
86                  &                           + zfv_t(ji,jj+1,jk) - zfv_t(ji  ,jj,jk)  ) * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,ktlev)
87            END DO
88         END DO
89      END DO
90      !
91      IF( l_trddyn ) THEN           ! trends: send trend to trddyn for diagnostic
92         zfu_uw(:,:,:) = pu_rhs(:,:,:) - zfu_uw(:,:,:)
93         zfv_vw(:,:,:) = pv_rhs(:,:,:) - zfv_vw(:,:,:)
94         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt )
95         zfu_t(:,:,:) = pu_rhs(:,:,:)
96         zfv_t(:,:,:) = pv_rhs(:,:,:)
97      ENDIF
98      !
99      !                             !==  Vertical advection  ==!
100      !
101      DO jj = 2, jpjm1                    ! surface/bottom advective fluxes set to zero
102         DO ji = fs_2, fs_jpim1
103            zfu_uw(ji,jj,jpk) = 0._wp   ;   zfv_vw(ji,jj,jpk) = 0._wp
104            zfu_uw(ji,jj, 1 ) = 0._wp   ;   zfv_vw(ji,jj, 1 ) = 0._wp
105         END DO
106      END DO
107      IF( ln_linssh ) THEN                ! linear free surface: advection through the surface
108         DO jj = 2, jpjm1
109            DO ji = fs_2, fs_jpim1
110               zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * ww(ji,jj,1) + e1e2t(ji+1,jj) * ww(ji+1,jj,1) ) * uu(ji,jj,1,ktlev)
111               zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * ww(ji,jj,1) + e1e2t(ji,jj+1) * ww(ji,jj+1,1) ) * vv(ji,jj,1,ktlev)
112            END DO
113         END DO
114      ENDIF
115      DO jk = 2, jpkm1                    ! interior advective fluxes
116         DO jj = 2, jpj                       ! 1/4 * Vertical transport
117            DO ji = 2, jpi
118               zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * ww(ji,jj,jk)
119            END DO
120         END DO
121         DO jj = 2, jpjm1
122            DO ji = fs_2, fs_jpim1   ! vector opt.
123               zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj  ,jk) ) * ( uu(ji,jj,jk,ktlev) + uu(ji,jj,jk-1,ktlev) )
124               zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji  ,jj+1,jk) ) * ( vv(ji,jj,jk,ktlev) + vv(ji,jj,jk-1,ktlev) )
125            END DO
126         END DO
127      END DO
128      DO jk = 1, jpkm1                    ! divergence of vertical momentum flux divergence
129         DO jj = 2, jpjm1 
130            DO ji = fs_2, fs_jpim1   ! vector opt.
131               pu_rhs(ji,jj,jk) = pu_rhs(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,ktlev)
132               pv_rhs(ji,jj,jk) = pv_rhs(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,ktlev)
133            END DO
134         END DO
135      END DO
136      !
137      IF( l_trddyn ) THEN                 ! trends: send trend to trddyn for diagnostic
138         zfu_t(:,:,:) = pu_rhs(:,:,:) - zfu_t(:,:,:)
139         zfv_t(:,:,:) = pv_rhs(:,:,:) - zfv_t(:,:,:)
140         CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt )
141      ENDIF
142      !                                   ! Control print
143      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
144         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
145      !
146   END SUBROUTINE dyn_adv_cen2
147
148   !!==============================================================================
149END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.