1 | MODULE dynkeg |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE dynkeg *** |
---|
4 | !! Ocean dynamics: kinetic energy gradient trend |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 1987-09 (P. Andrich, M.-A. Foujols) Original code |
---|
7 | !! 7.0 ! 1997-05 (G. Madec) Split dynber into dynkeg and dynhpg |
---|
8 | !! NEMO 1.0 ! 2002-07 (G. Madec) F90: Free form and module |
---|
9 | !! 3.6 ! 2015-05 (N. Ducousso, G. Madec) add Hollingsworth scheme as an option |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! dyn_keg : update the momentum trend with the horizontal tke |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | USE oce ! ocean dynamics and tracers |
---|
16 | USE dom_oce ! ocean space and time domain |
---|
17 | USE trd_oce ! trends: ocean variables |
---|
18 | USE trddyn ! trend manager: dynamics |
---|
19 | ! |
---|
20 | USE in_out_manager ! I/O manager |
---|
21 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
22 | USE lib_mpp ! MPP library |
---|
23 | USE prtctl ! Print control |
---|
24 | USE timing ! Timing |
---|
25 | USE bdy_oce ! ocean open boundary conditions |
---|
26 | |
---|
27 | IMPLICIT NONE |
---|
28 | PRIVATE |
---|
29 | |
---|
30 | PUBLIC dyn_keg ! routine called by step module |
---|
31 | |
---|
32 | INTEGER, PARAMETER, PUBLIC :: nkeg_C2 = 0 !: 2nd order centered scheme (standard scheme) |
---|
33 | INTEGER, PARAMETER, PUBLIC :: nkeg_HW = 1 !: Hollingsworth et al., QJRMS, 1983 |
---|
34 | ! |
---|
35 | REAL(wp) :: r1_48 = 1._wp / 48._wp !: =1/(4*2*6) |
---|
36 | |
---|
37 | !! * Substitutions |
---|
38 | # include "vectopt_loop_substitute.h90" |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
41 | !! $Id$ |
---|
42 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | CONTAINS |
---|
45 | |
---|
46 | SUBROUTINE dyn_keg( kt, kscheme, Kmm, puu, pvv, Krhs ) |
---|
47 | !!---------------------------------------------------------------------- |
---|
48 | !! *** ROUTINE dyn_keg *** |
---|
49 | !! |
---|
50 | !! ** Purpose : Compute the now momentum trend due to the horizontal |
---|
51 | !! gradient of the horizontal kinetic energy and add it to the |
---|
52 | !! general momentum trend. |
---|
53 | !! |
---|
54 | !! ** Method : * kscheme = nkeg_C2 : 2nd order centered scheme that |
---|
55 | !! conserve kinetic energy. Compute the now horizontal kinetic energy |
---|
56 | !! zhke = 1/2 [ mi-1( un^2 ) + mj-1( vn^2 ) ] |
---|
57 | !! * kscheme = nkeg_HW : Hollingsworth correction following |
---|
58 | !! Arakawa (2001). The now horizontal kinetic energy is given by: |
---|
59 | !! zhke = 1/6 [ mi-1( 2 * un^2 + ((u(j+1)+u(j-1))/2)^2 ) |
---|
60 | !! + mj-1( 2 * vn^2 + ((v(i+1)+v(i-1))/2)^2 ) ] |
---|
61 | !! |
---|
62 | !! Take its horizontal gradient and add it to the general momentum |
---|
63 | !! trend. |
---|
64 | !! u(rhs) = u(rhs) - 1/e1u di[ zhke ] |
---|
65 | !! v(rhs) = v(rhs) - 1/e2v dj[ zhke ] |
---|
66 | !! |
---|
67 | !! ** Action : - Update the (puu(:,:,:,Krhs), pvv(:,:,:,Krhs)) with the hor. ke gradient trend |
---|
68 | !! - send this trends to trd_dyn (l_trddyn=T) for post-processing |
---|
69 | !! |
---|
70 | !! ** References : Arakawa, A., International Geophysics 2001. |
---|
71 | !! Hollingsworth et al., Quart. J. Roy. Meteor. Soc., 1983. |
---|
72 | !!---------------------------------------------------------------------- |
---|
73 | INTEGER , INTENT( in ) :: kt ! ocean time-step index |
---|
74 | INTEGER , INTENT( in ) :: kscheme ! =0/1 type of KEG scheme |
---|
75 | INTEGER , INTENT( in ) :: Kmm, Krhs ! ocean time level indices |
---|
76 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv ! ocean velocities and RHS of momentum equation |
---|
77 | ! |
---|
78 | INTEGER :: ji, jj, jk, jb ! dummy loop indices |
---|
79 | INTEGER :: ii, ifu, ib_bdy ! local integers |
---|
80 | INTEGER :: ij, ifv, igrd ! - - |
---|
81 | REAL(wp) :: zu, zv ! local scalars |
---|
82 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhke |
---|
83 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdu, ztrdv |
---|
84 | !!---------------------------------------------------------------------- |
---|
85 | ! |
---|
86 | IF( ln_timing ) CALL timing_start('dyn_keg') |
---|
87 | ! |
---|
88 | IF( kt == nit000 ) THEN |
---|
89 | IF(lwp) WRITE(numout,*) |
---|
90 | IF(lwp) WRITE(numout,*) 'dyn_keg : kinetic energy gradient trend, scheme number=', kscheme |
---|
91 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
92 | ENDIF |
---|
93 | |
---|
94 | IF( l_trddyn ) THEN ! Save the input trends |
---|
95 | ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) ) |
---|
96 | ztrdu(:,:,:) = puu(:,:,:,Krhs) |
---|
97 | ztrdv(:,:,:) = pvv(:,:,:,Krhs) |
---|
98 | ENDIF |
---|
99 | |
---|
100 | zhke(:,:,jpk) = 0._wp |
---|
101 | |
---|
102 | IF (ln_bdy) THEN |
---|
103 | ! Maria Luneva & Fred Wobus: July-2016 |
---|
104 | ! compensate for lack of turbulent kinetic energy on liquid bdy points |
---|
105 | DO ib_bdy = 1, nb_bdy |
---|
106 | IF( cn_dyn3d(ib_bdy) /= 'none' ) THEN |
---|
107 | igrd = 2 ! Copying normal velocity into points outside bdy |
---|
108 | DO jb = 1, idx_bdy(ib_bdy)%nblenrim(igrd) |
---|
109 | DO jk = 1, jpkm1 |
---|
110 | ii = idx_bdy(ib_bdy)%nbi(jb,igrd) |
---|
111 | ij = idx_bdy(ib_bdy)%nbj(jb,igrd) |
---|
112 | ifu = NINT( idx_bdy(ib_bdy)%flagu(jb,igrd) ) |
---|
113 | puu(ii-ifu,ij,jk,Kmm) = puu(ii,ij,jk,Kmm) * umask(ii,ij,jk) |
---|
114 | END DO |
---|
115 | END DO |
---|
116 | ! |
---|
117 | igrd = 3 ! Copying normal velocity into points outside bdy |
---|
118 | DO jb = 1, idx_bdy(ib_bdy)%nblenrim(igrd) |
---|
119 | DO jk = 1, jpkm1 |
---|
120 | ii = idx_bdy(ib_bdy)%nbi(jb,igrd) |
---|
121 | ij = idx_bdy(ib_bdy)%nbj(jb,igrd) |
---|
122 | ifv = NINT( idx_bdy(ib_bdy)%flagv(jb,igrd) ) |
---|
123 | pvv(ii,ij-ifv,jk,Kmm) = pvv(ii,ij,jk,Kmm) * vmask(ii,ij,jk) |
---|
124 | END DO |
---|
125 | END DO |
---|
126 | ENDIF |
---|
127 | ENDDO |
---|
128 | ENDIF |
---|
129 | |
---|
130 | SELECT CASE ( kscheme ) !== Horizontal kinetic energy at T-point ==! |
---|
131 | ! |
---|
132 | CASE ( nkeg_C2 ) !-- Standard scheme --! |
---|
133 | DO jk = 1, jpkm1 |
---|
134 | DO jj = 2, jpj |
---|
135 | DO ji = fs_2, jpi ! vector opt. |
---|
136 | zu = puu(ji-1,jj ,jk,Kmm) * puu(ji-1,jj ,jk,Kmm) & |
---|
137 | & + puu(ji ,jj ,jk,Kmm) * puu(ji ,jj ,jk,Kmm) |
---|
138 | zv = pvv(ji ,jj-1,jk,Kmm) * pvv(ji ,jj-1,jk,Kmm) & |
---|
139 | & + pvv(ji ,jj ,jk,Kmm) * pvv(ji ,jj ,jk,Kmm) |
---|
140 | zhke(ji,jj,jk) = 0.25_wp * ( zv + zu ) |
---|
141 | END DO |
---|
142 | END DO |
---|
143 | END DO |
---|
144 | ! |
---|
145 | CASE ( nkeg_HW ) !-- Hollingsworth scheme --! |
---|
146 | DO jk = 1, jpkm1 |
---|
147 | DO jj = 2, jpjm1 |
---|
148 | DO ji = fs_2, jpim1 ! vector opt. |
---|
149 | zu = 8._wp * ( puu(ji-1,jj ,jk,Kmm) * puu(ji-1,jj ,jk,Kmm) & |
---|
150 | & + puu(ji ,jj ,jk,Kmm) * puu(ji ,jj ,jk,Kmm) ) & |
---|
151 | & + ( puu(ji-1,jj-1,jk,Kmm) + puu(ji-1,jj+1,jk,Kmm) ) * ( puu(ji-1,jj-1,jk,Kmm) + puu(ji-1,jj+1,jk,Kmm) ) & |
---|
152 | & + ( puu(ji ,jj-1,jk,Kmm) + puu(ji ,jj+1,jk,Kmm) ) * ( puu(ji ,jj-1,jk,Kmm) + puu(ji ,jj+1,jk,Kmm) ) |
---|
153 | ! |
---|
154 | zv = 8._wp * ( pvv(ji ,jj-1,jk,Kmm) * pvv(ji ,jj-1,jk,Kmm) & |
---|
155 | & + pvv(ji ,jj ,jk,Kmm) * pvv(ji ,jj ,jk,Kmm) ) & |
---|
156 | & + ( pvv(ji-1,jj-1,jk,Kmm) + pvv(ji+1,jj-1,jk,Kmm) ) * ( pvv(ji-1,jj-1,jk,Kmm) + pvv(ji+1,jj-1,jk,Kmm) ) & |
---|
157 | & + ( pvv(ji-1,jj ,jk,Kmm) + pvv(ji+1,jj ,jk,Kmm) ) * ( pvv(ji-1,jj ,jk,Kmm) + pvv(ji+1,jj ,jk,Kmm) ) |
---|
158 | zhke(ji,jj,jk) = r1_48 * ( zv + zu ) |
---|
159 | END DO |
---|
160 | END DO |
---|
161 | END DO |
---|
162 | CALL lbc_lnk( 'dynkeg', zhke, 'T', 1. ) |
---|
163 | ! |
---|
164 | END SELECT |
---|
165 | |
---|
166 | IF (ln_bdy) THEN |
---|
167 | ! restore velocity masks at points outside boundary |
---|
168 | puu(:,:,:,Kmm) = puu(:,:,:,Kmm) * umask(:,:,:) |
---|
169 | pvv(:,:,:,Kmm) = pvv(:,:,:,Kmm) * vmask(:,:,:) |
---|
170 | ENDIF |
---|
171 | |
---|
172 | ! |
---|
173 | DO jk = 1, jpkm1 !== grad( KE ) added to the general momentum trends ==! |
---|
174 | DO jj = 2, jpjm1 |
---|
175 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
176 | puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zhke(ji+1,jj ,jk) - zhke(ji,jj,jk) ) / e1u(ji,jj) |
---|
177 | pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zhke(ji ,jj+1,jk) - zhke(ji,jj,jk) ) / e2v(ji,jj) |
---|
178 | END DO |
---|
179 | END DO |
---|
180 | END DO |
---|
181 | ! |
---|
182 | IF( l_trddyn ) THEN ! save the Kinetic Energy trends for diagnostic |
---|
183 | ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:) |
---|
184 | ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:) |
---|
185 | CALL trd_dyn( ztrdu, ztrdv, jpdyn_keg, kt, Kmm ) |
---|
186 | DEALLOCATE( ztrdu , ztrdv ) |
---|
187 | ENDIF |
---|
188 | ! |
---|
189 | IF(ln_ctl) CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' keg - Ua: ', mask1=umask, & |
---|
190 | & tab3d_2=pvv(:,:,:,Krhs), clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' ) |
---|
191 | ! |
---|
192 | IF( ln_timing ) CALL timing_stop('dyn_keg') |
---|
193 | ! |
---|
194 | END SUBROUTINE dyn_keg |
---|
195 | |
---|
196 | !!====================================================================== |
---|
197 | END MODULE dynkeg |
---|