New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/IOM – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/IOM/restart.F90 @ 11027

Last change on this file since 11027 was 11027, checked in by acc, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Final renaming conversions and removal of temporary pointers. All non-AGRIF SETTE tests are passing (including test cases). AGRIF tests compile and link but segment on first call to Agrif_Regrid. NST changes are therefore a work in progress but nothing is broken that was not broken before
  • Property svn:keywords set to Id
File size: 16.2 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_si3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diu_bulk
30   USE lib_mpp         ! distribued memory computing library
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   rst_opn         ! routine called by step module
36   PUBLIC   rst_write       ! routine called by step module
37   PUBLIC   rst_read        ! routine called by istate module
38   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE rst_opn( kt )
50      !!---------------------------------------------------------------------
51      !!                   ***  ROUTINE rst_opn  ***
52      !!                     
53      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
54      !!              + open the restart when we are one time step before nitrst
55      !!                   - restart header is defined when kt = nitrst-1
56      !!                   - restart data  are written when kt = nitrst
57      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
58      !!----------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt     ! ocean time-step
60      !!
61      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
62      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
63      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
64      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
65      CHARACTER(LEN=256)  ::   clinfo    ! info character
66      !!----------------------------------------------------------------------
67      !
68      IF( kt == nit000 ) THEN   ! default definitions
69         lrst_oce = .FALSE.   
70         IF( ln_rst_list ) THEN
71            nrst_lst = 1
72            nitrst = nstocklist( nrst_lst )
73         ELSE
74            nitrst = nitend
75         ENDIF
76      ENDIF
77
78      ! frequency-based restart dumping (nn_stock)
79      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
80         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
81         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
82         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
83      ENDIF
84      ! to get better performances with NetCDF format:
85      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
86      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
87      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
88         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
89            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
90            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
91            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
92            ENDIF
93            ! create the file
94            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
95            clpath = TRIM(cn_ocerst_outdir)
96            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
97            IF(lwp) THEN
98               WRITE(numout,*)
99               IF(.NOT.lwxios) THEN
100                  WRITE(numout,*) '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
101                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
102                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
103                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
104                  ENDIF
105               ENDIF
106            ENDIF
107            !
108            IF(.NOT.lwxios) THEN
109               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
110            ELSE
111#if defined key_iomput
112               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
113               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
114                  clpname = clname
115               ELSE
116                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
117               ENDIF
118               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname), .false. )
119               CALL xios_update_calendar(nitrst)
120               CALL iom_swap(      cxios_context          )
121#else
122               clinfo = 'Can not use XIOS in rst_opn'
123               CALL ctl_stop(TRIM(clinfo))
124#endif
125            ENDIF
126            lrst_oce = .TRUE.
127         ENDIF
128      ENDIF
129      !
130   END SUBROUTINE rst_opn
131
132
133   SUBROUTINE rst_write( kt, Kbb, Kmm )
134      !!---------------------------------------------------------------------
135      !!                   ***  ROUTINE rstwrite  ***
136      !!                     
137      !! ** Purpose :   Write restart fields in NetCDF format
138      !!
139      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
140      !!              file, save fields which are necessary for restart
141      !!----------------------------------------------------------------------
142      INTEGER, INTENT(in) ::   kt         ! ocean time-step
143      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
144      !!----------------------------------------------------------------------
145                     IF(lwxios) CALL iom_swap(      cwxios_context          )
146                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       , ldxios = lwxios)   ! dynamics time step
147                     CALL iom_delay_rst( 'WRITE', 'OCE', numrow )   ! save only ocean delayed global communication variables
148
149      IF ( .NOT. ln_diurnal_only ) THEN
150                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , uu(:,:,:       ,Kbb), ldxios = lwxios        )     ! before fields
151                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vv(:,:,:       ,Kbb), ldxios = lwxios        )
152                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , ts(:,:,:,jp_tem,Kbb), ldxios = lwxios )
153                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , ts(:,:,:,jp_sal,Kbb), ldxios = lwxios )
154                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   ,ssh(:,:         ,Kbb), ldxios = lwxios      )
155                     !
156                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , uu(:,:,:       ,Kmm), ldxios = lwxios        )     ! now fields
157                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vv(:,:,:       ,Kmm), ldxios = lwxios        )
158                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , ts(:,:,:,jp_tem,Kmm), ldxios = lwxios )
159                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , ts(:,:,:,jp_sal,Kmm), ldxios = lwxios )
160                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   ,ssh(:,:         ,Kmm), ldxios = lwxios      )
161                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop, ldxios = lwxios      )
162                  ! extra variable needed for the ice sheet coupling
163                  IF ( ln_iscpl ) THEN
164                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask, ldxios = lwxios ) ! need to extrapolate T/S
165                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask, ldxios = lwxios ) ! need to correct barotropic velocity
166                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask, ldxios = lwxios ) ! need to correct barotropic velocity
167                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask, ldxios = lwxios) ! need to correct barotropic velocity
168                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t(:,:,:,Kmm), ldxios = lwxios )   ! need to compute temperature correction
169                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u(:,:,:,Kmm), ldxios = lwxios )   ! need to compute bt conservation
170                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v(:,:,:,Kmm), ldxios = lwxios )   ! need to compute bt conservation
171                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw(:,:,:,Kmm), ldxios = lwxios ) ! need to compute extrapolation if vvl
172                  END IF
173      ENDIF
174     
175      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios ) 
176      IF(lwxios) CALL iom_swap(      cxios_context          )
177      IF( kt == nitrst ) THEN
178         IF(.NOT.lwxios) THEN
179            CALL iom_close( numrow )     ! close the restart file (only at last time step)
180         ELSE
181            CALL iom_context_finalize(      cwxios_context          )
182         ENDIF
183!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
184!!gm  not sure what to do here   ===>>>  ask to Sebastian
185         lrst_oce = .FALSE.
186            IF( ln_rst_list ) THEN
187               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
188               nitrst = nstocklist( nrst_lst )
189            ENDIF
190      ENDIF
191      !
192   END SUBROUTINE rst_write
193
194
195   SUBROUTINE rst_read_open
196      !!----------------------------------------------------------------------
197      !!                   ***  ROUTINE rst_read_open  ***
198      !!
199      !! ** Purpose :   Open read files for NetCDF restart
200      !!
201      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
202      !!                the file has already been opened
203      !!----------------------------------------------------------------------
204      LOGICAL        ::   llok
205      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
206      !!----------------------------------------------------------------------
207      !
208      IF( numror <= 0 ) THEN
209         IF(lwp) THEN                                             ! Contol prints
210            WRITE(numout,*)
211            WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
212            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
213            WRITE(numout,*) '~~~~~~~~'
214         ENDIF
215         lxios_sini = .FALSE.
216         clpath = TRIM(cn_ocerst_indir)
217         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
218         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
219! are we using XIOS to read the data? Part above will have to modified once XIOS
220! can handle checking if variable is in the restart file (there will be no need to open
221! restart)
222         IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
223         IF( lrxios) THEN
224             crxios_context = 'nemo_rst'
225             IF( .NOT.lxios_set ) THEN
226                 IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
227                 CALL iom_init( crxios_context, ld_tmppatch = .false. )
228                 lxios_set = .TRUE.
229             ENDIF
230         ENDIF
231         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
232             CALL iom_init( crxios_context, ld_tmppatch = .false. )
233             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
234             lxios_set = .TRUE.
235         ENDIF
236      ENDIF
237
238   END SUBROUTINE rst_read_open
239
240
241   SUBROUTINE rst_read( Kbb, Kmm )
242      !!----------------------------------------------------------------------
243      !!                   ***  ROUTINE rst_read  ***
244      !!
245      !! ** Purpose :   Read files for NetCDF restart
246      !!
247      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
248      !!----------------------------------------------------------------------
249      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
250      REAL(wp) ::   zrdt
251      INTEGER  ::   jk
252      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
253      !!----------------------------------------------------------------------
254
255      CALL rst_read_open           ! open restart for reading (if not already opened)
256
257      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
258      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
259         CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
260         IF( zrdt /= rdt )   neuler = 0
261      ENDIF
262
263      CALL iom_delay_rst( 'READ', 'OCE', numror )   ! read only ocean delayed global communication variables
264     
265      ! Diurnal DSST
266      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios ) 
267      IF ( ln_diurnal_only ) THEN
268         IF(lwp) WRITE( numout, * ) &
269         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
270         rhop = rau0
271         CALL iom_get( numror, jpdom_autoglo, 'tn'     , w3d, ldxios = lrxios ) 
272         ts(:,:,1,jp_tem,Kmm) = w3d(:,:,1)
273         RETURN
274      ENDIF 
275     
276      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
277         CALL iom_get( numror, jpdom_autoglo, 'ub'     , uu(:,:,:       ,Kbb), ldxios = lrxios )   ! before fields
278         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vv(:,:,:       ,Kbb), ldxios = lrxios )
279         CALL iom_get( numror, jpdom_autoglo, 'tb'     , ts(:,:,:,jp_tem,Kbb), ldxios = lrxios )
280         CALL iom_get( numror, jpdom_autoglo, 'sb'     , ts(:,:,:,jp_sal,Kbb), ldxios = lrxios )
281         CALL iom_get( numror, jpdom_autoglo, 'sshb'   ,ssh(:,:         ,Kbb), ldxios = lrxios )
282      ELSE
283         neuler = 0
284      ENDIF
285      !
286      CALL iom_get( numror, jpdom_autoglo, 'un'     , uu(:,:,:       ,Kmm), ldxios = lrxios )       ! now    fields
287      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vv(:,:,:       ,Kmm), ldxios = lrxios )
288      CALL iom_get( numror, jpdom_autoglo, 'tn'     , ts(:,:,:,jp_tem,Kmm), ldxios = lrxios )
289      CALL iom_get( numror, jpdom_autoglo, 'sn'     , ts(:,:,:,jp_sal,Kmm), ldxios = lrxios )
290      CALL iom_get( numror, jpdom_autoglo, 'sshn'   ,ssh(:,:         ,Kmm), ldxios = lrxios )
291      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
292         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop, ldxios = lrxios )   ! now    potential density
293      ELSE
294         CALL eos( ts(:,:,:,:,Kmm), rhd, rhop, gdept(:,:,:,Kmm) )   
295      ENDIF
296      !
297      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
298         ts   (:,:,:,:,Kbb) = ts   (:,:,:,:,Kmm)              ! all before fields set to now values
299         uu   (:,:,:  ,Kbb) = uu   (:,:,:  ,Kmm)
300         vv   (:,:,:  ,Kbb) = vv   (:,:,:  ,Kmm)
301         ssh  (:,:    ,Kbb) = ssh  (:,:    ,Kmm)
302         !
303         IF( .NOT.ln_linssh ) THEN
304            DO jk = 1, jpk
305               e3t(:,:,jk,Kbb) = e3t(:,:,jk,Kmm)
306            END DO
307         ENDIF
308         !
309      ENDIF
310      !
311   END SUBROUTINE rst_read
312
313   !!=====================================================================
314END MODULE restart
Note: See TracBrowser for help on using the repository browser.