New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/IOM – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/IOM/restart.F90 @ 11822

Last change on this file since 11822 was 11822, checked in by acc, 4 years ago

Branch 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. Sette tested updates to branch to align with trunk changes between 10721 and 11740. Sette tests are passing but results differ from branch before these changes (except for GYRE_PISCES and VORTEX) and branch results already differed from trunk because of algorithmic fixes. Will need more checks to confirm correctness.
  • Property svn:keywords set to Id
File size: 16.3 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_si3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diu_bulk
30   USE lib_mpp         ! distribued memory computing library
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   rst_opn         ! routine called by step module
36   PUBLIC   rst_write       ! routine called by step module
37   PUBLIC   rst_read        ! routine called by istate module
38   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE rst_opn( kt )
50      !!---------------------------------------------------------------------
51      !!                   ***  ROUTINE rst_opn  ***
52      !!                     
53      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
54      !!              + open the restart when we are one time step before nitrst
55      !!                   - restart header is defined when kt = nitrst-1
56      !!                   - restart data  are written when kt = nitrst
57      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
58      !!----------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt     ! ocean time-step
60      !!
61      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
62      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
63      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
64      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
65      CHARACTER(LEN=256)  ::   clinfo    ! info character
66      !!----------------------------------------------------------------------
67      !
68      IF( kt == nit000 ) THEN   ! default definitions
69         lrst_oce = .FALSE.   
70         IF( ln_rst_list ) THEN
71            nrst_lst = 1
72            nitrst = nn_stocklist( nrst_lst )
73         ELSE
74            nitrst = nitend
75         ENDIF
76      ENDIF
77     
78      IF( .NOT. ln_rst_list .AND. nn_stock == -1 )   RETURN   ! we will never do any restart
79
80      ! frequency-based restart dumping (nn_stock)
81      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nn_stock ) == 0 ) THEN   
82         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
83         nitrst = kt + nn_stock - 1                  ! define the next value of nitrst for restart writing
84         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
85      ENDIF
86      ! to get better performances with NetCDF format:
87      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
88      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
89      IF( kt == nitrst - 1 .OR. nn_stock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
90         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
91            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
92            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
93            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
94            ENDIF
95            ! create the file
96            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
97            clpath = TRIM(cn_ocerst_outdir)
98            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
99            IF(lwp) THEN
100               WRITE(numout,*)
101               IF(.NOT.lwxios) THEN
102                  WRITE(numout,*) '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
103                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
104                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
105                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
106                  ENDIF
107               ENDIF
108            ENDIF
109            !
110            IF(.NOT.lwxios) THEN
111               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
112            ELSE
113#if defined key_iomput
114               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
115               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
116                  clpname = clname
117               ELSE
118                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
119               ENDIF
120               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname), .false. )
121               CALL xios_update_calendar(nitrst)
122               CALL iom_swap(      cxios_context          )
123#else
124               clinfo = 'Can not use XIOS in rst_opn'
125               CALL ctl_stop(TRIM(clinfo))
126#endif
127            ENDIF
128            lrst_oce = .TRUE.
129         ENDIF
130      ENDIF
131      !
132   END SUBROUTINE rst_opn
133
134
135   SUBROUTINE rst_write( kt, Kbb, Kmm )
136      !!---------------------------------------------------------------------
137      !!                   ***  ROUTINE rstwrite  ***
138      !!                     
139      !! ** Purpose :   Write restart fields in NetCDF format
140      !!
141      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
142      !!              file, save fields which are necessary for restart
143      !!----------------------------------------------------------------------
144      INTEGER, INTENT(in) ::   kt         ! ocean time-step
145      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
146      !!----------------------------------------------------------------------
147                     IF(lwxios) CALL iom_swap(      cwxios_context          )
148                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       , ldxios = lwxios)   ! dynamics time step
149                     CALL iom_delay_rst( 'WRITE', 'OCE', numrow )   ! save only ocean delayed global communication variables
150
151      IF ( .NOT. ln_diurnal_only ) THEN
152                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , uu(:,:,:       ,Kbb), ldxios = lwxios        )     ! before fields
153                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vv(:,:,:       ,Kbb), ldxios = lwxios        )
154                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , ts(:,:,:,jp_tem,Kbb), ldxios = lwxios )
155                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , ts(:,:,:,jp_sal,Kbb), ldxios = lwxios )
156                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   ,ssh(:,:         ,Kbb), ldxios = lwxios      )
157                     !
158                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , uu(:,:,:       ,Kmm), ldxios = lwxios        )     ! now fields
159                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vv(:,:,:       ,Kmm), ldxios = lwxios        )
160                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , ts(:,:,:,jp_tem,Kmm), ldxios = lwxios )
161                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , ts(:,:,:,jp_sal,Kmm), ldxios = lwxios )
162                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   ,ssh(:,:         ,Kmm), ldxios = lwxios      )
163                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop, ldxios = lwxios      )
164                  ! extra variable needed for the ice sheet coupling
165                  IF ( ln_iscpl ) THEN
166                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask, ldxios = lwxios ) ! need to extrapolate T/S
167                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask, ldxios = lwxios ) ! need to correct barotropic velocity
168                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask, ldxios = lwxios ) ! need to correct barotropic velocity
169                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask, ldxios = lwxios) ! need to correct barotropic velocity
170                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t(:,:,:,Kmm), ldxios = lwxios )   ! need to compute temperature correction
171                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u(:,:,:,Kmm), ldxios = lwxios )   ! need to compute bt conservation
172                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v(:,:,:,Kmm), ldxios = lwxios )   ! need to compute bt conservation
173                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw(:,:,:,Kmm), ldxios = lwxios ) ! need to compute extrapolation if vvl
174                  END IF
175      ENDIF
176     
177      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios ) 
178      IF(lwxios) CALL iom_swap(      cxios_context          )
179      IF( kt == nitrst ) THEN
180         IF(.NOT.lwxios) THEN
181            CALL iom_close( numrow )     ! close the restart file (only at last time step)
182         ELSE
183            CALL iom_context_finalize(      cwxios_context          )
184         ENDIF
185!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
186!!gm  not sure what to do here   ===>>>  ask to Sebastian
187         lrst_oce = .FALSE.
188            IF( ln_rst_list ) THEN
189               nrst_lst = MIN(nrst_lst + 1, SIZE(nn_stocklist,1))
190               nitrst = nn_stocklist( nrst_lst )
191            ENDIF
192      ENDIF
193      !
194   END SUBROUTINE rst_write
195
196
197   SUBROUTINE rst_read_open
198      !!----------------------------------------------------------------------
199      !!                   ***  ROUTINE rst_read_open  ***
200      !!
201      !! ** Purpose :   Open read files for NetCDF restart
202      !!
203      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
204      !!                the file has already been opened
205      !!----------------------------------------------------------------------
206      LOGICAL        ::   llok
207      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
208      !!----------------------------------------------------------------------
209      !
210      IF( numror <= 0 ) THEN
211         IF(lwp) THEN                                             ! Contol prints
212            WRITE(numout,*)
213            WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
214            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
215            WRITE(numout,*) '~~~~~~~~'
216         ENDIF
217         lxios_sini = .FALSE.
218         clpath = TRIM(cn_ocerst_indir)
219         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
220         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
221! are we using XIOS to read the data? Part above will have to modified once XIOS
222! can handle checking if variable is in the restart file (there will be no need to open
223! restart)
224         IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
225         IF( lrxios) THEN
226             crxios_context = 'nemo_rst'
227             IF( .NOT.lxios_set ) THEN
228                 IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
229                 CALL iom_init( crxios_context, ld_tmppatch = .false. )
230                 lxios_set = .TRUE.
231             ENDIF
232         ENDIF
233         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
234             CALL iom_init( crxios_context, ld_tmppatch = .false. )
235             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
236             lxios_set = .TRUE.
237         ENDIF
238      ENDIF
239
240   END SUBROUTINE rst_read_open
241
242
243   SUBROUTINE rst_read( Kbb, Kmm )
244      !!----------------------------------------------------------------------
245      !!                   ***  ROUTINE rst_read  ***
246      !!
247      !! ** Purpose :   Read files for NetCDF restart
248      !!
249      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
250      !!----------------------------------------------------------------------
251      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
252      REAL(wp) ::   zrdt
253      INTEGER  ::   jk
254      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
255      !!----------------------------------------------------------------------
256
257      CALL rst_read_open           ! open restart for reading (if not already opened)
258
259      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
260      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
261         CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
262         IF( zrdt /= rdt )   neuler = 0
263      ENDIF
264
265      CALL iom_delay_rst( 'READ', 'OCE', numror )   ! read only ocean delayed global communication variables
266     
267      ! Diurnal DSST
268      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios ) 
269      IF ( ln_diurnal_only ) THEN
270         IF(lwp) WRITE( numout, * ) &
271         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
272         rhop = rau0
273         CALL iom_get( numror, jpdom_autoglo, 'tn'     , w3d, ldxios = lrxios ) 
274         ts(:,:,1,jp_tem,Kmm) = w3d(:,:,1)
275         RETURN
276      ENDIF 
277     
278      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
279         CALL iom_get( numror, jpdom_autoglo, 'ub'     , uu(:,:,:       ,Kbb), ldxios = lrxios )   ! before fields
280         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vv(:,:,:       ,Kbb), ldxios = lrxios )
281         CALL iom_get( numror, jpdom_autoglo, 'tb'     , ts(:,:,:,jp_tem,Kbb), ldxios = lrxios )
282         CALL iom_get( numror, jpdom_autoglo, 'sb'     , ts(:,:,:,jp_sal,Kbb), ldxios = lrxios )
283         CALL iom_get( numror, jpdom_autoglo, 'sshb'   ,ssh(:,:         ,Kbb), ldxios = lrxios )
284      ELSE
285         neuler = 0
286      ENDIF
287      !
288      CALL iom_get( numror, jpdom_autoglo, 'un'     , uu(:,:,:       ,Kmm), ldxios = lrxios )       ! now    fields
289      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vv(:,:,:       ,Kmm), ldxios = lrxios )
290      CALL iom_get( numror, jpdom_autoglo, 'tn'     , ts(:,:,:,jp_tem,Kmm), ldxios = lrxios )
291      CALL iom_get( numror, jpdom_autoglo, 'sn'     , ts(:,:,:,jp_sal,Kmm), ldxios = lrxios )
292      CALL iom_get( numror, jpdom_autoglo, 'sshn'   ,ssh(:,:         ,Kmm), ldxios = lrxios )
293      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
294         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop, ldxios = lrxios )   ! now    potential density
295      ELSE
296         CALL eos( ts(:,:,:,:,Kmm), rhd, rhop, gdept(:,:,:,Kmm) )   
297      ENDIF
298      !
299      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
300         ts   (:,:,:,:,Kbb) = ts   (:,:,:,:,Kmm)              ! all before fields set to now values
301         uu   (:,:,:  ,Kbb) = uu   (:,:,:  ,Kmm)
302         vv   (:,:,:  ,Kbb) = vv   (:,:,:  ,Kmm)
303         ssh  (:,:    ,Kbb) = ssh  (:,:    ,Kmm)
304         !
305         IF( .NOT.ln_linssh ) THEN
306            DO jk = 1, jpk
307               e3t(:,:,jk,Kbb) = e3t(:,:,jk,Kmm)
308            END DO
309         ENDIF
310         !
311      ENDIF
312      !
313   END SUBROUTINE rst_read
314
315   !!=====================================================================
316END MODULE restart
Note: See TracBrowser for help on using the repository browser.