source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA/traadv.F90 @ 10806

Last change on this file since 10806 was 10806, checked in by davestorkey, 20 months ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps branch: Latest updates. Make sure all time-dependent 3D variables are converted in previously modified modules.

  • Property svn:keywords set to Id
File size: 16.2 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv       : compute ocean tracer advection trend
16   !!   tra_adv_init  : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! variable vertical scale factors
21   USE sbcwave        ! wave module
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE traadv_cen     ! centered scheme            (tra_adv_cen  routine)
24   USE traadv_fct     ! FCT      scheme            (tra_adv_fct  routine)
25   USE traadv_mus     ! MUSCL    scheme            (tra_adv_mus  routine)
26   USE traadv_ubs     ! UBS      scheme            (tra_adv_ubs  routine)
27   USE traadv_qck     ! QUICKEST scheme            (tra_adv_qck  routine)
28   USE tramle         ! Mixed Layer Eddy transport (tra_mle_trp  routine)
29   USE ldftra         ! Eddy Induced transport     (ldf_eiv_trp  routine)
30   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
31   USE trd_oce        ! trends: ocean variables
32   USE trdtra         ! trends manager: tracers
33   USE diaptr         ! Poleward heat transport
34   !
35   USE in_out_manager ! I/O manager
36   USE iom            ! I/O module
37   USE prtctl         ! Print control
38   USE lib_mpp        ! MPP library
39   USE timing         ! Timing
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   tra_adv        ! called by step.F90
45   PUBLIC   tra_adv_init   ! called by nemogcm.F90
46
47   !                            !!* Namelist namtra_adv *
48   LOGICAL ::   ln_traadv_OFF    ! no advection on T and S
49   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
50   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
51   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
52   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
53   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
54   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
55   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
56   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
57   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
58
59   INTEGER ::   nadv             ! choice of the type of advection scheme
60   !                             ! associated indices:
61   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
62   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
63   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
64   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
65   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
66   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
67   
68   !! * Substitutions
69#  include "vectopt_loop_substitute.h90"
70   !!----------------------------------------------------------------------
71   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
72   !! $Id$
73   !! Software governed by the CeCILL license (see ./LICENSE)
74   !!----------------------------------------------------------------------
75CONTAINS
76
77   SUBROUTINE tra_adv( kt, ktlev1, ktlev2, ktlev3, kt2lev, pts_rhs )
78      !!----------------------------------------------------------------------
79      !!                  ***  ROUTINE tra_adv  ***
80      !!
81      !! ** Purpose :   compute the ocean tracer advection trend.
82      !!
83      !! ** Method  : - Update (pu_rhs,pv_rhs) with the advection term following nadv
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt                       ! ocean time-step index
86      INTEGER, INTENT(in) ::   ktlev1, ktlev2, ktlev3   ! time level indices for 3-time-level source terms
87      INTEGER, INTENT(in) ::   kt2lev                   ! time level index for 2-time-level source terms
88      REAL(wp), INTENT( inout), DIMENSION(jpi,jpj,jpk,jpts) :: pts_rhs ! temperature and salinity trends
89      !
90      INTEGER ::   jk   ! dummy loop index
91      REAL(wp), DIMENSION(jpi,jpj,jpk)        :: zun, zvn, zwn   ! 3D workspace
92      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds
93      !!----------------------------------------------------------------------
94      !
95      IF( ln_timing )   CALL timing_start('tra_adv')
96      !
97      !                                          ! set time step
98      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   r2dt =         rdt   ! at nit000             (Euler)
99      ELSEIF( kt <= nit000 + 1 )           THEN   ;   r2dt = 2._wp * rdt   ! at nit000 or nit000+1 (Leapfrog)
100      ENDIF
101      !
102      !                                         !==  effective transport  ==!
103      zun(:,:,jpk) = 0._wp
104      zvn(:,:,jpk) = 0._wp
105      zwn(:,:,jpk) = 0._wp
106      IF( ln_wave .AND. ln_sdw )  THEN
107         DO jk = 1, jpkm1                                                       ! eulerian transport + Stokes Drift
108            zun(:,:,jk) = e2u  (:,:) * e3u(:,:,jk,ktlev2) * ( uu(:,:,jk,ktlev2) + usd(:,:,jk) )
109            zvn(:,:,jk) = e1v  (:,:) * e3v(:,:,jk,ktlev2) * ( vv(:,:,jk,ktlev2) + vsd(:,:,jk) )
110            zwn(:,:,jk) = e1e2t(:,:)                 * ( ww(:,:,jk) + wsd(:,:,jk) )
111         END DO
112      ELSE
113         DO jk = 1, jpkm1
114            zun(:,:,jk) = e2u  (:,:) * e3u(:,:,jk,ktlev2) * uu(:,:,jk,ktlev2)               ! eulerian transport only
115            zvn(:,:,jk) = e1v  (:,:) * e3v(:,:,jk,ktlev2) * vv(:,:,jk,ktlev2)
116            zwn(:,:,jk) = e1e2t(:,:)                 * ww(:,:,jk)
117         END DO
118      ENDIF
119      !
120      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
121         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
122         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
123      ENDIF
124      !
125      zun(:,:,jpk) = 0._wp                                                      ! no transport trough the bottom
126      zvn(:,:,jpk) = 0._wp
127      zwn(:,:,jpk) = 0._wp
128      !
129      IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
130         &              CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' )   ! add the eiv transport (if necessary)
131      !
132      IF( ln_mle    )   CALL tra_mle_trp( kt, nit000, zun, zvn, zwn, 'TRA' )   ! add the mle transport (if necessary)
133      !
134      CALL iom_put( "uocetr_eff", zun )                                        ! output effective transport     
135      CALL iom_put( "vocetr_eff", zvn )
136      CALL iom_put( "wocetr_eff", zwn )
137      !
138!!gm ???
139      IF( ln_diaptr )   CALL dia_ptr( zvn )                                    ! diagnose the effective MSF
140!!gm ???
141      !
142      IF( l_trdtra )   THEN                    !* Save ta and sa trends
143         ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
144         ztrdt(:,:,:) = pts_rhs(:,:,:,jp_tem)
145         ztrds(:,:,:) = pts_rhs(:,:,:,jp_sal)
146      ENDIF
147      !
148      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
149      !
150      CASE ( np_CEN )                                 ! Centered scheme : 2nd / 4th order
151         CALL tra_adv_cen    ( kt, nit000, ktlev2, 'TRA',         zun, zvn, zwn     , ts(:,:,:,:,ktlev2), pts_rhs, jpts, nn_cen_h, nn_cen_v )
152      CASE ( np_FCT )                                 ! FCT scheme      : 2nd / 4th order
153         CALL tra_adv_fct    ( kt, nit000, ktlev1, ktlev2, ktlev3, 'TRA', r2dt, zun, zvn, zwn,                      &
154     &                         ts(:,:,:,:,ktlev1), ts(:,:,:,:,ktlev2), pts_rhs, jpts, nn_fct_h, nn_fct_v )
155      CASE ( np_MUS )                                 ! MUSCL
156         CALL tra_adv_mus    ( kt, nit000, ktlev2, kt2lev, 'TRA', r2dt, zun, zvn, zwn, ts(:,:,:,:,ktlev1),      pts_rhs, jpts        , ln_mus_ups ) 
157      CASE ( np_UBS )                                 ! UBS
158         CALL tra_adv_ubs    ( kt, nit000, ktlev2, 'TRA', r2dt, zun, zvn, zwn, ts(:,:,:,:,ktlev1), ts(:,:,:,:,ktlev2), pts_rhs, jpts        , nn_ubs_v   )
159      CASE ( np_QCK )                                 ! QUICKEST
160         CALL tra_adv_qck    ( kt, nit000, ktlev2, 'TRA', r2dt, zun, zvn, zwn, ts(:,:,:,:,ktlev1), ts(:,:,:,:,ktlev2), pts_rhs, jpts                     )
161      !
162      END SELECT
163      !
164      IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
165         DO jk = 1, jpkm1
166            ztrdt(:,:,jk) = pts_rhs(:,:,jk,jp_tem) - ztrdt(:,:,jk)
167            ztrds(:,:,jk) = pts_rhs(:,:,jk,jp_sal) - ztrds(:,:,jk)
168         END DO
169         CALL trd_tra( kt, 'TRA', jp_tem, jptra_totad, ztrdt )
170         CALL trd_tra( kt, 'TRA', jp_sal, jptra_totad, ztrds )
171         DEALLOCATE( ztrdt, ztrds )
172      ENDIF
173      !                                              ! print mean trends (used for debugging)
174      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
175         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
176      !
177      IF( ln_timing )   CALL timing_stop( 'tra_adv' )
178      !
179   END SUBROUTINE tra_adv
180
181
182   SUBROUTINE tra_adv_init
183      !!---------------------------------------------------------------------
184      !!                  ***  ROUTINE tra_adv_init  ***
185      !!               
186      !! ** Purpose :   Control the consistency between namelist options for
187      !!              tracer advection schemes and set nadv
188      !!----------------------------------------------------------------------
189      INTEGER ::   ioptio, ios   ! Local integers
190      !
191      NAMELIST/namtra_adv/ ln_traadv_OFF,                        &   ! No advection
192         &                 ln_traadv_cen , nn_cen_h, nn_cen_v,   &   ! CEN
193         &                 ln_traadv_fct , nn_fct_h, nn_fct_v,   &   ! FCT
194         &                 ln_traadv_mus , ln_mus_ups,           &   ! MUSCL
195         &                 ln_traadv_ubs ,           nn_ubs_v,   &   ! UBS
196         &                 ln_traadv_qck                             ! QCK
197      !!----------------------------------------------------------------------
198      !
199      !                                !==  Namelist  ==!
200      REWIND( numnam_ref )                   ! Namelist namtra_adv in reference namelist : Tracer advection scheme
201      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
202901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
203      !
204      REWIND( numnam_cfg )                   ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
205      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
206902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
207      IF(lwm) WRITE( numond, namtra_adv )
208      !
209      IF(lwp) THEN                           ! Namelist print
210         WRITE(numout,*)
211         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
212         WRITE(numout,*) '~~~~~~~~~~~~'
213         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
214         WRITE(numout,*) '      No advection on T & S                     ln_traadv_OFF = ', ln_traadv_OFF
215         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
216         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
217         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
218         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
219         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
220         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
221         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
222         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
223         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
224         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
225         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
226      ENDIF
227      !
228      !                                !==  Parameter control & set nadv ==!
229      ioptio = 0                       
230      IF( ln_traadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
231      IF( ln_traadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
232      IF( ln_traadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
233      IF( ln_traadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
234      IF( ln_traadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
235      IF( ln_traadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
236      !
237      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection option in namelist namtra_adv' )
238      !
239      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
240                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
241        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
242      ENDIF
243      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
244                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
245        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
246      ENDIF
247      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
248        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
249      ENDIF
250      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
251         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
252      ENDIF
253      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
254         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
255            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
256      ENDIF
257      !
258      !                                !==  Print the choice  ==! 
259      IF(lwp) THEN
260         WRITE(numout,*)
261         SELECT CASE ( nadv )
262         CASE( np_NO_adv  )   ;   WRITE(numout,*) '   ==>>>   NO T-S advection'
263         CASE( np_CEN     )   ;   WRITE(numout,*) '   ==>>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
264            &                                                                        ' Vertical   order: ', nn_cen_v
265         CASE( np_FCT     )   ;   WRITE(numout,*) '   ==>>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
266            &                                                                        ' Vertical   order: ', nn_fct_v
267         CASE( np_MUS     )   ;   WRITE(numout,*) '   ==>>>   MUSCL    scheme is used'
268         CASE( np_UBS     )   ;   WRITE(numout,*) '   ==>>>   UBS      scheme is used'
269         CASE( np_QCK     )   ;   WRITE(numout,*) '   ==>>>   QUICKEST scheme is used'
270         END SELECT
271      ENDIF
272      !
273      CALL tra_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
274      !
275   END SUBROUTINE tra_adv_init
276
277  !!======================================================================
278END MODULE traadv
Note: See TracBrowser for help on using the repository browser.