source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA/traadv_mus.F90 @ 10802

Last change on this file since 10802 was 10802, checked in by davestorkey, 2 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : introduce new T/S variables and convert tracer advection routines (including calls from TOP).

  • Property svn:keywords set to Id
File size: 15.1 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26
27   !
28   USE iom            ! XIOS library
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
38   
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
40   !                                                           !  and in closed seas (orca 2 and 1 configurations)
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
42   
43   LOGICAL  ::   l_trd   ! flag to compute trends
44   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
45   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
46
47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE tra_adv_mus( kt, kit000, ktlev, cdtype, p2dt, pu, pv, pwn,             &
57      &                                                     pt, pt_rhs, kjpt, ld_msc_ups )
58      !!----------------------------------------------------------------------
59      !!                    ***  ROUTINE tra_adv_mus  ***
60      !!
61      !! ** Purpose :   Compute the now trend due to total advection of tracers
62      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
63      !!              Conservation Laws) and add it to the general tracer trend.
64      !!
65      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
66      !!              ld_msc_ups=T :
67      !!
68      !! ** Action : - update pt_rhs  with the now advective tracer trends
69      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
70      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
71      !!
72      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
73      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
74      !!----------------------------------------------------------------------
75      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
76      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
77      INTEGER                              , INTENT(in   ) ::   ktlev           ! time level index for source terms
78      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
79      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
80      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
81      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
82      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pu, pv, pwn   ! 3 ocean velocity components
83      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt             ! before tracer field
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pt_rhs             ! tracer trend
85      !
86      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
87      INTEGER  ::   ierr             ! local integer
88      REAL(wp) ::   zu, z0u, zzwx, zw , zalpha   ! local scalars
89      REAL(wp) ::   zv, z0v, zzwy, z0w           !   -      -
90      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwx, zslpx   ! 3D workspace
91      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwy, zslpy   ! -      -
92      !!----------------------------------------------------------------------
93      !
94      IF( kt == kit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
98         IF(lwp) WRITE(numout,*) '~~~~~~~'
99         IF(lwp) WRITE(numout,*)
100         !
101         ! Upstream / MUSCL scheme indicator
102         !
103         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
104         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
105         !
106         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
107            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
108            upsmsk(:,:) = 0._wp                             ! not upstream by default
109            !
110            DO jk = 1, jpkm1
111               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
112                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
113                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
114            END DO
115         ENDIF 
116         !
117      ENDIF 
118      !     
119      l_trd = .FALSE.
120      l_hst = .FALSE.
121      l_ptr = .FALSE.
122      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
123      IF(   cdtype == 'TRA' .AND. ln_diaptr )                                               l_ptr = .TRUE. 
124      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
125         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
126      !
127      DO jn = 1, kjpt            !==  loop over the tracers  ==!
128         !
129         !                          !* Horizontal advective fluxes
130         !
131         !                                !-- first guess of the slopes
132         zwx(:,:,jpk) = 0._wp                   ! bottom values
133         zwy(:,:,jpk) = 0._wp 
134         DO jk = 1, jpkm1                       ! interior values
135            DO jj = 1, jpjm1     
136               DO ji = 1, fs_jpim1   ! vector opt.
137                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( pt(ji+1,jj,jk,jn) - pt(ji,jj,jk,jn) )
138                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( pt(ji,jj+1,jk,jn) - pt(ji,jj,jk,jn) )
139               END DO
140           END DO
141         END DO
142         ! lateral boundary conditions   (changed sign)
143         CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1. , zwy, 'V', -1. )
144         !                                !-- Slopes of tracer
145         zslpx(:,:,jpk) = 0._wp                 ! bottom values
146         zslpy(:,:,jpk) = 0._wp
147         DO jk = 1, jpkm1                       ! interior values
148            DO jj = 2, jpj
149               DO ji = fs_2, jpi   ! vector opt.
150                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
151                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
152                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
153                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
154               END DO
155            END DO
156         END DO
157         !
158         DO jk = 1, jpkm1                 !-- Slopes limitation
159            DO jj = 2, jpj
160               DO ji = fs_2, jpi   ! vector opt.
161                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
162                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
163                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
164                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
165                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
166                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
167               END DO
168           END DO
169         END DO
170         !
171         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
172            DO jj = 2, jpjm1
173               DO ji = fs_2, fs_jpim1   ! vector opt.
174                  ! MUSCL fluxes
175                  z0u = SIGN( 0.5, pu(ji,jj,jk) )
176                  zalpha = 0.5 - z0u
177                  zu  = z0u - 0.5 * pu(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,ktlev)
178                  zzwx = pt(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
179                  zzwy = pt(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
180                  zwx(ji,jj,jk) = pu(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
181                  !
182                  z0v = SIGN( 0.5, pv(ji,jj,jk) )
183                  zalpha = 0.5 - z0v
184                  zv  = z0v - 0.5 * pv(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,ktlev)
185                  zzwx = pt(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
186                  zzwy = pt(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
187                  zwy(ji,jj,jk) = pv(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
188               END DO
189            END DO
190         END DO
191         CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1. , zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
192         !
193         DO jk = 1, jpkm1                 !-- Tracer advective trend
194            DO jj = 2, jpjm1     
195               DO ji = fs_2, fs_jpim1   ! vector opt.
196                  pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
197                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
198                  &                                   * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,ktlev)
199               END DO
200           END DO
201         END DO       
202         !                                ! trend diagnostics
203         IF( l_trd )  THEN
204            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pu, pt(:,:,:,jn) )
205            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pv, pt(:,:,:,jn) )
206         END IF
207         !                                 ! "Poleward" heat and salt transports
208         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
209         !                                 !  heat transport
210         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
211         !
212         !                          !* Vertical advective fluxes
213         !
214         !                                !-- first guess of the slopes
215         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
216         zwx(:,:,jpk) = 0._wp
217         DO jk = 2, jpkm1                       ! interior values
218            zwx(:,:,jk) = tmask(:,:,jk) * ( pt(:,:,jk-1,jn) - pt(:,:,jk,jn) )
219         END DO
220         !                                !-- Slopes of tracer
221         zslpx(:,:,1) = 0._wp                   ! surface values
222         DO jk = 2, jpkm1                       ! interior value
223            DO jj = 1, jpj
224               DO ji = 1, jpi
225                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
226                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
227               END DO
228            END DO
229         END DO
230         DO jk = 2, jpkm1                 !-- Slopes limitation
231            DO jj = 1, jpj                      ! interior values
232               DO ji = 1, jpi
233                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
234                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
235                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
236               END DO
237            END DO
238         END DO
239         DO jk = 1, jpk-2                 !-- vertical advective flux
240            DO jj = 2, jpjm1     
241               DO ji = fs_2, fs_jpim1   ! vector opt.
242                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
243                  zalpha = 0.5 + z0w
244                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
245                  zzwx = pt(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
246                  zzwy = pt(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
247                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
248               END DO
249            END DO
250         END DO
251         IF( ln_linssh ) THEN                   ! top values, linear free surface only
252            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
253               DO jj = 1, jpj
254                  DO ji = 1, jpi
255                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn)
256                  END DO
257               END DO   
258            ELSE                                      ! no cavities: only at the ocean surface
259               zwx(:,:,1) = pwn(:,:,1) * pt(:,:,1,jn)
260            ENDIF
261         ENDIF
262         !
263         DO jk = 1, jpkm1                 !-- vertical advective trend
264            DO jj = 2, jpjm1     
265               DO ji = fs_2, fs_jpim1   ! vector opt.
266                  pt_rhs(ji,jj,jk,jn) =  pt_rhs(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,ktlev)
267               END DO
268            END DO
269         END DO
270         !                                ! send trends for diagnostic
271         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, pt(:,:,:,jn) )
272         !
273      END DO                     ! end of tracer loop
274      !
275   END SUBROUTINE tra_adv_mus
276
277   !!======================================================================
278END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.