New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA/traldf_iso.F90 @ 10980

Last change on this file since 10980 was 10980, checked in by acc, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : interface changes to traldf routines for design compliance and consistency. SETTE tested (GYRE_PISCES, only)

  • Property svn:keywords set to Id
File size: 21.4 KB
RevLine 
[3]1MODULE traldf_iso
[503]2   !!======================================================================
[457]3   !!                   ***  MODULE  traldf_iso  ***
[2528]4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
[503]5   !!======================================================================
[5836]6   !! History :  OPA  ! 1994-08  (G. Madec, M. Imbard)
7   !!            8.0  ! 1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO ! 2002-08  (G. Madec)  Free form, F90
9   !!            1.0  ! 2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  ! 2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.7  ! 2014-01  (G. Madec, S. Masson)  restructuration/simplification of aht/aeiv specification
12   !!             -   ! 2014-02  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
[503]13   !!----------------------------------------------------------------------
[5836]14
[3]15   !!----------------------------------------------------------------------
[6140]16   !!   tra_ldf_iso   : update the tracer trend with the horizontal component of a iso-neutral laplacian operator
17   !!                   and with the vertical part of the isopycnal or geopotential s-coord. operator
[3]18   !!----------------------------------------------------------------------
[6140]19   USE oce            ! ocean dynamics and active tracers
20   USE dom_oce        ! ocean space and time domain
21   USE trc_oce        ! share passive tracers/Ocean variables
22   USE zdf_oce        ! ocean vertical physics
23   USE ldftra         ! lateral diffusion: tracer eddy coefficients
24   USE ldfslp         ! iso-neutral slopes
25   USE diaptr         ! poleward transport diagnostics
[7646]26   USE diaar5         ! AR5 diagnostics
[5836]27   !
[6140]28   USE in_out_manager ! I/O manager
29   USE iom            ! I/O library
30   USE phycst         ! physical constants
31   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
[3]32
33   IMPLICIT NONE
34   PRIVATE
35
[503]36   PUBLIC   tra_ldf_iso   ! routine called by step.F90
[3]37
[7646]38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat transport
40
[3]41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
[9598]44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
[2528]45   !! $Id$
[10068]46   !! Software governed by the CeCILL license (see ./LICENSE)
[247]47   !!----------------------------------------------------------------------
[3]48CONTAINS
49
[10980]50  SUBROUTINE tra_ldf_iso( kt, Kmm, kit000, cdtype, pahu, pahv,                    &
51      &                                            pgu , pgv    ,   pgui, pgvi,   &
52      &                                       pt , pt2 , pt_rhs , kjpt  , kpass )
[3]53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_iso  ***
[457]55      !!
[3]56      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
[457]57      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
58      !!      add it to the general trend of tracer equation.
[3]59      !!
60      !! ** Method  :   The horizontal component of the lateral diffusive trends
61      !!      is provided by a 2nd order operator rotated along neural or geopo-
62      !!      tential surfaces to which an eddy induced advection can be added
63      !!      It is computed using before fields (forward in time) and isopyc-
64      !!      nal or geopotential slopes computed in routine ldfslp.
65      !!
[2528]66      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
[5836]67      !!      ========    with partial cell update if ln_zps=T
68      !!                  with top     cell update if ln_isfcav
[457]69      !!
70      !!      2nd part :  horizontal fluxes of the lateral mixing operator
71      !!      ========   
[5836]72      !!         zftu =  pahu e2u*e3u/e1u di[ tb ]
73      !!               - pahu e2u*uslp    dk[ mi(mk(tb)) ]
74      !!         zftv =  pahv e1v*e3v/e2v dj[ tb ]
75      !!               - pahv e2u*vslp    dk[ mj(mk(tb)) ]
[3]76      !!      take the horizontal divergence of the fluxes:
[5836]77      !!         difft = 1/(e1e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
[3]78      !!      Add this trend to the general trend (ta,sa):
79      !!         ta = ta + difft
80      !!
[457]81      !!      3rd part: vertical trends of the lateral mixing operator
82      !!      ========  (excluding the vertical flux proportional to dk[t] )
83      !!      vertical fluxes associated with the rotated lateral mixing:
[5836]84      !!         zftw = - {  mi(mk(pahu)) * e2t*wslpi di[ mi(mk(tb)) ]
85      !!                   + mj(mk(pahv)) * e1t*wslpj dj[ mj(mk(tb)) ]  }
[457]86      !!      take the horizontal divergence of the fluxes:
[5836]87      !!         difft = 1/(e1e2t*e3t) dk[ zftw ]
[457]88      !!      Add this trend to the general trend (ta,sa):
[10980]89      !!         pt_rhs = pt_rhs + difft
[3]90      !!
[10980]91      !! ** Action :   Update pt_rhs arrays with the before rotated diffusion
[503]92      !!----------------------------------------------------------------------
[2528]93      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
[5836]94      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
[2528]95      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
96      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
[5836]97      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
[10954]98      INTEGER                              , INTENT(in   ) ::   Kmm        ! ocean time level index
[5836]99      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
100      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
101      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
[10980]102      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt         ! tracer (kpass=1) or laplacian of tracer (kpass=2)
103      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt2        ! tracer (only used in kpass=2)
104      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pt_rhs     ! tracer trend
[2715]105      !
[2528]106      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
[6140]107      INTEGER  ::  ikt
[5836]108      INTEGER  ::  ierr             ! local integer
109      REAL(wp) ::  zmsku, zahu_w, zabe1, zcof1, zcoef3   ! local scalars
110      REAL(wp) ::  zmskv, zahv_w, zabe2, zcof2, zcoef4   !   -      -
111      REAL(wp) ::  zcoef0, ze3w_2, zsign, z2dt, z1_2dt   !   -      -
[9019]112      REAL(wp), DIMENSION(jpi,jpj)     ::   zdkt, zdk1t, z2d
113      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, zftu, zftv, ztfw 
[3]114      !!----------------------------------------------------------------------
[3294]115      !
[9779]116      IF( kpass == 1 .AND. kt == kit000 )  THEN
[3]117         IF(lwp) WRITE(numout,*)
[2528]118         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
[457]119         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
[5836]120         !
[7753]121         akz     (:,:,:) = 0._wp     
122         ah_wslp2(:,:,:) = 0._wp
[3]123      ENDIF
[7646]124      !   
125      l_hst = .FALSE.
126      l_ptr = .FALSE.
127      IF( cdtype == 'TRA' .AND. ln_diaptr )                                                 l_ptr = .TRUE. 
128      IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
129         &                        iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )   l_hst = .TRUE.
130      !
131      !                                            ! set time step size (Euler/Leapfrog)
[6140]132      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   z2dt =     rdt      ! at nit000   (Euler)
133      ELSE                                        ;   z2dt = 2.* rdt      !             (Leapfrog)
[5836]134      ENDIF
135      z1_2dt = 1._wp / z2dt
136      !
137      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
138      ELSE                    ;   zsign = -1._wp
139      ENDIF
140         
141      !!----------------------------------------------------------------------
142      !!   0 - calculate  ah_wslp2 and akz
143      !!----------------------------------------------------------------------
144      !
145      IF( kpass == 1 ) THEN                  !==  first pass only  ==!
146         !
147         DO jk = 2, jpkm1
148            DO jj = 2, jpjm1
149               DO ji = fs_2, fs_jpim1   ! vector opt.
150                  !
[6140]151                  zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
[5836]152                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
[6140]153                  zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
[5836]154                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
155                     !
156                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
157                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
158                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
159                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
160                     !
161                  ah_wslp2(ji,jj,jk) = zahu_w * wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
162                     &               + zahv_w * wslpj(ji,jj,jk) * wslpj(ji,jj,jk)
163               END DO
164            END DO
165         END DO
166         !
167         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
168            DO jk = 2, jpkm1
169               DO jj = 2, jpjm1
170                  DO ji = fs_2, fs_jpim1
171                     akz(ji,jj,jk) = 0.25_wp * (                                                                     &
172                        &              ( pahu(ji  ,jj,jk) + pahu(ji  ,jj,jk-1) ) / ( e1u(ji  ,jj) * e1u(ji  ,jj) )   &
173                        &            + ( pahu(ji-1,jj,jk) + pahu(ji-1,jj,jk-1) ) / ( e1u(ji-1,jj) * e1u(ji-1,jj) )   &
174                        &            + ( pahv(ji,jj  ,jk) + pahv(ji,jj  ,jk-1) ) / ( e2v(ji,jj  ) * e2v(ji,jj  ) )   &
175                        &            + ( pahv(ji,jj-1,jk) + pahv(ji,jj-1,jk-1) ) / ( e2v(ji,jj-1) * e2v(ji,jj-1) )   )
176                  END DO
177               END DO
178            END DO
179            !
180            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
181               DO jk = 2, jpkm1
182                  DO jj = 1, jpjm1
183                     DO ji = 1, fs_jpim1
184                        akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
[10954]185                           &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) )  )
[5836]186                     END DO
187                  END DO
188               END DO
189            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
190               DO jk = 2, jpkm1
191                  DO jj = 1, jpjm1
192                     DO ji = 1, fs_jpim1
[10954]193                        ze3w_2 = e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm)
[5836]194                        zcoef0 = z2dt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
195                        akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt
196                     END DO
197                  END DO
198               END DO
199           ENDIF
200           !
201         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
[7753]202            akz(:,:,:) = ah_wslp2(:,:,:)     
[5836]203         ENDIF
204      ENDIF
205      !
[2528]206      !                                                          ! ===========
207      DO jn = 1, kjpt                                            ! tracer loop
208         !                                                       ! ===========
209         !                                               
210         !!----------------------------------------------------------------------
211         !!   I - masked horizontal derivative
212         !!----------------------------------------------------------------------
[5836]213!!gm : bug.... why (x,:,:)?   (1,jpj,:) and (jpi,1,:) should be sufficient....
[7753]214         zdit (1,:,:) = 0._wp     ;     zdit (jpi,:,:) = 0._wp
215         zdjt (1,:,:) = 0._wp     ;     zdjt (jpi,:,:) = 0._wp
[2528]216         !!end
[3]217
[2528]218         ! Horizontal tracer gradient
219         DO jk = 1, jpkm1
220            DO jj = 1, jpjm1
221               DO ji = 1, fs_jpim1   ! vector opt.
[10980]222                  zdit(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk)
223                  zdjt(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
[2528]224               END DO
[457]225            END DO
226         END DO
[5836]227         IF( ln_zps ) THEN      ! botton and surface ocean correction of the horizontal gradient
228            DO jj = 1, jpjm1              ! bottom correction (partial bottom cell)
[2528]229               DO ji = 1, fs_jpim1   ! vector opt.
[5120]230                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
231                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
232               END DO
233            END DO
[5836]234            IF( ln_isfcav ) THEN      ! first wet level beneath a cavity
235               DO jj = 1, jpjm1
236                  DO ji = 1, fs_jpim1   ! vector opt.
237                     IF( miku(ji,jj) > 1 )   zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
238                     IF( mikv(ji,jj) > 1 )   zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
239                  END DO
240               END DO
241            ENDIF
[5120]242         ENDIF
[6140]243         !
[2528]244         !!----------------------------------------------------------------------
245         !!   II - horizontal trend  (full)
246         !!----------------------------------------------------------------------
[5836]247         !
248         DO jk = 1, jpkm1                                 ! Horizontal slab
249            !
250            !                             !== Vertical tracer gradient
[10980]251            zdk1t(:,:) = ( pt(:,:,jk,jn) - pt(:,:,jk+1,jn) ) * wmask(:,:,jk+1)     ! level jk+1
[5836]252            !
[7753]253            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)                          ! surface: zdkt(jk=1)=zdkt(jk=2)
[10980]254            ELSE                 ;   zdkt(:,:) = ( pt(:,:,jk-1,jn) - pt(:,:,jk,jn) ) * wmask(:,:,jk)
[5836]255            ENDIF
256            DO jj = 1 , jpjm1            !==  Horizontal fluxes
[5120]257               DO ji = 1, fs_jpim1   ! vector opt.
[10954]258                  zabe1 = pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u(ji,jj,jk,Kmm)
259                  zabe2 = pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v(ji,jj,jk,Kmm)
[2528]260                  !
[6140]261                  zmsku = 1. / MAX(  wmask(ji+1,jj,jk  ) + wmask(ji,jj,jk+1)   &
262                     &             + wmask(ji+1,jj,jk+1) + wmask(ji,jj,jk  ), 1. )
[2528]263                  !
[6140]264                  zmskv = 1. / MAX(  wmask(ji,jj+1,jk  ) + wmask(ji,jj,jk+1)   &
265                     &             + wmask(ji,jj+1,jk+1) + wmask(ji,jj,jk  ), 1. )
[2528]266                  !
[5836]267                  zcof1 = - pahu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
268                  zcof2 = - pahv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
[2528]269                  !
270                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
[5836]271                     &               + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
272                     &                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
[2528]273                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
[5836]274                     &               + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
275                     &                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
[2528]276               END DO
[3]277            END DO
[5836]278            !
[10980]279            DO jj = 2 , jpjm1          !== horizontal divergence and add to pt_rhs
[5120]280               DO ji = fs_2, fs_jpim1   ! vector opt.
[10980]281                  pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + zsign * (  zftu(ji,jj,jk) - zftu(ji-1,jj,jk)      &
282                     &                                                 + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )   &
283                     &                                              * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
[2528]284               END DO
[3]285            END DO
[2528]286         END DO                                        !   End of slab 
[3]287
[2528]288         !!----------------------------------------------------------------------
[5836]289         !!   III - vertical trend (full)
[2528]290         !!----------------------------------------------------------------------
[6140]291         !
[7753]292         ztfw(1,:,:) = 0._wp     ;     ztfw(jpi,:,:) = 0._wp
[6140]293         !
[2528]294         ! Vertical fluxes
295         ! ---------------
[6140]296         !                          ! Surface and bottom vertical fluxes set to zero
[7753]297         ztfw(:,:, 1 ) = 0._wp      ;      ztfw(:,:,jpk) = 0._wp
[2528]298         
[6140]299         DO jk = 2, jpkm1           ! interior (2=<jk=<jpk-1)
[2528]300            DO jj = 2, jpjm1
301               DO ji = fs_2, fs_jpim1   ! vector opt.
302                  !
[6140]303                  zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
[5836]304                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
[6140]305                  zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
[5836]306                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
307                     !
308                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
309                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
310                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
311                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
312                     !
313                  zcoef3 = - zahu_w * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)   !wslpi & j are already w-masked
314                  zcoef4 = - zahv_w * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
[2528]315                  !
316                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
317                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
318                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
319                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
320               END DO
[457]321            END DO
322         END DO
[5836]323         !                                !==  add the vertical 33 flux  ==!
324         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
325            DO jk = 2, jpkm1       
326               DO jj = 1, jpjm1
327                  DO ji = fs_2, fs_jpim1
[10954]328                     ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * wmask(ji,jj,jk)   &
[10980]329                        &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )               &
330                        &                            * (  pt(ji,jj,jk-1,jn) -  pt(ji,jj,jk,jn) )
[5836]331                  END DO
332               END DO
333            END DO
334            !
335         ELSE                                   ! bilaplacian
336            SELECT CASE( kpass )
337            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
338               DO jk = 2, jpkm1 
339                  DO jj = 1, jpjm1
340                     DO ji = fs_2, fs_jpim1
[10980]341                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk)                       &
342                           &           + ah_wslp2(ji,jj,jk)  * e1e2t(ji,jj)   &
343                           &           * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) / e3w(ji,jj,jk,Kmm) * wmask(ji,jj,jk)
[5836]344                     END DO
345                  END DO
346               END DO
[10980]347            CASE(  2  )                         ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt  and pt2 gradients, resp.
[5836]348               DO jk = 2, jpkm1 
349                  DO jj = 1, jpjm1
350                     DO ji = fs_2, fs_jpim1
[10980]351                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * wmask(ji,jj,jk)                  &
352                           &                            * (  ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) )   &
353                           &                            +         akz(ji,jj,jk) * ( pt2(ji,jj,jk-1,jn) - pt2(ji,jj,jk,jn) )   )
[5836]354                     END DO
355                  END DO
356               END DO
357            END SELECT
358         ENDIF
359         !         
[10980]360         DO jk = 1, jpkm1                 !==  Divergence of vertical fluxes added to pt_rhs  ==!
[2528]361            DO jj = 2, jpjm1
362               DO ji = fs_2, fs_jpim1   ! vector opt.
[10980]363                  pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + zsign * (  ztfw (ji,jj,jk) - ztfw(ji,jj,jk+1)  )   &
364                     &                                              * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
[2528]365               END DO
[457]366            END DO
367         END DO
[2528]368         !
[5836]369         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
370             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
371            !
372            !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
[7646]373               ! note sign is reversed to give down-gradient diffusive transports )
374            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', -zftv(:,:,:)  )
375            !                          ! Diffusive heat transports
376            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', -zftu(:,:,:), -zftv(:,:,:) )
[5836]377            !
378         ENDIF                                                    !== end pass selection  ==!
379         !
380         !                                                        ! ===============
381      END DO                                                      ! end tracer loop
[503]382      !
[3]383   END SUBROUTINE tra_ldf_iso
384
385   !!==============================================================================
386END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.