New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap_blp.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA/traldf_lap_blp.F90 @ 10806

Last change on this file since 10806 was 10806, checked in by davestorkey, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps branch: Latest updates. Make sure all time-dependent 3D variables are converted in previously modified modules.
  • Property svn:keywords set to Id
File size: 14.0 KB
Line 
1MODULE traldf_lap_blp
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap_blp  ***
4   !! Ocean tracers:  lateral diffusivity trend  (laplacian and bilaplacian)
5   !!==============================================================================
6   !! History :  3.7  ! 2014-01  (G. Madec, S. Masson)  Original code, re-entrant laplacian
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_lap   : tracer trend update with iso-level laplacian diffusive operator
11   !!   tra_ldf_blp   : tracer trend update with iso-level or iso-neutral bilaplacian operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and active tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ldftra         ! lateral physics: eddy diffusivity
16   USE traldf_iso     ! iso-neutral lateral diffusion (standard operator)     (tra_ldf_iso   routine)
17   USE traldf_triad   ! iso-neutral lateral diffusion (triad    operator)     (tra_ldf_triad routine)
18   USE diaptr         ! poleward transport diagnostics
19   USE diaar5         ! AR5 diagnostics
20   USE trc_oce        ! share passive tracers/Ocean variables
21   USE zpshde         ! partial step: hor. derivative     (zps_hde routine)
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O library
25   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
26   USE lib_mpp        ! distribued memory computing library
27   USE timing         ! Timing
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_ldf_lap   ! called by traldf.F90
33   PUBLIC   tra_ldf_blp   ! called by traldf.F90
34
35   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
36   LOGICAL  ::   l_hst   ! flag to compute heat transport
37
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_ldf_lap( kt, kit000, ktlev, kt2lev, cdtype, pahu, pahv, pgu , pgv ,   &
48      &                                                    pgui, pgvi,   &
49      &                                        pt , pt_rhs , kjpt, kpass ) 
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_ldf_lap  ***
52      !!                   
53      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
54      !!      trend and add it to the general trend of tracer equation.
55      !!
56      !! ** Method  :   Second order diffusive operator evaluated using before
57      !!      fields (forward time scheme). The horizontal diffusive trends of
58      !!      the tracer is given by:
59      !!          difft = 1/(e1e2t*e3t) {  di-1[ pahu e2u*e3u/e1u di(tb) ]
60      !!                                 + dj-1[ pahv e1v*e3v/e2v dj(tb) ] }
61      !!      Add this trend to the general tracer trend pt_rhs :
62      !!          pt_rhs = pt_rhs + difft
63      !!
64      !! ** Action  : - Update pt_rhs arrays with the before iso-level
65      !!                harmonic mixing trend.
66      !!----------------------------------------------------------------------
67      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
68      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
69      INTEGER                              , INTENT(in   ) ::   ktlev      ! time level index for e3t
70      INTEGER                              , INTENT(in   ) ::   kt2lev     ! time level index for 2-time-level thicknesses
71      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
72      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
73      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
74      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
75      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
76      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt        ! before and now tracer fields
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pt_rhs        ! tracer trend
79      !
80      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
81      REAL(wp) ::   zsign            ! local scalars
82      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztu, ztv, zaheeu, zaheev
83      !!----------------------------------------------------------------------
84      !
85      IF( kt == nit000 .AND. lwp )  THEN
86         WRITE(numout,*)
87         WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype, ', pass=', kpass
88         WRITE(numout,*) '~~~~~~~~~~~ '
89      ENDIF
90      !
91      l_hst = .FALSE.
92      l_ptr = .FALSE.
93      IF( cdtype == 'TRA' .AND. ln_diaptr )                                                l_ptr = .TRUE. 
94      IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
95         &                        iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
96      !
97      !                                !==  Initialization of metric arrays used for all tracers  ==!
98      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
99      ELSE                    ;   zsign = -1._wp
100      ENDIF
101      DO jk = 1, jpkm1
102         DO jj = 1, jpjm1
103            DO ji = 1, fs_jpim1   ! vector opt.
104               zaheeu(ji,jj,jk) = zsign * pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u(ji,jj,jk,ktlev)   !!gm   * umask(ji,jj,jk) pah masked!
105               zaheev(ji,jj,jk) = zsign * pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v(ji,jj,jk,ktlev)   !!gm   * vmask(ji,jj,jk)
106            END DO
107         END DO
108      END DO
109      !
110      !                             ! =========== !
111      DO jn = 1, kjpt               ! tracer loop !
112         !                          ! =========== !   
113         !                               
114         DO jk = 1, jpkm1              !== First derivative (gradient)  ==!
115            DO jj = 1, jpjm1
116               DO ji = 1, fs_jpim1
117                  ztu(ji,jj,jk) = zaheeu(ji,jj,jk) * ( pt(ji+1,jj  ,jk,jn) - pt(ji,jj,jk,jn) )
118                  ztv(ji,jj,jk) = zaheev(ji,jj,jk) * ( pt(ji  ,jj+1,jk,jn) - pt(ji,jj,jk,jn) )
119               END DO
120            END DO
121         END DO 
122         IF( ln_zps ) THEN                ! set gradient at bottom/top ocean level
123            DO jj = 1, jpjm1                    ! bottom
124               DO ji = 1, fs_jpim1
125                  ztu(ji,jj,mbku(ji,jj)) = zaheeu(ji,jj,mbku(ji,jj)) * pgu(ji,jj,jn)
126                  ztv(ji,jj,mbkv(ji,jj)) = zaheev(ji,jj,mbkv(ji,jj)) * pgv(ji,jj,jn)
127               END DO
128            END DO 
129            IF( ln_isfcav ) THEN                ! top in ocean cavities only
130               DO jj = 1, jpjm1
131                  DO ji = 1, fs_jpim1   ! vector opt.
132                     IF( miku(ji,jj) > 1 )   ztu(ji,jj,miku(ji,jj)) = zaheeu(ji,jj,miku(ji,jj)) * pgui(ji,jj,jn) 
133                     IF( mikv(ji,jj) > 1 )   ztv(ji,jj,mikv(ji,jj)) = zaheev(ji,jj,mikv(ji,jj)) * pgvi(ji,jj,jn) 
134                  END DO
135               END DO
136            ENDIF
137         ENDIF
138         !
139         DO jk = 1, jpkm1              !== Second derivative (divergence) added to the general tracer trends  ==!
140            DO jj = 2, jpjm1
141               DO ji = fs_2, fs_jpim1
142                  pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)     &
143                     &                                   + ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )   &
144                     &                                / ( e1e2t(ji,jj) * e3t(ji,jj,jk,ktlev) )
145               END DO
146            END DO
147         END DO 
148         !
149         !                             !== "Poleward" diffusive heat or salt transports  ==!
150         IF( ( kpass == 1 .AND. .NOT.ln_traldf_blp ) .OR.  &     !==  first pass only (  laplacian)  ==!
151             ( kpass == 2 .AND.      ln_traldf_blp ) ) THEN      !==  2nd   pass only (bilaplacian)  ==!
152
153            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', -ztv(:,:,:)  )
154            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', -ztu(:,:,:), -ztv(:,:,:) )
155         ENDIF
156         !                          ! ==================
157      END DO                        ! end of tracer loop
158      !                             ! ==================
159      !
160   END SUBROUTINE tra_ldf_lap
161   
162
163   SUBROUTINE tra_ldf_blp( kt, kit000, ktlev, kt2lev, cdtype, pahu, pahv, pgu , pgv ,   &
164      &                                                    pgui, pgvi,   &
165      &                                                    pt , pt_rhs , kjpt, kldf )
166      !!----------------------------------------------------------------------
167      !!                 ***  ROUTINE tra_ldf_blp  ***
168      !!                   
169      !! ** Purpose :   Compute the before lateral tracer diffusive
170      !!      trend and add it to the general trend of tracer equation.
171      !!
172      !! ** Method  :   The lateral diffusive trends is provided by a bilaplacian
173      !!      operator applied to before field (forward in time).
174      !!      It is computed by two successive calls to laplacian routine
175      !!
176      !! ** Action :   pt_rhs   updated with the before rotated bilaplacian diffusion
177      !!----------------------------------------------------------------------
178      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
179      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
180      INTEGER                              , INTENT(in   ) ::   ktlev      ! time level index for e3t
181      INTEGER                              , INTENT(in   ) ::   kt2lev     ! time level index for 2-time-level thicknesses
182      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
183      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
184      INTEGER                              , INTENT(in   ) ::   kldf       ! type of operator used
185      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
186      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
187      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top levels
188      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt        ! before and now tracer fields
189      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pt_rhs        ! tracer trend
190      !
191      INTEGER ::   ji, jj, jk, jn   ! dummy loop indices
192      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt) :: zlap         ! laplacian at t-point
193      REAL(wp), DIMENSION(jpi,jpj,    kjpt) :: zglu, zglv   ! bottom GRADh of the laplacian (u- and v-points)
194      REAL(wp), DIMENSION(jpi,jpj,    kjpt) :: zgui, zgvi   ! top    GRADh of the laplacian (u- and v-points)
195      !!---------------------------------------------------------------------
196      !
197      IF( kt == kit000 .AND. lwp )  THEN
198         WRITE(numout,*)
199         SELECT CASE ( kldf )
200         CASE ( np_blp    )   ;   WRITE(numout,*) 'tra_ldf_blp : iso-level   bilaplacian operator on ', cdtype
201         CASE ( np_blp_i  )   ;   WRITE(numout,*) 'tra_ldf_blp : iso-neutral bilaplacian operator on ', cdtype, ' (Standard)'
202         CASE ( np_blp_it )   ;   WRITE(numout,*) 'tra_ldf_blp : iso-neutral bilaplacian operator on ', cdtype, ' (triad)'
203         END SELECT
204         WRITE(numout,*) '~~~~~~~~~~~'
205      ENDIF
206
207      zlap(:,:,:,:) = 0._wp
208      !
209      SELECT CASE ( kldf )       !==  1st laplacian applied to pt (output in zlap)  ==!
210      !
211      CASE ( np_blp    )               ! iso-level bilaplacian
212         CALL tra_ldf_lap  ( kt, kit000, ktlev, kt2lev, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, pt,      zlap, kjpt, 1 )
213      CASE ( np_blp_i  )               ! rotated   bilaplacian : standard operator (Madec)
214         CALL tra_ldf_iso  ( kt, kit000, ktlev, kt2lev, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, pt, pt, zlap, kjpt, 1 )
215      CASE ( np_blp_it )               ! rotated  bilaplacian : triad operator (griffies)
216         CALL tra_ldf_triad( kt, kit000, ktlev, kt2lev, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, pt, pt, zlap, kjpt, 1 )
217      END SELECT
218      !
219      CALL lbc_lnk( 'traldf_lap_blp', zlap(:,:,:,:) , 'T', 1. )     ! Lateral boundary conditions (unchanged sign)
220      !                                               ! Partial top/bottom cell: GRADh( zlap ) 
221      IF( ln_isfcav .AND. ln_zps ) THEN   ;   CALL zps_hde_isf( kt, kjpt, zlap, zglu, zglv, zgui, zgvi )  ! both top & bottom
222      ELSEIF(             ln_zps ) THEN   ;   CALL zps_hde    ( kt, kjpt, zlap, zglu, zglv )              ! only bottom
223      ENDIF
224      !
225      SELECT CASE ( kldf )       !==  2nd laplacian applied to zlap (output in pt_rhs)  ==!
226      !
227      CASE ( np_blp    )               ! iso-level bilaplacian
228         CALL tra_ldf_lap  ( kt, kit000, ktlev, kt2lev, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, pt_rhs,      kjpt, 2 )
229      CASE ( np_blp_i  )               ! rotated   bilaplacian : standard operator (Madec)
230         CALL tra_ldf_iso  ( kt, kit000, ktlev, kt2lev, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, pt, pt_rhs, kjpt, 2 )
231      CASE ( np_blp_it )               ! rotated  bilaplacian : triad operator (griffies)
232         CALL tra_ldf_triad( kt, kit000, ktlev, kt2lev, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, pt, pt_rhs, kjpt, 2 )
233      END SELECT
234      !
235   END SUBROUTINE tra_ldf_blp
236
237   !!==============================================================================
238END MODULE traldf_lap_blp
Note: See TracBrowser for help on using the repository browser.