source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA/traldf_lap_blp.F90 @ 10954

Last change on this file since 10954 was 10954, checked in by acc, 2 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Convert TRA modules and all knock on effects of these conversions. SETTE tested

  • Property svn:keywords set to Id
File size: 13.7 KB
Line 
1MODULE traldf_lap_blp
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap_blp  ***
4   !! Ocean tracers:  lateral diffusivity trend  (laplacian and bilaplacian)
5   !!==============================================================================
6   !! History :  3.7  ! 2014-01  (G. Madec, S. Masson)  Original code, re-entrant laplacian
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_lap   : tracer trend update with iso-level laplacian diffusive operator
11   !!   tra_ldf_blp   : tracer trend update with iso-level or iso-neutral bilaplacian operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and active tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ldftra         ! lateral physics: eddy diffusivity
16   USE traldf_iso     ! iso-neutral lateral diffusion (standard operator)     (tra_ldf_iso   routine)
17   USE traldf_triad   ! iso-neutral lateral diffusion (triad    operator)     (tra_ldf_triad routine)
18   USE diaptr         ! poleward transport diagnostics
19   USE diaar5         ! AR5 diagnostics
20   USE trc_oce        ! share passive tracers/Ocean variables
21   USE zpshde         ! partial step: hor. derivative     (zps_hde routine)
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O library
25   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
26   USE lib_mpp        ! distribued memory computing library
27   USE timing         ! Timing
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_ldf_lap   ! called by traldf.F90
33   PUBLIC   tra_ldf_blp   ! called by traldf.F90
34
35   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
36   LOGICAL  ::   l_hst   ! flag to compute heat transport
37
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_ldf_lap( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
48      &                                                    pgui, pgvi,   &
49      &                                        ptb , pta , kjpt, kpass, Kmm ) 
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_ldf_lap  ***
52      !!                   
53      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
54      !!      trend and add it to the general trend of tracer equation.
55      !!
56      !! ** Method  :   Second order diffusive operator evaluated using before
57      !!      fields (forward time scheme). The horizontal diffusive trends of
58      !!      the tracer is given by:
59      !!          difft = 1/(e1e2t*e3t) {  di-1[ pahu e2u*e3u/e1u di(tb) ]
60      !!                                 + dj-1[ pahv e1v*e3v/e2v dj(tb) ] }
61      !!      Add this trend to the general tracer trend pta :
62      !!          pta = pta + difft
63      !!
64      !! ** Action  : - Update pta arrays with the before iso-level
65      !!                harmonic mixing trend.
66      !!----------------------------------------------------------------------
67      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
68      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
69      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
70      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
71      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
72      INTEGER                              , INTENT(in   ) ::   Kmm        ! ocean time level index
73      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
74      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
75      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
76      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
78      !
79      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
80      REAL(wp) ::   zsign            ! local scalars
81      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztu, ztv, zaheeu, zaheev
82      !!----------------------------------------------------------------------
83      !
84      IF( kt == nit000 .AND. lwp )  THEN
85         WRITE(numout,*)
86         WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype, ', pass=', kpass
87         WRITE(numout,*) '~~~~~~~~~~~ '
88      ENDIF
89      !
90      l_hst = .FALSE.
91      l_ptr = .FALSE.
92      IF( cdtype == 'TRA' .AND. ln_diaptr )                                                l_ptr = .TRUE. 
93      IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
94         &                        iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
95      !
96      !                                !==  Initialization of metric arrays used for all tracers  ==!
97      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
98      ELSE                    ;   zsign = -1._wp
99      ENDIF
100      DO jk = 1, jpkm1
101         DO jj = 1, jpjm1
102            DO ji = 1, fs_jpim1   ! vector opt.
103               zaheeu(ji,jj,jk) = zsign * pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u(ji,jj,jk,Kmm)   !!gm   * umask(ji,jj,jk) pah masked!
104               zaheev(ji,jj,jk) = zsign * pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v(ji,jj,jk,Kmm)   !!gm   * vmask(ji,jj,jk)
105            END DO
106         END DO
107      END DO
108      !
109      !                             ! =========== !
110      DO jn = 1, kjpt               ! tracer loop !
111         !                          ! =========== !   
112         !                               
113         DO jk = 1, jpkm1              !== First derivative (gradient)  ==!
114            DO jj = 1, jpjm1
115               DO ji = 1, fs_jpim1
116                  ztu(ji,jj,jk) = zaheeu(ji,jj,jk) * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
117                  ztv(ji,jj,jk) = zaheev(ji,jj,jk) * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
118               END DO
119            END DO
120         END DO 
121         IF( ln_zps ) THEN                ! set gradient at bottom/top ocean level
122            DO jj = 1, jpjm1                    ! bottom
123               DO ji = 1, fs_jpim1
124                  ztu(ji,jj,mbku(ji,jj)) = zaheeu(ji,jj,mbku(ji,jj)) * pgu(ji,jj,jn)
125                  ztv(ji,jj,mbkv(ji,jj)) = zaheev(ji,jj,mbkv(ji,jj)) * pgv(ji,jj,jn)
126               END DO
127            END DO 
128            IF( ln_isfcav ) THEN                ! top in ocean cavities only
129               DO jj = 1, jpjm1
130                  DO ji = 1, fs_jpim1   ! vector opt.
131                     IF( miku(ji,jj) > 1 )   ztu(ji,jj,miku(ji,jj)) = zaheeu(ji,jj,miku(ji,jj)) * pgui(ji,jj,jn) 
132                     IF( mikv(ji,jj) > 1 )   ztv(ji,jj,mikv(ji,jj)) = zaheev(ji,jj,mikv(ji,jj)) * pgvi(ji,jj,jn) 
133                  END DO
134               END DO
135            ENDIF
136         ENDIF
137         !
138         DO jk = 1, jpkm1              !== Second derivative (divergence) added to the general tracer trends  ==!
139            DO jj = 2, jpjm1
140               DO ji = fs_2, fs_jpim1
141                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)     &
142                     &                                   + ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )   &
143                     &                                / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) )
144               END DO
145            END DO
146         END DO 
147         !
148         !                             !== "Poleward" diffusive heat or salt transports  ==!
149         IF( ( kpass == 1 .AND. .NOT.ln_traldf_blp ) .OR.  &     !==  first pass only (  laplacian)  ==!
150             ( kpass == 2 .AND.      ln_traldf_blp ) ) THEN      !==  2nd   pass only (bilaplacian)  ==!
151
152            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', -ztv(:,:,:)  )
153            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', -ztu(:,:,:), -ztv(:,:,:) )
154         ENDIF
155         !                          ! ==================
156      END DO                        ! end of tracer loop
157      !                             ! ==================
158      !
159   END SUBROUTINE tra_ldf_lap
160   
161
162   SUBROUTINE tra_ldf_blp( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
163      &                                                    pgui, pgvi,   &
164      &                                                    ptb , pta , kjpt, kldf, Kmm )
165      !!----------------------------------------------------------------------
166      !!                 ***  ROUTINE tra_ldf_blp  ***
167      !!                   
168      !! ** Purpose :   Compute the before lateral tracer diffusive
169      !!      trend and add it to the general trend of tracer equation.
170      !!
171      !! ** Method  :   The lateral diffusive trends is provided by a bilaplacian
172      !!      operator applied to before field (forward in time).
173      !!      It is computed by two successive calls to laplacian routine
174      !!
175      !! ** Action :   pta   updated with the before rotated bilaplacian diffusion
176      !!----------------------------------------------------------------------
177      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
178      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
179      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
180      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
181      INTEGER                              , INTENT(in   ) ::   kldf       ! type of operator used
182      INTEGER                              , INTENT(in   ) ::   Kmm        ! ocean time level indices
183      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
184      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
185      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top levels
186      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
187      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
188      !
189      INTEGER ::   ji, jj, jk, jn   ! dummy loop indices
190      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt) :: zlap         ! laplacian at t-point
191      REAL(wp), DIMENSION(jpi,jpj,    kjpt) :: zglu, zglv   ! bottom GRADh of the laplacian (u- and v-points)
192      REAL(wp), DIMENSION(jpi,jpj,    kjpt) :: zgui, zgvi   ! top    GRADh of the laplacian (u- and v-points)
193      !!---------------------------------------------------------------------
194      !
195      IF( kt == kit000 .AND. lwp )  THEN
196         WRITE(numout,*)
197         SELECT CASE ( kldf )
198         CASE ( np_blp    )   ;   WRITE(numout,*) 'tra_ldf_blp : iso-level   bilaplacian operator on ', cdtype
199         CASE ( np_blp_i  )   ;   WRITE(numout,*) 'tra_ldf_blp : iso-neutral bilaplacian operator on ', cdtype, ' (Standard)'
200         CASE ( np_blp_it )   ;   WRITE(numout,*) 'tra_ldf_blp : iso-neutral bilaplacian operator on ', cdtype, ' (triad)'
201         END SELECT
202         WRITE(numout,*) '~~~~~~~~~~~'
203      ENDIF
204
205      zlap(:,:,:,:) = 0._wp
206      !
207      SELECT CASE ( kldf )       !==  1st laplacian applied to ptb (output in zlap)  ==!
208      !
209      CASE ( np_blp    )               ! iso-level bilaplacian
210         CALL tra_ldf_lap  ( kt, kit000, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, ptb,      zlap, kjpt, 1, Kmm )
211      CASE ( np_blp_i  )               ! rotated   bilaplacian : standard operator (Madec)
212         CALL tra_ldf_iso  ( kt, kit000, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, ptb, ptb, zlap, kjpt, 1, Kmm )
213      CASE ( np_blp_it )               ! rotated  bilaplacian : triad operator (griffies)
214         CALL tra_ldf_triad( kt, kit000, cdtype, pahu, pahv, pgu, pgv, pgui, pgvi, ptb, ptb, zlap, kjpt, 1, Kmm )
215      END SELECT
216      !
217      CALL lbc_lnk( 'traldf_lap_blp', zlap(:,:,:,:) , 'T', 1. )     ! Lateral boundary conditions (unchanged sign)
218      !                                               ! Partial top/bottom cell: GRADh( zlap ) 
219      IF( ln_isfcav .AND. ln_zps ) THEN   ;   CALL zps_hde_isf( kt, Kmm, kjpt, zlap, zglu, zglv, zgui, zgvi )  ! both top & bottom
220      ELSEIF(             ln_zps ) THEN   ;   CALL zps_hde    ( kt, Kmm, kjpt, zlap, zglu, zglv )              ! only bottom
221      ENDIF
222      !
223      SELECT CASE ( kldf )       !==  2nd laplacian applied to zlap (output in pta)  ==!
224      !
225      CASE ( np_blp    )               ! iso-level bilaplacian
226         CALL tra_ldf_lap  ( kt, kit000, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, pta,      kjpt, 2, Kmm )
227      CASE ( np_blp_i  )               ! rotated   bilaplacian : standard operator (Madec)
228         CALL tra_ldf_iso  ( kt, kit000, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, ptb, pta, kjpt, 2, Kmm )
229      CASE ( np_blp_it )               ! rotated  bilaplacian : triad operator (griffies)
230         CALL tra_ldf_triad( kt, kit000, cdtype, pahu, pahv, zglu, zglv, zgui, zgvi, zlap, ptb, pta, kjpt, 2, Kmm )
231      END SELECT
232      !
233   END SUBROUTINE tra_ldf_blp
234
235   !!==============================================================================
236END MODULE traldf_lap_blp
Note: See TracBrowser for help on using the repository browser.