source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA/traldf_triad.F90 @ 10806

Last change on this file since 10806 was 10806, checked in by davestorkey, 20 months ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps branch: Latest updates. Make sure all time-dependent 3D variables are converted in previously modified modules.

  • Property svn:keywords set to Id
File size: 23.9 KB
Line 
1MODULE traldf_triad
2   !!======================================================================
3   !!                   ***  MODULE  traldf_triad  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec)  Griffies operator (original code)
7   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and active tracers
14   USE dom_oce        ! ocean space and time domain
15   USE phycst         ! physical constants
16   USE trc_oce        ! share passive tracers/Ocean variables
17   USE zdf_oce        ! ocean vertical physics
18   USE ldftra         ! lateral physics: eddy diffusivity
19   USE ldfslp         ! lateral physics: iso-neutral slopes
20   USE traldf_iso     ! lateral diffusion (Madec operator)         (tra_ldf_iso routine)
21   USE diaptr         ! poleward transport diagnostics
22   USE diaar5         ! AR5 diagnostics
23   USE zpshde         ! partial step: hor. derivative     (zps_hde routine)
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! I/O library
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_ldf_triad   ! routine called by traldf.F90
34
35   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zdkt3d   !: vertical tracer gradient at 2 levels
36
37   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
38   LOGICAL  ::   l_hst   ! flag to compute heat transport
39
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50  SUBROUTINE tra_ldf_triad( kt, kit000, ktlev, kt2lev, cdtype, pahu, pahv, pgu , pgv ,   &
51      &                                                     pgui, pgvi,   &
52      &                                         pt , pt_lev0, pt_rhs , kjpt, kpass )
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_triad  ***
55      !!
56      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
57      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
58      !!      add it to the general trend of tracer equation.
59      !!
60      !! ** Method  :   The horizontal component of the lateral diffusive trends
61      !!      is provided by a 2nd order operator rotated along neural or geopo-
62      !!      tential surfaces to which an eddy induced advection can be added
63      !!      It is computed using before fields (forward in time) and isopyc-
64      !!      nal or geopotential slopes computed in routine ldfslp.
65      !!
66      !!      see documentation for the desciption
67      !!
68      !! ** Action :   pt_rhs   updated with the before rotated diffusion
69      !!               ah_wslp2 ....
70      !!               akz   stabilizing vertical diffusivity coefficient (used in trazdf_imp)
71      !!----------------------------------------------------------------------
72      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
74      INTEGER                              , INTENT(in   ) ::   ktlev      ! time level index for e3t
75      INTEGER                              , INTENT(in   ) ::   kt2lev     ! time level index for 2-time-level thicknesses
76      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
77      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
78      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
79      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
80      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu , pgv  ! tracer gradient at pstep levels
81      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt        ! tracer (kpass=1) or laplacian of tracer (kpass=2)
83      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt_lev0       ! tracer (only used in kpass=2)
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pt_rhs        ! tracer trend
85      !
86      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
87      INTEGER  ::  ip,jp,kp         ! dummy loop indices
88      INTEGER  ::  ierr            ! local integer
89      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3          ! local scalars
90      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4          !   -      -
91      REAL(wp) ::  zcoef0, ze3w_2, zsign, z2dt, z1_2dt  !   -      -
92      !
93      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
94      REAL(wp) ::   ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt
95      REAL(wp) ::   zah, zah_slp, zaei_slp
96      REAL(wp), DIMENSION(jpi,jpj    ) ::   z2d                                              ! 2D workspace
97      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw   ! 3D     -
98      !!----------------------------------------------------------------------
99      !
100      IF( .NOT.ALLOCATED(zdkt3d) )  THEN
101         ALLOCATE( zdkt3d(jpi,jpj,0:1) , STAT=ierr )
102         CALL mpp_sum ( 'traldf_triad', ierr )
103         IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_triad: unable to allocate arrays')
104      ENDIF
105     !
106      IF( kpass == 1 .AND. kt == kit000 )  THEN
107         IF(lwp) WRITE(numout,*)
108         IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype
109         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
110      ENDIF
111      !   
112      l_hst = .FALSE.
113      l_ptr = .FALSE.
114      IF( cdtype == 'TRA' .AND. ln_diaptr )                                                 l_ptr = .TRUE. 
115      IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
116         &                        iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )   l_hst = .TRUE.
117      !
118      !                                                        ! set time step size (Euler/Leapfrog)
119      IF( neuler == 0 .AND. kt == kit000 ) THEN   ;   z2dt =     rdt      ! at nit000   (Euler)
120      ELSE                                        ;   z2dt = 2.* rdt      !             (Leapfrog)
121      ENDIF
122      z1_2dt = 1._wp / z2dt
123      !
124      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
125      ELSE                    ;   zsign = -1._wp
126      ENDIF
127      !   
128      !!----------------------------------------------------------------------
129      !!   0 - calculate  ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw
130      !!----------------------------------------------------------------------
131      !
132      IF( kpass == 1 ) THEN         !==  first pass only  and whatever the tracer is  ==!
133         !
134         akz     (:,:,:) = 0._wp     
135         ah_wslp2(:,:,:) = 0._wp
136         IF( ln_ldfeiv_dia ) THEN
137            zpsi_uw(:,:,:) = 0._wp
138            zpsi_vw(:,:,:) = 0._wp
139         ENDIF
140         !
141         DO ip = 0, 1                            ! i-k triads
142            DO kp = 0, 1
143               DO jk = 1, jpkm1
144                  DO jj = 1, jpjm1
145                     DO ji = 1, fs_jpim1
146                        ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,kt2lev)
147                        zbu   = e1e2u(ji,jj) * e3u(ji,jj,jk,ktlev)
148                        zah   = 0.25_wp * pahu(ji,jj,jk)
149                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
150                        ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth)
151                        zslope2 = zslope_skew + ( gdept(ji+1,jj,jk,kt2lev) - gdept(ji,jj,jk,kt2lev) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp)
152                        zslope2 = zslope2 *zslope2
153                        ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji+ip,jj) * zslope2
154                        akz     (ji+ip,jj,jk+kp) = akz     (ji+ip,jj,jk+kp) + zah * r1_e1u(ji,jj)       &
155                           &                                                      * r1_e1u(ji,jj) * umask(ji,jj,jk+kp)
156                           !
157                       IF( ln_ldfeiv_dia )   zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp)   &
158                           &                                       + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * zslope_skew
159                     END DO
160                  END DO
161               END DO
162            END DO
163         END DO
164         !
165         DO jp = 0, 1                            ! j-k triads
166            DO kp = 0, 1
167               DO jk = 1, jpkm1
168                  DO jj = 1, jpjm1
169                     DO ji = 1, fs_jpim1
170                        ze3wr = 1.0_wp / e3w(ji,jj+jp,jk+kp,kt2lev)
171                        zbv   = e1e2v(ji,jj) * e3v(ji,jj,jk,ktlev)
172                        zah   = 0.25_wp * pahv(ji,jj,jk)
173                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
174                        ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
175                        !    (do this by *adding* gradient of depth)
176                        zslope2 = zslope_skew + ( gdept(ji,jj+1,jk,kt2lev) - gdept(ji,jj,jk,kt2lev) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp)
177                        zslope2 = zslope2 * zslope2
178                        ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj+jp) * zslope2
179                        akz     (ji,jj+jp,jk+kp) = akz     (ji,jj+jp,jk+kp) + zah * r1_e2v(ji,jj)     &
180                           &                                                      * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp)
181                        !
182                        IF( ln_ldfeiv_dia )   zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp)   &
183                           &                                       + 0.25 * aeiv(ji,jj,jk) * e1v(ji,jj) * zslope_skew
184                     END DO
185                  END DO
186               END DO
187            END DO
188         END DO
189         !
190         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
191            !
192            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
193               DO jk = 2, jpkm1
194                  DO jj = 1, jpjm1
195                     DO ji = 1, fs_jpim1
196                        akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
197                           &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w(ji,jj,jk,kt2lev) * e3w(ji,jj,jk,kt2lev) )  )
198                     END DO
199                  END DO
200               END DO
201            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
202               DO jk = 2, jpkm1
203                  DO jj = 1, jpjm1
204                     DO ji = 1, fs_jpim1
205                        ze3w_2 = e3w(ji,jj,jk,kt2lev) * e3w(ji,jj,jk,kt2lev)
206                        zcoef0 = z2dt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
207                        akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt
208                     END DO
209                  END DO
210               END DO
211           ENDIF
212           !
213         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
214            akz(:,:,:) = ah_wslp2(:,:,:)     
215         ENDIF
216         !
217         IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' )   CALL ldf_eiv_dia( zpsi_uw, zpsi_vw )
218         !
219      ENDIF                                  !==  end 1st pass only  ==!
220      !
221      !                                                           ! ===========
222      DO jn = 1, kjpt                                             ! tracer loop
223         !                                                        ! ===========
224         ! Zero fluxes for each tracer
225!!gm  this should probably be done outside the jn loop
226         ztfw(:,:,:) = 0._wp
227         zftu(:,:,:) = 0._wp
228         zftv(:,:,:) = 0._wp
229         !
230         DO jk = 1, jpkm1        !==  before lateral T & S gradients at T-level jk  ==!
231            DO jj = 1, jpjm1
232               DO ji = 1, fs_jpim1   ! vector opt.
233                  zdit(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk)
234                  zdjt(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
235               END DO
236            END DO
237         END DO
238         IF( ln_zps .AND. l_grad_zps ) THEN    ! partial steps: correction at top/bottom ocean level
239            DO jj = 1, jpjm1                       ! bottom level
240               DO ji = 1, fs_jpim1   ! vector opt.
241                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)
242                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
243               END DO
244            END DO
245            IF( ln_isfcav ) THEN                   ! top level (ocean cavities only)
246               DO jj = 1, jpjm1
247                  DO ji = 1, fs_jpim1   ! vector opt.
248                     IF( miku(ji,jj)  > 1 )   zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) 
249                     IF( mikv(ji,jj)  > 1 )   zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) 
250                  END DO
251               END DO
252            ENDIF
253         ENDIF
254         !
255         !!----------------------------------------------------------------------
256         !!   II - horizontal trend  (full)
257         !!----------------------------------------------------------------------
258         !
259         DO jk = 1, jpkm1
260            !                    !==  Vertical tracer gradient at level jk and jk+1
261            zdkt3d(:,:,1) = ( pt(:,:,jk,jn) - pt(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
262            !
263            !                    ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1)
264            IF( jk == 1 ) THEN   ;   zdkt3d(:,:,0) = zdkt3d(:,:,1)
265            ELSE                 ;   zdkt3d(:,:,0) = ( pt(:,:,jk-1,jn) - pt(:,:,jk,jn) ) * tmask(:,:,jk)
266            ENDIF
267            !
268            zaei_slp = 0._wp
269            !
270            IF( ln_botmix_triad ) THEN
271               DO ip = 0, 1              !==  Horizontal & vertical fluxes
272                  DO kp = 0, 1
273                     DO jj = 1, jpjm1
274                        DO ji = 1, fs_jpim1
275                           ze1ur = r1_e1u(ji,jj)
276                           zdxt  = zdit(ji,jj,jk) * ze1ur
277                           ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,kt2lev)
278                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
279                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
280                           zslope_iso  = triadi  (ji+ip,jj,jk,1-ip,kp)
281                           !
282                           zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,ktlev)
283                           ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????   ahu is masked....
284                           zah = pahu(ji,jj,jk)
285                           zah_slp  = zah * zslope_iso
286                           IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew
287                           zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
288                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt                 * zbu * ze3wr
289                        END DO
290                     END DO
291                  END DO
292               END DO
293               !
294               DO jp = 0, 1
295                  DO kp = 0, 1
296                     DO jj = 1, jpjm1
297                        DO ji = 1, fs_jpim1
298                           ze2vr = r1_e2v(ji,jj)
299                           zdyt  = zdjt(ji,jj,jk) * ze2vr
300                           ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,kt2lev)
301                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
302                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
303                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
304                           zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,ktlev)
305                           ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????  ahv is masked...
306                           zah = pahv(ji,jj,jk)
307                           zah_slp = zah * zslope_iso
308                           IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew
309                           zftv(ji,jj   ,jk   ) = zftv(ji,jj   ,jk   ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
310                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt                * zbv * ze3wr
311                        END DO
312                     END DO
313                  END DO
314               END DO
315               !
316            ELSE
317               !
318               DO ip = 0, 1               !==  Horizontal & vertical fluxes
319                  DO kp = 0, 1
320                     DO jj = 1, jpjm1
321                        DO ji = 1, fs_jpim1
322                           ze1ur = r1_e1u(ji,jj)
323                           zdxt  = zdit(ji,jj,jk) * ze1ur
324                           ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,kt2lev)
325                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
326                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
327                           zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
328                           !
329                           zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,ktlev)
330                           ! ln_botmix_triad is .F. mask zah for bottom half cells
331                           zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp)         ! pahu(ji+ip,jj,jk)   ===>>  ????
332                           zah_slp  = zah * zslope_iso
333                           IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew        ! aeit(ji+ip,jj,jk)*zslope_skew
334                           zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
335                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
336                        END DO
337                     END DO
338                  END DO
339               END DO
340               !
341               DO jp = 0, 1
342                  DO kp = 0, 1
343                     DO jj = 1, jpjm1
344                        DO ji = 1, fs_jpim1
345                           ze2vr = r1_e2v(ji,jj)
346                           zdyt  = zdjt(ji,jj,jk) * ze2vr
347                           ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,kt2lev)
348                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
349                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
350                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
351                           zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,ktlev)
352                           ! ln_botmix_triad is .F. mask zah for bottom half cells
353                           zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp)         ! pahv(ji,jj+jp,jk)  ????
354                           zah_slp = zah * zslope_iso
355                           IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew        ! aeit(ji,jj+jp,jk)*zslope_skew
356                           zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
357                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
358                        END DO
359                     END DO
360                  END DO
361               END DO
362            ENDIF
363            !                             !==  horizontal divergence and add to the general trend  ==!
364            DO jj = 2 , jpjm1
365               DO ji = fs_2, fs_jpim1  ! vector opt.
366                  pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + zsign * (  zftu(ji-1,jj,jk) - zftu(ji,jj,jk)       &
367                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )   &
368                     &                                        / (  e1e2t(ji,jj) * e3t(ji,jj,jk,ktlev)  )
369               END DO
370            END DO
371            !
372         END DO
373         !
374         !                                !==  add the vertical 33 flux  ==!
375         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
376            DO jk = 2, jpkm1       
377               DO jj = 1, jpjm1
378                  DO ji = fs_2, fs_jpim1
379                     ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,kt2lev) * tmask(ji,jj,jk)   &
380                        &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
381                        &                            * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) )
382                  END DO
383               END DO
384            END DO
385         ELSE                                   ! bilaplacian
386            SELECT CASE( kpass )
387            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
388               DO jk = 2, jpkm1 
389                  DO jj = 1, jpjm1
390                     DO ji = fs_2, fs_jpim1
391                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,kt2lev) * tmask(ji,jj,jk)             &
392                           &                            * ah_wslp2(ji,jj,jk) * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) )
393                     END DO
394                  END DO
395               END DO
396            CASE(  2  )                            ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt  and pt_lev0 gradients, resp.
397               DO jk = 2, jpkm1 
398                  DO jj = 1, jpjm1
399                     DO ji = fs_2, fs_jpim1
400                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,kt2lev) * tmask(ji,jj,jk)                      &
401                           &                            * (  ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) )   &
402                           &                               + akz     (ji,jj,jk) * ( pt_lev0(ji,jj,jk-1,jn) - pt_lev0(ji,jj,jk,jn) )   )
403                     END DO
404                  END DO
405               END DO
406            END SELECT
407         ENDIF
408         !
409         DO jk = 1, jpkm1                 !==  Divergence of vertical fluxes added to pt_rhs  ==!
410            DO jj = 2, jpjm1
411               DO ji = fs_2, fs_jpim1  ! vector opt.
412                  pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) + zsign * (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
413                     &                                        / ( e1e2t(ji,jj) * e3t(ji,jj,jk,ktlev) )
414               END DO
415            END DO
416         END DO
417         !
418         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
419             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
420            !
421            !                          ! "Poleward" diffusive heat or salt transports (T-S case only)
422            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:)  )
423            !                          ! Diffusive heat transports
424            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) )
425            !
426         ENDIF                                                    !== end pass selection  ==!
427         !
428         !                                                        ! ===============
429      END DO                                                      ! end tracer loop
430      !                                                           ! ===============
431   END SUBROUTINE tra_ldf_triad
432
433   !!==============================================================================
434END MODULE traldf_triad
Note: See TracBrowser for help on using the repository browser.