New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA/trazdf.F90 @ 10954

Last change on this file since 10954 was 10954, checked in by acc, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Convert TRA modules and all knock on effects of these conversions. SETTE tested
  • Property svn:keywords set to Id
File size: 14.2 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            4.0  !  2017-06  (G. Madec)  remove explict time-stepping option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE ldftra         ! lateral diffusion: eddy diffusivity
21   USE ldfslp         ! lateral diffusion: iso-neutral slope
22   USE trd_oce        ! trends: ocean variables
23   USE trdtra         ! trends: tracer trend manager
24   !
25   USE in_out_manager ! I/O manager
26   USE prtctl         ! Print control
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_zdf       ! called by step.F90
35   PUBLIC   tra_zdf_imp   ! called by trczdf.F90
36
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE tra_zdf( kt, Kbb, Kmm, Krhs, pts, Kaa )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE tra_zdf  ***
49      !!
50      !! ** Purpose :   compute the vertical ocean tracer physics.
51      !!---------------------------------------------------------------------
52      INTEGER                                  , INTENT(in)    :: kt                  ! ocean time-step index
53      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs, Kaa ! time level indices
54      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts                 ! active tracers and RHS of tracer equation
55      !
56      INTEGER  ::   jk   ! Dummy loop indices
57      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds   ! 3D workspace
58      !!---------------------------------------------------------------------
59      !
60      IF( ln_timing )   CALL timing_start('tra_zdf')
61      !
62      IF( kt == nit000 )  THEN
63         IF(lwp)WRITE(numout,*)
64         IF(lwp)WRITE(numout,*) 'tra_zdf : implicit vertical mixing on T & S'
65         IF(lwp)WRITE(numout,*) '~~~~~~~ '
66      ENDIF
67      !
68      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   r2dt =      rdt   ! at nit000, =   rdt (restarting with Euler time stepping)
69      ELSEIF( kt <= nit000 + 1           ) THEN   ;   r2dt = 2. * rdt   ! otherwise, = 2 rdt (leapfrog)
70      ENDIF
71      !
72      IF( l_trdtra )   THEN                  !* Save ta and sa trends
73         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
74         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kaa)
75         ztrds(:,:,:) = pts(:,:,:,jp_sal,Kaa)
76      ENDIF
77      !
78      !                                      !* compute lateral mixing trend and add it to the general trend
79      CALL tra_zdf_imp( kt, nit000, 'TRA', r2dt, Kbb, Kmm, Krhs, pts, Kaa, jpts ) 
80
81!!gm WHY here !   and I don't like that !
82      ! DRAKKAR SSS control {
83      ! JMM avoid negative salinities near river outlet ! Ugly fix
84      ! JMM : restore negative salinities to small salinities:
85      WHERE( pts(:,:,:,jp_sal,Kaa) < 0._wp )   pts(:,:,:,jp_sal,Kaa) = 0.1_wp
86!!gm
87
88      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
89         DO jk = 1, jpkm1
90            ztrdt(:,:,jk) = ( ( pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa) - pts(:,:,jk,jp_tem,Kbb)*e3t(:,:,jk,Kbb) ) &
91               &          / (e3t(:,:,jk,Kmm)*r2dt) ) - ztrdt(:,:,jk)
92            ztrds(:,:,jk) = ( ( pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa) - pts(:,:,jk,jp_sal,Kbb)*e3t(:,:,jk,Kbb) ) &
93              &           / (e3t(:,:,jk,Kmm)*r2dt) ) - ztrds(:,:,jk)
94         END DO
95!!gm this should be moved in trdtra.F90 and done on all trends
96         CALL lbc_lnk_multi( 'trazdf', ztrdt, 'T', 1. , ztrds, 'T', 1. )
97!!gm
98         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_zdf, ztrdt )
99         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_zdf, ztrds )
100         DEALLOCATE( ztrdt , ztrds )
101      ENDIF
102      !                                          ! print mean trends (used for debugging)
103      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kaa), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
104         &                       tab3d_2=pts(:,:,:,jp_sal,Kaa), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
105      !
106      IF( ln_timing )   CALL timing_stop('tra_zdf')
107      !
108   END SUBROUTINE tra_zdf
109
110 
111   SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, Kbb, Kmm, Krhs, pt, Kaa, kjpt ) 
112      !!----------------------------------------------------------------------
113      !!                  ***  ROUTINE tra_zdf_imp  ***
114      !!
115      !! ** Purpose :   Compute the after tracer through a implicit computation
116      !!     of the vertical tracer diffusion (including the vertical component
117      !!     of lateral mixing (only for 2nd order operator, for fourth order
118      !!     it is already computed and add to the general trend in traldf)
119      !!
120      !! ** Method  :  The vertical diffusion of a tracer ,t , is given by:
121      !!          difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) )
122      !!      It is computed using a backward time scheme (t=after field)
123      !!      which provide directly the after tracer field.
124      !!      If ln_zdfddm=T, use avs for salinity or for passive tracers
125      !!      Surface and bottom boundary conditions: no diffusive flux on
126      !!      both tracers (bottom, applied through the masked field avt).
127      !!      If iso-neutral mixing, add to avt the contribution due to lateral mixing.
128      !!
129      !! ** Action  : - pt(:,:,:,:,Kaa)  becomes the after tracer
130      !!---------------------------------------------------------------------
131      INTEGER                                  , INTENT(in   ) ::   kt       ! ocean time-step index
132      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs, Kaa  ! ocean time level indices
133      INTEGER                                  , INTENT(in   ) ::   kit000   ! first time step index
134      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
135      INTEGER                                  , INTENT(in   ) ::   kjpt     ! number of tracers
136      REAL(wp)                                 , INTENT(in   ) ::   p2dt     ! tracer time-step
137      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt       ! tracers and RHS of tracer equation
138      !
139      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
140      REAL(wp) ::  zrhs, zzwi, zzws ! local scalars
141      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zwi, zwt, zwd, zws
142      !!---------------------------------------------------------------------
143      !
144      !                                               ! ============= !
145      DO jn = 1, kjpt                                 !  tracer loop  !
146         !                                            ! ============= !
147         !  Matrix construction
148         ! --------------------
149         ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer
150         !
151         IF(  ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR.   &
152            & ( cdtype == 'TRC' .AND. jn == 1 )  )  THEN
153            !
154            ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers
155            IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN   ;   zwt(:,:,2:jpk) = avt(:,:,2:jpk)
156            ELSE                                            ;   zwt(:,:,2:jpk) = avs(:,:,2:jpk)
157            ENDIF
158            zwt(:,:,1) = 0._wp
159            !
160            IF( l_ldfslp ) THEN            ! isoneutral diffusion: add the contribution
161               IF( ln_traldf_msc  ) THEN     ! MSC iso-neutral operator
162                  DO jk = 2, jpkm1
163                     DO jj = 2, jpjm1
164                        DO ji = fs_2, fs_jpim1   ! vector opt.
165                           zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk) 
166                        END DO
167                     END DO
168                  END DO
169               ELSE                          ! standard or triad iso-neutral operator
170                  DO jk = 2, jpkm1
171                     DO jj = 2, jpjm1
172                        DO ji = fs_2, fs_jpim1   ! vector opt.
173                           zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk)
174                        END DO
175                     END DO
176                  END DO
177               ENDIF
178            ENDIF
179            !
180            ! Diagonal, lower (i), upper (s)  (including the bottom boundary condition since avt is masked)
181            IF( ln_zad_Aimp ) THEN         ! Adaptive implicit vertical advection
182               DO jk = 1, jpkm1
183                  DO jj = 2, jpjm1
184                     DO ji = fs_2, fs_jpim1   ! vector opt. (ensure same order of calculation as below if wi=0.)
185                        zzwi = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk  ,Kmm)
186                        zzws = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
187                        zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zzwi - zzws   &
188                           &                 + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )
189                        zwi(ji,jj,jk) = zzwi + p2dt *   MIN( wi(ji,jj,jk  ) , 0._wp )
190                        zws(ji,jj,jk) = zzws - p2dt *   MAX( wi(ji,jj,jk+1) , 0._wp )
191                    END DO
192                  END DO
193               END DO
194            ELSE
195               DO jk = 1, jpkm1
196                  DO jj = 2, jpjm1
197                     DO ji = fs_2, fs_jpim1   ! vector opt.
198                        zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk,Kmm)
199                        zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
200                        zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zwi(ji,jj,jk) - zws(ji,jj,jk)
201                    END DO
202                  END DO
203               END DO
204            ENDIF
205            !
206            !! Matrix inversion from the first level
207            !!----------------------------------------------------------------------
208            !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
209            !
210            !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
211            !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
212            !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
213            !        (        ...               )( ...  ) ( ...  )
214            !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
215            !
216            !   m is decomposed in the product of an upper and lower triangular matrix.
217            !   The 3 diagonal terms are in 3d arrays: zwd, zws, zwi.
218            !   Suffices i,s and d indicate "inferior" (below diagonal), diagonal
219            !   and "superior" (above diagonal) components of the tridiagonal system.
220            !   The solution will be in the 4d array pta.
221            !   The 3d array zwt is used as a work space array.
222            !   En route to the solution pt(:,:,:,:,Kaa) is used a to evaluate the rhs and then
223            !   used as a work space array: its value is modified.
224            !
225            DO jj = 2, jpjm1        !* 1st recurrence:   Tk = Dk - Ik Sk-1 / Tk-1   (increasing k)
226               DO ji = fs_2, fs_jpim1            ! done one for all passive tracers (so included in the IF instruction)
227                  zwt(ji,jj,1) = zwd(ji,jj,1)
228               END DO
229            END DO
230            DO jk = 2, jpkm1
231               DO jj = 2, jpjm1
232                  DO ji = fs_2, fs_jpim1
233                     zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1)
234                  END DO
235               END DO
236            END DO
237            !
238         ENDIF 
239         !         
240         DO jj = 2, jpjm1           !* 2nd recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
241            DO ji = fs_2, fs_jpim1
242               pt(ji,jj,1,jn,Kaa) = e3t(ji,jj,1,Kbb) * pt(ji,jj,1,jn,Kbb) + p2dt * e3t(ji,jj,1,Kmm) * pt(ji,jj,1,jn,Krhs)
243            END DO
244         END DO
245         DO jk = 2, jpkm1
246            DO jj = 2, jpjm1
247               DO ji = fs_2, fs_jpim1
248                  zrhs = e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * e3t(ji,jj,jk,Kmm) * pt(ji,jj,jk,jn,Krhs)   ! zrhs=right hand side
249                  pt(ji,jj,jk,jn,Kaa) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pt(ji,jj,jk-1,jn,Kaa)
250               END DO
251            END DO
252         END DO
253         !
254         DO jj = 2, jpjm1           !* 3d recurrence:    Xk = (Zk - Sk Xk+1 ) / Tk   (result is the after tracer)
255            DO ji = fs_2, fs_jpim1
256               pt(ji,jj,jpkm1,jn,Kaa) = pt(ji,jj,jpkm1,jn,Kaa) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1)
257            END DO
258         END DO
259         DO jk = jpk-2, 1, -1
260            DO jj = 2, jpjm1
261               DO ji = fs_2, fs_jpim1
262                  pt(ji,jj,jk,jn,Kaa) = ( pt(ji,jj,jk,jn,Kaa) - zws(ji,jj,jk) * pt(ji,jj,jk+1,jn,Kaa) )   &
263                     &             / zwt(ji,jj,jk) * tmask(ji,jj,jk)
264               END DO
265            END DO
266         END DO
267         !                                            ! ================= !
268      END DO                                          !  end tracer loop  !
269      !                                               ! ================= !
270   END SUBROUTINE tra_zdf_imp
271
272   !!==============================================================================
273END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.