New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfmxl.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/ZDF – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/ZDF/zdfmxl.F90 @ 10955

Last change on this file since 10955 was 10955, checked in by acc, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Convert ZDF modules and all knock on effects of these conversions. SETTE tested

  • Property svn:keywords set to Id
File size: 7.1 KB
Line 
1MODULE zdfmxl
2   !!======================================================================
3   !!                       ***  MODULE  zdfmxl  ***
4   !! Ocean physics: mixed layer depth
5   !!======================================================================
6   !! History :  1.0  ! 2003-08  (G. Madec)  original code
7   !!            3.2  ! 2009-07  (S. Masson, G. Madec)  IOM + merge of DO-loop
8   !!            3.7  ! 2012-03  (G. Madec)  make public the density criteria for trdmxl
9   !!             -   ! 2014-02  (F. Roquet)  mixed layer depth calculated using N2 instead of rhop
10   !!----------------------------------------------------------------------
11   !!   zdf_mxl      : Compute the turbocline and mixed layer depths.
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers variables
14   USE dom_oce        ! ocean space and time domain variables
15   USE trc_oce  , ONLY: l_offline         ! ocean space and time domain variables
16   USE zdf_oce        ! ocean vertical physics
17   !
18   USE in_out_manager ! I/O manager
19   USE prtctl         ! Print control
20   USE phycst         ! physical constants
21   USE iom            ! I/O library
22   USE lib_mpp        ! MPP library
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   zdf_mxl   ! called by zdfphy.F90
28
29   INTEGER , PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   nmln    !: number of level in the mixed layer (used by LDF, ZDF, TRD, TOP)
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmld    !: mixing layer depth (turbocline)      [m]   (used by TOP)
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlp    !: mixed layer depth  (rho=rho0+zdcrit) [m]   (used by LDF)
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlpt   !: depth of the last T-point inside the mixed layer [m] (used by LDF)
33
34   REAL(wp), PUBLIC ::   rho_c = 0.01_wp    !: density criterion for mixed layer depth
35   REAL(wp), PUBLIC ::   avt_c = 5.e-4_wp   ! Kz criterion for the turbocline depth
36
37   !!----------------------------------------------------------------------
38   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
39   !! $Id$
40   !! Software governed by the CeCILL license (see ./LICENSE)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   INTEGER FUNCTION zdf_mxl_alloc()
45      !!----------------------------------------------------------------------
46      !!               ***  FUNCTION zdf_mxl_alloc  ***
47      !!----------------------------------------------------------------------
48      zdf_mxl_alloc = 0      ! set to zero if no array to be allocated
49      IF( .NOT. ALLOCATED( nmln ) ) THEN
50         ALLOCATE( nmln(jpi,jpj), hmld(jpi,jpj), hmlp(jpi,jpj), hmlpt(jpi,jpj), STAT= zdf_mxl_alloc )
51         !
52         CALL mpp_sum ( 'zdfmxl', zdf_mxl_alloc )
53         IF( zdf_mxl_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl_alloc: failed to allocate arrays.' )
54         !
55      ENDIF
56   END FUNCTION zdf_mxl_alloc
57
58
59   SUBROUTINE zdf_mxl( kt, Kmm )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE zdfmxl  ***
62      !!                   
63      !! ** Purpose :   Compute the turbocline depth and the mixed layer depth
64      !!              with density criteria.
65      !!
66      !! ** Method  :   The mixed layer depth is the shallowest W depth with
67      !!      the density of the corresponding T point (just bellow) bellow a
68      !!      given value defined locally as rho(10m) + rho_c
69      !!               The turbocline depth is the depth at which the vertical
70      !!      eddy diffusivity coefficient (resulting from the vertical physics
71      !!      alone, not the isopycnal part, see trazdf.F) fall below a given
72      !!      value defined locally (avt_c here taken equal to 5 cm/s2 by default)
73      !!
74      !! ** Action  :   nmln, hmld, hmlp, hmlpt
75      !!----------------------------------------------------------------------
76      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
77      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
78      !
79      INTEGER  ::   ji, jj, jk      ! dummy loop indices
80      INTEGER  ::   iikn, iiki, ikt ! local integer
81      REAL(wp) ::   zN2_c           ! local scalar
82      INTEGER, DIMENSION(jpi,jpj) ::   imld   ! 2D workspace
83      !!----------------------------------------------------------------------
84      !
85      IF( kt == nit000 ) THEN
86         IF(lwp) WRITE(numout,*)
87         IF(lwp) WRITE(numout,*) 'zdf_mxl : mixed layer depth'
88         IF(lwp) WRITE(numout,*) '~~~~~~~ '
89         !                             ! allocate zdfmxl arrays
90         IF( zdf_mxl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl : unable to allocate arrays' )
91      ENDIF
92      !
93      ! w-level of the mixing and mixed layers
94      nmln(:,:)  = nlb10               ! Initialization to the number of w ocean point
95      hmlp(:,:)  = 0._wp               ! here hmlp used as a dummy variable, integrating vertically N^2
96      zN2_c = grav * rho_c * r1_rau0   ! convert density criteria into N^2 criteria
97      DO jk = nlb10, jpkm1
98         DO jj = 1, jpj                ! Mixed layer level: w-level
99            DO ji = 1, jpi
100               ikt = mbkt(ji,jj)
101               hmlp(ji,jj) = hmlp(ji,jj) + MAX( rn2b(ji,jj,jk) , 0._wp ) * e3w(ji,jj,jk,Kmm)
102               IF( hmlp(ji,jj) < zN2_c )   nmln(ji,jj) = MIN( jk , ikt ) + 1   ! Mixed layer level
103            END DO
104         END DO
105      END DO
106      !
107      ! w-level of the turbocline and mixing layer (iom_use)
108      imld(:,:) = mbkt(:,:) + 1        ! Initialization to the number of w ocean point
109      DO jk = jpkm1, nlb10, -1         ! from the bottom to nlb10
110         DO jj = 1, jpj
111            DO ji = 1, jpi
112               IF( avt (ji,jj,jk) < avt_c * wmask(ji,jj,jk) )   imld(ji,jj) = jk      ! Turbocline
113            END DO
114         END DO
115      END DO
116      ! depth of the mixing and mixed layers
117      DO jj = 1, jpj
118         DO ji = 1, jpi
119            iiki = imld(ji,jj)
120            iikn = nmln(ji,jj)
121            hmld (ji,jj) = gdepw(ji,jj,iiki  ,Kmm) * ssmask(ji,jj)    ! Turbocline depth
122            hmlp (ji,jj) = gdepw(ji,jj,iikn  ,Kmm) * ssmask(ji,jj)    ! Mixed layer depth
123            hmlpt(ji,jj) = gdept(ji,jj,iikn-1,Kmm) * ssmask(ji,jj)    ! depth of the last T-point inside the mixed layer
124         END DO
125      END DO
126      !
127      IF( .NOT.l_offline ) THEN
128         IF( iom_use("mldr10_1") ) THEN
129            IF( ln_isfcav ) THEN  ;  CALL iom_put( "mldr10_1", hmlp - risfdep)   ! mixed layer thickness
130            ELSE                  ;  CALL iom_put( "mldr10_1", hmlp )            ! mixed layer depth
131            END IF
132         END IF
133         IF( iom_use("mldkz5") ) THEN
134            IF( ln_isfcav ) THEN  ;  CALL iom_put( "mldkz5"  , hmld - risfdep )   ! turbocline thickness
135            ELSE                  ;  CALL iom_put( "mldkz5"  , hmld )             ! turbocline depth
136            END IF
137         ENDIF
138      ENDIF
139      !
140      IF(ln_ctl)   CALL prt_ctl( tab2d_1=REAL(nmln,wp), clinfo1=' nmln : ', tab2d_2=hmlp, clinfo2=' hmlp : ' )
141      !
142   END SUBROUTINE zdf_mxl
143
144   !!======================================================================
145END MODULE zdfmxl
Note: See TracBrowser for help on using the repository browser.