New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OFF – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OFF/nemogcm.F90 @ 10905

Last change on this file since 10905 was 10905, checked in by davestorkey, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps :

  1. Alter top-level TOP routines so they use the time-level indices from step.F90 rather than having their own time level indices.
  2. First part of changes for OFF modules.
  • Property svn:keywords set to Id
File size: 28.8 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   nemo_gcm      : off-line: solve ocean tracer only
13   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14   !!   nemo_init     : initialization of the NEMO system
15   !!   nemo_ctl      : initialisation of the contol print
16   !!   nemo_closefile: close remaining open files
17   !!   nemo_alloc    : dynamical allocation
18   !!   istate_init   : simple initialization to zero of ocean fields
19   !!   stp_ctl       : reduced step control (no dynamics in off-line)
20   !!----------------------------------------------------------------------
21   USE dom_oce        ! ocean space domain variables
22   USE oce            ! dynamics and tracers variables
23   USE trc_oce        ! Shared ocean/passive tracers variables
24   USE c1d            ! 1D configuration
25   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
26   USE closea         ! treatment of closed seas (for ln_closea)
27   USE usrdef_nam     ! user defined configuration
28   USE eosbn2         ! equation of state            (eos bn2 routine)
29   !              ! ocean physics
30   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
31   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
32   USE traqsr         ! solar radiation penetration    (tra_qsr_init routine)
33   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
34   USE traldf         ! lateral physics                (tra_ldf_init routine)
35   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
36   USE phycst         ! physical constant                   (par_cst routine)
37   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
38   USE trcini         ! Initilization of the passive tracers
39   USE daymod         ! calendar                            (day     routine)
40   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
41   USE dtadyn         ! Lecture and interpolation of the dynamical fields
42   !              ! Passive tracers needs
43   USE trc            ! passive tracer : variables
44   USE trcnam         ! passive tracer : namelist
45   USE trcrst         ! passive tracer restart
46   USE diaptr         ! Need to initialise this as some variables are used in if statements later
47   USE sbc_oce , ONLY : ln_rnf
48   USE sbcrnf         ! surface boundary condition : runoffs
49   !              ! I/O & MPP
50   USE iom            ! I/O library
51   USE in_out_manager ! I/O manager
52   USE mppini         ! shared/distributed memory setting (mpp_init routine)
53   USE lib_mpp        ! distributed memory computing
54#if defined key_iomput
55   USE xios           ! xIOserver
56#endif
57   USE prtctl         ! Print control                    (prt_ctl_init routine)
58   USE timing         ! Timing
59   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
60   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
61   USE step, ONLY : update_pointers 
62
63   IMPLICIT NONE
64   PRIVATE
65   
66   PUBLIC   nemo_gcm   ! called by nemo.F90
67
68   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
69
70   !!----------------------------------------------------------------------
71   !! time level indices
72   !!----------------------------------------------------------------------
73   INTEGER :: Nbb, Nnn, Naa, Nrhs       
74
75   !!----------------------------------------------------------------------
76   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
77   !! $Id$
78   !! Software governed by the CeCILL license (see ./LICENSE)
79   !!----------------------------------------------------------------------
80CONTAINS
81
82   SUBROUTINE nemo_gcm
83      !!----------------------------------------------------------------------
84      !!                     ***  ROUTINE nemo_gcm  ***
85      !!
86      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
87      !!              curvilinear mesh on the sphere.
88      !!
89      !! ** Method  : - model general initialization
90      !!              - launch the time-stepping (dta_dyn and trc_stp)
91      !!              - finalize the run by closing files and communications
92      !!
93      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
94      !!              Madec, 2008, internal report, IPSL.
95      !!----------------------------------------------------------------------
96      INTEGER :: istp, indic       ! time step index
97      !!----------------------------------------------------------------------
98
99      CALL nemo_init  ! Initializations
100
101      ! check that all process are still there... If some process have an error,
102      ! they will never enter in step and other processes will wait until the end of the cpu time!
103      CALL mpp_max( 'nemogcm', nstop )
104
105      !                            !-----------------------!
106      !                            !==   time stepping   ==!
107      !                            !-----------------------!
108      istp = nit000
109      !
110      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
111      !
112      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
113      !
114      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
115         !
116         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
117                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
118#if defined key_sed_off
119                                CALL dta_dyn_sed( istp )         ! Interpolation of the dynamical fields
120#else
121                                CALL dta_dyn    ( istp )         ! Interpolation of the dynamical fields
122         IF( .NOT.ln_linssh )   CALL dta_dyn_swp( istp )         ! swap of sea  surface height and vertical scale factors
123#endif
124                                CALL trc_stp    ( istp, Nbb, Nnn, Nrhs, Naa )         ! time-stepping
125                                CALL stp_ctl    ( istp, indic )  ! Time loop: control and print
126         istp = istp + 1
127      END DO
128      !
129#if defined key_iomput
130      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
131#endif
132
133      !                            !------------------------!
134      !                            !==  finalize the run  ==!
135      !                            !------------------------!
136      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
137
138      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
139         WRITE(numout,cform_err)
140         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
141         WRITE(numout,*)
142      ENDIF
143      !
144      IF( ln_timing )   CALL timing_finalize
145      !
146      CALL nemo_closefile
147      !
148#if defined key_iomput
149                     CALL xios_finalize   ! end mpp communications with xios
150#else
151      IF( lk_mpp )   CALL mppstop         ! end mpp communications
152#endif
153      !
154   END SUBROUTINE nemo_gcm
155
156
157   SUBROUTINE nemo_init
158      !!----------------------------------------------------------------------
159      !!                     ***  ROUTINE nemo_init  ***
160      !!
161      !! ** Purpose :   initialization of the nemo model in off-line mode
162      !!----------------------------------------------------------------------
163      INTEGER  ::   ji                 ! dummy loop indices
164      INTEGER  ::   ios, ilocal_comm   ! local integers
165      CHARACTER(len=120), DIMENSION(30) ::   cltxt, cltxt2, clnam
166      !!
167      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
168         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
169         &             ln_timing, ln_diacfl
170      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
171      !!----------------------------------------------------------------------
172      !
173      cltxt  = ''
174      cltxt2 = ''
175      clnam  = '' 
176      cxios_context = 'nemo'
177      !
178      !                             ! Open reference namelist and configuration namelist files
179      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
180      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
181      !
182      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
183      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
184901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
185      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
186      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
187902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
188      !
189      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
190      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
191903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
192      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
193      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
194904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
195
196      !                             !--------------------------!
197      !                             !  Set global domain size  !   (control print return in cltxt2)
198      !                             !--------------------------!
199      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
200         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
201         !
202      ELSE                                ! user-defined namelist
203         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
204      ENDIF
205      !
206      l_offline = .true.                  ! passive tracers are run offline
207      !
208      !                             !--------------------------------------------!
209      !                             !  set communicator & select the local node  !
210      !                             !  NB: mynode also opens output.namelist.dyn !
211      !                             !      on unit number numond on first proc   !
212      !                             !--------------------------------------------!
213#if defined key_iomput
214      CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )
215      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
216#else
217      ilocal_comm = 0
218      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
219#endif
220
221      narea = narea + 1                       ! mynode return the rank of proc (0 --> jpnij -1 )
222
223      IF( sn_cfctl%l_config ) THEN
224         ! Activate finer control of report outputs
225         ! optionally switch off output from selected areas (note this only
226         ! applies to output which does not involve global communications)
227         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
228           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
229           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
230      ELSE
231         ! Use ln_ctl to turn on or off all options.
232         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
233      ENDIF
234
235      lwm = (narea == 1)                      ! control of output namelists
236      lwp = (narea == 1) .OR. ln_ctl          ! control of all listing output print
237
238      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
239         !                       ! now that the file has been opened in call to mynode.
240         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
241         WRITE( numond, namctl )
242         WRITE( numond, namcfg )
243         IF( .NOT.ln_read_cfg ) THEN
244            DO ji = 1, SIZE(clnam)
245               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
246            END DO
247         ENDIF
248      ENDIF
249
250      IF(lwp) THEN                            ! open listing units
251         !
252         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
253         !
254         WRITE(numout,*)
255         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
256         WRITE(numout,*) '                       NEMO team'
257         WRITE(numout,*) '                   Off-line TOP Model'
258         WRITE(numout,*) '                NEMO version 4.0  (2019) '
259         WRITE(numout,*)
260         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
261         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
262         WRITE(numout,*)
263         WRITE(numout,*) "           o         _,           _,             "
264         WRITE(numout,*) "            o      .' (        .-' /             "
265         WRITE(numout,*) "           o     _/..._'.    .'   /              "
266         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
267         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
268         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
269         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
270         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
271         WRITE(numout,*) "       )  )                        `     (   (   "
272         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
273         WRITE(numout,*)
274         DO ji = 1, SIZE(cltxt)
275            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) TRIM(cltxt(ji))    ! control print of mynode
276         END DO
277         WRITE(numout,*)
278         WRITE(numout,*)
279         DO ji = 1, SIZE(cltxt2)
280            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) TRIM(cltxt2(ji))   ! control print of domain size
281         END DO
282         !
283         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
284         !
285      ENDIF
286      ! open /dev/null file to be able to supress output write easily
287      CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
288      !
289      !                                      ! Domain decomposition
290      CALL mpp_init                          ! MPP
291
292      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
293      CALL nemo_alloc()
294
295      ! Initialise time level indices
296      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
297   
298      ! Initialisation of temporary pointers (to be deleted after development finished)
299      CALL update_pointers( Nbb, Nnn, Naa )
300
301      !                             !-------------------------------!
302      !                             !  NEMO general initialization  !
303      !                             !-------------------------------!
304
305      CALL nemo_ctl                          ! Control prints
306      !
307      !                                      ! General initialization
308      IF( ln_timing    )   CALL timing_init
309      IF( ln_timing    )   CALL timing_start( 'nemo_init')
310      !
311                           CALL     phy_cst         ! Physical constants
312                           CALL     eos_init        ! Equation of state
313      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
314                           CALL     dom_init("OPA") ! Domain
315      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
316
317                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
318
319                           CALL     sbc_init    ! Forcings : surface module
320
321      !                                      ! Tracer physics
322                           CALL ldf_tra_init    ! Lateral ocean tracer physics
323                           CALL ldf_eiv_init    ! Eddy induced velocity param
324                           CALL tra_ldf_init    ! lateral mixing
325      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
326      IF( ln_traqsr    )   CALL tra_qsr_init    ! penetrative solar radiation
327      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
328
329      !                                      ! Passive tracers
330                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
331                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
332#if defined key_sed_off
333                           CALL dta_dyn_sed_init ! Initialization for the dynamics
334#else
335                           CALL dta_dyn_init   ! Initialization for the dynamics
336#endif
337
338                           CALL     trc_init( Nbb, Nnn, Naa )   ! Passive tracers initialization
339                           CALL dia_ptr_init   ! Poleward TRansports initialization
340                           
341      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
342      !
343      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
344      !
345   END SUBROUTINE nemo_init
346
347
348   SUBROUTINE nemo_ctl
349      !!----------------------------------------------------------------------
350      !!                     ***  ROUTINE nemo_ctl  ***
351      !!
352      !! ** Purpose :   control print setting
353      !!
354      !! ** Method  : - print namctl information and check some consistencies
355      !!----------------------------------------------------------------------
356      !
357      IF(lwp) THEN                  ! control print
358         WRITE(numout,*)
359         WRITE(numout,*) 'nemo_ctl: Control prints'
360         WRITE(numout,*) '~~~~~~~~'
361         WRITE(numout,*) '   Namelist namctl'
362         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
363         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
364         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
365         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
366         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
367         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
368         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
369         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
370         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
371         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
372         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
373         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
374         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
375         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
376         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
377         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
378         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
379         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
380         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
381         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
382         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
383      ENDIF
384      !
385      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
386      nictls    = nn_ictls
387      nictle    = nn_ictle
388      njctls    = nn_jctls
389      njctle    = nn_jctle
390      isplt     = nn_isplt
391      jsplt     = nn_jsplt
392
393      IF(lwp) THEN                  ! control print
394         WRITE(numout,*)
395         WRITE(numout,*) '   Namelist namcfg'
396         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
397         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
398         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
399         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
400         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
401         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
402      ENDIF
403      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
404      !
405      !                             ! Parameter control
406      !
407      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
408         IF( lk_mpp .AND. jpnij > 1 ) THEN
409            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
410         ELSE
411            IF( isplt == 1 .AND. jsplt == 1  ) THEN
412               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
413                  &           ' - the print control will be done over the whole domain' )
414            ENDIF
415            ijsplt = isplt * jsplt            ! total number of processors ijsplt
416         ENDIF
417         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
418         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
419         !
420         !                              ! indices used for the SUM control
421         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
422            lsp_area = .FALSE.
423         ELSE                                             ! print control done over a specific  area
424            lsp_area = .TRUE.
425            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
426               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
427               nictls = 1
428            ENDIF
429            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
430               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
431               nictle = jpiglo
432            ENDIF
433            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
434               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
435               njctls = 1
436            ENDIF
437            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
438               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
439               njctle = jpjglo
440            ENDIF
441         ENDIF
442      ENDIF
443      !
444      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
445         &                                                'Compile with key_nosignedzero enabled' )
446      !
447   END SUBROUTINE nemo_ctl
448
449
450   SUBROUTINE nemo_closefile
451      !!----------------------------------------------------------------------
452      !!                     ***  ROUTINE nemo_closefile  ***
453      !!
454      !! ** Purpose :   Close the files
455      !!----------------------------------------------------------------------
456      !
457      IF( lk_mpp )   CALL mppsync
458      !
459      CALL iom_close                                 ! close all input/output files managed by iom_*
460      !
461      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
462      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
463      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
464      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
465      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
466      !
467      numout = 6                                     ! redefine numout in case it is used after this point...
468      !
469   END SUBROUTINE nemo_closefile
470
471
472   SUBROUTINE nemo_alloc
473      !!----------------------------------------------------------------------
474      !!                     ***  ROUTINE nemo_alloc  ***
475      !!
476      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
477      !!
478      !! ** Method  :
479      !!----------------------------------------------------------------------
480      USE diawri ,   ONLY : dia_wri_alloc
481      USE dom_oce,   ONLY : dom_oce_alloc
482      USE zdf_oce,   ONLY : zdf_oce_alloc
483      USE trc_oce,   ONLY : trc_oce_alloc
484      !
485      INTEGER :: ierr
486      !!----------------------------------------------------------------------
487      !
488      ierr =        oce_alloc    ()          ! ocean
489      ierr = ierr + dia_wri_alloc()
490      ierr = ierr + dom_oce_alloc()          ! ocean domain
491      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
492      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
493      !
494      CALL mpp_sum( 'nemogcm', ierr )
495      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
496      !
497   END SUBROUTINE nemo_alloc
498
499   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
500      !!----------------------------------------------------------------------
501      !!                     ***  ROUTINE nemo_set_cfctl  ***
502      !!
503      !! ** Purpose :   Set elements of the output control structure to setto.
504      !!                for_all should be .false. unless all areas are to be
505      !!                treated identically.
506      !!
507      !! ** Method  :   Note this routine can be used to switch on/off some
508      !!                types of output for selected areas but any output types
509      !!                that involve global communications (e.g. mpp_max, glob_sum)
510      !!                should be protected from selective switching by the
511      !!                for_all argument
512      !!----------------------------------------------------------------------
513      LOGICAL :: setto, for_all
514      TYPE(sn_ctl) :: sn_cfctl
515      !!----------------------------------------------------------------------
516      IF( for_all ) THEN
517         sn_cfctl%l_runstat = setto
518         sn_cfctl%l_trcstat = setto
519      ENDIF
520      sn_cfctl%l_oceout  = setto
521      sn_cfctl%l_layout  = setto
522      sn_cfctl%l_mppout  = setto
523      sn_cfctl%l_mpptop  = setto
524   END SUBROUTINE nemo_set_cfctl
525
526   SUBROUTINE istate_init
527      !!----------------------------------------------------------------------
528      !!                   ***  ROUTINE istate_init  ***
529      !!
530      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
531      !!----------------------------------------------------------------------
532      !
533      !     now fields         !     after fields      !
534      un   (:,:,:)   = 0._wp   ;   ua(:,:,:) = 0._wp   !
535      vn   (:,:,:)   = 0._wp   ;   va(:,:,:) = 0._wp   !
536      wn   (:,:,:)   = 0._wp   !                       !
537      hdivn(:,:,:)   = 0._wp   !                       !
538      tsn  (:,:,:,:) = 0._wp   !                       !
539      !
540      rhd  (:,:,:) = 0.e0
541      rhop (:,:,:) = 0.e0
542      rn2  (:,:,:) = 0.e0
543      !
544   END SUBROUTINE istate_init
545
546
547   SUBROUTINE stp_ctl( kt, kindic )
548      !!----------------------------------------------------------------------
549      !!                    ***  ROUTINE stp_ctl  ***
550      !!
551      !! ** Purpose :   Control the run
552      !!
553      !! ** Method  : - Save the time step in numstp
554      !!
555      !! ** Actions :   'time.step' file containing the last ocean time-step
556      !!----------------------------------------------------------------------
557      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
558      INTEGER, INTENT(inout) ::   kindic  ! indicator of solver convergence
559      !!----------------------------------------------------------------------
560      !
561      IF( kt == nit000 .AND. lwm ) THEN
562         WRITE(numout,*)
563         WRITE(numout,*) 'stp_ctl : time-stepping control'
564         WRITE(numout,*) '~~~~~~~'
565         ! open time.step file
566         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
567      ENDIF
568      !
569      IF(lwm) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
570      IF(lwm) REWIND( numstp )                       ! --------------------------
571      !
572   END SUBROUTINE stp_ctl
573   !!======================================================================
574END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.