New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p2zexp.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P2Z – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P2Z/p2zexp.F90 @ 10975

Last change on this file since 10975 was 10975, checked in by acc, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Finish converting all TOP routines and knock-on effects of these conversions. Fully SETTE tested (SETTE tests 1-6 and 9). This completes the first stage conversion of TRA and TOP but need to revisit and pass ts and tr arrays through the argument lists where appropriate.

  • Property svn:keywords set to Id
File size: 10.4 KB
Line 
1MODULE p2zexp
2   !!======================================================================
3   !!                         ***  MODULE p2zsed  ***
4   !! TOP :   LOBSTER Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :    -   !  1999    (O. Aumont, C. Le Quere)  original code
7   !!              -   !  2001-05 (O. Aumont, E. Kestenare) add sediment computations
8   !!             1.0  !  2005-06 (A.-S. Kremeur) new temporal integration for sedpoc
9   !!             2.0  !  2007-12  (C. Deltel, G. Madec)  F90
10   !!             3.5  !  2012-03  (C. Ethe)  Merge PISCES-LOBSTER
11   !!----------------------------------------------------------------------
12   !!   p2z_exp        :  Compute loss of organic matter in the sediments
13   !!----------------------------------------------------------------------
14   USE oce_trc         !
15   USE trc
16   USE sms_pisces
17   USE p2zsed
18   USE lbclnk
19   USE prtctl_trc      ! Print control for debbuging
20   USE trd_oce
21   USE trdtrc
22   USE iom
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p2z_exp   
28   PUBLIC   p2z_exp_init 
29   PUBLIC   p2z_exp_alloc
30
31   !
32   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   dminl     !: fraction of sinking POC released in sediments
33   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   dmin3     !: fraction of sinking POC released at each level
34   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocb   !: mass of POC in sediments
35   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocn   !: mass of POC in sediments
36   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   cmask     !: Coastal mask area
37   REAL(wp)                                ::   areacot   !: surface coastal area
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE p2z_exp( kt, Kmm, Krhs )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p2z_exp  ***
51      !!
52      !! ** Purpose :   MODELS EXPORT OF BIOGENIC MATTER (POC ''SOFT
53      !!              TISSUE'') AND ITS DISTRIBUTION IN WATER COLUMN
54      !!
55      !! ** Method  : - IN THE SURFACE LAYER POC IS PRODUCED ACCORDING TO
56      !!              NURTRIENTS AVAILABLE AND GROWTH CONDITIONS. NUTRIENT UPTAKE
57      !!              KINETICS FOLLOW MICHAELIS-MENTON FORMULATION.
58      !!              THE TOTAL PARTICLE AMOUNT PRODUCED, IS DISTRIBUTED IN THE WATER
59      !!              COLUMN BELOW THE SURFACE LAYER.
60      !!---------------------------------------------------------------------
61      !!
62      INTEGER, INTENT( in ) ::   kt             ! ocean time-step index     
63      INTEGER, INTENT( in ) ::   Kmm, Krhs      ! time level indices
64      !!
65      INTEGER  ::   ji, jj, jk, jl, ikt
66      REAL(wp) ::   zgeolpoc, zfact, zwork, ze3t, zsedpocd, zmaskt
67      REAL(wp), DIMENSION(jpi,jpj)   ::  zsedpoca
68      CHARACTER (len=25) :: charout
69      !!---------------------------------------------------------------------
70      !
71      IF( ln_timing )   CALL timing_start('p2z_exp')
72      !
73      IF( kt == nittrc000 )   CALL p2z_exp_init( Kmm )
74
75      zsedpoca(:,:) = 0.
76
77
78      ! VERTICAL DISTRIBUTION OF NEWLY PRODUCED BIOGENIC
79      ! POC IN THE WATER COLUMN
80      ! (PARTS OF NEWLY FORMED MATTER REMAINING IN THE DIFFERENT
81      ! LAYERS IS DETERMINED BY DMIN3 DEFINED IN sms_p2z.F90
82      ! ----------------------------------------------------------------------
83      DO jk = 1, jpkm1
84         DO jj = 2, jpjm1
85            DO ji = fs_2, fs_jpim1
86               ze3t = 1. / e3t(ji,jj,jk,Kmm)
87               tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) + ze3t * dmin3(ji,jj,jk) * xksi(ji,jj)
88            END DO
89         END DO
90      END DO
91
92      ! Find the last level of the water column
93      ! Compute fluxes due to sinking particles (slow)
94   
95
96      zgeolpoc = 0.e0         !     Initialization
97      ! Release of nutrients from the "simple" sediment
98      DO jj = 2, jpjm1
99         DO ji = fs_2, fs_jpim1
100            ikt = mbkt(ji,jj) 
101            tr(ji,jj,ikt,jpno3,Krhs) = tr(ji,jj,ikt,jpno3,Krhs) + sedlam * sedpocn(ji,jj) / e3t(ji,jj,ikt,Kmm) 
102            ! Deposition of organic matter in the sediment
103            zwork = vsed * tr(ji,jj,ikt,jpdet,Kmm)
104            zsedpoca(ji,jj) = ( zwork + dminl(ji,jj) * xksi(ji,jj)   &
105               &           - sedlam * sedpocn(ji,jj) - sedlostpoc * sedpocn(ji,jj) ) * rdt
106            zgeolpoc = zgeolpoc + sedlostpoc * sedpocn(ji,jj) * e1e2t(ji,jj)
107         END DO
108      END DO
109
110      DO jj = 2, jpjm1
111         DO ji = fs_2, fs_jpim1
112            tr(ji,jj,1,jpno3,Krhs) = tr(ji,jj,1,jpno3,Krhs) + zgeolpoc * cmask(ji,jj) / areacot / e3t(ji,jj,1,Kmm)
113         END DO
114      END DO
115
116      CALL lbc_lnk( 'p2zexp', sedpocn, 'T', 1. )
117 
118      ! Oa & Ek: diagnostics depending on jpdia2d !          left as example
119      IF( lk_iomput )  CALL iom_put( "SEDPOC" , sedpocn )
120
121     
122      ! Time filter and swap of arrays
123      ! ------------------------------
124      IF( neuler == 0 .AND. kt == nittrc000 ) THEN        ! Euler time-stepping at first time-step
125        !                                             ! (only swap)
126        sedpocn(:,:) = zsedpoca(:,:)
127        !                                             
128      ELSE
129        !
130        DO jj = 1, jpj
131           DO ji = 1, jpi
132              zsedpocd = zsedpoca(ji,jj) - 2. * sedpocn(ji,jj) + sedpocb(ji,jj)      ! time laplacian on tracers
133              sedpocb(ji,jj) = sedpocn(ji,jj) + atfp * zsedpocd                     ! sedpocb <-- filtered sedpocn
134              sedpocn(ji,jj) = zsedpoca(ji,jj)                                       ! sedpocn <-- sedpoca
135           END DO
136        END DO
137        !
138      ENDIF
139      !
140      IF( lrst_trc ) THEN
141         IF(lwp) WRITE(numout,*)
142         IF(lwp) WRITE(numout,*) 'p2z_exp : POC in sediment fields written in ocean restart file ',   &
143            &                    'at it= ', kt,' date= ', ndastp
144         IF(lwp) WRITE(numout,*) '~~~~'
145         CALL iom_rstput( kt, nitrst, numrtw, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
146         CALL iom_rstput( kt, nitrst, numrtw, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
147      ENDIF
148      !
149      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
150         WRITE(charout, FMT="('exp')")
151         CALL prt_ctl_trc_info(charout)
152         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
153      ENDIF
154      !
155      IF( ln_timing )  CALL timing_stop('p2z_exp')
156      !
157   END SUBROUTINE p2z_exp
158
159
160   SUBROUTINE p2z_exp_init( Kmm )
161      !!----------------------------------------------------------------------
162      !!                    ***  ROUTINE p4z_exp_init  ***
163      !! ** purpose :   specific initialisation for export
164      !!----------------------------------------------------------------------
165      INTEGER, INTENT(in)  ::  Kmm      ! time level index
166      INTEGER  ::   ji, jj, jk
167      REAL(wp) ::   zmaskt, zfluo, zfluu
168      REAL(wp), DIMENSION(jpi,jpj    ) :: zrro
169      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdm0
170      !!---------------------------------------------------------------------
171      !
172      IF(lwp) THEN
173         WRITE(numout,*)
174         WRITE(numout,*) ' p2z_exp: LOBSTER export'
175         WRITE(numout,*) ' ~~~~~~~'
176         WRITE(numout,*) '  compute remineralisation-damping arrays for tracers'
177      ENDIF
178      !
179
180      ! Calculate vertical distribution of newly formed biogenic poc
181      ! in the water column in the case of max. possible bottom depth
182      ! ------------------------------------------------------------
183      zdm0 = 0._wp
184      zrro = 1._wp
185      DO jk = jpkb, jpkm1
186         DO jj = 1, jpj
187            DO ji = 1, jpi
188               zfluo = ( gdepw(ji,jj,jk  ,Kmm) / gdepw(ji,jj,jpkb,Kmm) )**xhr
189               zfluu = ( gdepw(ji,jj,jk+1,Kmm) / gdepw(ji,jj,jpkb,Kmm) )**xhr
190               IF( zfluo.GT.1. )   zfluo = 1._wp
191               zdm0(ji,jj,jk) = zfluo - zfluu
192               IF( jk <= jpkb-1 )   zdm0(ji,jj,jk) = 0._wp
193               zrro(ji,jj) = zrro(ji,jj) - zdm0(ji,jj,jk)
194            END DO
195         END DO
196      END DO
197      !
198      zdm0(:,:,jpk) = zrro(:,:)
199
200      ! Calculate vertical distribution of newly formed biogenic poc
201      ! in the water column with realistic topography (first "dry" layer
202      ! contains total fraction, which has passed to the upper layers)
203      ! ----------------------------------------------------------------------
204      dminl(:,:)   = 0._wp
205      dmin3(:,:,:) = zdm0
206      DO jk = 1, jpk
207         DO jj = 1, jpj
208            DO ji = 1, jpi
209               IF( tmask(ji,jj,jk) == 0._wp ) THEN
210                  dminl(ji,jj) = dminl(ji,jj) + dmin3(ji,jj,jk)
211                  dmin3(ji,jj,jk) = 0._wp
212               ENDIF
213            END DO
214         END DO
215      END DO
216
217      DO jj = 1, jpj
218         DO ji = 1, jpi
219            IF( tmask(ji,jj,1) == 0 )   dmin3(ji,jj,1) = 0._wp
220         END DO
221      END DO
222
223      ! Coastal mask
224      cmask(:,:) = 0._wp
225      DO jj = 2, jpjm1
226         DO ji = fs_2, fs_jpim1
227            IF( tmask(ji,jj,1) /= 0. ) THEN
228               zmaskt = tmask(ji+1,jj,1) * tmask(ji-1,jj,1) * tmask(ji,jj+1,1) * tmask(ji,jj-1,1) 
229               IF( zmaskt == 0. )   cmask(ji,jj) = 1._wp
230            END IF
231         END DO
232      END DO
233      CALL lbc_lnk( 'p2zexp', cmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
234      areacot = glob_sum( 'p2zexp', e1e2t(:,:) * cmask(:,:) )
235      !
236      IF( ln_rsttr ) THEN
237         CALL iom_get( numrtr, jpdom_autoglo, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
238         CALL iom_get( numrtr, jpdom_autoglo, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
239      ELSE
240         sedpocb(:,:) = 0._wp
241         sedpocn(:,:) = 0._wp
242      ENDIF
243      !
244   END SUBROUTINE p2z_exp_init
245
246   INTEGER FUNCTION p2z_exp_alloc()
247      !!----------------------------------------------------------------------
248      !!                     ***  ROUTINE p2z_exp_alloc  ***
249      !!----------------------------------------------------------------------
250      ALLOCATE( cmask(jpi,jpj) , dminl(jpi,jpj) , dmin3(jpi,jpj,jpk), &
251         &      sedpocb(jpi,jpj) , sedpocn(jpi,jpj),   STAT=p2z_exp_alloc )
252      IF( p2z_exp_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p2z_exp_alloc : failed to allocate arrays.' )
253      !
254   END FUNCTION p2z_exp_alloc
255
256   !!======================================================================
257END MODULE p2zexp
Note: See TracBrowser for help on using the repository browser.