New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zche.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z/p4zche.F90 @ 10975

Last change on this file since 10975 was 10975, checked in by acc, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Finish converting all TOP routines and knock-on effects of these conversions. Fully SETTE tested (SETTE tests 1-6 and 9). This completes the first stage conversion of TRA and TOP but need to revisit and pass ts and tr arrays through the argument lists where appropriate.
  • Property svn:keywords set to Id
File size: 37.6 KB
Line 
1MODULE p4zche
2   !!======================================================================
3   !!                         ***  MODULE p4zche  ***
4   !! TOP :   PISCES Sea water chemistry computed following OCMIP protocol
5   !!======================================================================
6   !! History :   OPA  !  1988     (E. Maier-Reimer)  Original code
7   !!              -   !  1998     (O. Aumont)  addition
8   !!              -   !  1999     (C. Le Quere)  modification
9   !!   NEMO      1.0  !  2004     (O. Aumont)  modification
10   !!              -   !  2006     (R. Gangsto)  modification
11   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
12   !!                  !  2011-02  (J. Simeon, J.Orr ) update O2 solubility constants
13   !!             3.6  !  2016-03  (O. Aumont) Change chemistry to MOCSY standards
14   !!----------------------------------------------------------------------
15   !!   p4z_che      :  Sea water chemistry computed following OCMIP protocol
16   !!----------------------------------------------------------------------
17   USE oce_trc       !  shared variables between ocean and passive tracers
18   USE trc           !  passive tracers common variables
19   USE sms_pisces    !  PISCES Source Minus Sink variables
20   USE lib_mpp       !  MPP library
21   USE eosbn2, ONLY : neos
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_che          !
27   PUBLIC   p4z_che_alloc    !
28   PUBLIC   ahini_for_at     !
29   PUBLIC   solve_at_general !
30
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: sio3eq   ! chemistry of Si
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: fekeq    ! chemistry of Fe
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: chemc    ! Solubilities of O2 and CO2
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)   :: chemo2    ! Solubilities of O2 and CO2
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: fesol    ! solubility of Fe
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   salinprac  ! Practical salinity
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   tempis   ! In situ temperature
38
39   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   akb3       !: ???
40   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   akw3       !: ???
41   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   akf3       !: ???
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aks3       !: ???
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ak1p3      !: ???
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ak2p3      !: ???
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ak3p3      !: ???
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aksi3      !: ???
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   borat      !: ???
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   fluorid    !: ???
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sulfat     !: ???
50
51   !!* Variable for chemistry of the CO2 cycle
52
53   REAL(wp), PUBLIC ::   atcox  = 0.20946         ! units atm
54
55   REAL(wp) ::   o2atm  = 1. / ( 1000. * 0.20946 ) 
56
57   REAL(wp) ::   rgas   = 83.14472      ! universal gas constants
58   REAL(wp) ::   oxyco  = 1. / 22.4144  ! converts from liters of an ideal gas to moles
59   !                                    ! coeff. for seawater pressure correction : millero 95
60   !                                    ! AGRIF doesn't like the DATA instruction
61   REAL(wp) :: devk10  = -25.5
62   REAL(wp) :: devk11  = -15.82
63   REAL(wp) :: devk12  = -29.48
64   REAL(wp) :: devk13  = -20.02
65   REAL(wp) :: devk14  = -18.03
66   REAL(wp) :: devk15  = -9.78
67   REAL(wp) :: devk16  = -48.76
68   REAL(wp) :: devk17  = -14.51
69   REAL(wp) :: devk18  = -23.12
70   REAL(wp) :: devk19  = -26.57
71   REAL(wp) :: devk110  = -29.48
72   !
73   REAL(wp) :: devk20  = 0.1271
74   REAL(wp) :: devk21  = -0.0219
75   REAL(wp) :: devk22  = 0.1622
76   REAL(wp) :: devk23  = 0.1119
77   REAL(wp) :: devk24  = 0.0466
78   REAL(wp) :: devk25  = -0.0090
79   REAL(wp) :: devk26  = 0.5304
80   REAL(wp) :: devk27  = 0.1211
81   REAL(wp) :: devk28  = 0.1758
82   REAL(wp) :: devk29  = 0.2020
83   REAL(wp) :: devk210  = 0.1622
84   !
85   REAL(wp) :: devk30  = 0.
86   REAL(wp) :: devk31  = 0.
87   REAL(wp) :: devk32  = 2.608E-3
88   REAL(wp) :: devk33  = -1.409e-3
89   REAL(wp) :: devk34  = 0.316e-3
90   REAL(wp) :: devk35  = -0.942e-3
91   REAL(wp) :: devk36  = 0.
92   REAL(wp) :: devk37  = -0.321e-3
93   REAL(wp) :: devk38  = -2.647e-3
94   REAL(wp) :: devk39  = -3.042e-3
95   REAL(wp) :: devk310  = -2.6080e-3
96   !
97   REAL(wp) :: devk40  = -3.08E-3
98   REAL(wp) :: devk41  = 1.13E-3
99   REAL(wp) :: devk42  = -2.84E-3
100   REAL(wp) :: devk43  = -5.13E-3
101   REAL(wp) :: devk44  = -4.53e-3
102   REAL(wp) :: devk45  = -3.91e-3
103   REAL(wp) :: devk46  = -11.76e-3
104   REAL(wp) :: devk47  = -2.67e-3
105   REAL(wp) :: devk48  = -5.15e-3
106   REAL(wp) :: devk49  = -4.08e-3
107   REAL(wp) :: devk410  = -2.84e-3
108   !
109   REAL(wp) :: devk50  = 0.0877E-3
110   REAL(wp) :: devk51  = -0.1475E-3     
111   REAL(wp) :: devk52  = 0.
112   REAL(wp) :: devk53  = 0.0794E-3     
113   REAL(wp) :: devk54  = 0.09e-3
114   REAL(wp) :: devk55  = 0.054e-3
115   REAL(wp) :: devk56  = 0.3692E-3
116   REAL(wp) :: devk57  = 0.0427e-3
117   REAL(wp) :: devk58  = 0.09e-3
118   REAL(wp) :: devk59  = 0.0714e-3
119   REAL(wp) :: devk510  = 0.0
120   !
121   ! General parameters
122   REAL(wp), PARAMETER :: pp_rdel_ah_target = 1.E-4_wp
123   REAL(wp), PARAMETER :: pp_ln10 = 2.302585092994045684018_wp
124
125   ! Maximum number of iterations for each method
126   INTEGER, PARAMETER :: jp_maxniter_atgen    = 20
127
128   ! Bookkeeping variables for each method
129   ! - SOLVE_AT_GENERAL
130   INTEGER :: niter_atgen    = jp_maxniter_atgen
131
132   !!----------------------------------------------------------------------
133   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
134   !! $Id$
135   !! Software governed by the CeCILL license (see ./LICENSE)
136   !!----------------------------------------------------------------------
137CONTAINS
138
139   SUBROUTINE p4z_che( Kbb, Kmm )
140      !!---------------------------------------------------------------------
141      !!                     ***  ROUTINE p4z_che  ***
142      !!
143      !! ** Purpose :   Sea water chemistry computed following OCMIP protocol
144      !!
145      !! ** Method  : - ...
146      !!---------------------------------------------------------------------
147      INTEGER, INTENT(in) ::   Kbb, Kmm  ! time level indices
148      INTEGER  ::   ji, jj, jk
149      REAL(wp) ::   ztkel, ztkel1, zt , zsal  , zsal2 , zbuf1 , zbuf2
150      REAL(wp) ::   ztgg , ztgg2, ztgg3 , ztgg4 , ztgg5
151      REAL(wp) ::   zpres, ztc  , zcl   , zcpexp, zoxy  , zcpexp2
152      REAL(wp) ::   zsqrt, ztr  , zlogt , zcek1, zc1, zplat
153      REAL(wp) ::   zis  , zis2 , zsal15, zisqrt, za1, za2
154      REAL(wp) ::   zckb , zck1 , zck2  , zckw  , zak1 , zak2  , zakb , zaksp0, zakw
155      REAL(wp) ::   zck1p, zck2p, zck3p, zcksi, zak1p, zak2p, zak3p, zaksi
156      REAL(wp) ::   zst  , zft  , zcks  , zckf  , zaksp1
157      REAL(wp) ::   total2free, free2SWS, total2SWS, SWS2total
158      !!---------------------------------------------------------------------
159      !
160      IF( ln_timing )   CALL timing_start('p4z_che')
161      !
162      ! Computation of chemical constants require practical salinity
163      ! Thus, when TEOS08 is used, absolute salinity is converted to
164      ! practical salinity
165      ! -------------------------------------------------------------
166      IF (neos == -1) THEN
167         salinprac(:,:,:) = ts(:,:,:,jp_sal,Kmm) * 35.0 / 35.16504
168      ELSE
169         salinprac(:,:,:) = ts(:,:,:,jp_sal,Kmm)
170      ENDIF
171
172      !
173      ! Computations of chemical constants require in situ temperature
174      ! Here a quite simple formulation is used to convert
175      ! potential temperature to in situ temperature. The errors is less than
176      ! 0.04°C relative to an exact computation
177      ! ---------------------------------------------------------------------
178      DO jk = 1, jpk
179         DO jj = 1, jpj
180            DO ji = 1, jpi
181               zpres = gdept(ji,jj,jk,Kmm) / 1000.
182               za1 = 0.04 * ( 1.0 + 0.185 * ts(ji,jj,jk,jp_tem,Kmm) + 0.035 * (salinprac(ji,jj,jk) - 35.0) )
183               za2 = 0.0075 * ( 1.0 - ts(ji,jj,jk,jp_tem,Kmm) / 30.0 )
184               tempis(ji,jj,jk) = ts(ji,jj,jk,jp_tem,Kmm) - za1 * zpres + za2 * zpres**2
185            END DO
186         END DO
187      END DO
188      !
189      ! CHEMICAL CONSTANTS - SURFACE LAYER
190      ! ----------------------------------
191!CDIR NOVERRCHK
192      DO jj = 1, jpj
193!CDIR NOVERRCHK
194         DO ji = 1, jpi
195            !                             ! SET ABSOLUTE TEMPERATURE
196            ztkel = tempis(ji,jj,1) + 273.15
197            zt    = ztkel * 0.01
198            zsal  = salinprac(ji,jj,1) + ( 1.- tmask(ji,jj,1) ) * 35.
199            !                             ! LN(K0) OF SOLUBILITY OF CO2 (EQ. 12, WEISS, 1980)
200            !                             !     AND FOR THE ATMOSPHERE FOR NON IDEAL GAS
201            zcek1 = 9345.17/ztkel - 60.2409 + 23.3585 * LOG(zt) + zsal*(0.023517 - 0.00023656*ztkel    &
202            &       + 0.0047036e-4*ztkel**2)
203            chemc(ji,jj,1) = EXP( zcek1 ) * 1E-6 * rhop(ji,jj,1) / 1000. ! mol/(L atm)
204            chemc(ji,jj,2) = -1636.75 + 12.0408*ztkel - 0.0327957*ztkel**2 + 0.0000316528*ztkel**3
205            chemc(ji,jj,3) = 57.7 - 0.118*ztkel
206            !
207         END DO
208      END DO
209
210      ! OXYGEN SOLUBILITY - DEEP OCEAN
211      ! -------------------------------
212!CDIR NOVERRCHK
213      DO jk = 1, jpk
214!CDIR NOVERRCHK
215         DO jj = 1, jpj
216!CDIR NOVERRCHK
217            DO ji = 1, jpi
218              ztkel = tempis(ji,jj,jk) + 273.15
219              zsal  = salinprac(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 35.
220              zsal2 = zsal * zsal
221              ztgg  = LOG( ( 298.15 - tempis(ji,jj,jk) ) / ztkel )  ! Set the GORDON & GARCIA scaled temperature
222              ztgg2 = ztgg  * ztgg
223              ztgg3 = ztgg2 * ztgg
224              ztgg4 = ztgg3 * ztgg
225              ztgg5 = ztgg4 * ztgg
226
227              zoxy  = 2.00856 + 3.22400 * ztgg + 3.99063 * ztgg2 + 4.80299 * ztgg3    &
228              &       + 9.78188e-1 * ztgg4 + 1.71069 * ztgg5 + zsal * ( -6.24097e-3   &
229              &       - 6.93498e-3 * ztgg - 6.90358e-3 * ztgg2 - 4.29155e-3 * ztgg3 )   &
230              &       - 3.11680e-7 * zsal2
231              chemo2(ji,jj,jk) = ( EXP( zoxy ) * o2atm ) * oxyco * atcox     ! mol/(L atm)
232            END DO
233          END DO
234        END DO
235
236      ! CHEMICAL CONSTANTS - DEEP OCEAN
237      ! -------------------------------
238!CDIR NOVERRCHK
239      DO jk = 1, jpk
240!CDIR NOVERRCHK
241         DO jj = 1, jpj
242!CDIR NOVERRCHK
243            DO ji = 1, jpi
244
245               ! SET PRESSION ACCORDING TO SAUNDER (1980)
246               zplat   = SIN ( ABS(gphit(ji,jj)*3.141592654/180.) )
247               zc1 = 5.92E-3 + zplat**2 * 5.25E-3
248               zpres = ((1-zc1)-SQRT(((1-zc1)**2)-(8.84E-6*gdept(ji,jj,jk,Kmm)))) / 4.42E-6
249               zpres = zpres / 10.0
250
251               ! SET ABSOLUTE TEMPERATURE
252               ztkel   = tempis(ji,jj,jk) + 273.15
253               zsal    = salinprac(ji,jj,jk) + ( 1.-tmask(ji,jj,jk) ) * 35.
254               zsqrt  = SQRT( zsal )
255               zsal15  = zsqrt * zsal
256               zlogt  = LOG( ztkel )
257               ztr    = 1. / ztkel
258               zis    = 19.924 * zsal / ( 1000.- 1.005 * zsal )
259               zis2   = zis * zis
260               zisqrt = SQRT( zis )
261               ztc     = tempis(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 20.
262
263               ! CHLORINITY (WOOSTER ET AL., 1969)
264               zcl     = zsal / 1.80655
265
266               ! TOTAL SULFATE CONCENTR. [MOLES/kg soln]
267               zst     = 0.14 * zcl /96.062
268
269               ! TOTAL FLUORIDE CONCENTR. [MOLES/kg soln]
270               zft     = 0.000067 * zcl /18.9984
271
272               ! DISSOCIATION CONSTANT FOR SULFATES on free H scale (Dickson 1990)
273               zcks    = EXP(-4276.1 * ztr + 141.328 - 23.093 * zlogt         &
274               &         + (-13856. * ztr + 324.57 - 47.986 * zlogt) * zisqrt &
275               &         + (35474. * ztr - 771.54 + 114.723 * zlogt) * zis    &
276               &         - 2698. * ztr * zis**1.5 + 1776.* ztr * zis2         &
277               &         + LOG(1.0 - 0.001005 * zsal))
278
279               ! DISSOCIATION CONSTANT FOR FLUORIDES on free H scale (Dickson and Riley 79)
280               zckf    = EXP( 1590.2*ztr - 12.641 + 1.525*zisqrt   &
281               &         + LOG(1.0d0 - 0.001005d0*zsal)            &
282               &         + LOG(1.0d0 + zst/zcks))
283
284               ! DISSOCIATION CONSTANT FOR CARBONATE AND BORATE
285               zckb=  (-8966.90 - 2890.53*zsqrt - 77.942*zsal        &
286               &      + 1.728*zsal15 - 0.0996*zsal*zsal)*ztr         &
287               &      + (148.0248 + 137.1942*zsqrt + 1.62142*zsal)   &
288               &      + (-24.4344 - 25.085*zsqrt - 0.2474*zsal)      & 
289               &      * zlogt + 0.053105*zsqrt*ztkel
290
291               ! DISSOCIATION COEFFICIENT FOR CARBONATE ACCORDING TO
292               ! MEHRBACH (1973) REFIT BY MILLERO (1995), seawater scale
293               zck1    = -1.0*(3633.86*ztr - 61.2172 + 9.6777*zlogt  &
294                  - 0.011555*zsal + 0.0001152*zsal*zsal)
295               zck2    = -1.0*(471.78*ztr + 25.9290 - 3.16967*zlogt      &
296                  - 0.01781*zsal + 0.0001122*zsal*zsal)
297
298               ! PKW (H2O) (MILLERO, 1995) from composite data
299               zckw    = -13847.26 * ztr + 148.9652 - 23.6521 * zlogt + ( 118.67 * ztr    &
300                         - 5.977 + 1.0495 * zlogt ) * zsqrt - 0.01615 * zsal
301
302               ! CONSTANTS FOR PHOSPHATE (MILLERO, 1995)
303              zck1p    = -4576.752*ztr + 115.540 - 18.453*zlogt   &
304              &          + (-106.736*ztr + 0.69171) * zsqrt       &
305              &          + (-0.65643*ztr - 0.01844) * zsal
306
307              zck2p    = -8814.715*ztr + 172.1033 - 27.927*zlogt  &
308              &          + (-160.340*ztr + 1.3566)*zsqrt          &
309              &          + (0.37335*ztr - 0.05778)*zsal
310
311              zck3p    = -3070.75*ztr - 18.126                    &
312              &          + (17.27039*ztr + 2.81197) * zsqrt       &
313              &          + (-44.99486*ztr - 0.09984) * zsal 
314
315              ! CONSTANT FOR SILICATE, MILLERO (1995)
316              zcksi    = -8904.2*ztr  + 117.400 - 19.334*zlogt   &
317              &          + (-458.79*ztr + 3.5913) * zisqrt       &
318              &          + (188.74*ztr - 1.5998) * zis           &
319              &          + (-12.1652*ztr + 0.07871) * zis2       &
320              &          + LOG(1.0 - 0.001005*zsal)
321
322               ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE IN SEAWATER
323               !       (S=27-43, T=2-25 DEG C) at pres =0 (atmos. pressure) (MUCCI 1983)
324               zaksp0  = -171.9065 -0.077993*ztkel + 2839.319*ztr + 71.595*LOG10( ztkel )   &
325                  &      + (-0.77712 + 0.00284263*ztkel + 178.34*ztr) * zsqrt  &
326                  &      - 0.07711*zsal + 0.0041249*zsal15
327
328               ! CONVERT FROM DIFFERENT PH SCALES
329               total2free  = 1.0/(1.0 + zst/zcks)
330               free2SWS    = 1. + zst/zcks + zft/(zckf*total2free)
331               total2SWS   = total2free * free2SWS
332               SWS2total   = 1.0 / total2SWS
333
334               ! K1, K2 OF CARBONIC ACID, KB OF BORIC ACID, KW (H2O) (LIT.?)
335               zak1    = 10**(zck1) * total2SWS
336               zak2    = 10**(zck2) * total2SWS
337               zakb    = EXP( zckb ) * total2SWS
338               zakw    = EXP( zckw )
339               zaksp1  = 10**(zaksp0)
340               zak1p   = exp( zck1p )
341               zak2p   = exp( zck2p )
342               zak3p   = exp( zck3p )
343               zaksi   = exp( zcksi )
344               zckf    = zckf * total2SWS
345
346               ! FORMULA FOR CPEXP AFTER EDMOND & GIESKES (1970)
347               !        (REFERENCE TO CULBERSON & PYTKOQICZ (1968) AS MADE
348               !        IN BROECKER ET AL. (1982) IS INCORRECT; HERE RGAS IS
349               !        TAKEN TENFOLD TO CORRECT FOR THE NOTATION OF pres  IN
350               !        DBAR INSTEAD OF BAR AND THE EXPRESSION FOR CPEXP IS
351               !        MULTIPLIED BY LN(10.) TO ALLOW USE OF EXP-FUNCTION
352               !        WITH BASIS E IN THE FORMULA FOR AKSPP (CF. EDMOND
353               !        & GIESKES (1970), P. 1285-1286 (THE SMALL
354               !        FORMULA ON P. 1286 IS RIGHT AND CONSISTENT WITH THE
355               !        SIGN IN PARTIAL MOLAR VOLUME CHANGE AS SHOWN ON P. 1285))
356               zcpexp  = zpres / (rgas*ztkel)
357               zcpexp2 = zpres * zcpexp
358
359               ! KB OF BORIC ACID, K1,K2 OF CARBONIC ACID PRESSURE
360               !        CORRECTION AFTER CULBERSON AND PYTKOWICZ (1968)
361               !        (CF. BROECKER ET AL., 1982)
362
363               zbuf1  = -     ( devk10 + devk20 * ztc + devk30 * ztc * ztc )
364               zbuf2  = 0.5 * ( devk40 + devk50 * ztc )
365               ak13(ji,jj,jk) = zak1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
366
367               zbuf1  =     - ( devk11 + devk21 * ztc + devk31 * ztc * ztc )
368               zbuf2  = 0.5 * ( devk41 + devk51 * ztc )
369               ak23(ji,jj,jk) = zak2 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
370
371               zbuf1  =     - ( devk12 + devk22 * ztc + devk32 * ztc * ztc )
372               zbuf2  = 0.5 * ( devk42 + devk52 * ztc )
373               akb3(ji,jj,jk) = zakb * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
374
375               zbuf1  =     - ( devk13 + devk23 * ztc + devk33 * ztc * ztc )
376               zbuf2  = 0.5 * ( devk43 + devk53 * ztc )
377               akw3(ji,jj,jk) = zakw * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
378
379               zbuf1  =     - ( devk14 + devk24 * ztc + devk34 * ztc * ztc )
380               zbuf2  = 0.5 * ( devk44 + devk54 * ztc )
381               aks3(ji,jj,jk) = zcks * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
382
383               zbuf1  =     - ( devk15 + devk25 * ztc + devk35 * ztc * ztc )
384               zbuf2  = 0.5 * ( devk45 + devk55 * ztc )
385               akf3(ji,jj,jk) = zckf * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
386
387               zbuf1  =     - ( devk17 + devk27 * ztc + devk37 * ztc * ztc )
388               zbuf2  = 0.5 * ( devk47 + devk57 * ztc )
389               ak1p3(ji,jj,jk) = zak1p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
390
391               zbuf1  =     - ( devk18 + devk28 * ztc + devk38 * ztc * ztc )
392               zbuf2  = 0.5 * ( devk48 + devk58 * ztc )
393               ak2p3(ji,jj,jk) = zak2p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
394
395               zbuf1  =     - ( devk19 + devk29 * ztc + devk39 * ztc * ztc )
396               zbuf2  = 0.5 * ( devk49 + devk59 * ztc )
397               ak3p3(ji,jj,jk) = zak3p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
398
399               zbuf1  =     - ( devk110 + devk210 * ztc + devk310 * ztc * ztc )
400               zbuf2  = 0.5 * ( devk410 + devk510 * ztc )
401               aksi3(ji,jj,jk) = zaksi * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
402
403               ! CONVERT FROM DIFFERENT PH SCALES
404               total2free  = 1.0/(1.0 + zst/aks3(ji,jj,jk))
405               free2SWS    = 1. + zst/aks3(ji,jj,jk) + zft/akf3(ji,jj,jk)
406               total2SWS   = total2free * free2SWS
407               SWS2total   = 1.0 / total2SWS
408
409               ! Convert to total scale
410               ak13(ji,jj,jk)  = ak13(ji,jj,jk)  * SWS2total
411               ak23(ji,jj,jk)  = ak23(ji,jj,jk)  * SWS2total
412               akb3(ji,jj,jk)  = akb3(ji,jj,jk)  * SWS2total
413               akw3(ji,jj,jk)  = akw3(ji,jj,jk)  * SWS2total
414               ak1p3(ji,jj,jk) = ak1p3(ji,jj,jk) * SWS2total
415               ak2p3(ji,jj,jk) = ak2p3(ji,jj,jk) * SWS2total
416               ak3p3(ji,jj,jk) = ak3p3(ji,jj,jk) * SWS2total
417               aksi3(ji,jj,jk) = aksi3(ji,jj,jk) * SWS2total
418               akf3(ji,jj,jk)  = akf3(ji,jj,jk)  / total2free
419
420               ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE
421               !        AS FUNCTION OF PRESSURE FOLLOWING MILLERO
422               !        (P. 1285) AND BERNER (1976)
423               zbuf1  =     - ( devk16 + devk26 * ztc + devk36 * ztc * ztc )
424               zbuf2  = 0.5 * ( devk46 + devk56 * ztc )
425               aksp(ji,jj,jk) = zaksp1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
426
427               ! TOTAL F, S, and BORATE CONCENTR. [MOLES/L]
428               borat(ji,jj,jk) = 0.0002414 * zcl / 10.811
429               sulfat(ji,jj,jk) = zst
430               fluorid(ji,jj,jk) = zft 
431
432               ! Iron and SIO3 saturation concentration from ...
433               sio3eq(ji,jj,jk) = EXP(  LOG( 10.) * ( 6.44 - 968. / ztkel )  ) * 1.e-6
434               fekeq (ji,jj,jk) = 10**( 17.27 - 1565.7 / ztkel )
435
436               ! Liu and Millero (1999) only valid 5 - 50 degC
437               ztkel1 = MAX( 5. , tempis(ji,jj,jk) ) + 273.16
438               fesol(ji,jj,jk,1) = 10**(-13.486 - 0.1856* zis**0.5 + 0.3073*zis + 5254.0/ztkel1)
439               fesol(ji,jj,jk,2) = 10**(2.517 - 0.8885*zis**0.5 + 0.2139 * zis - 1320.0/ztkel1 )
440               fesol(ji,jj,jk,3) = 10**(0.4511 - 0.3305*zis**0.5 - 1996.0/ztkel1 )
441               fesol(ji,jj,jk,4) = 10**(-0.2965 - 0.7881*zis**0.5 - 4086.0/ztkel1 )
442               fesol(ji,jj,jk,5) = 10**(4.4466 - 0.8505*zis**0.5 - 7980.0/ztkel1 )
443            END DO
444         END DO
445      END DO
446      !
447      IF( ln_timing )  CALL timing_stop('p4z_che')
448      !
449   END SUBROUTINE p4z_che
450
451   SUBROUTINE ahini_for_at(p_hini, Kbb )
452      !!---------------------------------------------------------------------
453      !!                     ***  ROUTINE ahini_for_at  ***
454      !!
455      !! Subroutine returns the root for the 2nd order approximation of the
456      !! DIC -- B_T -- A_CB equation for [H+] (reformulated as a cubic
457      !! polynomial) around the local minimum, if it exists.
458      !! Returns * 1E-03_wp if p_alkcb <= 0
459      !!         * 1E-10_wp if p_alkcb >= 2*p_dictot + p_bortot
460      !!         * 1E-07_wp if 0 < p_alkcb < 2*p_dictot + p_bortot
461      !!                    and the 2nd order approximation does not have
462      !!                    a solution
463      !!---------------------------------------------------------------------
464      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT)  ::  p_hini
465      INTEGER,                          INTENT(in)   ::  Kbb      ! time level indices
466      INTEGER  ::   ji, jj, jk
467      REAL(wp)  ::  zca1, zba1
468      REAL(wp)  ::  zd, zsqrtd, zhmin
469      REAL(wp)  ::  za2, za1, za0
470      REAL(wp)  ::  p_dictot, p_bortot, p_alkcb 
471      !!---------------------------------------------------------------------
472
473      IF( ln_timing )  CALL timing_start('ahini_for_at')
474      !
475      DO jk = 1, jpk
476        DO jj = 1, jpj
477          DO ji = 1, jpi
478            p_alkcb  = tr(ji,jj,jk,jptal,Kbb) * 1000. / (rhop(ji,jj,jk) + rtrn)
479            p_dictot = tr(ji,jj,jk,jpdic,Kbb) * 1000. / (rhop(ji,jj,jk) + rtrn)
480            p_bortot = borat(ji,jj,jk)
481            IF (p_alkcb <= 0.) THEN
482                p_hini(ji,jj,jk) = 1.e-3
483            ELSEIF (p_alkcb >= (2.*p_dictot + p_bortot)) THEN
484                p_hini(ji,jj,jk) = 1.e-10_wp
485            ELSE
486                zca1 = p_dictot/( p_alkcb + rtrn )
487                zba1 = p_bortot/ (p_alkcb + rtrn )
488           ! Coefficients of the cubic polynomial
489                za2 = aKb3(ji,jj,jk)*(1. - zba1) + ak13(ji,jj,jk)*(1.-zca1)
490                za1 = ak13(ji,jj,jk)*akb3(ji,jj,jk)*(1. - zba1 - zca1)    &
491                &     + ak13(ji,jj,jk)*ak23(ji,jj,jk)*(1. - (zca1+zca1))
492                za0 = ak13(ji,jj,jk)*ak23(ji,jj,jk)*akb3(ji,jj,jk)*(1. - zba1 - (zca1+zca1))
493                                        ! Taylor expansion around the minimum
494                zd = za2*za2 - 3.*za1   ! Discriminant of the quadratic equation
495                                        ! for the minimum close to the root
496
497                IF(zd > 0.) THEN        ! If the discriminant is positive
498                  zsqrtd = SQRT(zd)
499                  IF(za2 < 0) THEN
500                    zhmin = (-za2 + zsqrtd)/3.
501                  ELSE
502                    zhmin = -za1/(za2 + zsqrtd)
503                  ENDIF
504                  p_hini(ji,jj,jk) = zhmin + SQRT(-(za0 + zhmin*(za1 + zhmin*(za2 + zhmin)))/zsqrtd)
505                ELSE
506                  p_hini(ji,jj,jk) = 1.e-7
507                ENDIF
508             !
509             ENDIF
510          END DO
511        END DO
512      END DO
513      !
514      IF( ln_timing )  CALL timing_stop('ahini_for_at')
515      !
516   END SUBROUTINE ahini_for_at
517
518   !===============================================================================
519
520   SUBROUTINE anw_infsup( p_alknw_inf, p_alknw_sup, Kbb )
521
522   ! Subroutine returns the lower and upper bounds of "non-water-selfionization"
523   ! contributions to total alkalinity (the infimum and the supremum), i.e
524   ! inf(TA - [OH-] + [H+]) and sup(TA - [OH-] + [H+])
525
526   ! Argument variables
527   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT) :: p_alknw_inf
528   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT) :: p_alknw_sup
529   INTEGER,                          INTENT(in)  ::  Kbb      ! time level indices
530
531   p_alknw_inf(:,:,:) =  -tr(:,:,:,jppo4,Kbb) * 1000. / (rhop(:,:,:) + rtrn) - sulfat(:,:,:)  &
532   &              - fluorid(:,:,:)
533   p_alknw_sup(:,:,:) =   (2. * tr(:,:,:,jpdic,Kbb) + 2. * tr(:,:,:,jppo4,Kbb) + tr(:,:,:,jpsil,Kbb) )    &
534   &               * 1000. / (rhop(:,:,:) + rtrn) + borat(:,:,:) 
535
536   END SUBROUTINE anw_infsup
537
538
539   SUBROUTINE solve_at_general( p_hini, zhi, Kbb )
540
541   ! Universal pH solver that converges from any given initial value,
542   ! determines upper an lower bounds for the solution if required
543
544   ! Argument variables
545   !--------------------
546   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(IN)   :: p_hini
547   REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT)  :: zhi
548   INTEGER,                          INTENT(in)   :: Kbb  ! time level indices
549
550   ! Local variables
551   !-----------------
552   INTEGER   ::  ji, jj, jk, jn
553   REAL(wp)  ::  zh_ini, zh, zh_prev, zh_lnfactor
554   REAL(wp)  ::  zdelta, zh_delta
555   REAL(wp)  ::  zeqn, zdeqndh, zalka
556   REAL(wp)  ::  aphscale
557   REAL(wp)  ::  znumer_dic, zdnumer_dic, zdenom_dic, zalk_dic, zdalk_dic
558   REAL(wp)  ::  znumer_bor, zdnumer_bor, zdenom_bor, zalk_bor, zdalk_bor
559   REAL(wp)  ::  znumer_po4, zdnumer_po4, zdenom_po4, zalk_po4, zdalk_po4
560   REAL(wp)  ::  znumer_sil, zdnumer_sil, zdenom_sil, zalk_sil, zdalk_sil
561   REAL(wp)  ::  znumer_so4, zdnumer_so4, zdenom_so4, zalk_so4, zdalk_so4
562   REAL(wp)  ::  znumer_flu, zdnumer_flu, zdenom_flu, zalk_flu, zdalk_flu
563   REAL(wp)  ::  zalk_wat, zdalk_wat
564   REAL(wp)  ::  zfact, p_alktot, zdic, zbot, zpt, zst, zft, zsit
565   LOGICAL   ::  l_exitnow
566   REAL(wp), PARAMETER :: pz_exp_threshold = 1.0
567   REAL(wp), DIMENSION(jpi,jpj,jpk) :: zalknw_inf, zalknw_sup, rmask, zh_min, zh_max, zeqn_absmin
568
569   IF( ln_timing )  CALL timing_start('solve_at_general')
570
571   CALL anw_infsup( zalknw_inf, zalknw_sup, Kbb )
572
573   rmask(:,:,:) = tmask(:,:,:)
574   zhi(:,:,:)   = 0.
575
576   ! TOTAL H+ scale: conversion factor for Htot = aphscale * Hfree
577   DO jk = 1, jpk
578      DO jj = 1, jpj
579         DO ji = 1, jpi
580            IF (rmask(ji,jj,jk) == 1.) THEN
581               p_alktot = tr(ji,jj,jk,jptal,Kbb) * 1000. / (rhop(ji,jj,jk) + rtrn)
582               aphscale = 1. + sulfat(ji,jj,jk)/aks3(ji,jj,jk)
583               zh_ini = p_hini(ji,jj,jk)
584
585               zdelta = (p_alktot-zalknw_inf(ji,jj,jk))**2 + 4.*akw3(ji,jj,jk)/aphscale
586
587               IF(p_alktot >= zalknw_inf(ji,jj,jk)) THEN
588                 zh_min(ji,jj,jk) = 2.*akw3(ji,jj,jk) /( p_alktot-zalknw_inf(ji,jj,jk) + SQRT(zdelta) )
589               ELSE
590                 zh_min(ji,jj,jk) = aphscale*(-(p_alktot-zalknw_inf(ji,jj,jk)) + SQRT(zdelta) ) / 2.
591               ENDIF
592
593               zdelta = (p_alktot-zalknw_sup(ji,jj,jk))**2 + 4.*akw3(ji,jj,jk)/aphscale
594
595               IF(p_alktot <= zalknw_sup(ji,jj,jk)) THEN
596                 zh_max(ji,jj,jk) = aphscale*(-(p_alktot-zalknw_sup(ji,jj,jk)) + SQRT(zdelta) ) / 2.
597               ELSE
598                 zh_max(ji,jj,jk) = 2.*akw3(ji,jj,jk) /( p_alktot-zalknw_sup(ji,jj,jk) + SQRT(zdelta) )
599               ENDIF
600
601               zhi(ji,jj,jk) = MAX(MIN(zh_max(ji,jj,jk), zh_ini), zh_min(ji,jj,jk))
602            ENDIF
603         END DO
604      END DO
605   END DO
606
607   zeqn_absmin(:,:,:) = HUGE(1._wp)
608
609   DO jn = 1, jp_maxniter_atgen 
610   DO jk = 1, jpk
611      DO jj = 1, jpj
612         DO ji = 1, jpi
613            IF (rmask(ji,jj,jk) == 1.) THEN
614               zfact = rhop(ji,jj,jk) / 1000. + rtrn
615               p_alktot = tr(ji,jj,jk,jptal,Kbb) / zfact
616               zdic  = tr(ji,jj,jk,jpdic,Kbb) / zfact
617               zbot  = borat(ji,jj,jk)
618               zpt = tr(ji,jj,jk,jppo4,Kbb) / zfact * po4r
619               zsit = tr(ji,jj,jk,jpsil,Kbb) / zfact
620               zst = sulfat (ji,jj,jk)
621               zft = fluorid(ji,jj,jk)
622               aphscale = 1. + sulfat(ji,jj,jk)/aks3(ji,jj,jk)
623               zh = zhi(ji,jj,jk)
624               zh_prev = zh
625
626               ! H2CO3 - HCO3 - CO3 : n=2, m=0
627               znumer_dic = 2.*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*ak13(ji,jj,jk)
628               zdenom_dic = ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*(ak13(ji,jj,jk) + zh)
629               zalk_dic   = zdic * (znumer_dic/zdenom_dic)
630               zdnumer_dic = ak13(ji,jj,jk)*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh     &
631                             *(4.*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*ak13(ji,jj,jk))
632               zdalk_dic   = -zdic*(zdnumer_dic/zdenom_dic**2)
633
634
635               ! B(OH)3 - B(OH)4 : n=1, m=0
636               znumer_bor = akb3(ji,jj,jk)
637               zdenom_bor = akb3(ji,jj,jk) + zh
638               zalk_bor   = zbot * (znumer_bor/zdenom_bor)
639               zdnumer_bor = akb3(ji,jj,jk)
640               zdalk_bor   = -zbot*(zdnumer_bor/zdenom_bor**2)
641
642
643               ! H3PO4 - H2PO4 - HPO4 - PO4 : n=3, m=1
644               znumer_po4 = 3.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)  &
645               &            + zh*(2.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh* ak1p3(ji,jj,jk))
646               zdenom_po4 = ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)     &
647               &            + zh*( ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh*(ak1p3(ji,jj,jk) + zh))
648               zalk_po4   = zpt * (znumer_po4/zdenom_po4 - 1.) ! Zero level of H3PO4 = 1
649               zdnumer_po4 = ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)  &
650               &             + zh*(4.*ak1p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)         &
651               &             + zh*(9.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk)                         &
652               &             + ak1p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)                                &
653               &             + zh*(4.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh * ak1p3(ji,jj,jk) ) ) )
654               zdalk_po4   = -zpt * (zdnumer_po4/zdenom_po4**2)
655
656               ! H4SiO4 - H3SiO4 : n=1, m=0
657               znumer_sil = aksi3(ji,jj,jk)
658               zdenom_sil = aksi3(ji,jj,jk) + zh
659               zalk_sil   = zsit * (znumer_sil/zdenom_sil)
660               zdnumer_sil = aksi3(ji,jj,jk)
661               zdalk_sil   = -zsit * (zdnumer_sil/zdenom_sil**2)
662
663               ! HSO4 - SO4 : n=1, m=1
664               aphscale = 1.0 + zst/aks3(ji,jj,jk)
665               znumer_so4 = aks3(ji,jj,jk) * aphscale
666               zdenom_so4 = aks3(ji,jj,jk) * aphscale + zh
667               zalk_so4   = zst * (znumer_so4/zdenom_so4 - 1.)
668               zdnumer_so4 = aks3(ji,jj,jk)
669               zdalk_so4   = -zst * (zdnumer_so4/zdenom_so4**2)
670
671               ! HF - F : n=1, m=1
672               znumer_flu =  akf3(ji,jj,jk)
673               zdenom_flu =  akf3(ji,jj,jk) + zh
674               zalk_flu   =  zft * (znumer_flu/zdenom_flu - 1.)
675               zdnumer_flu = akf3(ji,jj,jk)
676               zdalk_flu   = -zft * (zdnumer_flu/zdenom_flu**2)
677
678               ! H2O - OH
679               aphscale = 1.0 + zst/aks3(ji,jj,jk)
680               zalk_wat   = akw3(ji,jj,jk)/zh - zh/aphscale
681               zdalk_wat  = -akw3(ji,jj,jk)/zh**2 - 1./aphscale
682
683               ! CALCULATE [ALK]([CO3--], [HCO3-])
684               zeqn = zalk_dic + zalk_bor + zalk_po4 + zalk_sil   &
685               &      + zalk_so4 + zalk_flu                       &
686               &      + zalk_wat - p_alktot
687
688               zalka = p_alktot - (zalk_bor + zalk_po4 + zalk_sil   &
689               &       + zalk_so4 + zalk_flu + zalk_wat)
690
691               zdeqndh = zdalk_dic + zdalk_bor + zdalk_po4 + zdalk_sil &
692               &         + zdalk_so4 + zdalk_flu + zdalk_wat
693
694               ! Adapt bracketing interval
695               IF(zeqn > 0._wp) THEN
696                 zh_min(ji,jj,jk) = zh_prev
697               ELSEIF(zeqn < 0._wp) THEN
698                 zh_max(ji,jj,jk) = zh_prev
699               ENDIF
700
701               IF(ABS(zeqn) >= 0.5_wp*zeqn_absmin(ji,jj,jk)) THEN
702               ! if the function evaluation at the current point is
703               ! not decreasing faster than with a bisection step (at least linearly)
704               ! in absolute value take one bisection step on [ph_min, ph_max]
705               ! ph_new = (ph_min + ph_max)/2d0
706               !
707               ! In terms of [H]_new:
708               ! [H]_new = 10**(-ph_new)
709               !         = 10**(-(ph_min + ph_max)/2d0)
710               !         = SQRT(10**(-(ph_min + phmax)))
711               !         = SQRT(zh_max * zh_min)
712                  zh = SQRT(zh_max(ji,jj,jk) * zh_min(ji,jj,jk))
713                  zh_lnfactor = (zh - zh_prev)/zh_prev ! Required to test convergence below
714               ELSE
715               ! dzeqn/dpH = dzeqn/d[H] * d[H]/dpH
716               !           = -zdeqndh * LOG(10) * [H]
717               ! \Delta pH = -zeqn/(zdeqndh*d[H]/dpH) = zeqn/(zdeqndh*[H]*LOG(10))
718               !
719               ! pH_new = pH_old + \deltapH
720               !
721               ! [H]_new = 10**(-pH_new)
722               !         = 10**(-pH_old - \Delta pH)
723               !         = [H]_old * 10**(-zeqn/(zdeqndh*[H]_old*LOG(10)))
724               !         = [H]_old * EXP(-LOG(10)*zeqn/(zdeqndh*[H]_old*LOG(10)))
725               !         = [H]_old * EXP(-zeqn/(zdeqndh*[H]_old))
726
727                  zh_lnfactor = -zeqn/(zdeqndh*zh_prev)
728
729                  IF(ABS(zh_lnfactor) > pz_exp_threshold) THEN
730                     zh          = zh_prev*EXP(zh_lnfactor)
731                  ELSE
732                     zh_delta    = zh_lnfactor*zh_prev
733                     zh          = zh_prev + zh_delta
734                  ENDIF
735
736                  IF( zh < zh_min(ji,jj,jk) ) THEN
737                     ! if [H]_new < [H]_min
738                     ! i.e., if ph_new > ph_max then
739                     ! take one bisection step on [ph_prev, ph_max]
740                     ! ph_new = (ph_prev + ph_max)/2d0
741                     ! In terms of [H]_new:
742                     ! [H]_new = 10**(-ph_new)
743                     !         = 10**(-(ph_prev + ph_max)/2d0)
744                     !         = SQRT(10**(-(ph_prev + phmax)))
745                     !         = SQRT([H]_old*10**(-ph_max))
746                     !         = SQRT([H]_old * zh_min)
747                     zh                = SQRT(zh_prev * zh_min(ji,jj,jk))
748                     zh_lnfactor       = (zh - zh_prev)/zh_prev ! Required to test convergence below
749                  ENDIF
750
751                  IF( zh > zh_max(ji,jj,jk) ) THEN
752                     ! if [H]_new > [H]_max
753                     ! i.e., if ph_new < ph_min, then
754                     ! take one bisection step on [ph_min, ph_prev]
755                     ! ph_new = (ph_prev + ph_min)/2d0
756                     ! In terms of [H]_new:
757                     ! [H]_new = 10**(-ph_new)
758                     !         = 10**(-(ph_prev + ph_min)/2d0)
759                     !         = SQRT(10**(-(ph_prev + ph_min)))
760                     !         = SQRT([H]_old*10**(-ph_min))
761                     !         = SQRT([H]_old * zhmax)
762                     zh                = SQRT(zh_prev * zh_max(ji,jj,jk))
763                     zh_lnfactor       = (zh - zh_prev)/zh_prev ! Required to test convergence below
764                  ENDIF
765               ENDIF
766
767               zeqn_absmin(ji,jj,jk) = MIN( ABS(zeqn), zeqn_absmin(ji,jj,jk))
768
769               ! Stop iterations once |\delta{[H]}/[H]| < rdel
770               ! <=> |(zh - zh_prev)/zh_prev| = |EXP(-zeqn/(zdeqndh*zh_prev)) -1| < rdel
771               ! |EXP(-zeqn/(zdeqndh*zh_prev)) -1| ~ |zeqn/(zdeqndh*zh_prev)|
772
773               ! Alternatively:
774               ! |\Delta pH| = |zeqn/(zdeqndh*zh_prev*LOG(10))|
775               !             ~ 1/LOG(10) * |\Delta [H]|/[H]
776               !             < 1/LOG(10) * rdel
777
778               ! Hence |zeqn/(zdeqndh*zh)| < rdel
779
780               ! rdel <-- pp_rdel_ah_target
781               l_exitnow = (ABS(zh_lnfactor) < pp_rdel_ah_target)
782
783               IF(l_exitnow) THEN
784                  rmask(ji,jj,jk) = 0.
785               ENDIF
786
787               zhi(ji,jj,jk) =  zh
788
789               IF(jn >= jp_maxniter_atgen) THEN
790                  zhi(ji,jj,jk) = -1._wp
791               ENDIF
792
793            ENDIF
794         END DO
795      END DO
796   END DO
797   END DO
798   !
799
800      IF( ln_timing )   CALL timing_stop('solve_at_general')
801      !
802   END SUBROUTINE solve_at_general
803
804
805   INTEGER FUNCTION p4z_che_alloc()
806      !!----------------------------------------------------------------------
807      !!                     ***  ROUTINE p4z_che_alloc  ***
808      !!----------------------------------------------------------------------
809      INTEGER ::   ierr(3)        ! Local variables
810      !!----------------------------------------------------------------------
811
812      ierr(:) = 0
813
814      ALLOCATE( sio3eq(jpi,jpj,jpk), fekeq(jpi,jpj,jpk), chemc(jpi,jpj,3), chemo2(jpi,jpj,jpk), STAT=ierr(1) )
815
816      ALLOCATE( akb3(jpi,jpj,jpk)     , tempis(jpi, jpj, jpk),       &
817         &      akw3(jpi,jpj,jpk)     , borat (jpi,jpj,jpk)  ,       &
818         &      aks3(jpi,jpj,jpk)     , akf3(jpi,jpj,jpk)    ,       &
819         &      ak1p3(jpi,jpj,jpk)    , ak2p3(jpi,jpj,jpk)   ,       &
820         &      ak3p3(jpi,jpj,jpk)    , aksi3(jpi,jpj,jpk)   ,       &
821         &      fluorid(jpi,jpj,jpk)  , sulfat(jpi,jpj,jpk)  ,       &
822         &      salinprac(jpi,jpj,jpk),                 STAT=ierr(2) )
823
824      ALLOCATE( fesol(jpi,jpj,jpk,5), STAT=ierr(3) )
825
826      !* Variable for chemistry of the CO2 cycle
827      p4z_che_alloc = MAXVAL( ierr )
828      !
829      IF( p4z_che_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_che_alloc : failed to allocate arrays.' )
830      !
831   END FUNCTION p4z_che_alloc
832
833   !!======================================================================
834END MODULE p4zche
Note: See TracBrowser for help on using the repository browser.