New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z/p4zlys.F90 @ 11822

Last change on this file since 11822 was 11822, checked in by acc, 4 years ago

Branch 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. Sette tested updates to branch to align with trunk changes between 10721 and 11740. Sette tests are passing but results differ from branch before these changes (except for GYRE_PISCES and VORTEX) and branch results already differed from trunk because of algorithmic fixes. Will need more checks to confirm correctness.
  • Property svn:keywords set to Id
File size: 8.4 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
14   !!----------------------------------------------------------------------
15   !!   p4z_lys        :   Compute the CaCO3 dissolution
16   !!   p4z_lys_init   :   Read the namelist parameters
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zche          !  Chemical model
22   USE prtctl_trc      !  print control for debugging
23   USE iom             !  I/O manager
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
29   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
30
31   REAL(wp), PUBLIC ::   kdca   !: diss. rate constant calcite
32   REAL(wp), PUBLIC ::   nca    !: order of reaction for calcite dissolution
33
34   INTEGER  ::   rmtss              ! number of seconds per month
35   REAL(wp) ::   calcon = 1.03E-2   ! mean calcite concentration [Ca2+] in sea water [mole/kg solution]
36 
37   !!----------------------------------------------------------------------
38   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
39   !! $Id$
40   !! Software governed by the CeCILL license (see ./LICENSE)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE p4z_lys( kt, knt, Kbb, Krhs )
46      !!---------------------------------------------------------------------
47      !!                     ***  ROUTINE p4z_lys  ***
48      !!
49      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
50      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
51      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
52      !!
53      !! ** Method  : - ???
54      !!---------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step and ???
56      INTEGER, INTENT(in)  ::  Kbb, Krhs ! time level indices
57      !
58      INTEGER  ::   ji, jj, jk, jn
59      REAL(wp) ::   zdispot, zfact, zcalcon
60      REAL(wp) ::   zomegaca, zexcess, zexcess0
61      CHARACTER (len=25) ::   charout
62      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zco3, zcaldiss, zhinit, zhi, zco3sat
63      !!---------------------------------------------------------------------
64      !
65      IF( ln_timing )  CALL timing_start('p4z_lys')
66      !
67      zco3    (:,:,:) = 0.
68      zcaldiss(:,:,:) = 0.
69      zhinit  (:,:,:) = hi(:,:,:) * 1000. / ( rhop(:,:,:) + rtrn )
70      !
71      !     -------------------------------------------
72      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
73      !     -------------------------------------------
74
75      CALL solve_at_general( zhinit, zhi, Kbb )
76
77      DO jk = 1, jpkm1
78         DO jj = 1, jpj
79            DO ji = 1, jpi
80               zco3(ji,jj,jk) = tr(ji,jj,jk,jpdic,Kbb) * ak13(ji,jj,jk) * ak23(ji,jj,jk) / (zhi(ji,jj,jk)**2   &
81                  &             + ak13(ji,jj,jk) * zhi(ji,jj,jk) + ak13(ji,jj,jk) * ak23(ji,jj,jk) + rtrn )
82               hi  (ji,jj,jk) = zhi(ji,jj,jk) * rhop(ji,jj,jk) / 1000.
83            END DO
84         END DO
85      END DO
86
87      !     ---------------------------------------------------------
88      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
89      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
90      !        MGCO3)
91      !     ---------------------------------------------------------
92
93      DO jk = 1, jpkm1
94         DO jj = 1, jpj
95            DO ji = 1, jpi
96
97               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
98               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
99               zcalcon  = calcon * ( salinprac(ji,jj,jk) / 35._wp )
100               zfact    = rhop(ji,jj,jk) / 1000._wp
101               zomegaca = ( zcalcon * zco3(ji,jj,jk) ) / ( aksp(ji,jj,jk) * zfact + rtrn )
102               zco3sat(ji,jj,jk) = aksp(ji,jj,jk) * zfact / ( zcalcon + rtrn )
103
104               ! SET DEGREE OF UNDER-/SUPERSATURATION
105               excess(ji,jj,jk) = 1._wp - zomegaca
106               zexcess0 = MAX( 0., excess(ji,jj,jk) )
107               zexcess  = zexcess0**nca
108
109               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
110               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
111               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
112               zdispot = kdca * zexcess * tr(ji,jj,jk,jpcal,Kbb)
113              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
114              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
115              zcaldiss(ji,jj,jk)  = zdispot * rfact2 / rmtss ! calcite dissolution
116              !
117              tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + 2. * zcaldiss(ji,jj,jk)
118              tr(ji,jj,jk,jpcal,Krhs) = tr(ji,jj,jk,jpcal,Krhs) -      zcaldiss(ji,jj,jk)
119              tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) +      zcaldiss(ji,jj,jk)
120            END DO
121         END DO
122      END DO
123      !
124
125      IF( lk_iomput .AND. knt == nrdttrc ) THEN
126         IF( iom_use( "PH"     ) ) CALL iom_put( "PH"    , -1. * LOG10( MAX( hi(:,:,:), rtrn ) ) * tmask(:,:,:) )
127         IF( iom_use( "CO3"    ) ) CALL iom_put( "CO3"   , zco3(:,:,:)     * 1.e+3               * tmask(:,:,:) )
128         IF( iom_use( "CO3sat" ) ) CALL iom_put( "CO3sat", zco3sat(:,:,:)  * 1.e+3               * tmask(:,:,:) )
129         IF( iom_use( "DCAL"   ) ) CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * 1.e+3 * rfact2r     * tmask(:,:,:) )
130      ENDIF
131      !
132      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
133        WRITE(charout, FMT="('lys ')")
134        CALL prt_ctl_trc_info(charout)
135        CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
136      ENDIF
137      !
138      IF( ln_timing )   CALL timing_stop('p4z_lys')
139      !
140   END SUBROUTINE p4z_lys
141
142
143   SUBROUTINE p4z_lys_init
144      !!----------------------------------------------------------------------
145      !!                  ***  ROUTINE p4z_lys_init  ***
146      !!
147      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
148      !!
149      !! ** Method  :   Read the nampiscal namelist and check the parameters
150      !!      called at the first timestep (nittrc000)
151      !!
152      !! ** input   :   Namelist nampiscal
153      !!
154      !!----------------------------------------------------------------------
155      INTEGER ::   ios   ! Local integer
156      !
157      NAMELIST/nampiscal/ kdca, nca
158      !!----------------------------------------------------------------------
159      IF(lwp) THEN
160         WRITE(numout,*)
161         WRITE(numout,*) 'p4z_lys_init : initialization of CaCO3 dissolution'
162         WRITE(numout,*) '~~~~~~~~~~~~'
163      ENDIF
164      !
165      REWIND( numnatp_ref )              ! Namelist nampiscal in reference namelist : Pisces CaCO3 dissolution
166      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
167901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampiscal in reference namelist' )
168      REWIND( numnatp_cfg )              ! Namelist nampiscal in configuration namelist : Pisces CaCO3 dissolution
169      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
170902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampiscal in configuration namelist' )
171      IF(lwm) WRITE( numonp, nampiscal )
172      !
173      IF(lwp) THEN                         ! control print
174         WRITE(numout,*) '   Namelist : nampiscal'
175         WRITE(numout,*) '      diss. rate constant calcite (per month)        kdca =', kdca
176         WRITE(numout,*) '      order of reaction for calcite dissolution      nca  =', nca
177      ENDIF
178      !
179      ! Number of seconds per month
180      rmtss =  nyear_len(1) * rday / raamo
181      !
182   END SUBROUTINE p4z_lys_init
183
184   !!======================================================================
185END MODULE p4zlys
Note: See TracBrowser for help on using the repository browser.