New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z/p4zprod.F90 @ 11822

Last change on this file since 11822 was 11822, checked in by acc, 4 years ago

Branch 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. Sette tested updates to branch to align with trunk changes between 10721 and 11740. Sette tests are passing but results differ from branch before these changes (except for GYRE_PISCES and VORTEX) and branch results already differed from trunk because of algorithmic fixes. Will need more checks to confirm correctness.
  • Property svn:keywords set to Id
File size: 27.1 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10   !!   p4z_prod       : Compute the growth Rate of the two phytoplanktons groups
11   !!   p4z_prod_init  : Initialization of the parameters for growth
12   !!   p4z_prod_alloc : Allocate variables for growth
13   !!----------------------------------------------------------------------
14   USE oce_trc         ! shared variables between ocean and passive tracers
15   USE trc             ! passive tracers common variables
16   USE sms_pisces      ! PISCES Source Minus Sink variables
17   USE p4zlim          ! Co-limitations of differents nutrients
18   USE prtctl_trc      ! print control for debugging
19   USE iom             ! I/O manager
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_prod         ! called in p4zbio.F90
25   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
26   PUBLIC   p4z_prod_alloc
27
28   REAL(wp), PUBLIC ::   pislopen     !:
29   REAL(wp), PUBLIC ::   pisloped     !:
30   REAL(wp), PUBLIC ::   xadap        !:
31   REAL(wp), PUBLIC ::   excretn      !:
32   REAL(wp), PUBLIC ::   excretd      !:
33   REAL(wp), PUBLIC ::   bresp        !:
34   REAL(wp), PUBLIC ::   chlcnm       !:
35   REAL(wp), PUBLIC ::   chlcdm       !:
36   REAL(wp), PUBLIC ::   chlcmin      !:
37   REAL(wp), PUBLIC ::   fecnm        !:
38   REAL(wp), PUBLIC ::   fecdm        !:
39   REAL(wp), PUBLIC ::   grosip       !:
40
41   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
43   
44   REAL(wp) ::   r1_rday    ! 1 / rday
45   REAL(wp) ::   texcretn   ! 1 - excretn
46   REAL(wp) ::   texcretd   ! 1 - excretd       
47
48   !!----------------------------------------------------------------------
49   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
50   !! $Id$
51   !! Software governed by the CeCILL license (see ./LICENSE)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE p4z_prod( kt , knt, Kbb, Kmm, Krhs )
56      !!---------------------------------------------------------------------
57      !!                     ***  ROUTINE p4z_prod  ***
58      !!
59      !! ** Purpose :   Compute the phytoplankton production depending on
60      !!              light, temperature and nutrient availability
61      !!
62      !! ** Method  : - ???
63      !!---------------------------------------------------------------------
64      INTEGER, INTENT(in) ::   kt, knt   !
65      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
66      !
67      INTEGER  ::   ji, jj, jk
68      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
69      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap, zlim, zsilfac2, zsiborn
70      REAL(wp) ::   zprod, zproreg, zproreg2, zprochln, zprochld
71      REAL(wp) ::   zmaxday, zdocprod, zpislopen, zpisloped
72      REAL(wp) ::   zmxltst, zmxlday
73      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup, chlcnm_n, chlcdm_n
74      REAL(wp) ::   zfact
75      CHARACTER (len=25) :: charout
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zw2d
77      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
78      REAL(wp), DIMENSION(jpi,jpj    ) :: zstrn, zmixnano, zmixdiat
79      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprmaxn,zprmaxd
80      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpislopeadn, zpislopeadd, zysopt 
81      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprdia, zprbio, zprdch, zprnch   
82      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zprorcan, zprorcad, zprofed, zprofen
83      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpronewn, zpronewd
84      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmxl_fac, zmxl_chl
85      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zpligprod1, zpligprod2
86      !!---------------------------------------------------------------------
87      !
88      IF( ln_timing )   CALL timing_start('p4z_prod')
89      !
90      !  Allocate temporary workspace
91      !
92      zprorcan(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp ; zprofed (:,:,:) = 0._wp
93      zprofen (:,:,:) = 0._wp ; zysopt  (:,:,:) = 0._wp
94      zpronewn(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp ; zprdia  (:,:,:) = 0._wp
95      zprbio  (:,:,:) = 0._wp ; zprdch  (:,:,:) = 0._wp ; zprnch  (:,:,:) = 0._wp 
96      zmxl_fac(:,:,:) = 0._wp ; zmxl_chl(:,:,:) = 0._wp 
97
98      ! Computation of the optimal production
99      zprmaxn(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:)
100      zprmaxd(:,:,:) = zprmaxn(:,:,:)
101
102      ! compute the day length depending on latitude and the day
103      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
104      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
105
106      ! day length in hours
107      zstrn(:,:) = 0.
108      DO jj = 1, jpj
109         DO ji = 1, jpi
110            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
111            zargu = MAX( -1., MIN(  1., zargu ) )
112            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
113         END DO
114      END DO
115
116      ! Impact of the day duration and light intermittency on phytoplankton growth
117      DO jk = 1, jpkm1
118         DO jj = 1 ,jpj
119            DO ji = 1, jpi
120               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
121                  zval = MAX( 1., zstrn(ji,jj) )
122                  IF( gdept(ji,jj,jk,Kmm) <= hmld(ji,jj) ) THEN
123                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
124                  ENDIF
125                  zmxl_chl(ji,jj,jk) = zval / 24.
126                  zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
127               ENDIF
128            END DO
129         END DO
130      END DO
131
132      zprbio(:,:,:) = zprmaxn(:,:,:) * zmxl_fac(:,:,:)
133      zprdia(:,:,:) = zprmaxd(:,:,:) * zmxl_fac(:,:,:)
134
135      ! Maximum light intensity
136      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
137
138      ! Computation of the P-I slope for nanos and diatoms
139      DO jk = 1, jpkm1
140         DO jj = 1, jpj
141            DO ji = 1, jpi
142               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
143                  ztn         = MAX( 0., ts(ji,jj,jk,jp_tem,Kmm) - 15. )
144                  zadap       = xadap * ztn / ( 2.+ ztn )
145                  zconctemp   = MAX( 0.e0 , tr(ji,jj,jk,jpdia,Kbb) - xsizedia )
146                  zconctemp2  = tr(ji,jj,jk,jpdia,Kbb) - zconctemp
147                  !
148                  zpislopeadn(ji,jj,jk) = pislopen * ( 1.+ zadap  * EXP( -0.25 * enano(ji,jj,jk) ) )  &
149                  &                   * tr(ji,jj,jk,jpnch,Kbb) /( tr(ji,jj,jk,jpphy,Kbb) * 12. + rtrn)
150                  !
151                  zpislopeadd(ji,jj,jk) = (pislopen * zconctemp2 + pisloped * zconctemp) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )   &
152                  &                   * tr(ji,jj,jk,jpdch,Kbb) /( tr(ji,jj,jk,jpdia,Kbb) * 12. + rtrn)
153               ENDIF
154            END DO
155         END DO
156      END DO
157
158      DO jk = 1, jpkm1
159         DO jj = 1, jpj
160            DO ji = 1, jpi
161               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
162                   ! Computation of production function for Carbon
163                   !  ---------------------------------------------
164                   zpislopen = zpislopeadn(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
165                   &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
166                   zpisloped = zpislopeadd(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) &
167                   &            * zmxl_fac(ji,jj,jk) * rday + rtrn)
168                   zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
169                   zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
170                   !  Computation of production function for Chlorophyll
171                   !--------------------------------------------------
172                   zpislopen = zpislopeadn(ji,jj,jk) / ( zprmaxn(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
173                   zpisloped = zpislopeadd(ji,jj,jk) / ( zprmaxd(ji,jj,jk) * zmxl_chl(ji,jj,jk) * rday + rtrn )
174                   zprnch(ji,jj,jk) = zprmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enanom(ji,jj,jk) ) )
175                   zprdch(ji,jj,jk) = zprmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediatm(ji,jj,jk) ) )
176               ENDIF
177            END DO
178         END DO
179      END DO
180
181      !  Computation of a proxy of the N/C ratio
182      !  ---------------------------------------
183      DO jk = 1, jpkm1
184         DO jj = 1, jpj
185            DO ji = 1, jpi
186                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
187                &      * zprmaxn(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
188                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
189                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
190                &      * zprmaxd(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
191                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
192            END DO
193         END DO
194      END DO
195
196
197      DO jk = 1, jpkm1
198         DO jj = 1, jpj
199            DO ji = 1, jpi
200
201                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
202                   !    Si/C of diatoms
203                   !    ------------------------
204                   !    Si/C increases with iron stress and silicate availability
205                   !    Si/C is arbitrariliy increased for very high Si concentrations
206                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
207                  zlim  = tr(ji,jj,jk,jpsil,Kbb) / ( tr(ji,jj,jk,jpsil,Kbb) + xksi1 )
208                  zsilim = MIN( zprdia(ji,jj,jk) / ( zprmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
209                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
210                  zsiborn = tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb) * tr(ji,jj,jk,jpsil,Kbb)
211                  IF (gphit(ji,jj) < -30 ) THEN
212                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
213                  ELSE
214                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
215                  ENDIF
216                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
217              ENDIF
218            END DO
219         END DO
220      END DO
221
222      !  Mixed-layer effect on production
223      !  Sea-ice effect on production
224
225      DO jk = 1, jpkm1
226         DO jj = 1, jpj
227            DO ji = 1, jpi
228               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
229               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
230            END DO
231         END DO
232      END DO
233
234      ! Computation of the various production terms
235      DO jk = 1, jpkm1
236         DO jj = 1, jpj
237            DO ji = 1, jpi
238               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
239                  !  production terms for nanophyto. (C)
240                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * tr(ji,jj,jk,jpphy,Kbb) * rfact2
241                  zpronewn(ji,jj,jk)  = zprorcan(ji,jj,jk)* xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
242                  !
243                  zratio = tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) * fecnm + rtrn )
244                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
245                  zprofen(ji,jj,jk) = fecnm * zprmaxn(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
246                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
247                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
248                  &             * zmax * tr(ji,jj,jk,jpphy,Kbb) * rfact2
249                  !  production terms for diatoms (C)
250                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * tr(ji,jj,jk,jpdia,Kbb) * rfact2
251                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
252                  !
253                  zratio = tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) * fecdm + rtrn )
254                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
255                  zprofed(ji,jj,jk) = fecdm * zprmaxd(ji,jj,jk) * ( 1.0 - fr_i(ji,jj) )  &
256                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
257                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
258                  &             * zmax * tr(ji,jj,jk,jpdia,Kbb) * rfact2
259               ENDIF
260            END DO
261         END DO
262      END DO
263
264      ! Computation of the chlorophyll production terms
265      DO jk = 1, jpkm1
266         DO jj = 1, jpj
267            DO ji = 1, jpi
268               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
269                  !  production terms for nanophyto. ( chlorophyll )
270                  znanotot = enanom(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
271                  zprod    = rday * zprorcan(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
272                  zprochln = chlcmin * 12. * zprorcan (ji,jj,jk)
273                  chlcnm_n   = MIN ( chlcnm, ( chlcnm / (1. - 1.14 / 43.4 *ts(ji,jj,jk,jp_tem,Kmm))) * (1. - 1.14 / 43.4 * 20.))
274                  zprochln = zprochln + (chlcnm_n-chlcmin) * 12. * zprod / &
275                                        & (  zpislopeadn(ji,jj,jk) * znanotot +rtrn)
276                  !  production terms for diatoms ( chlorophyll )
277                  zdiattot = ediatm(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
278                  zprod    = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
279                  zprochld = chlcmin * 12. * zprorcad(ji,jj,jk)
280                  chlcdm_n   = MIN ( chlcdm, ( chlcdm / (1. - 1.14 / 43.4 * ts(ji,jj,jk,jp_tem,Kmm))) * (1. - 1.14 / 43.4 * 20.))
281                  zprochld = zprochld + (chlcdm_n-chlcmin) * 12. * zprod / &
282                                        & ( zpislopeadd(ji,jj,jk) * zdiattot +rtrn )
283                  !   Update the arrays TRA which contain the Chla sources and sinks
284                  tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) + zprochln * texcretn
285                  tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) + zprochld * texcretd
286               ENDIF
287            END DO
288         END DO
289      END DO
290
291      !   Update the arrays TRA which contain the biological sources and sinks
292      DO jk = 1, jpkm1
293         DO jj = 1, jpj
294           DO ji =1 ,jpi
295              IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
296                 zproreg  = zprorcan(ji,jj,jk) - zpronewn(ji,jj,jk)
297                 zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
298                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
299                 tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
300                 tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)
301                 tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) - zproreg - zproreg2
302                 tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) + zprorcan(ji,jj,jk) * texcretn
303                 tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) + zprofen(ji,jj,jk) * texcretn
304                 tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) + zprorcad(ji,jj,jk) * texcretd
305                 tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) + zprofed(ji,jj,jk) * texcretd
306                 tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
307                 tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zdocprod
308                 tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + o2ut * ( zproreg + zproreg2) &
309                 &                   + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) )
310                 !
311                 zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
312                 tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zfeup
313                 tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
314                 tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk)
315                 tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
316                 &                                         - rno3 * ( zproreg + zproreg2 )
317              ENDIF
318           END DO
319        END DO
320     END DO
321     !
322     IF( ln_ligand ) THEN
323         zpligprod1(:,:,:) = 0._wp    ;    zpligprod2(:,:,:) = 0._wp
324         DO jk = 1, jpkm1
325            DO jj = 1, jpj
326              DO ji =1 ,jpi
327                 IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
328                    zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)
329                    zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk)
330                    tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
331                    zpligprod1(ji,jj,jk) = zdocprod * ldocp
332                    zpligprod2(ji,jj,jk) = zfeup * plig(ji,jj,jk) * lthet
333                 ENDIF
334              END DO
335           END DO
336        END DO
337     ENDIF
338
339
340    ! Total primary production per year
341    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
342         & tpp = glob_sum( 'p4zprod', ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
343
344    IF( lk_iomput ) THEN
345       IF( knt == nrdttrc ) THEN
346          ALLOCATE( zw2d(jpi,jpj), zw3d(jpi,jpj,jpk) )
347          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
348          !
349          IF( iom_use( "PPPHYN" ) .OR. iom_use( "PPPHYD" ) )  THEN
350              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
351              CALL iom_put( "PPPHYN"  , zw3d )
352              !
353              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
354              CALL iom_put( "PPPHYD"  , zw3d )
355          ENDIF
356          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
357              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
358              CALL iom_put( "PPNEWN"  , zw3d )
359              !
360              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
361              CALL iom_put( "PPNEWD"  , zw3d )
362          ENDIF
363          IF( iom_use( "PBSi" ) )  THEN
364              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
365              CALL iom_put( "PBSi"  , zw3d )
366          ENDIF
367          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
368              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
369              CALL iom_put( "PFeN"  , zw3d )
370              !
371              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
372              CALL iom_put( "PFeD"  , zw3d )
373          ENDIF
374          IF( iom_use( "LPRODP" ) )  THEN
375              zw3d(:,:,:) = zpligprod1(:,:,:) * 1e9 * zfact * tmask(:,:,:)
376              CALL iom_put( "LPRODP"  , zw3d )
377          ENDIF
378          IF( iom_use( "LDETP" ) )  THEN
379              zw3d(:,:,:) = zpligprod2(:,:,:) * 1e9 * zfact * tmask(:,:,:)
380              CALL iom_put( "LDETP"  , zw3d )
381          ENDIF
382          IF( iom_use( "Mumax" ) )  THEN
383              zw3d(:,:,:) = zprmaxn(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
384              CALL iom_put( "Mumax"  , zw3d )
385          ENDIF
386          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
387              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
388              CALL iom_put( "MuN"  , zw3d )
389              !
390              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
391              CALL iom_put( "MuD"  , zw3d )
392          ENDIF
393          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
394              zw3d(:,:,:) = zprbio (:,:,:) / (zprmaxn(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
395              CALL iom_put( "LNlight"  , zw3d )
396              !
397              zw3d(:,:,:) = zprdia (:,:,:) / (zprmaxd(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
398              CALL iom_put( "LDlight"  , zw3d )
399          ENDIF
400          IF( iom_use( "TPP" ) )  THEN
401              zw3d(:,:,:) = ( zprorcan(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
402              CALL iom_put( "TPP"  , zw3d )
403          ENDIF
404          IF( iom_use( "TPNEW" ) )  THEN
405              zw3d(:,:,:) = ( zpronewn(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
406              CALL iom_put( "TPNEW"  , zw3d )
407          ENDIF
408          IF( iom_use( "TPBFE" ) )  THEN
409              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
410              CALL iom_put( "TPBFE"  , zw3d )
411          ENDIF
412          IF( iom_use( "INTPPPHYN" ) .OR. iom_use( "INTPPPHYD" ) ) THEN 
413             zw2d(:,:) = 0.
414             DO jk = 1, jpkm1
415               zw2d(:,:) = zw2d(:,:) + zprorcan(:,:,jk) * e3t(:,:,jk,Kmm) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
416             ENDDO
417             CALL iom_put( "INTPPPHYN" , zw2d )
418             !
419             zw2d(:,:) = 0.
420             DO jk = 1, jpkm1
421                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * e3t(:,:,jk,Kmm) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
422             ENDDO
423             CALL iom_put( "INTPPPHYD" , zw2d )
424          ENDIF
425          IF( iom_use( "INTPP" ) ) THEN   
426             zw2d(:,:) = 0.
427             DO jk = 1, jpkm1
428                zw2d(:,:) = zw2d(:,:) + ( zprorcan(:,:,jk) + zprorcad(:,:,jk) ) * e3t(:,:,jk,Kmm) * zfact * tmask(:,:,jk) ! vert. integrated pp
429             ENDDO
430             CALL iom_put( "INTPP" , zw2d )
431          ENDIF
432          IF( iom_use( "INTPNEW" ) ) THEN   
433             zw2d(:,:) = 0.
434             DO jk = 1, jpkm1
435                zw2d(:,:) = zw2d(:,:) + ( zpronewn(:,:,jk) + zpronewd(:,:,jk) ) * e3t(:,:,jk,Kmm) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
436             ENDDO
437             CALL iom_put( "INTPNEW" , zw2d )
438          ENDIF
439          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
440             zw2d(:,:) = 0.
441             DO jk = 1, jpkm1
442                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * e3t(:,:,jk,Kmm) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
443             ENDDO
444            CALL iom_put( "INTPBFE" , zw2d )
445          ENDIF
446          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
447             zw2d(:,:) = 0.
448             DO jk = 1, jpkm1
449                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * e3t(:,:,jk,Kmm) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
450             ENDDO
451             CALL iom_put( "INTPBSI" , zw2d )
452          ENDIF
453          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
454          !
455          DEALLOCATE( zw2d, zw3d )
456       ENDIF
457     ENDIF
458
459     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
460         WRITE(charout, FMT="('prod')")
461         CALL prt_ctl_trc_info(charout)
462         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
463     ENDIF
464      !
465      IF( ln_timing )  CALL timing_stop('p4z_prod')
466      !
467   END SUBROUTINE p4z_prod
468
469
470   SUBROUTINE p4z_prod_init
471      !!----------------------------------------------------------------------
472      !!                  ***  ROUTINE p4z_prod_init  ***
473      !!
474      !! ** Purpose :   Initialization of phytoplankton production parameters
475      !!
476      !! ** Method  :   Read the nampisprod namelist and check the parameters
477      !!      called at the first timestep (nittrc000)
478      !!
479      !! ** input   :   Namelist nampisprod
480      !!----------------------------------------------------------------------
481      INTEGER ::   ios   ! Local integer
482      !
483      NAMELIST/namp4zprod/ pislopen, pisloped, xadap, bresp, excretn, excretd,  &
484         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
485      !!----------------------------------------------------------------------
486      !
487      IF(lwp) THEN                         ! control print
488         WRITE(numout,*)
489         WRITE(numout,*) 'p4z_prod_init : phytoplankton growth'
490         WRITE(numout,*) '~~~~~~~~~~~~~'
491      ENDIF
492      !
493      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
494      READ  ( numnatp_ref, namp4zprod, IOSTAT = ios, ERR = 901)
495901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zprod in reference namelist' )
496      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
497      READ  ( numnatp_cfg, namp4zprod, IOSTAT = ios, ERR = 902 )
498902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zprod in configuration namelist' )
499      IF(lwm) WRITE( numonp, namp4zprod )
500
501      IF(lwp) THEN                         ! control print
502         WRITE(numout,*) '   Namelist : namp4zprod'
503         WRITE(numout,*) '      mean Si/C ratio                           grosip       =', grosip
504         WRITE(numout,*) '      P-I slope                                 pislopen     =', pislopen
505         WRITE(numout,*) '      Acclimation factor to low light           xadap        =', xadap
506         WRITE(numout,*) '      excretion ratio of nanophytoplankton      excretn      =', excretn
507         WRITE(numout,*) '      excretion ratio of diatoms                excretd      =', excretd
508         WRITE(numout,*) '      basal respiration in phytoplankton        bresp        =', bresp
509         WRITE(numout,*) '      Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
510         WRITE(numout,*) '      P-I slope  for diatoms                    pisloped     =', pisloped
511         WRITE(numout,*) '      Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
512         WRITE(numout,*) '      Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
513         WRITE(numout,*) '      Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
514         WRITE(numout,*) '      Minimum Fe/C in diatoms                   fecdm        =', fecdm
515      ENDIF
516      !
517      r1_rday   = 1._wp / rday 
518      texcretn  = 1._wp - excretn
519      texcretd  = 1._wp - excretd
520      tpp       = 0._wp
521      !
522   END SUBROUTINE p4z_prod_init
523
524
525   INTEGER FUNCTION p4z_prod_alloc()
526      !!----------------------------------------------------------------------
527      !!                     ***  ROUTINE p4z_prod_alloc  ***
528      !!----------------------------------------------------------------------
529      ALLOCATE( quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
530      !
531      IF( p4z_prod_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p4z_prod_alloc : failed to allocate arrays.' )
532      !
533   END FUNCTION p4z_prod_alloc
534
535   !!======================================================================
536END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.