New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z/p4zsed.F90 @ 10975

Last change on this file since 10975 was 10975, checked in by acc, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Finish converting all TOP routines and knock-on effects of these conversions. Fully SETTE tested (SETTE tests 1-6 and 9). This completes the first stage conversion of TRA and TOP but need to revisit and pass ts and tr arrays through the argument lists where appropriate.
  • Property svn:keywords set to Id
File size: 26.1 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11   !!   p4z_sed        :  Compute loss of organic matter in the sediments
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Co-limitations of differents nutrients
17   USE p4zsbc          !  External source of nutrients
18   USE p4zint          !  interpolation and computation of various fields
19   USE sed             !  Sediment module
20   USE iom             !  I/O manager
21   USE prtctl_trc      !  print control for debugging
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_sed 
27   PUBLIC   p4z_sed_alloc
28 
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
31   REAL(wp) :: r1_rday                  !: inverse of rday
32   LOGICAL, SAVE :: lk_sed
33
34   !!----------------------------------------------------------------------
35   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE p4z_sed( kt, knt, Kbb, Kmm, Krhs )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE p4z_sed  ***
44      !!
45      !! ** Purpose :   Compute loss of organic matter in the sediments. This
46      !!              is by no way a sediment model. The loss is simply
47      !!              computed to balance the inout from rivers and dust
48      !!
49      !! ** Method  : - ???
50      !!---------------------------------------------------------------------
51      !
52      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
53      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
54      INTEGER  ::  ji, jj, jk, ikt
55      REAL(wp) ::  zrivalk, zrivsil, zrivno3
56      REAL(wp) ::  zwflux, zfminus, zfplus
57      REAL(wp) ::  zlim, zfact, zfactcal
58      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zolimit
59      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep
60      REAL(wp) ::  zwstpoc, zwstpon, zwstpop
61      REAL(wp) ::  ztrfer, ztrpo4s, ztrdp, zwdust, zmudia, ztemp
62      REAL(wp) ::  xdiano3, xdianh4
63      !
64      CHARACTER (len=25) :: charout
65      REAL(wp), DIMENSION(jpi,jpj    ) :: zdenit2d, zbureff, zwork
66      REAL(wp), DIMENSION(jpi,jpj    ) :: zwsbio3, zwsbio4
67      REAL(wp), DIMENSION(jpi,jpj    ) :: zsedcal, zsedsi, zsedc
68      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zsoufer, zlight
69      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrpo4, ztrdop, zirondep, zpdep
70      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zsidep, zironice
71      !!---------------------------------------------------------------------
72      !
73      IF( ln_timing )  CALL timing_start('p4z_sed')
74      !
75      IF( kt == nittrc000 .AND. knt == 1 )   THEN
76          r1_rday  = 1. / rday
77          IF (ln_sediment .AND. ln_sed_2way) THEN
78             lk_sed = .TRUE.
79          ELSE
80             lk_sed = .FALSE.
81          ENDIF
82      ENDIF
83      !
84      IF( kt == nittrc000 .AND. knt == 1 )   r1_rday  = 1. / rday
85      !
86      ! Allocate temporary workspace
87      ALLOCATE( ztrpo4(jpi,jpj,jpk) )
88      IF( ln_p5z )    ALLOCATE( ztrdop(jpi,jpj,jpk) )
89
90      zdenit2d(:,:) = 0.e0
91      zbureff (:,:) = 0.e0
92      zwork   (:,:) = 0.e0
93      zsedsi  (:,:) = 0.e0
94      zsedcal (:,:) = 0.e0
95      zsedc   (:,:) = 0.e0
96
97      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
98      ! ----------------------------------------------------
99      IF( ln_ironice ) THEN 
100         !                                             
101         ALLOCATE( zironice(jpi,jpj) )
102         !                                             
103         DO jj = 1, jpj
104            DO ji = 1, jpi
105               zdep    = rfact2 / e3t(ji,jj,1,Kmm)
106               zwflux  = fmmflx(ji,jj) / 1000._wp
107               zfminus = MIN( 0._wp, -zwflux ) * tr(ji,jj,1,jpfer,Kbb) * zdep
108               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
109               zironice(ji,jj) =  zfplus + zfminus
110            END DO
111         END DO
112         !
113         tr(:,:,1,jpfer,Krhs) = tr(:,:,1,jpfer,Krhs) + zironice(:,:) 
114         !
115         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironice" ) )   &
116            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * e3t(:,:,1,Kmm) * tmask(:,:,1) ) ! iron flux from ice
117         !
118         DEALLOCATE( zironice )
119         !                                             
120      ENDIF
121
122      ! Add the external input of nutrients from dust deposition
123      ! ----------------------------------------------------------
124      IF( ln_dust ) THEN
125         !                                             
126         ALLOCATE( zsidep(jpi,jpj), zpdep(jpi,jpj,jpk), zirondep(jpi,jpj,jpk) )
127         !                                              ! Iron and Si deposition at the surface
128         IF( ln_solub ) THEN
129            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / e3t(:,:,1,Kmm) / 55.85 + 3.e-10 * r1_ryyss 
130         ELSE
131            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / e3t(:,:,1,Kmm) / 55.85 + 3.e-10 * r1_ryyss 
132         ENDIF
133         zsidep(:,:)   = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / e3t(:,:,1,Kmm) / 28.1 
134         zpdep (:,:,1) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / e3t(:,:,1,Kmm) / 31. / po4r 
135         !                                              ! Iron solubilization of particles in the water column
136         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
137         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
138         DO jk = 2, jpkm1
139            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -gdept(:,:,jk,Kmm) / 540. )
140            zpdep   (:,:,jk) = zirondep(:,:,jk) * 0.023
141         END DO
142         !                                              ! Iron solubilization of particles in the water column
143         tr(:,:,1,jpsil,Krhs) = tr(:,:,1,jpsil,Krhs) + zsidep  (:,:)
144         DO jk = 1, jpkm1
145            tr(:,:,jk,jppo4,Krhs) = tr(:,:,jk,jppo4,Krhs) + zpdep   (:,:,jk)
146            tr(:,:,jk,jpfer,Krhs) = tr(:,:,jk,jpfer,Krhs) + zirondep(:,:,jk) 
147         ENDDO
148         !
149         IF( lk_iomput ) THEN
150            IF( knt == nrdttrc ) THEN
151                IF( iom_use( "Irondep" ) )   &
152                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * e3t(:,:,1,Kmm) * tmask(:,:,1) ) ! surface downward dust depo of iron
153                IF( iom_use( "pdust" ) )   &
154                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
155            ENDIF
156         ENDIF
157         DEALLOCATE( zsidep, zpdep, zirondep )
158         !                                             
159      ENDIF
160     
161      ! Add the external input of nutrients from river
162      ! ----------------------------------------------------------
163      IF( ln_river ) THEN
164         DO jj = 1, jpj
165            DO ji = 1, jpi
166               DO jk = 1, nk_rnf(ji,jj)
167                  tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) +  rivdip(ji,jj) * rfact2
168                  tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) +  rivdin(ji,jj) * rfact2
169                  tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) +  rivdic(ji,jj) * 5.e-5 * rfact2
170                  tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) +  rivdsi(ji,jj) * rfact2
171                  tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) +  rivdic(ji,jj) * rfact2
172                  tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) +  ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2
173                  tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) +  rivdoc(ji,jj) * rfact2
174               ENDDO
175            ENDDO
176         ENDDO
177         IF (ln_ligand) THEN
178            DO jj = 1, jpj
179               DO ji = 1, jpi
180                  DO jk = 1, nk_rnf(ji,jj)
181                     tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) +  rivdic(ji,jj) * 5.e-5 * rfact2
182                  ENDDO
183               ENDDO
184            ENDDO
185         ENDIF
186         IF( ln_p5z ) THEN
187            DO jj = 1, jpj
188               DO ji = 1, jpi
189                  DO jk = 1, nk_rnf(ji,jj)
190                     tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) + rivdop(ji,jj) * rfact2
191                     tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) + rivdon(ji,jj) * rfact2
192                  ENDDO
193               ENDDO
194            ENDDO
195         ENDIF
196      ENDIF
197     
198      ! Add the external input of nutrients from nitrogen deposition
199      ! ----------------------------------------------------------
200      IF( ln_ndepo ) THEN
201         tr(:,:,1,jpno3,Krhs) = tr(:,:,1,jpno3,Krhs) + nitdep(:,:) * rfact2
202         tr(:,:,1,jptal,Krhs) = tr(:,:,1,jptal,Krhs) - rno3 * nitdep(:,:) * rfact2
203      ENDIF
204
205      ! Add the external input of iron from hydrothermal vents
206      ! ------------------------------------------------------
207      IF( ln_hydrofe ) THEN
208            tr(:,:,:,jpfer,Krhs) = tr(:,:,:,jpfer,Krhs) + hydrofe(:,:,:) * rfact2
209         IF( ln_ligand ) THEN
210            tr(:,:,:,jplgw,Krhs) = tr(:,:,:,jplgw,Krhs) + ( hydrofe(:,:,:) * lgw_rath ) * rfact2
211         ENDIF
212         !
213         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "HYDR" ) )   &
214            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
215      ENDIF
216
217      ! OA: Warning, the following part is necessary to avoid CFL problems above the sediments
218      ! --------------------------------------------------------------------
219      DO jj = 1, jpj
220         DO ji = 1, jpi
221            ikt  = mbkt(ji,jj)
222            zdep = e3t(ji,jj,ikt,Kmm) / xstep
223            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
224            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
225         END DO
226      END DO
227      !
228      IF( .NOT.lk_sed ) THEN
229!
230         ! Add the external input of iron from sediment mobilization
231         ! ------------------------------------------------------
232         IF( ln_ironsed ) THEN
233                            tr(:,:,:,jpfer,Krhs) = tr(:,:,:,jpfer,Krhs) + ironsed(:,:,:) * rfact2
234            !
235            IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
236               &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
237         ENDIF
238
239         ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
240         ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
241         ! -------------------------------------------------------
242         DO jj = 1, jpj
243            DO ji = 1, jpi
244              IF( tmask(ji,jj,1) == 1 ) THEN
245                 ikt = mbkt(ji,jj)
246                 zflx = (  tr(ji,jj,ikt,jpgoc,Kbb) * zwsbio4(ji,jj)   &
247                   &     + tr(ji,jj,ikt,jppoc,Kbb) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
248                 zflx  = LOG10( MAX( 1E-3, zflx ) )
249                 zo2   = LOG10( MAX( 10. , tr(ji,jj,ikt,jpoxy,Kbb) * 1E6 ) )
250                 zno3  = LOG10( MAX( 1.  , tr(ji,jj,ikt,jpno3,Kbb) * 1E6 * rno3 ) )
251                 zdep  = LOG10( gdepw(ji,jj,ikt+1,Kmm) )
252                 zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
253                   &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
254                 zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
255                   !
256                 zflx = (  tr(ji,jj,ikt,jpgoc,Kbb) * zwsbio4(ji,jj)   &
257                   &     + tr(ji,jj,ikt,jppoc,Kbb) * zwsbio3(ji,jj) ) * 1E6
258                 zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
259              ENDIF
260            END DO
261         END DO 
262         !
263      ENDIF
264
265      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
266      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
267      ! ------------------------------------------------------
268      IF( .NOT.lk_sed )  zrivsil = 1._wp - sedsilfrac
269
270      DO jj = 1, jpj
271         DO ji = 1, jpi
272            ikt  = mbkt(ji,jj)
273            zdep = xstep / e3t(ji,jj,ikt,Kmm) 
274            zwsc = zwsbio4(ji,jj) * zdep
275            zsiloss = tr(ji,jj,ikt,jpgsi,Kbb) * zwsc
276            zcaloss = tr(ji,jj,ikt,jpcal,Kbb) * zwsc
277            !
278            tr(ji,jj,ikt,jpgsi,Krhs) = tr(ji,jj,ikt,jpgsi,Krhs) - zsiloss
279            tr(ji,jj,ikt,jpcal,Krhs) = tr(ji,jj,ikt,jpcal,Krhs) - zcaloss
280         END DO
281      END DO
282      !
283      IF( .NOT.lk_sed ) THEN
284         DO jj = 1, jpj
285            DO ji = 1, jpi
286               ikt  = mbkt(ji,jj)
287               zdep = xstep / e3t(ji,jj,ikt,Kmm) 
288               zwsc = zwsbio4(ji,jj) * zdep
289               zsiloss = tr(ji,jj,ikt,jpgsi,Kbb) * zwsc
290               zcaloss = tr(ji,jj,ikt,jpcal,Kbb) * zwsc
291               tr(ji,jj,ikt,jpsil,Krhs) = tr(ji,jj,ikt,jpsil,Krhs) + zsiloss * zrivsil 
292               !
293               zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
294               zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
295               zrivalk  = sedcalfrac * zfactcal
296               tr(ji,jj,ikt,jptal,Krhs) =  tr(ji,jj,ikt,jptal,Krhs) + zcaloss * zrivalk * 2.0
297               tr(ji,jj,ikt,jpdic,Krhs) =  tr(ji,jj,ikt,jpdic,Krhs) + zcaloss * zrivalk
298               zsedcal(ji,jj) = (1.0 - zrivalk) * zcaloss * e3t(ji,jj,ikt,Kmm) 
299               zsedsi (ji,jj) = (1.0 - zrivsil) * zsiloss * e3t(ji,jj,ikt,Kmm) 
300            END DO
301         END DO
302      ENDIF
303      !
304      DO jj = 1, jpj
305         DO ji = 1, jpi
306            ikt  = mbkt(ji,jj)
307            zdep = xstep / e3t(ji,jj,ikt,Kmm) 
308            zws4 = zwsbio4(ji,jj) * zdep
309            zws3 = zwsbio3(ji,jj) * zdep
310            tr(ji,jj,ikt,jpgoc,Krhs) = tr(ji,jj,ikt,jpgoc,Krhs) - tr(ji,jj,ikt,jpgoc,Kbb) * zws4 
311            tr(ji,jj,ikt,jppoc,Krhs) = tr(ji,jj,ikt,jppoc,Krhs) - tr(ji,jj,ikt,jppoc,Kbb) * zws3
312            tr(ji,jj,ikt,jpbfe,Krhs) = tr(ji,jj,ikt,jpbfe,Krhs) - tr(ji,jj,ikt,jpbfe,Kbb) * zws4
313            tr(ji,jj,ikt,jpsfe,Krhs) = tr(ji,jj,ikt,jpsfe,Krhs) - tr(ji,jj,ikt,jpsfe,Kbb) * zws3
314         END DO
315      END DO
316      !
317      IF( ln_p5z ) THEN
318         DO jj = 1, jpj
319            DO ji = 1, jpi
320               ikt  = mbkt(ji,jj)
321               zdep = xstep / e3t(ji,jj,ikt,Kmm) 
322               zws4 = zwsbio4(ji,jj) * zdep
323               zws3 = zwsbio3(ji,jj) * zdep
324               tr(ji,jj,ikt,jpgon,Krhs) = tr(ji,jj,ikt,jpgon,Krhs) - tr(ji,jj,ikt,jpgon,Kbb) * zws4
325               tr(ji,jj,ikt,jppon,Krhs) = tr(ji,jj,ikt,jppon,Krhs) - tr(ji,jj,ikt,jppon,Kbb) * zws3
326               tr(ji,jj,ikt,jpgop,Krhs) = tr(ji,jj,ikt,jpgop,Krhs) - tr(ji,jj,ikt,jpgop,Kbb) * zws4
327               tr(ji,jj,ikt,jppop,Krhs) = tr(ji,jj,ikt,jppop,Krhs) - tr(ji,jj,ikt,jppop,Kbb) * zws3
328            END DO
329         END DO
330      ENDIF
331
332      IF( .NOT.lk_sed ) THEN
333         ! The 0.5 factor in zpdenit is to avoid negative NO3 concentration after
334         ! denitrification in the sediments. Not very clever, but simpliest option.
335         DO jj = 1, jpj
336            DO ji = 1, jpi
337               ikt  = mbkt(ji,jj)
338               zdep = xstep / e3t(ji,jj,ikt,Kmm) 
339               zws4 = zwsbio4(ji,jj) * zdep
340               zws3 = zwsbio3(ji,jj) * zdep
341               zrivno3 = 1. - zbureff(ji,jj)
342               zwstpoc = tr(ji,jj,ikt,jpgoc,Kbb) * zws4 + tr(ji,jj,ikt,jppoc,Kbb) * zws3
343               zpdenit  = MIN( 0.5 * ( tr(ji,jj,ikt,jpno3,Kbb) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
344               z1pdenit = zwstpoc * zrivno3 - zpdenit
345               zolimit = MIN( ( tr(ji,jj,ikt,jpoxy,Kbb) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
346               tr(ji,jj,ikt,jpdoc,Krhs) = tr(ji,jj,ikt,jpdoc,Krhs) + z1pdenit - zolimit
347               tr(ji,jj,ikt,jppo4,Krhs) = tr(ji,jj,ikt,jppo4,Krhs) + zpdenit + zolimit
348               tr(ji,jj,ikt,jpnh4,Krhs) = tr(ji,jj,ikt,jpnh4,Krhs) + zpdenit + zolimit
349               tr(ji,jj,ikt,jpno3,Krhs) = tr(ji,jj,ikt,jpno3,Krhs) - rdenit * zpdenit
350               tr(ji,jj,ikt,jpoxy,Krhs) = tr(ji,jj,ikt,jpoxy,Krhs) - zolimit * o2ut
351               tr(ji,jj,ikt,jptal,Krhs) = tr(ji,jj,ikt,jptal,Krhs) + rno3 * (zolimit + (1.+rdenit) * zpdenit )
352               tr(ji,jj,ikt,jpdic,Krhs) = tr(ji,jj,ikt,jpdic,Krhs) + zpdenit + zolimit 
353               sdenit(ji,jj) = rdenit * zpdenit * e3t(ji,jj,ikt,Kmm)
354               zsedc(ji,jj)   = (1. - zrivno3) * zwstpoc * e3t(ji,jj,ikt,Kmm)
355               IF( ln_p5z ) THEN
356                  zwstpop              = tr(ji,jj,ikt,jpgop,Kbb) * zws4 + tr(ji,jj,ikt,jppop,Kbb) * zws3
357                  zwstpon              = tr(ji,jj,ikt,jpgon,Kbb) * zws4 + tr(ji,jj,ikt,jppon,Kbb) * zws3
358                  tr(ji,jj,ikt,jpdon,Krhs) = tr(ji,jj,ikt,jpdon,Krhs) + ( z1pdenit - zolimit ) * zwstpon / (zwstpoc + rtrn)
359                  tr(ji,jj,ikt,jpdop,Krhs) = tr(ji,jj,ikt,jpdop,Krhs) + ( z1pdenit - zolimit ) * zwstpop / (zwstpoc + rtrn)
360               ENDIF
361            END DO
362         END DO
363       ENDIF
364
365
366      ! Nitrogen fixation process
367      ! Small source iron from particulate inorganic iron
368      !-----------------------------------
369      DO jk = 1, jpkm1
370         zlight (:,:,jk) =  ( 1.- EXP( -etot_ndcy(:,:,jk) / diazolight ) ) * ( 1. - fr_i(:,:) ) 
371         zsoufer(:,:,jk) = zlight(:,:,jk) * 2E-11 / ( 2E-11 + biron(:,:,jk) )
372      ENDDO
373      IF( ln_p4z ) THEN
374         DO jk = 1, jpkm1
375            DO jj = 1, jpj
376               DO ji = 1, jpi
377                  !                      ! Potential nitrogen fixation dependant on temperature and iron
378                  ztemp = ts(ji,jj,jk,jp_tem,Kmm)
379                  zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
380                  !       Potential nitrogen fixation dependant on temperature and iron
381                  xdianh4 = tr(ji,jj,jk,jpnh4,Kbb) / ( concnnh4 + tr(ji,jj,jk,jpnh4,Kbb) )
382                  xdiano3 = tr(ji,jj,jk,jpno3,Kbb) / ( concnno3 + tr(ji,jj,jk,jpno3,Kbb) ) * (1. - xdianh4)
383                  zlim = ( 1.- xdiano3 - xdianh4 )
384                  IF( zlim <= 0.1 )   zlim = 0.01
385                  zfact = zlim * rfact2
386                  ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
387                  ztrpo4(ji,jj,jk) = tr(ji,jj,jk,jppo4,Kbb) / ( 1E-6 + tr(ji,jj,jk,jppo4,Kbb) )
388                  ztrdp = ztrpo4(ji,jj,jk)
389                  nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
390               END DO
391            END DO
392         END DO
393      ELSE       ! p5z
394         DO jk = 1, jpkm1
395            DO jj = 1, jpj
396               DO ji = 1, jpi
397                  !                      ! Potential nitrogen fixation dependant on temperature and iron
398                  ztemp = ts(ji,jj,jk,jp_tem,Kmm)
399                  zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
400                  !       Potential nitrogen fixation dependant on temperature and iron
401                  xdianh4 = tr(ji,jj,jk,jpnh4,Kbb) / ( concnnh4 + tr(ji,jj,jk,jpnh4,Kbb) )
402                  xdiano3 = tr(ji,jj,jk,jpno3,Kbb) / ( concnno3 + tr(ji,jj,jk,jpno3,Kbb) ) * (1. - xdianh4)
403                  zlim = ( 1.- xdiano3 - xdianh4 )
404                  IF( zlim <= 0.1 )   zlim = 0.01
405                  zfact = zlim * rfact2
406                  ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
407                  ztrpo4(ji,jj,jk) = tr(ji,jj,jk,jppo4,Kbb) / ( 1E-6 + tr(ji,jj,jk,jppo4,Kbb) )
408                  ztrdop(ji,jj,jk) = tr(ji,jj,jk,jpdop,Kbb) / ( 1E-6 + tr(ji,jj,jk,jpdop,Kbb) ) * (1. - ztrpo4(ji,jj,jk))
409                  ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk)
410                  nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
411               END DO
412            END DO
413         END DO
414      ENDIF
415
416      ! Nitrogen change due to nitrogen fixation
417      ! ----------------------------------------
418      IF( ln_p4z ) THEN
419         DO jk = 1, jpkm1
420            DO jj = 1, jpj
421               DO ji = 1, jpi
422                  zfact = nitrpot(ji,jj,jk) * nitrfix
423                  tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zfact / 3.0
424                  tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zfact / 3.0
425                  tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - zfact * 2.0 / 3.0
426                  tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zfact * 1.0 / 3.0
427                  tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zfact * 1.0 / 3.0 * 2.0 / 3.0
428                  tr(ji,jj,jk,jpgoc,Krhs) = tr(ji,jj,jk,jpgoc,Krhs) + zfact * 1.0 / 3.0 * 1.0 / 3.0
429                  tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
430                  tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - 30E-6 * zfact * 1.0 / 3.0
431                  tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
432                  tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
433                  tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
434                  tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + concdnh4 / ( concdnh4 + tr(ji,jj,jk,jppo4,Kbb) ) &
435                  &                     * 0.001 * tr(ji,jj,jk,jpdoc,Kbb) * xstep
436              END DO
437            END DO
438         END DO
439      ELSE    ! p5z
440         DO jk = 1, jpkm1
441            DO jj = 1, jpj
442               DO ji = 1, jpi
443                  zfact = nitrpot(ji,jj,jk) * nitrfix
444                  tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zfact / 3.0
445                  tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zfact / 3.0
446                  tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) &
447                  &                     * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
448                  tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) + zfact * 1.0 / 3.0
449                  tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zfact * 1.0 / 3.0
450                  tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) + 16.0 / 46.0 * zfact / 3.0  &
451                  &                     - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk)   &
452                  &                     / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
453                  tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zfact * 1.0 / 3.0 * 2.0 / 3.0
454                  tr(ji,jj,jk,jppon,Krhs) = tr(ji,jj,jk,jppon,Krhs) + zfact * 1.0 / 3.0 * 2.0 /3.0
455                  tr(ji,jj,jk,jppop,Krhs) = tr(ji,jj,jk,jppop,Krhs) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0
456                  tr(ji,jj,jk,jpgoc,Krhs) = tr(ji,jj,jk,jpgoc,Krhs) + zfact * 1.0 / 3.0 * 1.0 / 3.0
457                  tr(ji,jj,jk,jpgon,Krhs) = tr(ji,jj,jk,jpgon,Krhs) + zfact * 1.0 / 3.0 * 1.0 /3.0
458                  tr(ji,jj,jk,jpgop,Krhs) = tr(ji,jj,jk,jpgop,Krhs) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0
459                  tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
460                  tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - 30E-6 * zfact * 1.0 / 3.0 
461                  tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
462                  tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
463                  tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
464              END DO
465            END DO
466         END DO
467         !
468      ENDIF
469
470      IF( lk_iomput ) THEN
471         IF( knt == nrdttrc ) THEN
472            zfact = 1.e+3 * rfact2r !  conversion from molC/l/kt  to molN/m3/s
473            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
474            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
475               zwork(:,:) = 0.
476               DO jk = 1, jpkm1
477                 zwork(:,:) = zwork(:,:) + nitrpot(:,:,jk) * nitrfix * rno3 * zfact * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
478               ENDDO
479               CALL iom_put( "INTNFIX" , zwork ) 
480            ENDIF
481            IF( iom_use("SedCal" ) ) CALL iom_put( "SedCal", zsedcal(:,:) * zfact )
482            IF( iom_use("SedSi" ) )  CALL iom_put( "SedSi",  zsedsi (:,:) * zfact )
483            IF( iom_use("SedC" ) )   CALL iom_put( "SedC",   zsedc  (:,:) * zfact )
484            IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", sdenit (:,:) * zfact * rno3 )
485         ENDIF
486      ENDIF
487      !
488      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
489         WRITE(charout, fmt="('sed ')")
490         CALL prt_ctl_trc_info(charout)
491         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
492      ENDIF
493      !
494      IF( ln_p5z )    DEALLOCATE( ztrpo4, ztrdop )
495      !
496      IF( ln_timing )  CALL timing_stop('p4z_sed')
497      !
498   END SUBROUTINE p4z_sed
499
500
501   INTEGER FUNCTION p4z_sed_alloc()
502      !!----------------------------------------------------------------------
503      !!                     ***  ROUTINE p4z_sed_alloc  ***
504      !!----------------------------------------------------------------------
505      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc )
506      !
507      IF( p4z_sed_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_alloc: failed to allocate arrays' )
508      !
509   END FUNCTION p4z_sed_alloc
510
511   !!======================================================================
512END MODULE p4zsed
Note: See TracBrowser for help on using the repository browser.