New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zmicro.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z/p5zmicro.F90 @ 10975

Last change on this file since 10975 was 10975, checked in by acc, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Finish converting all TOP routines and knock-on effects of these conversions. Fully SETTE tested (SETTE tests 1-6 and 9). This completes the first stage conversion of TRA and TOP but need to revisit and pass ts and tr arrays through the argument lists where appropriate.
  • Property svn:keywords set to Id
File size: 23.1 KB
Line 
1MODULE p5zmicro
2   !!======================================================================
3   !!                         ***  MODULE p5zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_micro       :   Compute the sources/sinks for microzooplankton
12   !!   p5z_micro_init  :   Initialize and read the appropriate namelist
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zlim
18   USE p5zlim          !  Phytoplankton limitation terms
19   USE iom             !  I/O manager
20   USE prtctl_trc      !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p5z_micro         ! called in p5zbio.F90
26   PUBLIC   p5z_micro_init    ! called in trcsms_pisces.F90
27
28   !! * Shared module variables
29   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
30   REAL(wp), PUBLIC ::  xprefc     !: microzoo preference for POC
31   REAL(wp), PUBLIC ::  xprefn     !: microzoo preference for nanophyto
32   REAL(wp), PUBLIC ::  xprefp     !: microzoo preference for picophyto
33   REAL(wp), PUBLIC ::  xprefd     !: microzoo preference for diatoms
34   REAL(wp), PUBLIC ::  xprefz     !: microzoo preference for microzoo
35   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::  xthreshpic  !: picophyto feeding threshold for microzooplankton
37   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
38   REAL(wp), PUBLIC ::  xthreshzoo  !: microzoo threshold for microzooplankton
39   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
40   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
41   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
42   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
43   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
44   REAL(wp), PUBLIC ::  xkgraz      !: Half-saturation constant of assimilation
45   REAL(wp), PUBLIC ::  unassc      !: Non-assimilated part of food
46   REAL(wp), PUBLIC ::  unassn      !: Non-assimilated part of food
47   REAL(wp), PUBLIC ::  unassp      !: Non-assimilated part of food
48   REAL(wp), PUBLIC ::  epsher      !: Growth efficiency for microzoo
49   REAL(wp), PUBLIC ::  epshermin   !: Minimum growth efficiency for microzoo
50   REAL(wp), PUBLIC ::  srespir     !: half sturation constant for grazing 1
51   REAL(wp), PUBLIC ::  ssigma      !: Fraction excreted as semi-labile DOM
52   LOGICAL,  PUBLIC ::  bmetexc     !: Use of excess carbon for respiration
53
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p5z_micro( kt, knt, Kbb, Krhs )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p5z_micro  ***
65      !!
66      !! ** Purpose :   Compute the sources/sinks for microzooplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in) ::  kt  ! ocean time step
71      INTEGER, INTENT(in) ::  knt 
72      INTEGER, INTENT(in) ::  Kbb, Krhs      ! time level indices
73      !
74      INTEGER  :: ji, jj, jk
75      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc, zcompapon, zcompapop
76      REAL(wp) :: zcompapi, zgraze  , zdenom, zfact, zfood, zfoodlim
77      REAL(wp) :: ztmp1, ztmp2, ztmp3, ztmp4, ztmp5, ztmptot
78      REAL(wp) :: zepsherf, zepshert, zepsherv, zrespirc, zrespirn, zrespirp, zbasresb, zbasresi
79      REAL(wp) :: zgraztotc, zgraztotn, zgraztotp, zgraztotf, zbasresn, zbasresp, zbasresf
80      REAL(wp) :: zgradoc, zgradon, zgradop, zgraref, zgradoct, zgradont, zgradopt, zgrareft
81      REAL(wp) :: zexcess, zgraren, zgrarep, zgrarem
82      REAL(wp) :: zgrapoc, zgrapon, zgrapop, zgrapof, zprcaca, zmortz
83      REAL(wp) :: zrespz, ztortz, zgrasratf, zgrasratn, zgrasratp
84      REAL(wp) :: zgraznc, zgraznn, zgraznp, zgrazpoc, zgrazpon, zgrazpop, zgrazpof
85      REAL(wp) :: zgrazdc, zgrazdn, zgrazdp, zgrazdf, zgraznf, zgrazz
86      REAL(wp) :: zgrazpc, zgrazpn, zgrazpp, zgrazpf, zbeta, zrfact2, zmetexcess
87      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo
88      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d, zzligprod
89      CHARACTER (len=25) :: charout
90      !!---------------------------------------------------------------------
91      !
92      IF( ln_timing )   CALL timing_start('p5z_micro')
93      !
94      IF (ln_ligand) THEN
95         ALLOCATE( zzligprod(jpi,jpj,jpk) )
96         zzligprod(:,:,:) = 0._wp
97      ENDIF
98      !
99      zmetexcess = 0.0
100      IF ( bmetexc ) zmetexcess = 1.0
101      !
102      DO jk = 1, jpkm1
103         DO jj = 1, jpj
104            DO ji = 1, jpi
105               zcompaz = MAX( ( tr(ji,jj,jk,jpzoo,Kbb) - 1.e-9 ), 0.e0 )
106               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
107
108               !   Michaelis-Menten mortality rates of microzooplankton
109               !   -----------------------------------------------------
110               zrespz = resrat * zfact * ( tr(ji,jj,jk,jpzoo,Kbb) / ( xkmort + tr(ji,jj,jk,jpzoo,Kbb) )  &
111               &        + 3. * nitrfac(ji,jj,jk) )
112
113               !   Zooplankton mortality. A square function has been selected with
114               !   no real reason except that it seems to be more stable and may mimic predation.
115               !   ------------------------------------------------------------------------------
116               ztortz = mzrat * 1.e6 * zfact * tr(ji,jj,jk,jpzoo,Kbb) * (1. - nitrfac(ji,jj,jk))
117
118               !   Computation of the abundance of the preys
119               !   A threshold can be specified in the namelist
120               !   --------------------------------------------
121               zcompadi  = MIN( MAX( ( tr(ji,jj,jk,jpdia,Kbb) - xthreshdia ), 0.e0 ), xsizedia )
122               zcompaph  = MAX( ( tr(ji,jj,jk,jpphy,Kbb) - xthreshphy ), 0.e0 )
123               zcompaz   = MAX( ( tr(ji,jj,jk,jpzoo,Kbb) - xthreshzoo ), 0.e0 )
124               zcompapi  = MAX( ( tr(ji,jj,jk,jppic,Kbb) - xthreshpic ), 0.e0 )
125               zcompapoc = MAX( ( tr(ji,jj,jk,jppoc,Kbb) - xthreshpoc ), 0.e0 )
126               
127               !   Microzooplankton grazing
128               !   ------------------------
129               zfood     = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi   &
130               &           + xprefz * zcompaz + xprefp * zcompapi
131               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
132               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
133               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpzoo,Kbb) * (1. - nitrfac(ji,jj,jk)) 
134
135               !   An active switching parameterization is used here.
136               !   We don't use the KTW parameterization proposed by
137               !   Vallina et al. because it tends to produce to steady biomass
138               !   composition and the variance of Chl is too low as it grazes
139               !   too strongly on winning organisms. Thus, instead of a square
140               !   a 1.5 power value is used which decreases the pressure on the
141               !   most abundant species
142               !   ------------------------------------------------------------ 
143               ztmp1 = xprefn * zcompaph**1.5
144               ztmp2 = xprefp * zcompapi**1.5
145               ztmp3 = xprefc * zcompapoc**1.5
146               ztmp4 = xprefd * zcompadi**1.5
147               ztmp5 = xprefz * zcompaz**1.5
148               ztmptot = ztmp1 + ztmp2 + ztmp3 + ztmp4 + ztmp5 + rtrn
149               ztmp1 = ztmp1 / ztmptot
150               ztmp2 = ztmp2 / ztmptot
151               ztmp3 = ztmp3 / ztmptot
152               ztmp4 = ztmp4 / ztmptot
153               ztmp5 = ztmp5 / ztmptot
154
155               !   Microzooplankton regular grazing on the different preys
156               !   -------------------------------------------------------
157               zgraznc   = zgraze  * ztmp1  * zdenom
158               zgraznn   = zgraznc * tr(ji,jj,jk,jpnph,Kbb) / (tr(ji,jj,jk,jpphy,Kbb) + rtrn)
159               zgraznp   = zgraznc * tr(ji,jj,jk,jppph,Kbb) / (tr(ji,jj,jk,jpphy,Kbb) + rtrn)
160               zgraznf   = zgraznc * tr(ji,jj,jk,jpnfe,Kbb) / (tr(ji,jj,jk,jpphy,Kbb) + rtrn)
161               zgrazpc   = zgraze  * ztmp2  * zdenom
162               zgrazpn   = zgrazpc * tr(ji,jj,jk,jpnpi,Kbb) / (tr(ji,jj,jk,jppic,Kbb) + rtrn)
163               zgrazpp   = zgrazpc * tr(ji,jj,jk,jpppi,Kbb) / (tr(ji,jj,jk,jppic,Kbb) + rtrn)
164               zgrazpf   = zgrazpc * tr(ji,jj,jk,jppfe,Kbb) / (tr(ji,jj,jk,jppic,Kbb) + rtrn)
165               zgrazz    = zgraze  * ztmp5   * zdenom
166               zgrazpoc  = zgraze  * ztmp3   * zdenom
167               zgrazpon  = zgrazpoc * tr(ji,jj,jk,jppon,Kbb) / ( tr(ji,jj,jk,jppoc,Kbb) + rtrn )
168               zgrazpop  = zgrazpoc * tr(ji,jj,jk,jppop,Kbb) / ( tr(ji,jj,jk,jppoc,Kbb) + rtrn )
169               zgrazpof  = zgrazpoc* tr(ji,jj,jk,jpsfe,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + rtrn)
170               zgrazdc   = zgraze  * ztmp4  * zdenom
171               zgrazdn   = zgrazdc * tr(ji,jj,jk,jpndi,Kbb) / (tr(ji,jj,jk,jpdia,Kbb) + rtrn)
172               zgrazdp   = zgrazdc * tr(ji,jj,jk,jppdi,Kbb) / (tr(ji,jj,jk,jpdia,Kbb) + rtrn)
173               zgrazdf   = zgrazdc * tr(ji,jj,jk,jpdfe,Kbb) / (tr(ji,jj,jk,jpdia,Kbb) + rtrn)
174               !
175               zgraztotc = zgraznc + zgrazpoc + zgrazdc + zgrazz + zgrazpc
176               zgraztotn = zgraznn + zgrazpn + zgrazpon + zgrazdn + zgrazz * no3rat3
177               zgraztotp = zgraznp + zgrazpp + zgrazpop + zgrazdp + zgrazz * po4rat3
178               zgraztotf = zgraznf + zgrazpf + zgrazpof + zgrazdf + zgrazz * ferat3
179               !
180               ! Grazing by microzooplankton
181               zgrazing(ji,jj,jk) = zgraztotc
182
183               !   Stoichiometruc ratios of the food ingested by zooplanton
184               !   --------------------------------------------------------
185               zgrasratf =  (zgraztotf + rtrn) / ( zgraztotc + rtrn )
186               zgrasratn =  (zgraztotn + rtrn) / ( zgraztotc + rtrn )
187               zgrasratp =  (zgraztotp + rtrn) / ( zgraztotc + rtrn )
188
189               !   Growth efficiency is made a function of the quality
190               !   and the quantity of the preys
191               !   ---------------------------------------------------
192               zepshert  = MIN( 1., zgrasratn/ no3rat3, zgrasratp/ po4rat3, zgrasratf / ferat3)
193               zbeta     = MAX( 0., (epsher - epshermin) )
194               zepsherf  = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
195               zepsherv  = zepsherf * zepshert
196
197               !   Respiration of microzooplankton
198               !   Excess carbon in the food is used preferentially
199               !   ------------------------------------------------
200               zexcess  = zgraztotc * zepsherf * (1.0 - zepshert) * zmetexcess
201               zbasresb = MAX(0., zrespz - zexcess)
202               zbasresi = zexcess + MIN(0., zrespz - zexcess) 
203               zrespirc = srespir * zepsherv * zgraztotc + zbasresb
204               
205               !   When excess carbon is used, the other elements in excess
206               !   are also used proportionally to their abundance
207               !   --------------------------------------------------------
208               zexcess  = ( zgrasratn/ no3rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
209               zbasresn = zbasresi * zexcess * zgrasratn 
210               zexcess  = ( zgrasratp/ po4rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
211               zbasresp = zbasresi * zexcess * zgrasratp
212               zexcess  = ( zgrasratf/ ferat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
213               zbasresf = zbasresi * zexcess * zgrasratf
214
215               !   Voiding of the excessive elements as DOM
216               !   ----------------------------------------
217               zgradoct   = (1. - unassc - zepsherv) * zgraztotc - zbasresi 
218               zgradont   = (1. - unassn) * zgraztotn - zepsherv * no3rat3 * zgraztotc - zbasresn
219               zgradopt   = (1. - unassp) * zgraztotp - zepsherv * po4rat3 * zgraztotc - zbasresp
220               zgrareft   = (1. - unassc) * zgraztotf - zepsherv * ferat3 * zgraztotc - zbasresf
221
222               !  Since only semilabile DOM is represented in PISCES
223               !  part of DOM is in fact labile and is then released
224               !  as dissolved inorganic compounds (ssigma)
225               !  --------------------------------------------------
226               zgradoc =  zgradoct * ssigma
227               zgradon =  zgradont * ssigma
228               zgradop =  zgradopt * ssigma
229               zgrarem = (1.0 - ssigma) * zgradoct
230               zgraren = (1.0 - ssigma) * zgradont
231               zgrarep = (1.0 - ssigma) * zgradopt
232               zgraref = zgrareft
233
234               !   Defecation as a result of non assimilated products
235               !   --------------------------------------------------
236               zgrapoc   = zgraztotc * unassc
237               zgrapon   = zgraztotn * unassn
238               zgrapop   = zgraztotp * unassp
239               zgrapof   = zgraztotf * unassc
240
241               !  Addition of respiration to the release of inorganic nutrients
242               !  -------------------------------------------------------------
243               zgrarem = zgrarem + zbasresi + zrespirc
244               zgraren = zgraren + zbasresn + zrespirc * no3rat3
245               zgrarep = zgrarep + zbasresp + zrespirc * po4rat3
246               zgraref = zgraref + zbasresf + zrespirc * ferat3
247
248               !   Update of the TRA arrays
249               !   ------------------------
250               tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zgrarep
251               tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zgraren
252               tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zgradoc
253               !
254               IF( ln_ligand ) THEN
255                  tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + zgradoc * ldocz
256                  zzligprod(ji,jj,jk) = zgradoc * ldocz
257               ENDIF
258               !
259               tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) + zgradon
260               tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) + zgradop
261               tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2ut * zgrarem 
262               tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + zgraref
263               zfezoo(ji,jj,jk)    = zgraref
264               tr(ji,jj,jk,jpzoo,Krhs) = tr(ji,jj,jk,jpzoo,Krhs) + zepsherv * zgraztotc - zrespirc - ztortz - zgrazz
265               tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) - zgraznc
266               tr(ji,jj,jk,jpnph,Krhs) = tr(ji,jj,jk,jpnph,Krhs) - zgraznn
267               tr(ji,jj,jk,jppph,Krhs) = tr(ji,jj,jk,jppph,Krhs) - zgraznp
268               tr(ji,jj,jk,jppic,Krhs) = tr(ji,jj,jk,jppic,Krhs) - zgrazpc
269               tr(ji,jj,jk,jpnpi,Krhs) = tr(ji,jj,jk,jpnpi,Krhs) - zgrazpn
270               tr(ji,jj,jk,jpppi,Krhs) = tr(ji,jj,jk,jpppi,Krhs) - zgrazpp
271               tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) - zgrazdc
272               tr(ji,jj,jk,jpndi,Krhs) = tr(ji,jj,jk,jpndi,Krhs) - zgrazdn
273               tr(ji,jj,jk,jppdi,Krhs) = tr(ji,jj,jk,jppdi,Krhs) - zgrazdp
274               tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) - zgraznc * tr(ji,jj,jk,jpnch,Kbb)/(tr(ji,jj,jk,jpphy,Kbb)+rtrn)
275               tr(ji,jj,jk,jppch,Krhs) = tr(ji,jj,jk,jppch,Krhs) - zgrazpc * tr(ji,jj,jk,jppch,Kbb)/(tr(ji,jj,jk,jppic,Kbb)+rtrn)
276               tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) - zgrazdc * tr(ji,jj,jk,jpdch,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn)
277               tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) - zgrazdc * tr(ji,jj,jk,jpdsi,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn)
278               tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) + zgrazdc * tr(ji,jj,jk,jpdsi,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn)
279               tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) - zgraznf
280               tr(ji,jj,jk,jppfe,Krhs) = tr(ji,jj,jk,jppfe,Krhs) - zgrazpf
281               tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) - zgrazdf
282               tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + ztortz + zgrapoc - zgrazpoc 
283               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + ztortz + zgrapoc
284               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc
285               tr(ji,jj,jk,jppon,Krhs) = tr(ji,jj,jk,jppon,Krhs) + no3rat3 * ztortz + zgrapon - zgrazpon
286               tr(ji,jj,jk,jppop,Krhs) = tr(ji,jj,jk,jppop,Krhs) + po4rat3 * ztortz + zgrapop - zgrazpop
287               tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + ferat3 * ztortz  + zgrapof - zgrazpof
288               !
289               ! calcite production
290               zprcaca = xfracal(ji,jj,jk) * zgraznc
291               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
292               !
293               zprcaca = part * zprcaca
294               tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrarem - zprcaca
295               tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) - 2. * zprcaca     &
296               &                     + rno3 * zgraren
297               tr(ji,jj,jk,jpcal,Krhs) = tr(ji,jj,jk,jpcal,Krhs) + zprcaca
298            END DO
299         END DO
300      END DO
301      !
302      IF( lk_iomput ) THEN
303         IF( knt == nrdttrc ) THEN
304            ALLOCATE( zw3d(jpi,jpj,jpk) )
305            IF( iom_use( "GRAZ1" ) ) THEN
306               zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
307               CALL iom_put( "GRAZ1", zw3d )
308            ENDIF
309            IF( iom_use( "FEZOO" ) ) THEN
310               zw3d(:,:,:) = zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
311               CALL iom_put( "FEZOO", zw3d )
312            ENDIF
313            IF( iom_use( "LPRODZ" ) .AND. ln_ligand )  THEN
314               zw3d(:,:,:) = zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
315               CALL iom_put( "LPRODZ"  , zw3d )
316            ENDIF
317            DEALLOCATE( zw3d )
318         ENDIF
319      ENDIF
320      !
321      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
322         WRITE(charout, FMT="('micro')")
323         CALL prt_ctl_trc_info(charout)
324         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
325      ENDIF
326      !
327      IF( ln_timing )   CALL timing_stop('p5z_micro')
328      !
329   END SUBROUTINE p5z_micro
330
331
332   SUBROUTINE p5z_micro_init
333      !!----------------------------------------------------------------------
334      !!                  ***  ROUTINE p5z_micro_init  ***
335      !!
336      !! ** Purpose :   Initialization of microzooplankton parameters
337      !!
338      !! ** Method  :   Read the nampiszoo namelist and check the parameters
339      !!                called at the first timestep (nittrc000)
340      !!
341      !! ** input   :   Namelist nampiszoo
342      !!
343      !!----------------------------------------------------------------------
344      INTEGER ::   ios   ! Local integer
345      !!
346      NAMELIST/namp5zzoo/ part, grazrat, bmetexc, resrat, mzrat, xprefc, xprefn, &
347         &                xprefp, xprefd, xprefz, xthreshdia, xthreshphy, &
348         &                xthreshpic, xthreshpoc, xthreshzoo, xthresh, xkgraz, &
349         &                epsher, epshermin, ssigma, srespir, unassc, unassn, unassp
350      !!----------------------------------------------------------------------
351      !
352      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
353      READ  ( numnatp_ref, namp5zzoo, IOSTAT = ios, ERR = 901)
354901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zzoo in reference namelist', lwp )
355      !
356      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
357      READ  ( numnatp_cfg, namp5zzoo, IOSTAT = ios, ERR = 902 )
358902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namp5zzoo in configuration namelist', lwp )
359      IF(lwm) WRITE ( numonp, namp5zzoo )
360      !
361      IF(lwp) THEN                         ! control print
362         WRITE(numout,*) ' '
363         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszooq'
364         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
365         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
366         WRITE(numout,*) '    microzoo preference for POC                     xprefc     =', xprefc
367         WRITE(numout,*) '    microzoo preference for nano                    xprefn     =', xprefn
368         WRITE(numout,*) '    microzoo preference for pico                    xprefp     =', xprefp
369         WRITE(numout,*) '    microzoo preference for diatoms                 xprefd     =', xprefd
370         WRITE(numout,*) '    microzoo preference for microzoo                xprefz     =', xprefz
371         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
372         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
373         WRITE(numout,*) '    picophyto feeding threshold for microzoo        xthreshpic  =', xthreshpic
374         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
375         WRITE(numout,*) '    microzoo feeding threshold for microzoo         xthreshzoo  =', xthreshzoo
376         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
377         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
378         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
379         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
380         WRITE(numout,*) '    C egested fraction of fodd by microzoo          unassc      =', unassc
381         WRITE(numout,*) '    N egested fraction of fodd by microzoo          unassn      =', unassn
382         WRITE(numout,*) '    P egested fraction of fodd by microzoo          unassp      =', unassp
383         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
384         WRITE(numout,*) '    Minimum Efficiency of Microzoo growth           epshermin   =', epshermin
385         WRITE(numout,*) '    Fraction excreted as semi-labile DOM            ssigma      =', ssigma
386         WRITE(numout,*) '    Active respiration                              srespir     =', srespir
387         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
388         WRITE(numout,*) '    Use of excess carbon for respiration            bmetexc     =', bmetexc
389      ENDIF
390      !
391   END SUBROUTINE p5z_micro_init
392
393   !!======================================================================
394END MODULE p5zmicro
Note: See TracBrowser for help on using the repository browser.