source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/TRP/trcrad.F90 @ 10985

Last change on this file since 10985 was 10985, checked in by acc, 18 months ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : interface changes to tra and trc routines for design compliance and consistency. Fully SETTE tested (non-AGRIF, only)

  • Property svn:keywords set to Id
File size: 15.2 KB
Line 
1MODULE trcrad
2   !!======================================================================
3   !!                       ***  MODULE  trcrad  ***
4   !! Ocean passive tracers:  correction of negative concentrations
5   !!======================================================================
6   !! History :   -   !  01-01  (O. Aumont & E. Kestenare)  Original code
7   !!            1.0  !  04-03  (C. Ethe)  free form F90
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!   trc_rad    : correction of negative concentrations
14   !!----------------------------------------------------------------------
15   USE par_trc             ! need jptra, number of passive tracers
16   USE oce_trc             ! ocean dynamics and tracers variables
17   USE trc                 ! ocean passive tracers variables
18   USE trd_oce
19   USE trdtra
20   USE prtctl_trc          ! Print control for debbuging
21   USE lib_fortran
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC trc_rad     
27   PUBLIC trc_rad_ini 
28
29   LOGICAL , PUBLIC ::   ln_trcrad           !: flag to artificially correct negative concentrations
30   REAL(wp), DIMENSION(:,:), ALLOCATABLE::   gainmass
31
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE trc_rad( kt, Kbb, Kmm, Krhs, ptr )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE trc_rad  ***
42      !!
43      !! ** Purpose :   "crappy" routine to correct artificial negative
44      !!              concentrations due to isopycnal scheme
45      !!
46      !! ** Method  : - PISCES or LOBSTER: Set negative concentrations to zero
47      !!                while computing the corresponding tracer content that
48      !!                is added to the tracers. Then, adjust the tracer
49      !!                concentration using a multiplicative factor so that
50      !!                the total tracer concentration is preserved.
51      !!              - CFC: simply set to zero the negative CFC concentration
52      !!                (the total CFC content is not strictly preserved)
53      !!----------------------------------------------------------------------
54      INTEGER,                                    INTENT(in   ) :: kt              ! ocean time-step index
55      INTEGER,                                    INTENT(in   ) :: Kbb, Kmm, Krhs  ! time level indices
56      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr             ! passive tracers and RHS of tracer equation
57      !
58      CHARACTER (len=22) :: charout
59      !!----------------------------------------------------------------------
60      !
61      IF( ln_timing )   CALL timing_start('trc_rad')
62      !
63      IF( ln_age     )   CALL trc_rad_sms( kt, Kmm, Krhs, ptr(:,:,:,:,Kbb), ptr(:,:,:,:,Kmm), jp_age , jp_age                )  !  AGE
64      IF( ll_cfc     )   CALL trc_rad_sms( kt, Kmm, Krhs, ptr(:,:,:,:,Kbb), ptr(:,:,:,:,Kmm), jp_cfc0, jp_cfc1               )  !  CFC model
65      IF( ln_c14     )   CALL trc_rad_sms( kt, Kmm, Krhs, ptr(:,:,:,:,Kbb), ptr(:,:,:,:,Kmm), jp_c14 , jp_c14                )  !  C14
66      IF( ln_pisces  )   CALL trc_rad_sms( kt, Kmm, Krhs, ptr(:,:,:,:,Kbb), ptr(:,:,:,:,Kmm), jp_pcs0, jp_pcs1, cpreserv='Y' )  !  PISCES model
67      IF( ln_my_trc  )   CALL trc_rad_sms( kt, Kmm, Krhs, ptr(:,:,:,:,Kbb), ptr(:,:,:,:,Kmm), jp_myt0, jp_myt1               )  !  MY_TRC model
68      !
69      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
70         WRITE(charout, FMT="('rad')")
71         CALL prt_ctl_trc_info( charout )
72         CALL prt_ctl_trc( tab4d=ptr(:,:,:,:,Kmm), mask=tmask, clinfo=ctrcnm )
73      ENDIF
74      !
75      IF( ln_timing )   CALL timing_stop('trc_rad')
76      !
77   END SUBROUTINE trc_rad
78
79
80   SUBROUTINE trc_rad_ini
81      !!---------------------------------------------------------------------
82      !!                  ***  ROUTINE trc _rad_ini ***
83      !!
84      !! ** Purpose :   read  namelist options
85      !!----------------------------------------------------------------------
86      INTEGER ::   ios   ! Local integer output status for namelist read
87      !!
88      NAMELIST/namtrc_rad/ ln_trcrad
89      !!----------------------------------------------------------------------
90      !
91      REWIND( numnat_ref )              ! namtrc_rad in reference namelist
92      READ  ( numnat_ref, namtrc_rad, IOSTAT = ios, ERR = 907)
93907   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_rad in reference namelist', lwp )
94      REWIND( numnat_cfg )              ! namtrc_rad in configuration namelist
95      READ  ( numnat_cfg, namtrc_rad, IOSTAT = ios, ERR = 908 )
96908   IF( ios > 0 )   CALL ctl_nam ( ios , 'namtrc_rad in configuration namelist', lwp )
97      IF(lwm) WRITE( numont, namtrc_rad )
98
99      IF(lwp) THEN                     !   ! Control print
100         WRITE(numout,*)
101         WRITE(numout,*) 'trc_rad : Correct artificial negative concentrations '
102         WRITE(numout,*) '~~~~~~~ '
103         WRITE(numout,*) '   Namelist namtrc_rad : treatment of negative concentrations'
104         WRITE(numout,*) '      correct artificially negative concen. or not   ln_trcrad = ', ln_trcrad
105         WRITE(numout,*)
106         IF( ln_trcrad ) THEN   ;   WRITE(numout,*) '      ===>>   ensure the global tracer conservation'
107         ELSE                   ;   WRITE(numout,*) '      ===>>   NO strict global tracer conservation'     
108         ENDIF
109      ENDIF
110      !
111      ALLOCATE( gainmass(jptra,2) )
112      gainmass(:,:) = 0.
113      !
114   END SUBROUTINE trc_rad_ini
115
116
117   SUBROUTINE trc_rad_sms( kt, Kmm, Krhs, ptrb, ptrn, jp_sms0, jp_sms1, cpreserv )
118      !!-----------------------------------------------------------------------------
119      !!                  ***  ROUTINE trc_rad_sms  ***
120      !!
121      !! ** Purpose :   "crappy" routine to correct artificial negative
122      !!              concentrations due to isopycnal scheme
123      !!
124      !! ** Method  : 2 cases :
125      !!                - Set negative concentrations to zero while computing
126      !!                  the corresponding tracer content that is added to the
127      !!                  tracers. Then, adjust the tracer concentration using
128      !!                  a multiplicative factor so that the total tracer
129      !!                  concentration is preserved.
130      !!                - simply set to zero the negative CFC concentration
131      !!                  (the total content of concentration is not strictly preserved)
132      !!--------------------------------------------------------------------------------
133      INTEGER                                , INTENT(in   ) ::   kt                 ! ocean time-step index
134      INTEGER                                , INTENT(in   ) ::   Kmm, Krhs          ! time level indices
135      INTEGER                                , INTENT(in   ) ::   jp_sms0, jp_sms1   ! First & last index of the passive tracer model
136      REAL(wp), DIMENSION (jpi,jpj,jpk,jptra), INTENT(inout) ::   ptrb    , ptrn     ! before and now traceur concentration
137      CHARACTER( len = 1), OPTIONAL          , INTENT(in   ) ::   cpreserv           ! flag to preserve content or not
138      !
139      INTEGER ::   ji, ji2, jj, jj2, jk, jn     ! dummy loop indices
140      INTEGER ::   icnt
141      LOGICAL ::   lldebug = .FALSE.            ! local logical
142      REAL(wp)::   zcoef, zs2rdt, ztotmass
143      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrneg, ztrpos
144      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrtrd   ! workspace arrays
145      !!----------------------------------------------------------------------
146      !
147      IF( l_trdtrc )   ALLOCATE( ztrtrd(jpi,jpj,jpk) )
148      zs2rdt = 1. / ( 2. * rdt * REAL( nn_dttrc, wp ) )
149      !
150      IF( PRESENT( cpreserv )  ) THEN     !==  total tracer concentration is preserved  ==!
151         !
152         ALLOCATE( ztrneg(1:jpi,1:jpj,jp_sms0:jp_sms1), ztrpos(1:jpi,1:jpj,jp_sms0:jp_sms1) )
153
154         DO jn = jp_sms0, jp_sms1
155            ztrneg(:,:,jn) = SUM( MIN( 0., ptrb(:,:,:,jn) ) * cvol(:,:,:), dim = 3 )   ! sum of the negative values
156            ztrpos(:,:,jn) = SUM( MAX( 0., ptrb(:,:,:,jn) ) * cvol(:,:,:), dim = 3 )   ! sum of the positive values
157         END DO
158         CALL sum3x3( ztrneg )
159         CALL sum3x3( ztrpos )
160         
161         DO jn = jp_sms0, jp_sms1
162            !
163            IF( l_trdtrc )   ztrtrd(:,:,:) = ptrb(:,:,:,jn)                            ! save input tr(:,:,:,:,Kbb) for trend computation           
164            !
165            DO jk = 1, jpkm1
166               DO jj = 1, jpj
167                  DO ji = 1, jpi
168                     IF( ztrneg(ji,jj,jn) /= 0. ) THEN                                 ! if negative values over the 3x3 box
169                        !
170                        ptrb(ji,jj,jk,jn) = ptrb(ji,jj,jk,jn) * tmask(ji,jj,jk)   ! really needed?
171                        IF( ptrb(ji,jj,jk,jn) < 0. ) ptrb(ji,jj,jk,jn) = 0.       ! supress negative values
172                        IF( ptrb(ji,jj,jk,jn) > 0. ) THEN                         ! use positive values to compensate mass gain
173                           zcoef = 1. + ztrneg(ji,jj,jn) / ztrpos(ji,jj,jn)       ! ztrpos > 0 as ptrb > 0
174                           ptrb(ji,jj,jk,jn) = ptrb(ji,jj,jk,jn) * zcoef
175                           IF( zcoef < 0. ) THEN                                  ! if the compensation exceed the positive value
176                              gainmass(jn,1) = gainmass(jn,1) - ptrb(ji,jj,jk,jn) * cvol(ji,jj,jk)   ! we are adding mass...
177                              ptrb(ji,jj,jk,jn) = 0.                              ! limit the compensation to keep positive value
178                           ENDIF
179                        ENDIF
180                        !
181                     ENDIF
182                  END DO
183               END DO
184            END DO
185            !
186            IF( l_trdtrc ) THEN
187               ztrtrd(:,:,:) = ( ptrb(:,:,:,jn) - ztrtrd(:,:,:) ) * zs2rdt
188               CALL trd_tra( kt, Kmm, Krhs, 'TRC', jn, jptra_radb, ztrtrd )       ! Asselin-like trend handling
189            ENDIF
190            !
191         END DO
192 
193         IF( kt == nitend ) THEN
194            CALL mpp_sum( 'trcrad', gainmass(:,1) )
195            DO jn = jp_sms0, jp_sms1
196               IF( gainmass(jn,1) > 0. ) THEN
197                  ztotmass = glob_sum( 'trcrad', ptrb(:,:,:,jn) * cvol(:,:,:) )
198                  IF(lwp) WRITE(numout, '(a, i2, a, D23.16, a, D23.16)') 'trcrad ptrb, traceur ', jn  &
199                     &        , ' total mass : ', ztotmass, ', mass gain : ',  gainmass(jn,1)
200               END IF
201            END DO
202         ENDIF
203
204         DO jn = jp_sms0, jp_sms1
205            ztrneg(:,:,jn) = SUM( MIN( 0., ptrn(:,:,:,jn) ) * cvol(:,:,:), dim = 3 )   ! sum of the negative values
206            ztrpos(:,:,jn) = SUM( MAX( 0., ptrn(:,:,:,jn) ) * cvol(:,:,:), dim = 3 )   ! sum of the positive values
207         END DO
208         CALL sum3x3( ztrneg )
209         CALL sum3x3( ztrpos )
210         
211         DO jn = jp_sms0, jp_sms1
212            !
213            IF( l_trdtrc )   ztrtrd(:,:,:) = ptrn(:,:,:,jn)                            ! save input tr for trend computation
214            !
215            DO jk = 1, jpkm1
216               DO jj = 1, jpj
217                  DO ji = 1, jpi
218                     IF( ztrneg(ji,jj,jn) /= 0. ) THEN                                 ! if negative values over the 3x3 box
219                        !
220                        ptrn(ji,jj,jk,jn) = ptrn(ji,jj,jk,jn) * tmask(ji,jj,jk)   ! really needed?
221                        IF( ptrn(ji,jj,jk,jn) < 0. ) ptrn(ji,jj,jk,jn) = 0.       ! supress negative values
222                        IF( ptrn(ji,jj,jk,jn) > 0. ) THEN                         ! use positive values to compensate mass gain
223                           zcoef = 1. + ztrneg(ji,jj,jn) / ztrpos(ji,jj,jn)       ! ztrpos > 0 as ptrb > 0
224                           ptrn(ji,jj,jk,jn) = ptrn(ji,jj,jk,jn) * zcoef
225                           IF( zcoef < 0. ) THEN                                  ! if the compensation exceed the positive value
226                              gainmass(jn,2) = gainmass(jn,2) - ptrn(ji,jj,jk,jn) * cvol(ji,jj,jk)   ! we are adding mass...
227                              ptrn(ji,jj,jk,jn) = 0.                              ! limit the compensation to keep positive value
228                           ENDIF
229                        ENDIF
230                        !
231                     ENDIF
232                  END DO
233               END DO
234            END DO
235            !
236            IF( l_trdtrc ) THEN
237               ztrtrd(:,:,:) = ( ptrn(:,:,:,jn) - ztrtrd(:,:,:) ) * zs2rdt
238               CALL trd_tra( kt, Kmm, Krhs, 'TRC', jn, jptra_radn, ztrtrd )       ! standard     trend handling
239            ENDIF
240            !
241         END DO
242 
243         IF( kt == nitend ) THEN
244            CALL mpp_sum( 'trcrad', gainmass(:,2) )
245            DO jn = jp_sms0, jp_sms1
246               IF( gainmass(jn,2) > 0. ) THEN
247                  ztotmass = glob_sum( 'trcrad', ptrn(:,:,:,jn) * cvol(:,:,:) )
248                  WRITE(numout, '(a, i2, a, D23.16, a, D23.16)') 'trcrad ptrn, traceur ', jn  &
249                     &        , ' total mass : ', ztotmass, ', mass gain : ',  gainmass(jn,1)
250               END IF
251            END DO
252         ENDIF
253
254         DEALLOCATE( ztrneg, ztrpos )
255         !
256      ELSE                                !==  total CFC content is NOT strictly preserved  ==!
257         !
258         DO jn = jp_sms0, jp_sms1 
259            !
260            IF( l_trdtrc )   ztrtrd(:,:,:) = ptrb(:,:,:,jn)                        ! save input tr for trend computation
261            !
262            WHERE( ptrb(:,:,:,jn) < 0. )   ptrb(:,:,:,jn) = 0.
263            !
264            IF( l_trdtrc ) THEN
265               ztrtrd(:,:,:) = ( ptrb(:,:,:,jn) - ztrtrd(:,:,:) ) * zs2rdt
266               CALL trd_tra( kt, Kmm, Krhs, 'TRC', jn, jptra_radb, ztrtrd )       ! Asselin-like trend handling
267            ENDIF
268            !
269            IF( l_trdtrc )   ztrtrd(:,:,:) = ptrn(:,:,:,jn)                        ! save input tr for trend computation
270            !
271            WHERE( ptrn(:,:,:,jn) < 0. )   ptrn(:,:,:,jn) = 0.
272            !
273            IF( l_trdtrc ) THEN
274               ztrtrd(:,:,:) = ( ptrn(:,:,:,jn) - ztrtrd(:,:,:) ) * zs2rdt
275               CALL trd_tra( kt, Kmm, Krhs, 'TRC', jn, jptra_radn, ztrtrd )       ! standard     trend handling
276            ENDIF
277            !
278         END DO
279         !
280      ENDIF
281      !
282      IF( l_trdtrc )  DEALLOCATE( ztrtrd )
283      !
284   END SUBROUTINE trc_rad_sms
285
286#else
287   !!----------------------------------------------------------------------
288   !!   Dummy module :                                         NO TOP model
289   !!----------------------------------------------------------------------
290CONTAINS
291   SUBROUTINE trc_rad( kt, Kbb, Kmm, Krhs )              ! Empty routine
292      INTEGER, INTENT(in) ::   kt
293      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
294      WRITE(*,*) 'trc_rad: You should not have seen this print! error?', kt
295   END SUBROUTINE trc_rad
296#endif
297   
298   !!======================================================================
299END MODULE trcrad
Note: See TracBrowser for help on using the repository browser.