source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/trcbc.F90 @ 10963

Last change on this file since 10963 was 10963, checked in by acc, 19 months ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Convert TOP routines in top-level TOP directory and all knock on effects of these conversions. SETTE tested.

  • Property svn:keywords set to Id
File size: 23.4 KB
Line 
1MODULE trcbc
2   !!======================================================================
3   !!                     ***  MODULE  trcbc  ***
4   !! TOP :  module for passive tracer boundary conditions
5   !!=====================================================================
6   !! History :  3.5 !  2014 (M. Vichi, T. Lovato)  Original
7   !!            3.6 !  2015 (T . Lovato) Revision and BDY support
8   !!            4.0 !  2016 (T . Lovato) Include application of sbc and cbc
9   !!----------------------------------------------------------------------
10#if defined key_top
11   !!----------------------------------------------------------------------
12   !!   'key_top'                                                TOP model
13   !!----------------------------------------------------------------------
14   !!   trc_bc       :  Apply tracer Boundary Conditions
15   !!----------------------------------------------------------------------
16   USE par_trc       !  passive tracers parameters
17   USE oce_trc       !  shared variables between ocean and passive tracers
18   USE trc           !  passive tracers common variables
19   USE iom           !  I/O manager
20   USE lib_mpp       !  MPP library
21   USE fldread       !  read input fields
22   USE bdy_oce,  ONLY: ln_bdy, nb_bdy , idx_bdy, ln_coords_file, rn_time_dmp, rn_time_dmp_out
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   trc_bc         ! called in trcstp.F90 or within TOP modules
28   PUBLIC   trc_bc_ini     ! called in trcini.F90
29
30   INTEGER  , SAVE, PUBLIC                             :: nb_trcobc    ! number of tracers with open BC
31   INTEGER  , SAVE, PUBLIC                             :: nb_trcsbc    ! number of tracers with surface BC
32   INTEGER  , SAVE, PUBLIC                             :: nb_trccbc    ! number of tracers with coastal BC
33   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indobc ! index of tracer with OBC data
34   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indsbc ! index of tracer with SBC data
35   INTEGER  , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: n_trc_indcbc ! index of tracer with CBC data
36   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trsfac    ! multiplicative factor for SBC tracer values
37   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trcsbc    ! structure of data input SBC (file informations, fields read)
38   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trcfac    ! multiplicative factor for CBC tracer values
39   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trccbc    ! structure of data input CBC (file informations, fields read)
40   REAL(wp) , SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: rf_trofac    ! multiplicative factor for OBCtracer values
41#if defined key_agrif
42   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:)  :: sf_trcobc    ! structure of data input OBC (file informations, fields read)
43#else
44   TYPE(FLD), SAVE, PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET  :: sf_trcobc
45#endif
46   TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr   ! array of pointers to nbmap
47
48   !! * Substitutions
49#  include "vectopt_loop_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
52   !! $Id$
53   !! Software governed by the CeCILL license (see ./LICENSE)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE trc_bc_ini( ntrc, Kmm )
58      !!----------------------------------------------------------------------
59      !!                   ***  ROUTINE trc_bc_ini  ***
60      !!                   
61      !! ** Purpose :   initialisation of passive tracer BC data
62      !!
63      !! ** Method  : - Read namtsd namelist
64      !!              - allocates passive tracer BC data structure
65      !!----------------------------------------------------------------------
66      INTEGER, INTENT(in) :: ntrc                          ! number of tracers
67      INTEGER, INTENT(in) ::   Kmm                         ! time level index
68      !
69      INTEGER            :: jl, jn , ib, ibd, ii, ij, ik   ! dummy loop indices
70      INTEGER            :: ierr0, ierr1, ierr2, ierr3     ! temporary integers
71      INTEGER            :: ios                            ! Local integer output status for namelist read
72      INTEGER            :: nblen, igrd                    ! support arrays for BDY
73      CHARACTER(len=100) :: clndta, clntrc
74      !
75      CHARACTER(len=100) :: cn_dir_sbc, cn_dir_cbc, cn_dir_obc
76      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_i  ! local array of namelist informations on the fields to read
77      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trcobc    ! open
78      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trcsbc    ! surface
79      TYPE(FLD_N), DIMENSION(jpmaxtrc) :: sn_trccbc    ! coastal
80      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trofac    ! multiplicative factor for tracer values
81      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trsfac    ! multiplicative factor for tracer values
82      REAL(wp)   , DIMENSION(jpmaxtrc) :: rn_trcfac    ! multiplicative factor for tracer values
83      !!
84      NAMELIST/namtrc_bc/ cn_dir_obc, sn_trcobc, rn_trofac, cn_dir_sbc, sn_trcsbc, rn_trsfac, & 
85                        & cn_dir_cbc, sn_trccbc, rn_trcfac, ln_rnf_ctl, rn_bc_time
86      NAMELIST/namtrc_bdy/ cn_trc_dflt, cn_trc, nn_trcdmp_bdy
87      !!----------------------------------------------------------------------
88      !
89      IF( lwp ) THEN
90         WRITE(numout,*)
91         WRITE(numout,*) 'trc_bc_ini : Tracers Boundary Conditions (BC)'
92         WRITE(numout,*) '~~~~~~~~~~~ '
93      ENDIF
94      !  Initialisation and local array allocation
95      ierr0 = 0   ;   ierr1 = 0   ;   ierr2 = 0   ;   ierr3 = 0 
96      ALLOCATE( slf_i(ntrc), STAT=ierr0 )
97      IF( ierr0 > 0 ) THEN
98         CALL ctl_stop( 'trc_bc_ini: unable to allocate local slf_i' )   ;   RETURN
99      ENDIF
100
101      ! Compute the number of tracers to be initialised with open, surface and boundary data
102      ALLOCATE( n_trc_indobc(ntrc), STAT=ierr0 )
103      IF( ierr0 > 0 ) THEN
104         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indobc' )   ;   RETURN
105      ENDIF
106      nb_trcobc       = 0
107      n_trc_indobc(:) = 0
108      !
109      ALLOCATE( n_trc_indsbc(ntrc), STAT=ierr0 )
110      IF( ierr0 > 0 ) THEN
111         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indsbc' )   ;   RETURN
112      ENDIF
113      nb_trcsbc       = 0
114      n_trc_indsbc(:) = 0
115      !
116      ALLOCATE( n_trc_indcbc(ntrc), STAT=ierr0 )
117      IF( ierr0 > 0 ) THEN
118         CALL ctl_stop( 'trc_bc_ini: unable to allocate n_trc_indcbc' )   ;   RETURN
119      ENDIF
120      nb_trccbc       = 0
121      n_trc_indcbc(:) = 0
122      !
123      ! Read Boundary Conditions Namelists
124      REWIND( numnat_ref )              ! Namelist namtrc_bc in reference namelist : Passive tracer data structure
125      READ  ( numnat_ref, namtrc_bc, IOSTAT = ios, ERR = 901)
126901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_bc in reference namelist', lwp )
127      REWIND( numnat_cfg )              ! Namelist namtrc_bc in configuration namelist : Passive tracer data structure
128      READ  ( numnat_cfg, namtrc_bc, IOSTAT = ios, ERR = 902 )
129902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_bc in configuration namelist', lwp )
130      IF(lwm) WRITE ( numont, namtrc_bc )
131
132      IF ( ln_bdy ) THEN
133         REWIND( numnat_ref )              ! Namelist namtrc_bdy in reference namelist : Passive tracer data structure
134         READ  ( numnat_ref, namtrc_bdy, IOSTAT = ios, ERR = 903)
135903      IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_bdy in reference namelist', lwp )
136
137         REWIND( numnat_cfg )              ! Namelist namtrc_bdy in configuration namelist : Passive tracer data structure
138         READ  ( numnat_cfg, namtrc_bdy, IOSTAT = ios, ERR = 904 )
139904      IF( ios >  0 )   CALL ctl_nam ( ios , 'namtrc_bdy in configuration namelist', lwp )
140         IF(lwm) WRITE ( numont, namtrc_bdy )
141     
142         ! setup up preliminary informations for BDY structure
143         DO jn = 1, ntrc
144            DO ib = 1, nb_bdy
145               ! Set type of obc in BDY data structure (around here we may plug user override of obc type from nml)
146               IF ( ln_trc_obc(jn) ) THEN   ;   trcdta_bdy(jn,ib)%cn_obc = TRIM( cn_trc     (ib) )
147               ELSE                         ;   trcdta_bdy(jn,ib)%cn_obc = TRIM( cn_trc_dflt(ib) )
148               ENDIF
149               ! set damping use in BDY data structure
150               trcdta_bdy(jn,ib)%dmp = .false.
151               IF(nn_trcdmp_bdy(ib) == 1 .AND. ln_trc_obc(jn) )   trcdta_bdy(jn,ib)%dmp = .true.
152               IF(nn_trcdmp_bdy(ib) == 2                      )   trcdta_bdy(jn,ib)%dmp = .true.
153               IF(trcdta_bdy(jn,ib)%cn_obc == 'frs' .AND. nn_trcdmp_bdy(ib) /= 0 )  &
154                   & CALL ctl_stop( 'trc_bc_ini: Use FRS OR relaxation' )
155               IF(  .NOT.( 0 < nn_trcdmp_bdy(ib)  .AND.  nn_trcdmp_bdy(ib) <= 2 )  )   &
156                   & CALL ctl_stop( 'trc_bc_ini: Not a valid option for nn_trcdmp_bdy. Allowed: 0,1,2.' )
157            END DO
158         END DO
159      ELSE
160         ! Force all tracers OBC to false if bdy not used
161         ln_trc_obc = .false.
162      ENDIF
163
164      ! compose BC data indexes
165      DO jn = 1, ntrc
166         IF( ln_trc_obc(jn) ) THEN
167             nb_trcobc       = nb_trcobc + 1   ;   n_trc_indobc(jn) = nb_trcobc
168         ENDIF
169         IF( ln_trc_sbc(jn) ) THEN
170             nb_trcsbc       = nb_trcsbc + 1   ;   n_trc_indsbc(jn) = nb_trcsbc
171         ENDIF
172         IF( ln_trc_cbc(jn) ) THEN
173             nb_trccbc       = nb_trccbc + 1   ;   n_trc_indcbc(jn) = nb_trccbc
174         ENDIF
175      END DO
176
177      ! Print summmary of Boundary Conditions
178      IF( lwp ) THEN
179         WRITE(numout,*)
180         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with SURFACE BCs data:', nb_trcsbc
181         IF ( nb_trcsbc > 0 ) THEN
182            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact. '
183            DO jn = 1, ntrc
184               IF ( ln_trc_sbc(jn) ) WRITE(numout,9001) jn, TRIM( sn_trcsbc(jn)%clvar ), 'SBC', rn_trsfac(jn)
185            END DO
186         ENDIF
187         WRITE(numout,'(2a)') '   SURFACE BC data repository : ', TRIM(cn_dir_sbc)
188         !
189         WRITE(numout,*)
190         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with COASTAL BCs data:', nb_trccbc
191         IF( nb_trccbc > 0 ) THEN
192            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact. '
193            DO jn = 1, ntrc
194               IF ( ln_trc_cbc(jn) ) WRITE(numout, 9001) jn, TRIM( sn_trccbc(jn)%clvar ), 'CBC', rn_trcfac(jn)
195            END DO
196         ENDIF
197         WRITE(numout,'(2a)') '   COASTAL BC data repository : ', TRIM(cn_dir_cbc)
198         IF( .NOT.ln_rnf .OR. .NOT.ln_linssh )   ln_rnf_ctl = .FALSE.
199         IF( ln_rnf_ctl )  WRITE(numout,'(a)') &
200              &            ' -> Remove runoff dilution effect on tracers with absent river load (ln_rnf_ctl = .TRUE.)'
201         WRITE(numout,*)
202         WRITE(numout,'(a,i3)') '   Total tracers to be initialized with OPEN BCs data:', nb_trcobc
203
204         IF( ln_bdy .AND. nb_trcobc > 0 ) THEN
205            WRITE(numout,*) '   #trc        NAME        Boundary     Mult.Fact.   OBC Settings'
206            DO jn = 1, ntrc
207               IF (       ln_trc_obc(jn) )  WRITE(numout, 9001) jn, TRIM( sn_trcobc(jn)%clvar ), 'OBC', rn_trofac(jn), &
208                    &                                           (trcdta_bdy(jn,ib)%cn_obc,ib=1,nb_bdy)
209               IF ( .NOT. ln_trc_obc(jn) )  WRITE(numout, 9002) jn, 'Set data to IC and use default condition'       , &
210                    &                                           (trcdta_bdy(jn,ib)%cn_obc,ib=1,nb_bdy)
211            END DO
212            WRITE(numout,*) ' '
213            DO ib = 1, nb_bdy
214               IF(nn_trcdmp_bdy(ib) == 0) WRITE(numout,9003) '   Boundary ', ib, &
215                  &                                          ' -> NO damping of tracers'
216               IF(nn_trcdmp_bdy(ib) == 1) WRITE(numout,9003) '   Boundary ', ib, &
217                  &                                          ' -> damping ONLY for tracers with external data provided'
218               IF(nn_trcdmp_bdy(ib) == 2) WRITE(numout,9003) '   Boundary ', ib, &
219                  &                                          ' -> damping of ALL tracers'
220               IF(nn_trcdmp_bdy(ib) >  0) THEN
221                   WRITE(numout,9003) '     USE damping parameters from nambdy for boundary ', ib,' : '
222                   WRITE(numout,'(a,f10.2,a)') '     - Inflow damping time scale  : ',rn_time_dmp    (ib),' days'
223                   WRITE(numout,'(a,f10.2,a)') '     - Outflow damping time scale : ',rn_time_dmp_out(ib),' days'
224               ENDIF
225            END DO
226         ENDIF
227         !
228         WRITE(numout,'(2a)') '   OPEN BC data repository : ', TRIM(cn_dir_obc)
229      ENDIF
2309001  FORMAT(2x,i5, 3x, a15, 3x, a5, 6x, e11.3, 4x, 10a13)
2319002  FORMAT(2x,i5, 3x, a41, 3x, 10a13)
2329003  FORMAT(a, i5, a)
233      !
234      !
235      ! OPEN Lateral boundary conditions
236      IF( ln_bdy .AND. nb_trcobc > 0 ) THEN
237         ALLOCATE ( sf_trcobc(nb_trcobc), rf_trofac(nb_trcobc), nbmap_ptr(nb_trcobc), STAT=ierr1 )
238         IF( ierr1 > 0 ) THEN
239            CALL ctl_stop( 'trc_bc_ini: unable to allocate sf_trcobc structure' )   ;   RETURN
240         ENDIF
241         !
242         igrd = 1                       ! Everything is at T-points here
243         !
244         DO jn = 1, ntrc
245            DO ib = 1, nb_bdy
246               !
247               nblen = idx_bdy(ib)%nblen(igrd)
248               !
249               IF( ln_trc_obc(jn) ) THEN     !* Initialise from external data *!
250                  jl = n_trc_indobc(jn)
251                  slf_i(jl)    = sn_trcobc(jn)
252                  rf_trofac(jl) = rn_trofac(jn)
253                                                ALLOCATE( sf_trcobc(jl)%fnow(nblen,1,jpk)   , STAT=ierr2 )
254                  IF( sn_trcobc(jn)%ln_tint )   ALLOCATE( sf_trcobc(jl)%fdta(nblen,1,jpk,2) , STAT=ierr3 )
255                  IF( ierr2 + ierr3 > 0 ) THEN
256                    CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer OBC data arrays' )   ;   RETURN
257                  ENDIF
258                  trcdta_bdy(jn,ib)%trc => sf_trcobc(jl)%fnow(:,1,:)
259                  trcdta_bdy(jn,ib)%rn_fac = rf_trofac(jl)
260                  ! create OBC mapping array
261                  nbmap_ptr(jl)%ptr => idx_bdy(ib)%nbmap(:,igrd)
262                  nbmap_ptr(jl)%ll_unstruc = ln_coords_file(igrd)
263                  !
264               ELSE                          !* Initialise obc arrays from initial conditions *!
265                  ALLOCATE ( trcdta_bdy(jn,ib)%trc(nblen,jpk) )
266                  DO ibd = 1, nblen
267                     DO ik = 1, jpkm1
268                        ii = idx_bdy(ib)%nbi(ibd,igrd)
269                        ij = idx_bdy(ib)%nbj(ibd,igrd)
270                        trcdta_bdy(jn,ib)%trc(ibd,ik) = tr(ii,ij,ik,jn,Kmm) * tmask(ii,ij,ik)
271                     END DO
272                  END DO
273                  trcdta_bdy(jn,ib)%rn_fac = 1._wp
274               ENDIF
275            END DO
276         END DO
277         !
278         CALL fld_fill( sf_trcobc, slf_i, cn_dir_obc, 'trc_bc_ini', 'Passive tracer OBC data', 'namtrc_bc' )
279      ENDIF
280
281      ! SURFACE Boundary conditions
282      IF( nb_trcsbc > 0 ) THEN       !  allocate only if the number of tracer to initialise is greater than zero
283         ALLOCATE( sf_trcsbc(nb_trcsbc), rf_trsfac(nb_trcsbc), STAT=ierr1 )
284         IF( ierr1 > 0 ) THEN
285            CALL ctl_stop( 'trc_bc_ini: unable to allocate  sf_trcsbc structure' )   ;   RETURN
286         ENDIF
287         !
288         DO jn = 1, ntrc
289            IF( ln_trc_sbc(jn) ) THEN      ! update passive tracers arrays with input data read from file
290               jl = n_trc_indsbc(jn)
291               slf_i(jl)    = sn_trcsbc(jn)
292               rf_trsfac(jl) = rn_trsfac(jn)
293                                            ALLOCATE( sf_trcsbc(jl)%fnow(jpi,jpj,1)   , STAT=ierr2 )
294               IF( sn_trcsbc(jn)%ln_tint )  ALLOCATE( sf_trcsbc(jl)%fdta(jpi,jpj,1,2) , STAT=ierr3 )
295               IF( ierr2 + ierr3 > 0 ) THEN
296                 CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer SBC data arrays' )   ;   RETURN
297               ENDIF
298            ENDIF
299            !   
300         END DO
301         !                         ! fill sf_trcsbc with slf_i and control print
302         CALL fld_fill( sf_trcsbc, slf_i, cn_dir_sbc, 'trc_bc_ini', 'Passive tracer SBC data', 'namtrc_bc' )
303         !
304      ENDIF
305      !
306      ! COSTAL Boundary conditions
307      IF( nb_trccbc > 0 ) THEN       !  allocate only if the number of tracer to initialise is greater than zero
308         ALLOCATE( sf_trccbc(nb_trccbc), rf_trcfac(nb_trccbc), STAT=ierr1 )
309         IF( ierr1 > 0 ) THEN
310            CALL ctl_stop( 'trc_bc_ini: unable to allocate  sf_trccbc structure' )   ;   RETURN
311         ENDIF
312         !
313         DO jn = 1, ntrc
314            IF( ln_trc_cbc(jn) ) THEN      ! update passive tracers arrays with input data read from file
315               jl = n_trc_indcbc(jn)
316               slf_i(jl)    = sn_trccbc(jn)
317               rf_trcfac(jl) = rn_trcfac(jn)
318                                            ALLOCATE( sf_trccbc(jl)%fnow(jpi,jpj,1)   , STAT=ierr2 )
319               IF( sn_trccbc(jn)%ln_tint )  ALLOCATE( sf_trccbc(jl)%fdta(jpi,jpj,1,2) , STAT=ierr3 )
320               IF( ierr2 + ierr3 > 0 ) THEN
321                 CALL ctl_stop( 'trc_bc_ini : unable to allocate passive tracer CBC data arrays' )   ;   RETURN
322               ENDIF
323            ENDIF
324            !   
325         END DO
326         !                         ! fill sf_trccbc with slf_i and control print
327         CALL fld_fill( sf_trccbc, slf_i, cn_dir_cbc, 'trc_bc_ini', 'Passive tracer CBC data', 'namtrc_bc' )
328         !
329      ENDIF
330      !
331      DEALLOCATE( slf_i )          ! deallocate local field structure
332      !
333   END SUBROUTINE trc_bc_ini
334
335
336   SUBROUTINE trc_bc(kt, Kmm, Krhs, jit)
337      !!----------------------------------------------------------------------
338      !!                   ***  ROUTINE trc_bc  ***
339      !!
340      !! ** Purpose :  Apply Boundary Conditions data to tracers
341      !!
342      !! ** Method  :  1) Read BC inputs and update data structures using fldread
343      !!               2) Apply Boundary Conditions to tracers
344      !!----------------------------------------------------------------------
345      USE fldread
346      !!     
347      INTEGER, INTENT(in)           ::   kt        ! ocean time-step index
348      INTEGER, INTENT(in)           ::   Kmm, Krhs ! time level indices
349      INTEGER, INTENT(in), OPTIONAL ::   jit       ! subcycle time-step index (for timesplitting option)
350      !!
351      INTEGER  :: ji, jj, jk, jn, jl             ! Loop index
352      REAL(wp) :: zfact, zrnf
353      !!---------------------------------------------------------------------
354      !
355      IF( ln_timing )   CALL timing_start('trc_bc')
356
357      IF( kt == nit000 .AND. lwp) THEN
358         WRITE(numout,*)
359         WRITE(numout,*) 'trc_bc : Surface boundary conditions for passive tracers.'
360         WRITE(numout,*) '~~~~~~~ '
361      ENDIF
362
363      ! 1. Update Boundary conditions data
364      IF( PRESENT(jit) ) THEN 
365         !
366         ! OPEN boundary conditions (use time_offset=+1 as they are applied at the end of the step)
367         IF( nb_trcobc > 0 ) THEN
368           if (lwp) write(numout,'(a,i5,a,i10)') '   reading OBC data for ', nb_trcobc ,' variable(s) at step ', kt
369           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcobc, map=nbmap_ptr, kit=jit, kt_offset=+1)
370         ENDIF
371         !
372         ! SURFACE boundary conditions
373         IF( nb_trcsbc > 0 ) THEN
374           if (lwp) write(numout,'(a,i5,a,i10)') '   reading SBC data for ', nb_trcsbc ,' variable(s) at step ', kt
375           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcsbc, kit=jit)
376         ENDIF
377         !
378         ! COASTAL boundary conditions
379         IF( nb_trccbc > 0 ) THEN
380           if (lwp) write(numout,'(a,i5,a,i10)') '   reading CBC data for ', nb_trccbc ,' variable(s) at step ', kt
381           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trccbc, kit=jit)
382         ENDIF
383         !
384      ELSE
385         !
386         ! OPEN boundary conditions (use time_offset=+1 as they are applied at the end of the step)
387         IF( nb_trcobc > 0 ) THEN
388           if (lwp) write(numout,'(a,i5,a,i10)') '   reading OBC data for ', nb_trcobc ,' variable(s) at step ', kt
389           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcobc, map=nbmap_ptr, kt_offset=+1)
390         ENDIF
391         !
392         ! SURFACE boundary conditions
393         IF( nb_trcsbc > 0 ) THEN
394           if (lwp) write(numout,'(a,i5,a,i10)') '   reading SBC data for ', nb_trcsbc ,' variable(s) at step ', kt
395           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trcsbc )
396         ENDIF
397         !
398         ! COASTAL boundary conditions
399         IF( nb_trccbc > 0 ) THEN
400           if (lwp) write(numout,'(a,i5,a,i10)') '   reading CBC data for ', nb_trccbc ,' variable(s) at step ', kt
401           CALL fld_read( kt=kt, kn_fsbc=1, sd=sf_trccbc )
402         ENDIF
403         !
404      ENDIF
405
406      ! 2. Apply Boundary conditions data
407      !
408      DO jn = 1 , jptra
409         !
410         ! Remove river dilution for tracers with absent river load
411         IF( ln_rnf_ctl .AND. .NOT.ln_trc_cbc(jn) ) THEN
412            DO jj = 2, jpj
413               DO ji = fs_2, fs_jpim1
414                  DO jk = 1, nk_rnf(ji,jj)
415                     zrnf = (rnf(ji,jj) + rnf_b(ji,jj)) * 0.5_wp * r1_rau0 / h_rnf(ji,jj)
416                     tr(ji,jj,jk,jn,Krhs) = tr(ji,jj,jk,jn,Krhs)  + (tr(ji,jj,jk,jn,Kmm) * zrnf)
417                  END DO
418               END DO
419            END DO
420         ENDIF
421         !
422         ! OPEN boundary conditions: trcbdy is called in trcnxt !
423         !
424         ! SURFACE boundary conditions
425         IF( ln_trc_sbc(jn) ) THEN
426            jl = n_trc_indsbc(jn)
427            DO jj = 2, jpj
428               DO ji = fs_2, fs_jpim1   ! vector opt.
429                  zfact = 1. / ( e3t(ji,jj,1,Kmm) * rn_bc_time )
430                  tr(ji,jj,1,jn,Krhs) = tr(ji,jj,1,jn,Krhs) + rf_trsfac(jl) * sf_trcsbc(jl)%fnow(ji,jj,1) * zfact
431               END DO
432            END DO
433         ENDIF
434         !
435         ! COASTAL boundary conditions
436         IF( ln_rnf .AND. ln_trc_cbc(jn) ) THEN
437            jl = n_trc_indcbc(jn)
438            DO jj = 2, jpj
439               DO ji = fs_2, fs_jpim1   ! vector opt.
440                  DO jk = 1, nk_rnf(ji,jj)
441                     zfact = rn_rfact / ( e1e2t(ji,jj) * h_rnf(ji,jj) * rn_bc_time ) 
442                     tr(ji,jj,jk,jn,Krhs) = tr(ji,jj,jk,jn,Krhs) + rf_trcfac(jl) * sf_trccbc(jl)%fnow(ji,jj,1) * zfact
443                  END DO
444               END DO
445            END DO
446         ENDIF
447         !                                                       ! ===========
448      END DO                                                     ! tracer loop
449      !                                                          ! ===========
450      IF( ln_timing )   CALL timing_stop('trc_bc')
451      !
452   END SUBROUTINE trc_bc
453
454#else
455   !!----------------------------------------------------------------------
456   !!   Dummy module                              NO 3D passive tracer data
457   !!----------------------------------------------------------------------
458CONTAINS
459   SUBROUTINE trc_bc_ini( ntrc, Kmm )        ! Empty routine
460      INTEGER, INTENT(IN) :: ntrc                           ! number of tracers
461      INTEGER, INTENT(in) :: Kmm                            ! time level index
462      WRITE(*,*) 'trc_bc_ini: You should not have seen this print! error?', kt
463   END SUBROUTINE trc_bc_ini
464   SUBROUTINE trc_bc( kt, Kmm, Krhs )        ! Empty routine
465      INTEGER, INTENT(in) :: Kmm, Krhs ! time level indices
466      WRITE(*,*) 'trc_bc: You should not have seen this print! error?', kt
467   END SUBROUTINE trc_bc
468#endif
469
470   !!======================================================================
471END MODULE trcbc
Note: See TracBrowser for help on using the repository browser.